docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 find_package(PythonInterp)
  62 find_package(Sphinx 1.2.3 COMPONENTS pygments)
  63
  64 # Even if we aren't going to make the full webpage, set up to put all
  65 # the documentation output in the same place, for convenience
  66 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  67 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  68
  69 # The directory from which man pages will be installed; if it remains
  70 # empty, they will be silently skipped.
  71 set(MAN_PAGE_DIR)
  72 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  73     # When building from the tarball, install the bundled man pages
  74     # (unless overridden).
  75     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  76 endif()
  77
  78 add_subdirectory(doxygen)
  79 add_subdirectory(manual)
  80
  81 if (SPHINX_FOUND)
  82     # We need to have all the Sphinx input files in a single directory, and
  83     # since some of them are generated, we copy everything into the build tree,
  84     # to this directory.
  85     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  86     set(SPHINX_CONFIG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/conf.py)
  87     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
  88     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  89     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_TARBALL)
  90         # The real build of the webpage happens from the tarball, and
  91         # this should be set to the matching MD5 sum.
  92         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
  93     else()
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     endif()
  98     set(SPHINX_SOURCE_FILES
  99         index.rst
 100         download.rst
 101         dev-manual/index.rst
 102         dev-manual/build-system.rst
 103         dev-manual/doxygen.rst
 104         dev-manual/formatting.rst
 105         dev-manual/gmxtree.rst
 106         dev-manual/includestyle.rst
 107         dev-manual/jenkins.rst
 108         dev-manual/naming.rst
 109         dev-manual/overview.rst
 110         dev-manual/relocatable-binaries.rst
 111         dev-manual/style.rst
 112         dev-manual/testutils.rst
 113         dev-manual/tools.rst
 114         dev-manual/uncrustify.rst
 115         fragments/doxygen-links.rst
 116         install-guide/index.rst
 117         user-guide/index.rst
 118         user-guide/getting-started.rst
 119         user-guide/flow.rst
 120         user-guide/cutoff-schemes.rst
 121         user-guide/mdrun-features.rst
 122         user-guide/mdrun-performance.rst
 123         user-guide/mdp-options.rst
 124         user-guide/file-formats.rst
 125         user-guide/tools.rst
 126         user-guide/environment-variables.rst
 127         user-guide/plotje.gif
 128         user-guide/xvgr.gif
 129         conf.py
 130         links.dat
 131         )
 132
 133     # Remove other rst files from the build tree, since they confuse Sphinx.
 134     file(GLOB_RECURSE _obsolete_sources RELATIVE ${SPHINX_INPUT_DIR}
 135          ${SPHINX_INPUT_DIR}/*.rst)
 136     list(REMOVE_ITEM _obsolete_sources ${SPHINX_SOURCE_FILES})
 137     foreach(_file ${_obsolete_sources})
 138         # Skip generated files in onlinehelp/, and fragments.
 139         # The latter do not cause issues with obsolete files, as they
 140         # are not considered as Sphinx input files, but will only be
 141         # included using an explicit .. include::.
 142         if (NOT _file MATCHES "^(onlinehelp|fragments)/.*\\.rst$")
 143             message(STATUS "Removing obsolete Sphinx input ${_file}")
 144             file(REMOVE ${SPHINX_INPUT_DIR}/${_file})
 145         endif()
 146     endforeach()
 147
 148     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 149         EXTRA_VARS
 150             SPHINX_EXTENSION_PATH
 151             EXPECTED_DOXYGEN_VERSION
 152             GMX_CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 153             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 154             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 155         COMMENT "Configuring Sphinx configuration file")
 156     set(SPHINX_INPUT_FILES ${SPHINX_CONFIG_VARS_FILE})
 157     foreach(_file ${SPHINX_SOURCE_FILES})
 158         add_custom_command(
 159             OUTPUT ${SPHINX_INPUT_DIR}/${_file}
 160             COMMAND ${CMAKE_COMMAND} -E copy
 161                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 162                 ${SPHINX_INPUT_DIR}/${_file}
 163             DEPENDS
 164                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 165             COMMENT "Copying Sphinx input file ${_file}"
 166             VERBATIM)
 167         list(APPEND SPHINX_INPUT_FILES ${SPHINX_INPUT_DIR}/${_file})
 168     endforeach()
 169     gmx_add_custom_output_target(sphinx-input OUTPUT STAMP
 170         DEPENDS ${SPHINX_INPUT_FILES})
 171     # TODO: Make this remove obsolete .rst files.
 172     # TODO: This does not work in cross-compilation scenarios; disable up to
 173     # the necessary level.
 174     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 175         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 176         COMMAND gmx -quiet help -export rst
 177         DEPENDS gmx
 178         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 179         COMMENT "Generating reStructuredText help")
 180     # This dependency ensures that the directories exist before the
 181     # executable tries to write things there.
 182     add_dependencies(sphinx-programs sphinx-input)
 183
 184     # Make the INSTALL file for CPack for the tarball. This gets put
 185     # into the tarball via the CPack rules below, which requires that
 186     # the INSTALL file is in a separate directory by itself.
 187     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 188     add_custom_target(install-guide
 189         COMMAND
 190             ${SPHINX_EXECUTABLE}
 191             -q -b text
 192             -w sphinx-install.log
 193             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 194             -c ${SPHINX_INPUT_DIR}
 195             "${SPHINX_INPUT_DIR}/install-guide"
 196             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 197         COMMAND
 198             ${CMAKE_COMMAND} -E rename
 199             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 200             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 201         WORKING_DIRECTORY
 202             ${CMAKE_CURRENT_BINARY_DIR}
 203         COMMENT "Building INSTALL with Sphinx"
 204         VERBATIM
 205         )
 206     add_dependencies(install-guide sphinx-input)
 207     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 208
 209     # Sphinx cache with pickled ReST documents
 210     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 211
 212     add_custom_target(webpage-sphinx
 213         COMMAND
 214             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 215         COMMAND
 216             ${SPHINX_EXECUTABLE}
 217             -q -b html
 218             -w sphinx-html.log
 219             -d "${SPHINX_CACHE_DIR}"
 220             "${SPHINX_INPUT_DIR}"
 221             "${HTML_OUTPUT_DIR}"
 222         WORKING_DIRECTORY
 223             ${CMAKE_CURRENT_BINARY_DIR}
 224         COMMENT "Building HTML documentation with Sphinx"
 225         VERBATIM
 226         )
 227     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 228
 229     add_custom_target(man
 230         COMMAND
 231             ${SPHINX_EXECUTABLE}
 232             -q -b man
 233             -w sphinx-man.log
 234             -d ${SPHINX_CACHE_DIR}
 235             -t do_man
 236             ${SPHINX_INPUT_DIR}
 237             ${CMAKE_CURRENT_BINARY_DIR}/man
 238         COMMENT "Building man pages with Sphinx"
 239         VERBATIM)
 240     add_dependencies(man sphinx-input sphinx-programs)
 241     if (GMX_BUILD_HELP)
 242         # If requested, install the man pages built by the 'man' target
 243         # created above.  Nothing will be installed if the user did not
 244         # manually build the target.
 245         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 246     endif()
 247 else()
 248     add_custom_target(webpage-sphinx
 249         COMMAND ${CMAKE_COMMAND} -E echo
 250             "HTML pages cannot be built because Sphinx is not available"
 251         VERBATIM)
 252     add_custom_target(man
 253         COMMAND ${CMAKE_COMMAND} -E echo
 254             "man pages cannot be built because Sphinx is not available"
 255         VERBATIM)
 256 endif()
 257
 258 if (MAN_PAGE_DIR)
 259     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 260     # Trailing slash on directory is significant for
 261     # install(DIRECTORY). See CMake docs.
 262     install(DIRECTORY ${MAN_PAGE_DIR}/
 263         DESTINATION ${MAN_INSTALL_DIR}/man1
 264         COMPONENT man OPTIONAL
 265         FILES_MATCHING PATTERN "*.1")
 266     install(DIRECTORY ${MAN_PAGE_DIR}/
 267         DESTINATION ${MAN_INSTALL_DIR}/man7
 268         COMPONENT man OPTIONAL
 269         FILES_MATCHING PATTERN "*.7")
 270 endif()
 271 gmx_cpack_add_generated_source_directory(man)
 272
 273 # Determine whether we can build all the HTML pages and content linked from
 274 # there.  If not, construct an informative message if the user tries to
 275 # build the target; most people never need to know, unless they've asked for
 276 # the webpage build.
 277 set(HTML_BUILD_IS_POSSIBLE ON)
 278 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 279 set(HTML_BUILD_WARNINGS)
 280
 281 # Next, turn it off if any of the preconditions are unsatisified
 282 if (NOT PYTHON_EXECUTABLE)
 283     set(HTML_BUILD_IS_POSSIBLE OFF)
 284     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 285 elseif (NOT SPHINX_FOUND)
 286     # Hardly anything gets built if Sphinx is not available, so don't bother.
 287     set(HTML_BUILD_IS_POSSIBLE OFF)
 288     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx is required")
 289 endif()
 290 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 291     list(APPEND HTML_BUILD_WARNINGS
 292          "Reference PDF manual was not built, so links to it do not work")
 293 endif()
 294 if (NOT DOXYGEN_EXECUTABLE)
 295     list(APPEND HTML_BUILD_WARNINGS
 296         "Doxygen was not available, so links to Doxygen do not work")
 297 endif()
 298 if (NOT DOXYGEN_DOT_EXECUTABLE)
 299     list(APPEND HTML_BUILD_WARNINGS
 300         "dot/graphviz was not found, so some graphs are missing")
 301 endif()
 302
 303 if (HTML_BUILD_IS_POSSIBLE)
 304     set(_webpage_target_properties)
 305     if (HTML_BUILD_WARNINGS)
 306         list(APPEND _webpage_target_properties
 307              COMMAND ${CMAKE_COMMAND} -E echo
 308                  "webpage was built, but with the following limitations:")
 309         foreach(_warning ${HTML_BUILD_WARNINGS})
 310         list(APPEND _webpage_target_properties
 311              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 312         endforeach()
 313     endif()
 314
 315     if (MANUAL_BUILD_IS_POSSIBLE)
 316         # Make the PDF reference guide
 317         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 318         # TODO Make this depend on the output of the manual build, so that the
 319         # file actually gets copied multiple times.
 320         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 321         add_custom_command(
 322             OUTPUT ${_manual_target_location}
 323             COMMAND ${CMAKE_COMMAND}
 324                 -E remove -f ${_manual_target_location}
 325             COMMAND ${CMAKE_COMMAND}
 326                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 327             DEPENDS manual
 328             VERBATIM)
 329         list(APPEND _webpage_target_properties
 330              DEPENDS ${_manual_target_location})
 331     endif()
 332
 333     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 334     # makes all the Doxygen output directly in
 335     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 336     # to).
 337
 338     # Add a top-level target that builds everything related to the webpage,
 339     # for Jenkins (and possibly others) to use
 340     add_custom_target(webpage ${_webpage_target_properties}
 341         COMMENT "Building webpage"
 342         VERBATIM)
 343     add_dependencies(webpage webpage-sphinx doxygen-all)
 344 else()
 345     add_custom_target(webpage
 346         COMMAND ${CMAKE_COMMAND} -E echo
 347             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 348         COMMENT "Webpage build not possible"
 349         VERBATIM)
 350 endif()