docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 option(GMX_BUILD_WEBPAGE "Whether to try to configure to build the GROMACS static webpages" OFF)
  55 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
  56 mark_as_advanced(GMX_BUILD_WEBPAGE GMX_BUILD_MANUAL)
  57
  58 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  59
  60 find_package(PythonInterp)
  61 find_package(Sphinx 1.2.3 COMPONENTS pygments)
  62
  63 # Even if we aren't going to make the full webpage, set up to put all
  64 # the documentation output in the same place, for convenience
  65 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  66 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  67
  68 # The directory from which man pages will be installed; if it remains
  69 # empty, they will be silently skipped.
  70 set(MAN_PAGE_DIR)
  71 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  72     # When building from the tarball, install the bundled man pages
  73     # (unless overridden).
  74     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  75 endif()
  76
  77 add_subdirectory(doxygen)
  78
  79 set(SOURCE_MD5SUM "unknown" CACHE STRING "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  80 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  81 mark_as_advanced(SOURCE_MD5SUM)
  82
  83 if(GMX_BUILD_MANUAL)
  84     # Make sure we only do detection of manual-building dependencies
  85     # when the user opted in for that.
  86     add_subdirectory(manual)
  87 endif()
  88
  89 if (SPHINX_FOUND)
  90     # We need to have all the Sphinx input files in a single directory, and
  91     # since some of them are generated, we copy everything into the build tree,
  92     # to this directory.
  93     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  94     set(SPHINX_CONFIG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/conf.py)
  95     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
  96     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  97     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_TARBALL)
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     else()
 102         # But for testing the webpage build (e.g. from the repo) we
 103         # need a default value.
 104         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 105     endif()
 106     set(SPHINX_SOURCE_FILES
 107         index.rst
 108         download.rst
 109         dev-manual/index.rst
 110         dev-manual/codelayout.rst
 111         dev-manual/doxygen.rst
 112         dev-manual/doxygen-links.rst
 113         dev-manual/formatting.rst
 114         dev-manual/gmxtree.rst
 115         dev-manual/includestyle.rst
 116         dev-manual/naming.rst
 117         dev-manual/overview.rst
 118         dev-manual/style.rst
 119         dev-manual/testutils.rst
 120         dev-manual/tools.rst
 121         dev-manual/uncrustify.rst
 122         install-guide/index.rst
 123         man/gromacs.7.rst
 124         user-guide/index.rst
 125         user-guide/getting-started.rst
 126         user-guide/flow.rst
 127         user-guide/cutoff-schemes.rst
 128         user-guide/mdrun-features.rst
 129         user-guide/mdrun-performance.rst
 130         user-guide/mdp-options.rst
 131         user-guide/file-formats.rst
 132         user-guide/tools.rst
 133         user-guide/environment-variables.rst
 134         user-guide/plotje.gif
 135         user-guide/xvgr.gif
 136         conf.py
 137         links.dat
 138         )
 139
 140     # Remove other rst files from the build tree, since they confuse Sphinx.
 141     file(GLOB_RECURSE _obsolete_sources RELATIVE ${SPHINX_INPUT_DIR}
 142          ${SPHINX_INPUT_DIR}/*.rst)
 143     list(REMOVE_ITEM _obsolete_sources ${SPHINX_SOURCE_FILES})
 144     foreach(_file ${_obsolete_sources})
 145         # Skip generated files.
 146         if (NOT _file MATCHES "^(programs/.*|man/bytopic)\\.rst$")
 147             message(STATUS "Removing obsolete Sphinx input ${_file}")
 148             file(REMOVE ${SPHINX_INPUT_DIR}/${_file})
 149         endif()
 150     endforeach()
 151
 152     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 153         EXTRA_VARS
 154             SPHINX_EXTENSION_PATH
 155             EXPECTED_DOXYGEN_VERSION
 156             GMX_CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 157             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 158             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 159         COMMENT "Configuring Sphinx configuration file")
 160     set(SPHINX_INPUT_FILES ${SPHINX_CONFIG_VARS_FILE})
 161     foreach(_file ${SPHINX_SOURCE_FILES})
 162         add_custom_command(
 163             OUTPUT ${SPHINX_INPUT_DIR}/${_file}
 164             COMMAND ${CMAKE_COMMAND} -E copy
 165                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 166                 ${SPHINX_INPUT_DIR}/${_file}
 167             DEPENDS
 168                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 169             COMMENT "Copying Sphinx input file ${_file}"
 170             VERBATIM)
 171         list(APPEND SPHINX_INPUT_FILES ${SPHINX_INPUT_DIR}/${_file})
 172     endforeach()
 173     gmx_add_custom_output_target(sphinx-input OUTPUT STAMP
 174         DEPENDS ${SPHINX_INPUT_FILES})
 175     # TODO: Make this remove obsolete .rst files.
 176     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 177         COMMAND ${CMAKE_COMMAND} -E make_directory programs
 178         COMMAND gmx -quiet help -export rst
 179         DEPENDS gmx
 180         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 181         COMMENT "Generating reStructuredText help")
 182     # This dependency ensures that the directories exist before the
 183     # executable tries to write things there.
 184     add_dependencies(sphinx-programs sphinx-input)
 185
 186     # Make the INSTALL file for CPack for the tarball. This gets put
 187     # into the tarball via the CPack rules below, which requires that
 188     # the INSTALL file is in a separate directory by itself.
 189     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 190     add_custom_target(install-guide
 191         COMMAND
 192             ${SPHINX_EXECUTABLE}
 193             -q -b text
 194             -w sphinx-install.log
 195             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 196             -c ${SPHINX_INPUT_DIR}
 197             "${SPHINX_INPUT_DIR}/install-guide"
 198             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 199         COMMAND
 200             ${CMAKE_COMMAND} -E rename
 201             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 202             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 203         WORKING_DIRECTORY
 204             ${CMAKE_CURRENT_BINARY_DIR}
 205         COMMENT "Building INSTALL with Sphinx"
 206         VERBATIM
 207         )
 208     add_dependencies(install-guide sphinx-input)
 209     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 210
 211     # Sphinx cache with pickled ReST documents
 212     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 213
 214     add_custom_target(webpage-sphinx
 215         COMMAND
 216             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 217         COMMAND
 218             ${SPHINX_EXECUTABLE}
 219             -q -b html
 220             -w sphinx-html.log
 221             -d "${SPHINX_CACHE_DIR}"
 222             "${SPHINX_INPUT_DIR}"
 223             "${HTML_OUTPUT_DIR}"
 224         WORKING_DIRECTORY
 225             ${CMAKE_CURRENT_BINARY_DIR}
 226         COMMENT "Building HTML documentation with Sphinx"
 227         VERBATIM
 228         )
 229     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 230
 231     add_custom_target(man
 232         COMMAND
 233             ${SPHINX_EXECUTABLE}
 234             -q -b man
 235             -w sphinx-man.log
 236             -d ${SPHINX_CACHE_DIR}
 237             -t do_man
 238             ${SPHINX_INPUT_DIR}
 239             ${CMAKE_CURRENT_BINARY_DIR}/man
 240         COMMENT "Building man pages with Sphinx"
 241         VERBATIM)
 242     add_dependencies(man sphinx-input sphinx-programs)
 243     if (GMX_BUILD_HELP)
 244         # If requested, install the man pages built by the 'man' target
 245         # created above.  Nothing will be installed if the user did not
 246         # manually build the target.
 247         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 248     endif()
 249 endif()
 250
 251 if (MAN_PAGE_DIR)
 252     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 253     # Trailing slash on directory is significant for
 254     # install(DIRECTORY). See CMake docs.
 255     install(DIRECTORY ${MAN_PAGE_DIR}/
 256         DESTINATION ${MAN_INSTALL_DIR}/man1
 257         COMPONENT man OPTIONAL
 258         FILES_MATCHING PATTERN "*.1")
 259     install(DIRECTORY ${MAN_PAGE_DIR}/
 260         DESTINATION ${MAN_INSTALL_DIR}/man7
 261         COMPONENT man OPTIONAL
 262         FILES_MATCHING PATTERN "*.7")
 263 endif()
 264 gmx_cpack_add_generated_source_directory(man)
 265
 266 set(HTML_BUILD_IS_POSSIBLE OFF)
 267 # We can only configure to build the webpage if the user asked for it,
 268 # the build is outside of the source dir, and all the components can
 269 # be built. There's no intrinsic need to be talkative if we fail -
 270 # most people never need to know, unless they've asked for the webpage
 271 # build.
 272 if(GMX_BUILD_WEBPAGE)
 273     set(HTML_BUILD_IS_POSSIBLE ON)
 274     # Next, turn it off in any of the preconditions are unsatisified
 275
 276     if(NOT MANUAL_BUILD_IS_POSSIBLE)
 277         set(HTML_BUILD_IS_POSSIBLE OFF)
 278         message(STATUS "Cannot build webpage without being able to build the reference PDF manual")
 279     endif()
 280
 281     if(NOT PYTHON_EXECUTABLE)
 282         set(HTML_BUILD_IS_POSSIBLE OFF)
 283         message(STATUS "Cannot build webpage without python")
 284     endif()
 285
 286     if(NOT SPHINX_FOUND)
 287         set(HTML_BUILD_IS_POSSIBLE OFF)
 288         message(STATUS "Cannot build webpage without sphinx")
 289     endif()
 290
 291     if(NOT DOXYGEN_EXECUTABLE)
 292         set(HTML_BUILD_IS_POSSIBLE OFF)
 293         message(STATUS "Cannot build webpage without doxygen")
 294     endif()
 295
 296     if(NOT DOXYGEN_MSCGEN_EXECUTABLE)
 297         set(HTML_BUILD_IS_POSSIBLE OFF)
 298         message(STATUS "Cannot build webpage without mscgen")
 299     endif()
 300 endif()
 301
 302 if(HTML_BUILD_IS_POSSIBLE)
 303     # Make the PDF reference guide
 304     # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 305     add_custom_command(
 306         OUTPUT ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 307         COMMAND ${CMAKE_COMMAND}
 308             -E remove -f ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 309         COMMAND ${CMAKE_COMMAND}
 310             -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 311         # UseLATEX.cmake makes a target called pdf, not ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf
 312         DEPENDS pdf
 313         VERBATIM
 314         )
 315
 316     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 317     # makes all the Doxygen output directly in
 318     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 319     # to).
 320
 321     # Add a top-level target for the others to hook onto
 322     add_custom_target(webpage
 323         DEPENDS ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 324     add_dependencies(webpage webpage-sphinx doxygen-all)
 325 else()
 326     add_custom_target(webpage
 327         COMMAND ${CMAKE_COMMAND} -E echo "Cannot build webpage because of missing requirements. Check cmake status output for reasons"
 328         COMMENT "Webpage build disabled"
 329         )
 330 endif()