docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   5 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 # This directory provides a unified place for building all kinds of
  37 # GROMACS documentation. This includes some "static" content (Doxygen
  38 # code documentation, reference manual, install guide, old online HTML
  39 # images), and content generated from the gmx program for the various
  40 # tools (man and HTML pages). It also provides the "webpage" target,
  41 # that combines all of the above (except man pages in man format) into
  42 # a form suitable for automated deployment to the GROMACS website. It
  43 # also provides the INSTALL file for the tarball.
  44 #
  45 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  46 # substitutions are configured by CMake (for things like version numbers),
  47 # using gmx_configure_version_file().  This happens during build time instead
  48 # of configure time, because 1) some of the version variables are only
  49 # available during build time, and 2) we don't want to do all the Sphinx setup
  50 # during configuration to save some time when not building the content.
  51 # All of the generated values get put into conf.py (generated from
  52 # conf.cmakein.py).
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.6.1)
  62
  63 # By default, suppress output after first configuration.
  64 if(SPHINX_ALREADY_SEARCHED)
  65     set(Sphinx_FIND_QUIETLY ON)
  66 endif()
  67 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} COMPONENTS pygments)
  68 set(SPHINX_ALREADY_SEARCHED TRUE CACHE BOOL "True if a search for Sphinx has already been done")
  69 mark_as_advanced(SPHINX_ALREADY_SEARCHED)
  70
  71 # Even if we aren't going to make the full webpage, set up to put all
  72 # the documentation output in the same place, for convenience
  73 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  74 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  75
  76 # Prepare directories for pdf/tex output
  77 set(TEX_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/manual")
  78 set(SPHINX_LATEX_FILE "${TEX_OUTPUT_DIR}/gromacs.tex")
  79 file(MAKE_DIRECTORY ${TEX_OUTPUT_DIR})
  80
  81 # The directory from which man pages will be installed; if it remains
  82 # empty, they will be silently skipped.
  83 set(MAN_PAGE_DIR)
  84 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  85     # When building from the tarball, install the bundled man pages
  86     # (unless overridden).
  87     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  88 endif()
  89
  90 add_subdirectory(doxygen)
  91
  92 # TODO: Consider whether this could just be replaced by using
  93 # GMX_DEVELOPER_BUILD to control this as well.
  94 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
  95 mark_as_advanced(GMX_BUILD_MANUAL)
  96
  97 set(MANUAL_BUILD_IS_POSSIBLE ON)
  98 set(MANUAL_BUILD_NOT_POSSIBLE_REASON)
  99 set(NO_IMAGE_CONVERT_REASON)
 100 if (NOT GMX_BUILD_MANUAL)
 101     # Make sure we only do detection of manual-building dependencies
 102     # when the user opted in for that.
 103     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 104     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "GMX_BUILD_MANUAL is not ON")
 105 elseif (BUILD_IS_INSOURCE)
 106     # UseLATEX.cmake does not work with an in-source build
 107     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 108     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "the build is in-source")
 109 else()
 110     include(manual/UseLATEX.cmake)
 111     if(NOT SPHINX_FOUND)
 112         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 113         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx has not been found and is needed to create the LaTex input files")
 114     elseif(NOT PDFLATEX_COMPILER)
 115         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 116         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "pdflatex is not available")
 117     elseif(NOT IMAGE_CONVERT_POSSIBLE)
 118         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 119         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "a working form of ImageMagick convert is not available")
 120         set(NO_IMAGE_CONVERT_REASON "Can not convert files for online or pdf manual")
 121         # TODO Later, identify other dependencies like bibtex,
 122         # make_index, date, some graphics conversion program,
 123         # etc. Perhaps patch UseLATEX.cmake and contribute upstream.
 124     endif()
 125
 126 endif()
 127
 128 if (SPHINX_FOUND)
 129     # We need to have all the Sphinx input files in a single directory, and
 130     # since some of them are generated, we copy everything into the build tree,
 131     # to this directory.
 132     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
 133     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 134     # As the manual build now depends also on Sphinx, the inclusion path needs
 135     # to be set after we know the basic information for Sphinx.
 136     add_subdirectory(manual)
 137     if (SOURCE_MD5SUM STREQUAL "unknown")
 138         # But for testing the webpage build (e.g. from the repo) we
 139         # need a default value.
 140         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 141     else()
 142         # The real build of the webpage happens from the tarball, and
 143         # this should be set to the matching MD5 sum.
 144         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 145     endif()
 146     # The reference manual still contains the individual sections from the
 147     # LaTeX document, with the files below grouped and annotated by chapter.
 148     set(REFERENCEMANUAL_SPHINX_FILES_GENERAL
 149         # Main index file, preface and introduction.
 150         reference-manual/index.rst
 151         reference-manual/preface.rst
 152         reference-manual/introduction.rst
 153         # Definitions and Units chapter
 154         reference-manual/definitions.rst
 155         # Topologies chapter
 156         reference-manual/topologies.rst
 157         reference-manual/topologies/particle-type.rst
 158         reference-manual/topologies/parameter-files.rst
 159         reference-manual/topologies/molecule-definition.rst
 160         reference-manual/topologies/constraint-algorithm-section.rst
 161         reference-manual/topologies/pdb2gmx-input-files.rst
 162         reference-manual/topologies/topology-file-formats.rst
 163         reference-manual/topologies/force-field-organization.rst
 164         # File formats chapter
 165         reference-manual/file-formats.rst
 166         # Run parameters and programs chapter
 167         reference-manual/run-parameters.rst
 168         # Implementation details chapter
 169         reference-manual/details.rst
 170         # Averages and fluctations chapter
 171         reference-manual/averages.rst
 172         # References
 173         reference-manual/references.rst
 174         # PNG formated plot files that don't need to be converted into PNG
 175         # for the web page.
 176         reference-manual/plots/GMX_logos/gmx_falcon_blue.png
 177         reference-manual/plots/adress.png
 178         reference-manual/plots/plotje.png
 179         reference-manual/plots/xvgr.png
 180         )
 181     set(REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES
 182         # Algorithms chapter
 183         reference-manual/algorithms.rst
 184         reference-manual/algorithms/periodic-boundary-conditions.rst
 185         reference-manual/algorithms/group-concept.rst
 186         reference-manual/algorithms/molecular-dynamics.rst
 187         reference-manual/algorithms/shell-molecular-dynamics.rst
 188         reference-manual/algorithms/constraint-algorithms.rst
 189         reference-manual/algorithms/simulated-annealing.rst
 190         reference-manual/algorithms/stochastic-dynamics.rst
 191         reference-manual/algorithms/brownian-dynamics.rst
 192         reference-manual/algorithms/energy-minimization.rst
 193         reference-manual/algorithms/normal-mode-analysis.rst
 194         reference-manual/algorithms/free-energy-calculations.rst
 195         reference-manual/algorithms/replica-exchange.rst
 196         reference-manual/algorithms/essential-dynamics.rst
 197         reference-manual/algorithms/expanded-ensemble.rst
 198         reference-manual/algorithms/parallelization-domain-decomp.rst
 199         # Interaction functions and force fields chapter
 200         reference-manual/functions.rst
 201         reference-manual/functions/bonded-interactions.rst
 202         reference-manual/functions/force-field.rst
 203         reference-manual/functions/free-energy-interactions.rst
 204         reference-manual/functions/interaction-methods.rst
 205         reference-manual/functions/long-range-electrostatics.rst
 206         reference-manual/functions/long-range-vdw.rst
 207         reference-manual/functions/nonbonded-interactions.rst
 208         reference-manual/functions/polarization.rst
 209         reference-manual/functions/restraints.rst
 210         # Special topics chapter
 211         reference-manual/special.rst
 212         reference-manual/special/free-energy-implementation.rst
 213         reference-manual/special/pulling.rst
 214         reference-manual/special/awh.rst
 215         reference-manual/special/enforced-rotation.rst
 216         reference-manual/special/electric-fields.rst
 217         reference-manual/special/comp-electrophys.rst
 218         reference-manual/special/free-energy-pmf.rst
 219         reference-manual/special/remove-fast-dgf.rst
 220         reference-manual/special/viscosity-calculation.rst
 221         reference-manual/special/tabulated-interaction-functions.rst
 222         reference-manual/special/qmmm.rst
 223         reference-manual/special/vmd-imd.rst
 224         reference-manual/special/membrane-embedding.rst
 225         reference-manual/special/mimic-qmmm.rst
 226         reference-manual/special/density-guided-simulation.rst
 227         # Analysis chapter
 228         reference-manual/analysis.rst
 229         reference-manual/analysis/using-groups.rst
 230         reference-manual/analysis/looking-at-trajectory.rst
 231         reference-manual/analysis/general-properties.rst
 232         reference-manual/analysis/radial-distribution-function.rst
 233         reference-manual/analysis/correlation-function.rst
 234         reference-manual/analysis/curve-fitting.rst
 235         reference-manual/analysis/mean-square-displacement.rst
 236         reference-manual/analysis/bond-angle-dihedral.rst
 237         reference-manual/analysis/radius-of-gyration.rst
 238         reference-manual/analysis/rmsd.rst
 239         reference-manual/analysis/covariance-analysis.rst
 240         reference-manual/analysis/dihedral-pca.rst
 241         reference-manual/analysis/hydrogen-bonds.rst
 242         reference-manual/analysis/protein-related.rst
 243         reference-manual/analysis/interface-related.rst)
 244     # The image files have also been ordered by the respective
 245     # chapter they are included in in the reference manual
 246     set(REFERENCEMANUAL_IMAGE_FILES
 247         # General folder
 248         reference-manual/plots/decomp.pdf
 249         reference-manual/plots/dih.pdf
 250         reference-manual/plots/drift-all.pdf
 251         reference-manual/plots/f-angle.pdf
 252         reference-manual/plots/f-bond.pdf
 253         reference-manual/plots/fp-highres.pdf
 254         reference-manual/plots/int-mat.pdf
 255         reference-manual/plots/mdpar.pdf
 256         reference-manual/plots/parsort.pdf
 257         reference-manual/plots/ring.pdf
 258         reference-manual/plots/shiftf.pdf
 259         # Algorithms chapter
 260         reference-manual/algorithms/plots/dd-cells.pdf
 261         reference-manual/algorithms/plots/dd-tric.pdf
 262         reference-manual/algorithms/plots/flowchart.pdf
 263         reference-manual/algorithms/plots/free1.pdf
 264         reference-manual/algorithms/plots/free2.pdf
 265         reference-manual/algorithms/plots/leapfrog.pdf
 266         reference-manual/algorithms/plots/lincs.pdf
 267         reference-manual/algorithms/plots/maxwell.pdf
 268         reference-manual/algorithms/plots/mpmd-pme.pdf
 269         reference-manual/algorithms/plots/nstric.pdf
 270         reference-manual/algorithms/plots/par-lincs2.pdf
 271         reference-manual/algorithms/plots/pbctric.pdf
 272         reference-manual/algorithms/plots/rhododec.pdf
 273         reference-manual/algorithms/plots/truncoct.pdf
 274         reference-manual/algorithms/plots/verlet-drift.pdf
 275         # Interaction functions chapter
 276         reference-manual/functions/plots/angle.pdf
 277         reference-manual/functions/plots/bstretch.pdf
 278         reference-manual/functions/plots/chain.pdf
 279         reference-manual/functions/plots/dummies.pdf
 280         reference-manual/functions/plots/f-bham.pdf
 281         reference-manual/functions/plots/fbposres.pdf
 282         reference-manual/functions/plots/f-dih.pdf
 283         reference-manual/functions/plots/f-dr.pdf
 284         reference-manual/functions/plots/fig-02.pdf
 285         reference-manual/functions/plots/fig-04.pdf
 286         reference-manual/functions/plots/f-imps.pdf
 287         reference-manual/functions/plots/f-lj.pdf
 288         reference-manual/functions/plots/f-morse.pdf
 289         reference-manual/functions/plots/f-pr.pdf
 290         reference-manual/functions/plots/f-rbs.pdf
 291         reference-manual/functions/plots/ring-imp.pdf
 292         reference-manual/functions/plots/softcore.pdf
 293         reference-manual/functions/plots/subst-im.pdf
 294         reference-manual/functions/plots/tetra-im.pdf
 295         reference-manual/functions/plots/vcrf.pdf
 296         reference-manual/functions/plots/vsite-4fdn.pdf
 297         # Special topics chapter
 298         reference-manual/special/plots/awh-invN.pdf
 299         reference-manual/special/plots/awh-pmfs.pdf
 300         reference-manual/special/plots/awh-sampleweights.pdf
 301         reference-manual/special/plots/awh-traj.pdf
 302         reference-manual/special/plots/compelsetup.pdf
 303         reference-manual/special/plots/dumaro.pdf
 304         reference-manual/special/plots/dumtypes.pdf
 305         reference-manual/special/plots/equipotential.pdf
 306         reference-manual/special/plots/field.pdf
 307         reference-manual/special/plots/gaussians.pdf
 308         reference-manual/special/plots/lambda-values.pdf
 309         reference-manual/special/plots/pulldirrel.pdf
 310         reference-manual/special/plots/pull.pdf
 311         reference-manual/special/plots/pullref.pdf
 312         reference-manual/special/plots/rotation.pdf
 313         # Analysis chapter
 314         reference-manual/analysis/plots/dih-def.pdf
 315         reference-manual/analysis/plots/distm.pdf
 316         reference-manual/analysis/plots/dssp.pdf
 317         reference-manual/analysis/plots/hbond-insert.pdf
 318         reference-manual/analysis/plots/hbond.pdf
 319         reference-manual/analysis/plots/hpr-wheel.pdf
 320         reference-manual/analysis/plots/msdwater.pdf
 321         reference-manual/analysis/plots/ngmxdump.pdf
 322         reference-manual/analysis/plots/phipsi.pdf
 323         reference-manual/analysis/plots/rama.pdf
 324         reference-manual/analysis/plots/rdfO-O.pdf
 325         reference-manual/analysis/plots/rdf.pdf
 326         reference-manual/analysis/plots/sgangle.pdf
 327         )
 328     set(SPHINX_SOURCE_FILES
 329         index.rst
 330         download.rst
 331         links.dat
 332         dev-manual/build-system.rst
 333         dev-manual/change-management.rst
 334         dev-manual/commitstyle.rst
 335         dev-manual/containers.rst
 336         dev-manual/documentation-generation.rst
 337         dev-manual/contribute.rst
 338         dev-manual/doxygen.rst
 339         dev-manual/error-handling.rst
 340         dev-manual/formatting.rst
 341         dev-manual/gitlab.rst
 342         dev-manual/gmxtree.rst
 343         dev-manual/includestyle.rst
 344         dev-manual/index.rst
 345         dev-manual/infrastructure.rst
 346         dev-manual/jenkins.rst
 347         dev-manual/known-issues.rst
 348         dev-manual/language-features.rst
 349         dev-manual/naming.rst
 350         dev-manual/overview.rst
 351         dev-manual/physical_validation.rst
 352         dev-manual/redmine-states.png
 353         dev-manual/relocatable-binaries.rst
 354         dev-manual/reportstyle.rst
 355         dev-manual/style.rst
 356         dev-manual/testutils.rst
 357         dev-manual/tools.rst
 358         dev-manual/code-formatting.rst
 359         fragments/doxygen-links.rst
 360         how-to/index.rst
 361         how-to/beginners.rst
 362         how-to/topology.rst
 363         how-to/special.rst
 364         how-to/visualize.rst
 365         install-guide/index.rst
 366         release-notes/index.rst
 367         release-notes/2021/2021.4.rst
 368         release-notes/2021/2021.3.rst
 369         release-notes/2021/2021.2.rst
 370         release-notes/2021/2021.1.rst
 371         release-notes/2021/major/highlights.rst
 372         release-notes/2021/major/features.rst
 373         release-notes/2021/major/performance.rst
 374         release-notes/2021/major/tools.rst
 375         release-notes/2021/major/bugs-fixed.rst
 376         release-notes/2021/major/removed-functionality.rst
 377         release-notes/2021/major/deprecated-functionality.rst
 378         release-notes/2021/major/portability.rst
 379         release-notes/2021/major/miscellaneous.rst
 380         release-notes/2020/2020.1.rst
 381         release-notes/2020/2020.2.rst
 382         release-notes/2020/2020.3.rst
 383         release-notes/2020/2020.4.rst
 384         release-notes/2020/2020.5.rst
 385         release-notes/2020/2020.6.rst
 386         release-notes/2020/major/highlights.rst
 387         release-notes/2020/major/features.rst
 388         release-notes/2020/major/performance.rst
 389         release-notes/2020/major/tools.rst
 390         release-notes/2020/major/bugs-fixed.rst
 391         release-notes/2020/major/removed-functionality.rst
 392         release-notes/2020/major/deprecated-functionality.rst
 393         release-notes/2020/major/portability.rst
 394         release-notes/2020/major/miscellaneous.rst
 395         release-notes/2019/2019.6.rst
 396         release-notes/2019/2019.5.rst
 397         release-notes/2019/2019.4.rst
 398         release-notes/2019/2019.3.rst
 399         release-notes/2019/2019.2.rst
 400         release-notes/2019/2019.1.rst
 401         release-notes/2019/major/highlights.rst
 402         release-notes/2019/major/features.rst
 403         release-notes/2019/major/performance.rst
 404         release-notes/2019/major/tools.rst
 405         release-notes/2019/major/bugs-fixed.rst
 406         release-notes/2019/major/removed-functionality.rst
 407         release-notes/2019/major/deprecated-functionality.rst
 408         release-notes/2019/major/portability.rst
 409         release-notes/2019/major/miscellaneous.rst
 410         release-notes/2018/2018.7.rst
 411         release-notes/2018/2018.6.rst
 412         release-notes/2018/2018.5.rst
 413         release-notes/2018/2018.4.rst
 414         release-notes/2018/2018.3.rst
 415         release-notes/2018/2018.2.rst
 416         release-notes/2018/2018.1.rst
 417         release-notes/2018/major/highlights.rst
 418         release-notes/2018/major/features.rst
 419         release-notes/2018/major/performance.rst
 420         release-notes/2018/major/tools.rst
 421         release-notes/2018/major/bugs-fixed.rst
 422         release-notes/2018/major/removed-features.rst
 423         release-notes/2018/major/portability.rst
 424         release-notes/2018/major/miscellaneous.rst
 425         release-notes/2016/2016.5.rst
 426         release-notes/2016/2016.4.rst
 427         release-notes/2016/2016.3.rst
 428         release-notes/2016/2016.2.rst
 429         release-notes/2016/2016.1.rst
 430         release-notes/2016/major/highlights.rst
 431         release-notes/2016/major/new-features.rst
 432         release-notes/2016/major/performance.rst
 433         release-notes/2016/major/tools.rst
 434         release-notes/2016/major/bugs-fixed.rst
 435         release-notes/2016/major/removed-features.rst
 436         release-notes/2016/major/miscellaneous.rst
 437         release-notes/older/index.rst
 438         # the entry for user-guide/index.rst should not appear here,
 439         # as it will be included conditionally further down depending on
 440         # if the documentation will be build with the full reference
 441         # manual or without.
 442         user-guide/cmdline.rst
 443         user-guide/deprecation-policy.rst
 444         user-guide/environment-variables.rst
 445         user-guide/faq.rst
 446         user-guide/floating-point.rst
 447         user-guide/flow.rst
 448         user-guide/force-fields.rst
 449         user-guide/getting-started.rst
 450         user-guide/index.rst
 451         user-guide/known-issues.rst
 452         user-guide/managing-simulations.rst
 453         user-guide/mdp-options.rst
 454         user-guide/mdrun-features.rst
 455         user-guide/mdrun-performance.rst
 456         user-guide/run-time-errors.rst
 457         user-guide/security.rst
 458         user-guide/system-preparation.rst
 459         user-guide/terminology.rst
 460         )
 461
 462     include(SphinxMacros.cmake)
 463     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 464
 465     # set temporary variables for doi inclusion
 466     # into the manual, plain string + some wrapping
 467     # for release builds, and dummy string for non-release
 468     # builds
 469     if("${GMX_MANUAL_DOI}" STREQUAL "")
 470       # empty string means no doi, set dummy text
 471       set(GMX_MANUAL_DOI_STRING "This is not a release build of GROMACS, so please reference")
 472       set(GMX_MANUAL_DOI_STRING "${GMX_MANUAL_DOI_STRING} one of the GROMACS papers and the base release of the manual.")
 473     else()
 474       # release version, set plain old boring string
 475       set(GMX_MANUAL_DOI_STRING "Please reference this documentation as https://doi.org/${GMX_MANUAL_DOI}.")
 476     endif()
 477     # same for source doi, but modify the text
 478     if("${GMX_SOURCE_DOI}" STREQUAL "")
 479       # empty string means no release build
 480       set(GMX_SOURCE_DOI_STRING "This is not a release build of GROMACS. Please reference one of the")
 481       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} GROMACS papers, as well as the base release that this version is built from.")
 482       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} Also, please state what modifcations have been performed or where the version")
 483       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} was sourced from.")
 484     else()
 485       # release version, give them a doi url string
 486       set(GMX_SOURCE_DOI_STRING "To cite the source code for this release, please cite")
 487       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} https://doi.org/${GMX_SOURCE_DOI}.")
 488     endif()
 489
 490     if(IMAGE_CONVERT_POSSIBLE)
 491         set(IMAGE_CONVERT_STRING "possible")
 492     else()
 493         set(IMAGE_CONVERT_STRING "impossible")
 494     endif()
 495
 496     set(SPHINX_CONFIG_FILE ${SPHINX_INPUT_DIR}/conf.py)
 497     if (GMX_PYTHON_PACKAGE)
 498         set(GMXAPI_PYTHON_STAGING_DIR ${CMAKE_BINARY_DIR}/python_packaging/src/gmxapi_staging)
 499         # TODO: Resolve circular reference. We would like to get the CMake build-time directory for
 500         # the gmxapi Python package from the _gmxapi target, as we do when building sample_restraint.
 501         # Instead of the above hard-coded path, how can we do
 502         # get_target_property(GMXAPI_PYTHON_STAGING_DIR _gmxapi staging_dir)
 503         # in this context?
 504     endif ()
 505
 506     gmx_configure_version_file(
 507         conf.cmakein.py ${SPHINX_CONFIG_FILE}
 508         EXTRA_VARS
 509             CMAKE_MINIMUM_REQUIRED_VERSION
 510             EXPECTED_DOXYGEN_VERSION
 511             EXPECTED_SPHINX_VERSION
 512             GMX_ADMIN_DIR
 513             GMX_LMFIT_REQUIRED_VERSION
 514             GMX_MANUAL_DOI_STRING
 515             GMX_TNG_MINIMUM_REQUIRED_VERSION
 516             GMX_SOURCE_DOI_STRING
 517             GMXAPI_PYTHON_STAGING_DIR
 518             IMAGE_CONVERT_STRING
 519             REGRESSIONTEST_VERSION
 520             REQUIRED_CUDA_COMPUTE_CAPABILITY
 521             REQUIRED_CUDA_VERSION
 522             REQUIRED_OPENCL_MIN_VERSION
 523             REGRESSIONTEST_MD5SUM_STRING
 524             RELENG_PATH
 525             SOURCE_MD5SUM
 526             SPHINX_EXTENSION_PATH
 527         COMMENT "Configuring Sphinx configuration file")
 528     gmx_add_sphinx_input_file(${SPHINX_CONFIG_FILE})
 529     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 530     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 531         include(${RELENG_PATH}/docs/FileList.cmake)
 532         gmx_add_sphinx_source_files(
 533             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 534             FILES ${RELENG_SPHINX_FILES})
 535     else()
 536         gmx_add_sphinx_source_files(FILES
 537             dev-manual/releng/index.rst
 538             )
 539     endif()
 540
 541     gmx_add_sphinx_source_files(
 542             FILES
 543             gmxapi/index.rst
 544             gmxapi/userguide/install.rst
 545             gmxapi/userguide/usage.rst
 546             gmxapi/userguide/userguide.rst
 547     )
 548
 549     if (GMX_PYTHON_PACKAGE)
 550         gmx_add_sphinx_source_files(
 551             FILES
 552             gmxapi/userguide/pythonreference.rst
 553             )
 554     else()
 555         gmx_add_sphinx_source_files(
 556             FROM ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi/userguide-stub
 557             TO gmxapi/userguide/
 558             FILES pythonreference.rst
 559             )
 560     endif ()
 561
 562     gmx_add_sphinx_source_files(
 563             FILES
 564             nblib/index.rst
 565             nblib/guide-to-writing-MD-programs.rst
 566     )
 567
 568     gmx_add_sphinx_source_files(
 569         FILES
 570         ${REFERENCEMANUAL_SPHINX_FILES_GENERAL})
 571     if (IMAGE_CONVERT_POSSIBLE)
 572         gmx_add_sphinx_source_files(
 573             FILES
 574             ${REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES}
 575             ${REFERENCEMANUAL_IMAGE_FILES})
 576         gmx_add_sphinx_image_conversion_files(
 577             FILES
 578             ${REFERENCEMANUAL_IMAGE_FILES})
 579     endif()
 580     gmx_add_sphinx_input_target(sphinx-input-rst)
 581     gmx_add_sphinx_image_conversion_target(sphinx-image-conversion)
 582     add_custom_target(sphinx-input)
 583     add_dependencies(sphinx-input sphinx-input-rst sphinx-image-conversion)
 584     if (GMX_PYTHON_PACKAGE)
 585         add_dependencies(sphinx-input _gmxapi)
 586     endif()
 587     # Remove other rst files from the build tree, since they confuse Sphinx.
 588     # Skip generated files in onlinehelp/, and fragments.
 589     # The latter do not cause issues with obsolete files, as they
 590     # are not considered as Sphinx input files, but will only be
 591     # included using an explicit .. include::.
 592     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 593
 594     # TODO: Make this remove obsolete .rst files.
 595     # TODO: This does not work in cross-compilation scenarios; disable up to
 596     # the necessary level.
 597     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 598         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 599         COMMAND gmx -quiet help -export rst
 600         DEPENDS gmx
 601         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 602         COMMENT "Generating reStructuredText help")
 603     # This dependency ensures that the directories exist before the
 604     # executable tries to write things there.
 605     add_dependencies(sphinx-programs sphinx-input)
 606
 607     # Make the INSTALL file for CPack for the tarball. This gets put
 608     # into the tarball via the CPack rules below, which requires that
 609     # the INSTALL file is in a separate directory by itself.
 610     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 611     add_custom_target(install-guide
 612         COMMAND
 613             ${SPHINX_EXECUTABLE}
 614             -q -b text
 615             -w sphinx-install.log
 616             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 617             -c ${SPHINX_INPUT_DIR}
 618             "${SPHINX_INPUT_DIR}/install-guide"
 619             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 620         COMMAND
 621             ${CMAKE_COMMAND} -E rename
 622             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 623             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 624         WORKING_DIRECTORY
 625             ${CMAKE_CURRENT_BINARY_DIR}
 626         COMMENT "Building INSTALL with Sphinx"
 627         VERBATIM
 628         )
 629     add_dependencies(install-guide sphinx-input)
 630     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 631
 632     # Sphinx cache with pickled ReST documents
 633     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 634     set(SPHINX_CONFIG_OVERRIDES "")
 635     if (GMX_DEVELOPER_BUILD)
 636         set(SPHINX_CONFIG_OVERRIDES "-Dtodo_include_todos=1")
 637     endif()
 638     add_custom_target(webpage-sphinx
 639         DEPENDS sphinx-programs
 640         DEPENDS sphinx-input
 641         DEPENDS sphinx-image-conversion
 642         DEPENDS manual
 643         COMMAND
 644             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 645         COMMAND
 646             ${SPHINX_EXECUTABLE}
 647             -q -b html
 648             -w sphinx-html.log
 649             -d "${SPHINX_CACHE_DIR}"
 650             ${SPHINX_CONFIG_OVERRIDES}
 651             "${SPHINX_INPUT_DIR}"
 652             "${HTML_OUTPUT_DIR}"
 653         WORKING_DIRECTORY
 654             ${CMAKE_CURRENT_BINARY_DIR}
 655         COMMENT "Building HTML documentation with Sphinx"
 656         VERBATIM
 657         )
 658
 659     add_custom_target(man
 660         COMMAND
 661             ${SPHINX_EXECUTABLE}
 662             -q -b man
 663             -w sphinx-man.log
 664             -d ${SPHINX_CACHE_DIR}
 665             -t do_man
 666             ${SPHINX_INPUT_DIR}
 667             ${CMAKE_CURRENT_BINARY_DIR}/man
 668         COMMENT "Building man pages with Sphinx"
 669         VERBATIM)
 670     add_dependencies(man sphinx-input sphinx-programs)
 671     if (GMX_BUILD_HELP)
 672         # If requested, install the man pages built by the 'man' target
 673         # created above.  Nothing will be installed if the user did not
 674         # manually build the target.
 675         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 676     endif()
 677
 678 else()
 679     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 680     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available")
 681
 682     add_custom_target(webpage-sphinx
 683         COMMAND ${CMAKE_COMMAND} -E echo
 684             "HTML pages cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 685         VERBATIM)
 686     add_custom_target(install-guide
 687         COMMAND ${CMAKE_COMMAND} -E echo
 688             "INSTALL cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 689         VERBATIM)
 690     add_custom_target(man
 691         COMMAND ${CMAKE_COMMAND} -E echo
 692             "man pages cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 693         VERBATIM)
 694     add_custom_target(sphinx-create-texman
 695         COMMAND ${CMAKE_COMMAND} -E echo
 696             "Cannot prepare LaTeX input files because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 697         VERBATIM)
 698     add_custom_target(manual
 699         COMMAND ${CMAKE_COMMAND} -E echo
 700             "manual cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available")
 701 endif()
 702
 703 if (MAN_PAGE_DIR)
 704     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 705     # Trailing slash on directory is significant for
 706     # install(DIRECTORY). See CMake docs.
 707     install(DIRECTORY ${MAN_PAGE_DIR}/
 708         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 709         COMPONENT man OPTIONAL
 710         FILES_MATCHING PATTERN "*.1")
 711 endif()
 712 gmx_cpack_add_generated_source_directory(man)
 713
 714 # Determine whether we can build all the HTML pages and content linked from
 715 # there.  If not, construct an informative message if the user tries to
 716 # build the target; most people never need to know, unless they've asked for
 717 # the webpage build.
 718 set(HTML_BUILD_IS_POSSIBLE ON)
 719 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 720 set(HTML_BUILD_WARNINGS)
 721
 722 # Next, turn it off if any of the preconditions are unsatisified
 723 if (NOT Python3_Interpreter_FOUND)
 724     set(HTML_BUILD_IS_POSSIBLE OFF)
 725     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 726 elseif (NOT SPHINX_FOUND)
 727     # Hardly anything gets built if Sphinx is not available, so don't bother.
 728     set(HTML_BUILD_IS_POSSIBLE OFF)
 729     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is required")
 730 endif()
 731 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 732     list(APPEND HTML_BUILD_WARNINGS
 733          "Reference PDF manual was not built, so links to it do not work")
 734 endif()
 735 if (NOT DOXYGEN_EXECUTABLE)
 736     list(APPEND HTML_BUILD_WARNINGS
 737         "Doxygen was not available, so links to Doxygen do not work")
 738 endif()
 739 if (NOT DOXYGEN_DOT_EXECUTABLE)
 740     list(APPEND HTML_BUILD_WARNINGS
 741         "dot/graphviz was not found, so some graphs are missing")
 742 endif()
 743
 744 if (HTML_BUILD_IS_POSSIBLE)
 745     set(_webpage_target_properties)
 746     if (HTML_BUILD_WARNINGS)
 747         list(APPEND _webpage_target_properties
 748              COMMAND ${CMAKE_COMMAND} -E echo
 749                  "webpage was built, but with the following limitations:")
 750         foreach(_warning ${HTML_BUILD_WARNINGS})
 751         list(APPEND _webpage_target_properties
 752              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 753         endforeach()
 754     endif()
 755
 756     if (MANUAL_BUILD_IS_POSSIBLE)
 757         # Make the PDF reference guide
 758         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 759         # TODO Make this depend on the output of the manual build, so that the
 760         # file actually gets copied multiple times.
 761         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 762         add_custom_command(
 763             OUTPUT ${_manual_target_location}
 764             COMMAND ${CMAKE_COMMAND}
 765                 -E remove -f ${_manual_target_location}
 766             COMMAND ${CMAKE_COMMAND}
 767                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 768             DEPENDS manual
 769             VERBATIM)
 770         list(APPEND _webpage_target_properties
 771              DEPENDS ${_manual_target_location})
 772     endif()
 773
 774     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 775     # makes all the Doxygen output directly in
 776     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 777     # to).
 778
 779     # Add a top-level target that builds everything related to the webpage,
 780     # for Jenkins (and possibly others) to use
 781     add_custom_target(webpage ${_webpage_target_properties}
 782         COMMENT "Building webpage"
 783         VERBATIM)
 784     add_dependencies(webpage webpage-sphinx doxygen-all)
 785 else()
 786     add_custom_target(webpage
 787         COMMAND ${CMAKE_COMMAND} -E echo
 788             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 789         COMMENT "Webpage build not possible"
 790         VERBATIM)
 791 endif()