docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.6.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # Prepare directories for pdf/tex output
  76 set(TEX_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/manual")
  77 set(SPHINX_LATEX_FILE "${TEX_OUTPUT_DIR}/gromacs.tex")
  78 file(MAKE_DIRECTORY ${TEX_OUTPUT_DIR})
  79
  80 # The directory from which man pages will be installed; if it remains
  81 # empty, they will be silently skipped.
  82 set(MAN_PAGE_DIR)
  83 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  84     # When building from the tarball, install the bundled man pages
  85     # (unless overridden).
  86     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  87 endif()
  88
  89 add_subdirectory(doxygen)
  90 if (SPHINX_FOUND)
  91     # We need to have all the Sphinx input files in a single directory, and
  92     # since some of them are generated, we copy everything into the build tree,
  93     # to this directory.
  94     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  95     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  96     # As the manual build now depends also on Sphinx, the inclusion path needs
  97     # to be set after we know the basic information for Sphinx.
  98     add_subdirectory(manual)
  99     if (SOURCE_MD5SUM STREQUAL "unknown")
 100         # But for testing the webpage build (e.g. from the repo) we
 101         # need a default value.
 102         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 103     else()
 104         # The real build of the webpage happens from the tarball, and
 105         # this should be set to the matching MD5 sum.
 106         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 107     endif()
 108     # The reference manual still contains the individual sections from the
 109     # LaTeX document, with the files below grouped and annotated by chapter.
 110     set(REFERENCEMANUAL_SPHINX_FILES
 111         # Main index file, preface and introduction.
 112         reference-manual/index.rst
 113         reference-manual/preface.rst
 114         reference-manual/introduction.rst
 115         # Definitions and Units chapter
 116         reference-manual/definitions.rst
 117         # Algorithms chapter
 118         reference-manual/algorithms.rst
 119         reference-manual/algorithms/periodic-boundary-conditions.rst
 120         reference-manual/algorithms/group-concept.rst
 121         reference-manual/algorithms/molecular-dynamics.rst
 122         reference-manual/algorithms/shell-molecular-dynamics.rst
 123         reference-manual/algorithms/constraint-algorithms.rst
 124         reference-manual/algorithms/simulated-annealing.rst
 125         reference-manual/algorithms/stochastic-dynamics.rst
 126         reference-manual/algorithms/brownian-dynamics.rst
 127         reference-manual/algorithms/energy-minimization.rst
 128         reference-manual/algorithms/normal-mode-analysis.rst
 129         reference-manual/algorithms/free-energy-calculations.rst
 130         reference-manual/algorithms/replica-exchange.rst
 131         reference-manual/algorithms/essential-dynamics.rst
 132         reference-manual/algorithms/expanded-ensemble.rst
 133         reference-manual/algorithms/parallelization-domain-decomp.rst
 134         # Interaction functions and force fields chapter
 135         reference-manual/functions.rst
 136         reference-manual/functions/bonded-interactions.rst
 137         reference-manual/functions/force-field.rst
 138         reference-manual/functions/free-energy-interactions.rst
 139         reference-manual/functions/interaction-methods.rst
 140         reference-manual/functions/long-range-electrostatics.rst
 141         reference-manual/functions/long-range-vdw.rst
 142         reference-manual/functions/nonbonded-interactions.rst
 143         reference-manual/functions/polarization.rst
 144         reference-manual/functions/restraints.rst
 145         # Topologies chapter
 146         reference-manual/topologies.rst
 147         reference-manual/topologies/particle-type.rst
 148         reference-manual/topologies/parameter-files.rst
 149         reference-manual/topologies/molecule-definition.rst
 150         reference-manual/topologies/constraint-algorithm-section.rst
 151         reference-manual/topologies/pdb2gmx-input-files.rst
 152         reference-manual/topologies/topology-file-formats.rst
 153         reference-manual/topologies/force-field-organization.rst
 154         # File formats chapter
 155         reference-manual/file-formats.rst
 156         # Special topics chapter
 157         reference-manual/special.rst
 158         reference-manual/special/free-energy-implementation.rst
 159         reference-manual/special/pulling.rst
 160         reference-manual/special/awh.rst
 161         reference-manual/special/enforced-rotation.rst
 162         reference-manual/special/electric-fields.rst
 163         reference-manual/special/comp-electrophys.rst
 164         reference-manual/special/free-energy-pmf.rst
 165         reference-manual/special/remove-fast-dgf.rst
 166         reference-manual/special/viscosity-calculation.rst
 167         reference-manual/special/tabulated-interaction-functions.rst
 168         reference-manual/special/qmmm.rst
 169         reference-manual/special/vmd-imd.rst
 170         reference-manual/special/membrane-embedding.rst
 171         # Run parameters and programs chapter
 172         reference-manual/run-parameters.rst
 173         # Analysis chapter
 174         reference-manual/analysis.rst
 175         reference-manual/analysis/using-groups.rst
 176         reference-manual/analysis/looking-at-trajectory.rst
 177         reference-manual/analysis/general-properties.rst
 178         reference-manual/analysis/radial-distribution-function.rst
 179         reference-manual/analysis/correlation-function.rst
 180         reference-manual/analysis/curve-fitting.rst
 181         reference-manual/analysis/mean-square-displacement.rst
 182         reference-manual/analysis/bond-angle-dihedral.rst
 183         reference-manual/analysis/radius-of-gyration.rst
 184         reference-manual/analysis/rmsd.rst
 185         reference-manual/analysis/covariance-analysis.rst
 186         reference-manual/analysis/dihedral-pca.rst
 187         reference-manual/analysis/protein-related.rst
 188         reference-manual/analysis/interface-related.rst
 189         # Implementation details chapter
 190         reference-manual/details.rst
 191         # Averages and fluctations chapter
 192         reference-manual/averages.rst
 193         # References
 194         reference-manual/references.rst
 195         # PNG formated plot files that don't need to be converted into PNG
 196         # for the web page.
 197         reference-manual/plots/peregrine.png
 198         reference-manual/plots/adress.png
 199         reference-manual/plots/plotje.png
 200         reference-manual/plots/xvgr.png
 201         )
 202     # The image files have also been ordered by the respective
 203     # chapter they are included in in the reference manual
 204     set(REFERENCEMANUAL_IMAGE_FILES
 205         # General folder
 206         reference-manual/plots/decomp.pdf
 207         reference-manual/plots/dih.pdf
 208         reference-manual/plots/drift-all.pdf
 209         reference-manual/plots/f-angle.pdf
 210         reference-manual/plots/f-bond.pdf
 211         reference-manual/plots/fp-highres.pdf
 212         reference-manual/plots/int-mat.pdf
 213         reference-manual/plots/mdpar.pdf
 214         reference-manual/plots/parsort.pdf
 215         reference-manual/plots/ring.pdf
 216         reference-manual/plots/shiftf.pdf
 217         # Algorithms chapter
 218         reference-manual/algorithms/plots/dd-cells.pdf
 219         reference-manual/algorithms/plots/dd-tric.pdf
 220         reference-manual/algorithms/plots/flowchart.pdf
 221         reference-manual/algorithms/plots/free1.pdf
 222         reference-manual/algorithms/plots/free2.pdf
 223         reference-manual/algorithms/plots/leapfrog.pdf
 224         reference-manual/algorithms/plots/lincs.pdf
 225         reference-manual/algorithms/plots/maxwell.pdf
 226         reference-manual/algorithms/plots/mpmd-pme.pdf
 227         reference-manual/algorithms/plots/nstric.pdf
 228         reference-manual/algorithms/plots/par-lincs2.pdf
 229         reference-manual/algorithms/plots/pbctric.pdf
 230         reference-manual/algorithms/plots/rhododec.pdf
 231         reference-manual/algorithms/plots/truncoct.pdf
 232         reference-manual/algorithms/plots/verlet-drift.pdf
 233         # Interaction functions chapter
 234         reference-manual/functions/plots/angle.pdf
 235         reference-manual/functions/plots/bstretch.pdf
 236         reference-manual/functions/plots/chain.pdf
 237         reference-manual/functions/plots/dummies.pdf
 238         reference-manual/functions/plots/f-bham.pdf
 239         reference-manual/functions/plots/fbposres.pdf
 240         reference-manual/functions/plots/f-dih.pdf
 241         reference-manual/functions/plots/f-dr.pdf
 242         reference-manual/functions/plots/fig-02.pdf
 243         reference-manual/functions/plots/fig-04.pdf
 244         reference-manual/functions/plots/f-imps.pdf
 245         reference-manual/functions/plots/f-lj.pdf
 246         reference-manual/functions/plots/f-morse.pdf
 247         reference-manual/functions/plots/f-pr.pdf
 248         reference-manual/functions/plots/f-rbs.pdf
 249         reference-manual/functions/plots/ring-imp.pdf
 250         reference-manual/functions/plots/softcore.pdf
 251         reference-manual/functions/plots/subst-im.pdf
 252         reference-manual/functions/plots/tetra-im.pdf
 253         reference-manual/functions/plots/vcrf.pdf
 254         reference-manual/functions/plots/vsite-4fdn.pdf
 255         # Special topics chapter
 256         reference-manual/special/plots/awh-invN.pdf
 257         reference-manual/special/plots/awh-pmfs.pdf
 258         reference-manual/special/plots/awh-sampleweights.pdf
 259         reference-manual/special/plots/awh-traj.pdf
 260         reference-manual/special/plots/compelsetup.pdf
 261         reference-manual/special/plots/dumaro.pdf
 262         reference-manual/special/plots/dumtypes.pdf
 263         reference-manual/special/plots/equipotential.pdf
 264         reference-manual/special/plots/field.pdf
 265         reference-manual/special/plots/gaussians.pdf
 266         reference-manual/special/plots/pulldirrel.pdf
 267         reference-manual/special/plots/pull.pdf
 268         reference-manual/special/plots/pullref.pdf
 269         reference-manual/special/plots/rotation.pdf
 270         # Analysis chapter
 271         reference-manual/analysis/plots/dih-def.pdf
 272         reference-manual/analysis/plots/distm.pdf
 273         reference-manual/analysis/plots/dssp.pdf
 274         reference-manual/analysis/plots/hbond-insert.pdf
 275         reference-manual/analysis/plots/hbond.pdf
 276         reference-manual/analysis/plots/hpr-wheel.pdf
 277         reference-manual/analysis/plots/msdwater.pdf
 278         reference-manual/analysis/plots/ngmxdump.pdf
 279         reference-manual/analysis/plots/phipsi.pdf
 280         reference-manual/analysis/plots/rama.pdf
 281         reference-manual/analysis/plots/rdfO-O.pdf
 282         reference-manual/analysis/plots/rdf.pdf
 283         reference-manual/analysis/plots/sgangle.pdf
 284         )
 285     set(SPHINX_SOURCE_FILES
 286         index.rst
 287         download.rst
 288         conf.py
 289         links.dat
 290         dev-manual/build-system.rst
 291         dev-manual/commitstyle.rst
 292         dev-manual/documentation-generation.rst
 293         dev-manual/contribute.rst
 294         dev-manual/doxygen.rst
 295         dev-manual/error-handling.rst
 296         dev-manual/formatting.rst
 297         dev-manual/gmxtree.rst
 298         dev-manual/includestyle.rst
 299         dev-manual/index.rst
 300         dev-manual/jenkins.rst
 301         dev-manual/language-features.rst
 302         dev-manual/naming.rst
 303         dev-manual/overview.rst
 304         dev-manual/redmine-states.png
 305         dev-manual/relocatable-binaries.rst
 306         dev-manual/reportstyle.rst
 307         dev-manual/style.rst
 308         dev-manual/testutils.rst
 309         dev-manual/tools.rst
 310         dev-manual/uncrustify.rst
 311         fragments/doxygen-links.rst
 312         install-guide/index.rst
 313         release-notes/index.rst
 314         release-notes/highlights.rst
 315         release-notes/features.rst
 316         release-notes/performance.rst
 317         release-notes/tools.rst
 318         release-notes/bugs-fixed.rst
 319         release-notes/removed-features.rst
 320         release-notes/portability.rst
 321         release-notes/miscellaneous.rst
 322         release-notes/2018/2018.3.rst
 323         release-notes/2018/2018.2.rst
 324         release-notes/2018/2018.1.rst
 325         release-notes/2018/major/highlights.rst
 326         release-notes/2018/major/features.rst
 327         release-notes/2018/major/performance.rst
 328         release-notes/2018/major/tools.rst
 329         release-notes/2018/major/bugs-fixed.rst
 330         release-notes/2018/major/removed-features.rst
 331         release-notes/2018/major/portability.rst
 332         release-notes/2018/major/miscellaneous.rst
 333         release-notes/2016/2016.5.rst
 334         release-notes/2016/2016.4.rst
 335         release-notes/2016/2016.3.rst
 336         release-notes/2016/2016.2.rst
 337         release-notes/2016/2016.1.rst
 338         release-notes/2016/major/highlights.rst
 339         release-notes/2016/major/new-features.rst
 340         release-notes/2016/major/performance.rst
 341         release-notes/2016/major/tools.rst
 342         release-notes/2016/major/bugs-fixed.rst
 343         release-notes/2016/major/removed-features.rst
 344         release-notes/2016/major/miscellaneous.rst
 345         release-notes/older/index.rst
 346         user-guide/index.rst
 347         user-guide/cmdline.rst
 348         user-guide/cutoff-schemes.rst
 349         user-guide/environment-variables.rst
 350         user-guide/faq.rst
 351         user-guide/floating-point.rst
 352         user-guide/system-preparation.rst
 353         user-guide/force-fields.rst
 354         user-guide/getting-started.rst
 355         user-guide/managing-simulations.rst
 356         user-guide/mdp-options.rst
 357         user-guide/mdrun-features.rst
 358         user-guide/mdrun-performance.rst
 359         user-guide/run-time-errors.rst
 360         user-guide/system-preparation.rst
 361         user-guide/terminology.rst
 362         )
 363
 364     include(SphinxMacros.cmake)
 365     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 366
 367     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 368     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 369         EXTRA_VARS
 370             SPHINX_EXTENSION_PATH RELENG_PATH
 371             EXPECTED_DOXYGEN_VERSION
 372             EXPECTED_SPHINX_VERSION
 373             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 374             REQUIRED_OPENCL_MIN_VERSION
 375             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 376             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 377             GMX_TNG_MINIMUM_REQUIRED_VERSION
 378             GMX_LMFIT_REQUIRED_VERSION
 379         COMMENT "Configuring Sphinx configuration file")
 380     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 381     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 382     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 383         include(${RELENG_PATH}/docs/FileList.cmake)
 384         gmx_add_sphinx_source_files(
 385             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 386             FILES ${RELENG_SPHINX_FILES})
 387     else()
 388         gmx_add_sphinx_source_files(FILES
 389             dev-manual/releng/index.rst
 390             dev-manual/releng/jenkins-howto.rst
 391             dev-manual/releng/jenkins-ui.rst
 392             )
 393     endif()
 394     if (IMAGE_CONVERT_POSSIBLE)
 395         gmx_add_sphinx_source_files(
 396             FILES
 397             ${REFERENCEMANUAL_SPHINX_FILES}
 398             user-guide/index.rst
 399             user-guide/flow.rst)
 400         gmx_add_sphinx_source_files(
 401             FILES
 402             ${REFERENCEMANUAL_IMAGE_FILES})
 403         gmx_add_sphinx_image_conversion_files(
 404             FILES
 405             ${REFERENCEMANUAL_IMAGE_FILES})
 406     else()
 407         gmx_add_sphinx_source_files(
 408             FROM ${CMAKE_CURRENT_SOURCE_DIR}/reference-manual TO user-guide
 409             FILES
 410             file-formats.rst
 411             plots/plotje.png
 412             plots/xvgr.png)
 413         gmx_add_sphinx_source_files(
 414             FROM ${CMAKE_CURRENT_SOURCE_DIR}/reference-manual-minimal TO reference-manual
 415             FILES
 416             index.rst)
 417         gmx_add_sphinx_source_files(
 418             FROM ${CMAKE_CURRENT_SOURCE_DIR}/user-guide-old TO user-guide
 419             FILES
 420             index.rst
 421             flow.rst)
 422     endif()
 423     gmx_add_sphinx_input_target(sphinx-input)
 424     gmx_add_sphinx_image_conversion_target(sphinx-image-conversion)
 425     # Remove other rst files from the build tree, since they confuse Sphinx.
 426     # Skip generated files in onlinehelp/, and fragments.
 427     # The latter do not cause issues with obsolete files, as they
 428     # are not considered as Sphinx input files, but will only be
 429     # included using an explicit .. include::.
 430     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 431
 432     # TODO: Make this remove obsolete .rst files.
 433     # TODO: This does not work in cross-compilation scenarios; disable up to
 434     # the necessary level.
 435     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 436         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 437         COMMAND gmx -quiet help -export rst
 438         DEPENDS gmx
 439         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 440         COMMENT "Generating reStructuredText help")
 441     # This dependency ensures that the directories exist before the
 442     # executable tries to write things there.
 443     add_dependencies(sphinx-programs sphinx-input)
 444
 445     # Make the INSTALL file for CPack for the tarball. This gets put
 446     # into the tarball via the CPack rules below, which requires that
 447     # the INSTALL file is in a separate directory by itself.
 448     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 449     add_custom_target(install-guide
 450         COMMAND
 451             ${SPHINX_EXECUTABLE}
 452             -q -E -b text
 453             -w sphinx-install.log
 454             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 455             -c ${SPHINX_INPUT_DIR}
 456             "${SPHINX_INPUT_DIR}/install-guide"
 457             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 458         COMMAND
 459             ${CMAKE_COMMAND} -E rename
 460             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 461             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 462         WORKING_DIRECTORY
 463             ${CMAKE_CURRENT_BINARY_DIR}
 464         COMMENT "Building INSTALL with Sphinx"
 465         VERBATIM
 466         )
 467     add_dependencies(install-guide sphinx-input)
 468     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 469
 470     # Sphinx cache with pickled ReST documents
 471     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 472     add_custom_target(webpage-sphinx
 473         DEPENDS sphinx-programs
 474         DEPENDS sphinx-input
 475         DEPENDS sphinx-image-conversion
 476         COMMAND
 477             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 478         COMMAND
 479             ${SPHINX_EXECUTABLE}
 480             -q -E -b html
 481             -w sphinx-html.log
 482             -d "${SPHINX_CACHE_DIR}"
 483             "${SPHINX_INPUT_DIR}"
 484             "${HTML_OUTPUT_DIR}"
 485         WORKING_DIRECTORY
 486             ${CMAKE_CURRENT_BINARY_DIR}
 487         COMMENT "Building HTML documentation with Sphinx"
 488         VERBATIM
 489         )
 490
 491     add_custom_target(man
 492         COMMAND
 493             ${SPHINX_EXECUTABLE}
 494             -q -E -b man
 495             -w sphinx-man.log
 496             -d ${SPHINX_CACHE_DIR}
 497             -t do_man
 498             ${SPHINX_INPUT_DIR}
 499             ${CMAKE_CURRENT_BINARY_DIR}/man
 500         COMMENT "Building man pages with Sphinx"
 501         VERBATIM)
 502     add_dependencies(man sphinx-input sphinx-programs)
 503     if (GMX_BUILD_HELP)
 504         # If requested, install the man pages built by the 'man' target
 505         # created above.  Nothing will be installed if the user did not
 506         # manually build the target.
 507         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 508     endif()
 509
 510 else()
 511     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 512     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is not available")
 513
 514     add_custom_target(webpage-sphinx
 515         COMMAND ${CMAKE_COMMAND} -E echo
 516             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 517         VERBATIM)
 518     add_custom_target(install-guide
 519         COMMAND ${CMAKE_COMMAND} -E echo
 520             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 521         VERBATIM)
 522     add_custom_target(man
 523         COMMAND ${CMAKE_COMMAND} -E echo
 524             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 525         VERBATIM)
 526     add_custom_target(sphinx-create-texman
 527         COMMAND ${CMAKE_COMMAND} -E echo
 528             "Cannot prepare LaTeX input files because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 529         VERBATIM)
 530 endif()
 531
 532 if (MAN_PAGE_DIR)
 533     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 534     # Trailing slash on directory is significant for
 535     # install(DIRECTORY). See CMake docs.
 536     install(DIRECTORY ${MAN_PAGE_DIR}/
 537         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 538         COMPONENT man OPTIONAL
 539         FILES_MATCHING PATTERN "*.1")
 540 endif()
 541 gmx_cpack_add_generated_source_directory(man)
 542
 543 # Determine whether we can build all the HTML pages and content linked from
 544 # there.  If not, construct an informative message if the user tries to
 545 # build the target; most people never need to know, unless they've asked for
 546 # the webpage build.
 547 set(HTML_BUILD_IS_POSSIBLE ON)
 548 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 549 set(HTML_BUILD_WARNINGS)
 550
 551 # Next, turn it off if any of the preconditions are unsatisified
 552 if (NOT PYTHON_EXECUTABLE)
 553     set(HTML_BUILD_IS_POSSIBLE OFF)
 554     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 555 elseif (NOT SPHINX_FOUND)
 556     # Hardly anything gets built if Sphinx is not available, so don't bother.
 557     set(HTML_BUILD_IS_POSSIBLE OFF)
 558     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 559 endif()
 560 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 561     list(APPEND HTML_BUILD_WARNINGS
 562          "Reference PDF manual was not built, so links to it do not work")
 563 endif()
 564 if (NOT DOXYGEN_EXECUTABLE)
 565     list(APPEND HTML_BUILD_WARNINGS
 566         "Doxygen was not available, so links to Doxygen do not work")
 567 endif()
 568 if (NOT DOXYGEN_DOT_EXECUTABLE)
 569     list(APPEND HTML_BUILD_WARNINGS
 570         "dot/graphviz was not found, so some graphs are missing")
 571 endif()
 572
 573 if (HTML_BUILD_IS_POSSIBLE)
 574     set(_webpage_target_properties)
 575     if (HTML_BUILD_WARNINGS)
 576         list(APPEND _webpage_target_properties
 577              COMMAND ${CMAKE_COMMAND} -E echo
 578                  "webpage was built, but with the following limitations:")
 579         foreach(_warning ${HTML_BUILD_WARNINGS})
 580         list(APPEND _webpage_target_properties
 581              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 582         endforeach()
 583     endif()
 584
 585     if (MANUAL_BUILD_IS_POSSIBLE)
 586         # Make the PDF reference guide
 587         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 588         # TODO Make this depend on the output of the manual build, so that the
 589         # file actually gets copied multiple times.
 590         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 591         add_custom_command(
 592             OUTPUT ${_manual_target_location}
 593             COMMAND ${CMAKE_COMMAND}
 594                 -E remove -f ${_manual_target_location}
 595             COMMAND ${CMAKE_COMMAND}
 596                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 597             DEPENDS manual
 598             VERBATIM)
 599         list(APPEND _webpage_target_properties
 600              DEPENDS ${_manual_target_location})
 601     endif()
 602
 603     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 604     # makes all the Doxygen output directly in
 605     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 606     # to).
 607
 608     # Add a top-level target that builds everything related to the webpage,
 609     # for Jenkins (and possibly others) to use
 610     add_custom_target(webpage ${_webpage_target_properties}
 611         COMMENT "Building webpage"
 612         VERBATIM)
 613     add_dependencies(webpage webpage-sphinx doxygen-all)
 614 else()
 615     add_custom_target(webpage
 616         COMMAND ${CMAKE_COMMAND} -E echo
 617             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 618         COMMENT "Webpage build not possible"
 619         VERBATIM)
 620 endif()