docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.6.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68
  69
  70 if (NOT ${PYTHON_VERSION_MAJOR} EQUAL 3)
  71     find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  72 else()
  73     MESSAGE(STATUS "Can not build documentation with Python 3")
  74 endif()
  75
  76 # Even if we aren't going to make the full webpage, set up to put all
  77 # the documentation output in the same place, for convenience
  78 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  79 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  80
  81 # Prepare directories for pdf/tex output
  82 set(TEX_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/manual")
  83 set(SPHINX_LATEX_FILE "${TEX_OUTPUT_DIR}/gromacs.tex")
  84 file(MAKE_DIRECTORY ${TEX_OUTPUT_DIR})
  85
  86 # The directory from which man pages will be installed; if it remains
  87 # empty, they will be silently skipped.
  88 set(MAN_PAGE_DIR)
  89 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  90     # When building from the tarball, install the bundled man pages
  91     # (unless overridden).
  92     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  93 endif()
  94
  95 add_subdirectory(doxygen)
  96
  97 # TODO: Consider whether this could just be replaced by using
  98 # GMX_DEVELOPER_BUILD to control this as well.
  99 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 100 mark_as_advanced(GMX_BUILD_MANUAL)
 101
 102 set(MANUAL_BUILD_IS_POSSIBLE ON)
 103 set(MANUAL_BUILD_NOT_POSSIBLE_REASON)
 104 set(NO_IMAGE_CONVERT_REASON)
 105 if (NOT GMX_BUILD_MANUAL)
 106     # Make sure we only do detection of manual-building dependencies
 107     # when the user opted in for that.
 108     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 109     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "GMX_BUILD_MANUAL is not ON")
 110 elseif (BUILD_IS_INSOURCE)
 111     # UseLATEX.cmake does not work with an in-source build
 112     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 113     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "the build is in-source")
 114 else()
 115     include(manual/UseLATEX.cmake)
 116     if(${PYTHON_VERSION_MAJOR} EQUAL 3)
 117         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 118         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "We can not build the documentation when using python3")
 119     elseif(NOT SPHINX_FOUND)
 120         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 121         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx has not been found and is needed to create the LaTex input files")
 122     elseif(NOT PDFLATEX_COMPILER OR NOT IMAGE_CONVERT_POSSIBLE)
 123         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 124         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "pdflatex or some other dependency (ImageMagick convert) is not available")
 125         if (NOT IMAGE_CONVERT_POSSIBLE)
 126             set(NO_IMAGE_CONVERT_REASON "Can not convert files for online or pdf manual")
 127         endif()
 128         # TODO Later, identify other dependencies like bibtex,
 129         # make_index, date, some graphics conversion program,
 130         # etc. Perhaps patch UseLATEX.cmake and contribute upstream.
 131     endif()
 132
 133 endif()
 134
 135 if (SPHINX_FOUND)
 136     # We need to have all the Sphinx input files in a single directory, and
 137     # since some of them are generated, we copy everything into the build tree,
 138     # to this directory.
 139     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
 140     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 141     # As the manual build now depends also on Sphinx, the inclusion path needs
 142     # to be set after we know the basic information for Sphinx.
 143     add_subdirectory(manual)
 144     if (SOURCE_MD5SUM STREQUAL "unknown")
 145         # But for testing the webpage build (e.g. from the repo) we
 146         # need a default value.
 147         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 148     else()
 149         # The real build of the webpage happens from the tarball, and
 150         # this should be set to the matching MD5 sum.
 151         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 152     endif()
 153     # The reference manual still contains the individual sections from the
 154     # LaTeX document, with the files below grouped and annotated by chapter.
 155     set(REFERENCEMANUAL_SPHINX_FILES_GENERAL
 156         # Main index file, preface and introduction.
 157         reference-manual/index.rst
 158         reference-manual/preface.rst
 159         reference-manual/introduction.rst
 160         # Definitions and Units chapter
 161         reference-manual/definitions.rst
 162         # Topologies chapter
 163         reference-manual/topologies.rst
 164         reference-manual/topologies/particle-type.rst
 165         reference-manual/topologies/parameter-files.rst
 166         reference-manual/topologies/molecule-definition.rst
 167         reference-manual/topologies/constraint-algorithm-section.rst
 168         reference-manual/topologies/pdb2gmx-input-files.rst
 169         reference-manual/topologies/topology-file-formats.rst
 170         reference-manual/topologies/force-field-organization.rst
 171         # File formats chapter
 172         reference-manual/file-formats.rst
 173         # Run parameters and programs chapter
 174         reference-manual/run-parameters.rst
 175         # Implementation details chapter
 176         reference-manual/details.rst
 177         # Averages and fluctations chapter
 178         reference-manual/averages.rst
 179         # References
 180         reference-manual/references.rst
 181         # PNG formated plot files that don't need to be converted into PNG
 182         # for the web page.
 183         reference-manual/plots/peregrine.png
 184         reference-manual/plots/adress.png
 185         reference-manual/plots/plotje.png
 186         reference-manual/plots/xvgr.png
 187         )
 188     set(REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES
 189         # Algorithms chapter
 190         reference-manual/algorithms.rst
 191         reference-manual/algorithms/periodic-boundary-conditions.rst
 192         reference-manual/algorithms/group-concept.rst
 193         reference-manual/algorithms/molecular-dynamics.rst
 194         reference-manual/algorithms/shell-molecular-dynamics.rst
 195         reference-manual/algorithms/constraint-algorithms.rst
 196         reference-manual/algorithms/simulated-annealing.rst
 197         reference-manual/algorithms/stochastic-dynamics.rst
 198         reference-manual/algorithms/brownian-dynamics.rst
 199         reference-manual/algorithms/energy-minimization.rst
 200         reference-manual/algorithms/normal-mode-analysis.rst
 201         reference-manual/algorithms/free-energy-calculations.rst
 202         reference-manual/algorithms/replica-exchange.rst
 203         reference-manual/algorithms/essential-dynamics.rst
 204         reference-manual/algorithms/expanded-ensemble.rst
 205         reference-manual/algorithms/parallelization-domain-decomp.rst
 206         # Interaction functions and force fields chapter
 207         reference-manual/functions.rst
 208         reference-manual/functions/bonded-interactions.rst
 209         reference-manual/functions/force-field.rst
 210         reference-manual/functions/free-energy-interactions.rst
 211         reference-manual/functions/interaction-methods.rst
 212         reference-manual/functions/long-range-electrostatics.rst
 213         reference-manual/functions/long-range-vdw.rst
 214         reference-manual/functions/nonbonded-interactions.rst
 215         reference-manual/functions/polarization.rst
 216         reference-manual/functions/restraints.rst
 217         # Special topics chapter
 218         reference-manual/special.rst
 219         reference-manual/special/free-energy-implementation.rst
 220         reference-manual/special/pulling.rst
 221         reference-manual/special/awh.rst
 222         reference-manual/special/enforced-rotation.rst
 223         reference-manual/special/electric-fields.rst
 224         reference-manual/special/comp-electrophys.rst
 225         reference-manual/special/free-energy-pmf.rst
 226         reference-manual/special/remove-fast-dgf.rst
 227         reference-manual/special/viscosity-calculation.rst
 228         reference-manual/special/tabulated-interaction-functions.rst
 229         reference-manual/special/qmmm.rst
 230         reference-manual/special/vmd-imd.rst
 231         reference-manual/special/membrane-embedding.rst
 232         # Analysis chapter
 233         reference-manual/analysis.rst
 234         reference-manual/analysis/using-groups.rst
 235         reference-manual/analysis/looking-at-trajectory.rst
 236         reference-manual/analysis/general-properties.rst
 237         reference-manual/analysis/radial-distribution-function.rst
 238         reference-manual/analysis/correlation-function.rst
 239         reference-manual/analysis/curve-fitting.rst
 240         reference-manual/analysis/mean-square-displacement.rst
 241         reference-manual/analysis/bond-angle-dihedral.rst
 242         reference-manual/analysis/radius-of-gyration.rst
 243         reference-manual/analysis/rmsd.rst
 244         reference-manual/analysis/covariance-analysis.rst
 245         reference-manual/analysis/dihedral-pca.rst
 246         reference-manual/analysis/protein-related.rst
 247         reference-manual/analysis/interface-related.rst)
 248     # The image files have also been ordered by the respective
 249     # chapter they are included in in the reference manual
 250     set(REFERENCEMANUAL_IMAGE_FILES
 251         # General folder
 252         reference-manual/plots/decomp.pdf
 253         reference-manual/plots/dih.pdf
 254         reference-manual/plots/drift-all.pdf
 255         reference-manual/plots/f-angle.pdf
 256         reference-manual/plots/f-bond.pdf
 257         reference-manual/plots/fp-highres.pdf
 258         reference-manual/plots/int-mat.pdf
 259         reference-manual/plots/mdpar.pdf
 260         reference-manual/plots/parsort.pdf
 261         reference-manual/plots/ring.pdf
 262         reference-manual/plots/shiftf.pdf
 263         # Algorithms chapter
 264         reference-manual/algorithms/plots/dd-cells.pdf
 265         reference-manual/algorithms/plots/dd-tric.pdf
 266         reference-manual/algorithms/plots/flowchart.pdf
 267         reference-manual/algorithms/plots/free1.pdf
 268         reference-manual/algorithms/plots/free2.pdf
 269         reference-manual/algorithms/plots/leapfrog.pdf
 270         reference-manual/algorithms/plots/lincs.pdf
 271         reference-manual/algorithms/plots/maxwell.pdf
 272         reference-manual/algorithms/plots/mpmd-pme.pdf
 273         reference-manual/algorithms/plots/nstric.pdf
 274         reference-manual/algorithms/plots/par-lincs2.pdf
 275         reference-manual/algorithms/plots/pbctric.pdf
 276         reference-manual/algorithms/plots/rhododec.pdf
 277         reference-manual/algorithms/plots/truncoct.pdf
 278         reference-manual/algorithms/plots/verlet-drift.pdf
 279         # Interaction functions chapter
 280         reference-manual/functions/plots/angle.pdf
 281         reference-manual/functions/plots/bstretch.pdf
 282         reference-manual/functions/plots/chain.pdf
 283         reference-manual/functions/plots/dummies.pdf
 284         reference-manual/functions/plots/f-bham.pdf
 285         reference-manual/functions/plots/fbposres.pdf
 286         reference-manual/functions/plots/f-dih.pdf
 287         reference-manual/functions/plots/f-dr.pdf
 288         reference-manual/functions/plots/fig-02.pdf
 289         reference-manual/functions/plots/fig-04.pdf
 290         reference-manual/functions/plots/f-imps.pdf
 291         reference-manual/functions/plots/f-lj.pdf
 292         reference-manual/functions/plots/f-morse.pdf
 293         reference-manual/functions/plots/f-pr.pdf
 294         reference-manual/functions/plots/f-rbs.pdf
 295         reference-manual/functions/plots/ring-imp.pdf
 296         reference-manual/functions/plots/softcore.pdf
 297         reference-manual/functions/plots/subst-im.pdf
 298         reference-manual/functions/plots/tetra-im.pdf
 299         reference-manual/functions/plots/vcrf.pdf
 300         reference-manual/functions/plots/vsite-4fdn.pdf
 301         # Special topics chapter
 302         reference-manual/special/plots/awh-invN.pdf
 303         reference-manual/special/plots/awh-pmfs.pdf
 304         reference-manual/special/plots/awh-sampleweights.pdf
 305         reference-manual/special/plots/awh-traj.pdf
 306         reference-manual/special/plots/compelsetup.pdf
 307         reference-manual/special/plots/dumaro.pdf
 308         reference-manual/special/plots/dumtypes.pdf
 309         reference-manual/special/plots/equipotential.pdf
 310         reference-manual/special/plots/field.pdf
 311         reference-manual/special/plots/gaussians.pdf
 312         reference-manual/special/plots/pulldirrel.pdf
 313         reference-manual/special/plots/pull.pdf
 314         reference-manual/special/plots/pullref.pdf
 315         reference-manual/special/plots/rotation.pdf
 316         # Analysis chapter
 317         reference-manual/analysis/plots/dih-def.pdf
 318         reference-manual/analysis/plots/distm.pdf
 319         reference-manual/analysis/plots/dssp.pdf
 320         reference-manual/analysis/plots/hbond-insert.pdf
 321         reference-manual/analysis/plots/hbond.pdf
 322         reference-manual/analysis/plots/hpr-wheel.pdf
 323         reference-manual/analysis/plots/msdwater.pdf
 324         reference-manual/analysis/plots/ngmxdump.pdf
 325         reference-manual/analysis/plots/phipsi.pdf
 326         reference-manual/analysis/plots/rama.pdf
 327         reference-manual/analysis/plots/rdfO-O.pdf
 328         reference-manual/analysis/plots/rdf.pdf
 329         reference-manual/analysis/plots/sgangle.pdf
 330         )
 331     set(SPHINX_SOURCE_FILES
 332         index.rst
 333         download.rst
 334         conf.py
 335         links.dat
 336         dev-manual/build-system.rst
 337         dev-manual/change-management.rst
 338         dev-manual/commitstyle.rst
 339         dev-manual/documentation-generation.rst
 340         dev-manual/contribute.rst
 341         dev-manual/doxygen.rst
 342         dev-manual/error-handling.rst
 343         dev-manual/formatting.rst
 344         dev-manual/gmxtree.rst
 345         dev-manual/includestyle.rst
 346         dev-manual/index.rst
 347         dev-manual/jenkins.rst
 348         dev-manual/language-features.rst
 349         dev-manual/naming.rst
 350         dev-manual/overview.rst
 351         dev-manual/physical_validation.rst
 352         dev-manual/redmine-states.png
 353         dev-manual/relocatable-binaries.rst
 354         dev-manual/reportstyle.rst
 355         dev-manual/style.rst
 356         dev-manual/testutils.rst
 357         dev-manual/tools.rst
 358         dev-manual/uncrustify.rst
 359         fragments/doxygen-links.rst
 360         how-to/index.rst
 361         how-to/beginners.rst
 362         how-to/topology.rst
 363         how-to/special.rst
 364         how-to/visualize.rst
 365         install-guide/index.rst
 366         release-notes/index.rst
 367         release-notes/2019/major/highlights.rst
 368         release-notes/2019/major/features.rst
 369         release-notes/2019/major/performance.rst
 370         release-notes/2019/major/tools.rst
 371         release-notes/2019/major/bugs-fixed.rst
 372         release-notes/2019/major/removed-functionality.rst
 373         release-notes/2019/major/deprecated-functionality.rst
 374         release-notes/2019/major/portability.rst
 375         release-notes/2019/major/miscellaneous.rst
 376         release-notes/2018/2018.5.rst
 377         release-notes/2018/2018.4.rst
 378         release-notes/2018/2018.3.rst
 379         release-notes/2018/2018.2.rst
 380         release-notes/2018/2018.1.rst
 381         release-notes/2018/major/highlights.rst
 382         release-notes/2018/major/features.rst
 383         release-notes/2018/major/performance.rst
 384         release-notes/2018/major/tools.rst
 385         release-notes/2018/major/bugs-fixed.rst
 386         release-notes/2018/major/removed-features.rst
 387         release-notes/2018/major/portability.rst
 388         release-notes/2018/major/miscellaneous.rst
 389         release-notes/2016/2016.5.rst
 390         release-notes/2016/2016.4.rst
 391         release-notes/2016/2016.3.rst
 392         release-notes/2016/2016.2.rst
 393         release-notes/2016/2016.1.rst
 394         release-notes/2016/major/highlights.rst
 395         release-notes/2016/major/new-features.rst
 396         release-notes/2016/major/performance.rst
 397         release-notes/2016/major/tools.rst
 398         release-notes/2016/major/bugs-fixed.rst
 399         release-notes/2016/major/removed-features.rst
 400         release-notes/2016/major/miscellaneous.rst
 401         release-notes/older/index.rst
 402         # the entry for user-guide/index.rst should not appear here,
 403         # as it will be included conditionally further down depending on
 404         # if the documentation will be build with the full reference
 405         # manual or without.
 406         user-guide/cmdline.rst
 407         user-guide/cutoff-schemes.rst
 408         user-guide/deprecation-policy.rst
 409         user-guide/environment-variables.rst
 410         user-guide/faq.rst
 411         user-guide/floating-point.rst
 412         user-guide/flow.rst
 413         user-guide/force-fields.rst
 414         user-guide/getting-started.rst
 415         user-guide/index.rst
 416         user-guide/managing-simulations.rst
 417         user-guide/mdp-options.rst
 418         user-guide/mdrun-features.rst
 419         user-guide/mdrun-performance.rst
 420         user-guide/run-time-errors.rst
 421         user-guide/security.rst
 422         user-guide/system-preparation.rst
 423         user-guide/terminology.rst
 424         )
 425
 426     include(SphinxMacros.cmake)
 427     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 428
 429     # set temporary variables for doi inclusion
 430     # into the manual, plain string + some wrapping
 431     # for release builds, and dummy string for non-release
 432     # builds
 433     if("${GMX_MANUAL_DOI}" STREQUAL "")
 434       # empty string means no doi, set dummy text
 435       set(GMX_MANUAL_DOI_STRING "This is not a release build of GROMACS, so please reference")
 436       set(GMX_MANUAL_DOI_STRING "${GMX_MANUAL_DOI_STRING} one of the GROMACS papers and the base release of the manual.")
 437     else()
 438       # release version, set plain old boring string
 439       set(GMX_MANUAL_DOI_STRING "Please reference this documentation as https://doi.org/${GMX_MANUAL_DOI}.")
 440     endif()
 441     # same for source doi, but modify the text
 442     if("${GMX_SOURCE_DOI}" STREQUAL "")
 443       # empty string means no release build
 444       set(GMX_SOURCE_DOI_STRING "This is not a release build of GROMACS. Please reference one of the")
 445       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} GROMACS papers, as well as the base release that this version is built from.")
 446       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} Also, please state what modifcations have been performed or where the version")
 447       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} was sourced from.")
 448     else()
 449       # release version, give them a doi url string
 450       set(GMX_SOURCE_DOI_STRING "To cite the source code for this release, please cite")
 451       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} https://doi.org/${GMX_SOURCE_DOI}.")
 452     endif()
 453
 454     if(IMAGE_CONVERT_POSSIBLE)
 455         set(IMAGE_CONVERT_STRING "possible")
 456     else()
 457         set(IMAGE_CONVERT_STRING "impossible")
 458     endif()
 459
 460     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 461     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 462         EXTRA_VARS
 463             SPHINX_EXTENSION_PATH RELENG_PATH
 464             IMAGE_CONVERT_STRING
 465             EXPECTED_DOXYGEN_VERSION
 466             EXPECTED_SPHINX_VERSION
 467             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 468             REQUIRED_OPENCL_MIN_VERSION
 469             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 470             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 471             GMX_TNG_MINIMUM_REQUIRED_VERSION
 472             GMX_LMFIT_REQUIRED_VERSION
 473             GMX_MANUAL_DOI_STRING
 474             GMX_SOURCE_DOI_STRING
 475         COMMENT "Configuring Sphinx configuration file")
 476     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 477     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 478     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 479         include(${RELENG_PATH}/docs/FileList.cmake)
 480         gmx_add_sphinx_source_files(
 481             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 482             FILES ${RELENG_SPHINX_FILES})
 483     else()
 484         gmx_add_sphinx_source_files(FILES
 485             dev-manual/releng/index.rst
 486             dev-manual/releng/jenkins-howto.rst
 487             dev-manual/releng/jenkins-ui.rst
 488             )
 489     endif()
 490     gmx_add_sphinx_source_files(
 491         FILES
 492         ${REFERENCEMANUAL_SPHINX_FILES_GENERAL})
 493     if (IMAGE_CONVERT_POSSIBLE)
 494         gmx_add_sphinx_source_files(
 495             FILES
 496             ${REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES}
 497             ${REFERENCEMANUAL_IMAGE_FILES})
 498         gmx_add_sphinx_image_conversion_files(
 499             FILES
 500             ${REFERENCEMANUAL_IMAGE_FILES})
 501     endif()
 502     gmx_add_sphinx_input_target(sphinx-input-rst)
 503     gmx_add_sphinx_image_conversion_target(sphinx-image-conversion)
 504     add_custom_target(sphinx-input)
 505     add_dependencies(sphinx-input sphinx-input-rst sphinx-image-conversion)
 506     # Remove other rst files from the build tree, since they confuse Sphinx.
 507     # Skip generated files in onlinehelp/, and fragments.
 508     # The latter do not cause issues with obsolete files, as they
 509     # are not considered as Sphinx input files, but will only be
 510     # included using an explicit .. include::.
 511     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 512
 513     # TODO: Make this remove obsolete .rst files.
 514     # TODO: This does not work in cross-compilation scenarios; disable up to
 515     # the necessary level.
 516     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 517         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 518         COMMAND gmx -quiet help -export rst
 519         DEPENDS gmx
 520         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 521         COMMENT "Generating reStructuredText help")
 522     # This dependency ensures that the directories exist before the
 523     # executable tries to write things there.
 524     add_dependencies(sphinx-programs sphinx-input)
 525
 526     # Make the INSTALL file for CPack for the tarball. This gets put
 527     # into the tarball via the CPack rules below, which requires that
 528     # the INSTALL file is in a separate directory by itself.
 529     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 530     add_custom_target(install-guide
 531         COMMAND
 532             ${SPHINX_EXECUTABLE}
 533             -q -E -b text
 534             -w sphinx-install.log
 535             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 536             -c ${SPHINX_INPUT_DIR}
 537             "${SPHINX_INPUT_DIR}/install-guide"
 538             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 539         COMMAND
 540             ${CMAKE_COMMAND} -E rename
 541             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 542             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 543         WORKING_DIRECTORY
 544             ${CMAKE_CURRENT_BINARY_DIR}
 545         COMMENT "Building INSTALL with Sphinx"
 546         VERBATIM
 547         )
 548     add_dependencies(install-guide sphinx-input)
 549     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 550
 551     # Sphinx cache with pickled ReST documents
 552     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 553     add_custom_target(webpage-sphinx
 554         DEPENDS sphinx-programs
 555         DEPENDS sphinx-input
 556         DEPENDS sphinx-image-conversion
 557         COMMAND
 558             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 559         COMMAND
 560             ${SPHINX_EXECUTABLE}
 561             -q -E -b html
 562             -w sphinx-html.log
 563             -d "${SPHINX_CACHE_DIR}"
 564             "${SPHINX_INPUT_DIR}"
 565             "${HTML_OUTPUT_DIR}"
 566         WORKING_DIRECTORY
 567             ${CMAKE_CURRENT_BINARY_DIR}
 568         COMMENT "Building HTML documentation with Sphinx"
 569         VERBATIM
 570         )
 571
 572     add_custom_target(man
 573         COMMAND
 574             ${SPHINX_EXECUTABLE}
 575             -q -E -b man
 576             -w sphinx-man.log
 577             -d ${SPHINX_CACHE_DIR}
 578             -t do_man
 579             ${SPHINX_INPUT_DIR}
 580             ${CMAKE_CURRENT_BINARY_DIR}/man
 581         COMMENT "Building man pages with Sphinx"
 582         VERBATIM)
 583     add_dependencies(man sphinx-input sphinx-programs)
 584     if (GMX_BUILD_HELP)
 585         # If requested, install the man pages built by the 'man' target
 586         # created above.  Nothing will be installed if the user did not
 587         # manually build the target.
 588         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 589     endif()
 590
 591 else()
 592     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 593     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is not available")
 594
 595     add_custom_target(webpage-sphinx
 596         COMMAND ${CMAKE_COMMAND} -E echo
 597             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 598         VERBATIM)
 599     add_custom_target(install-guide
 600         COMMAND ${CMAKE_COMMAND} -E echo
 601             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 602         VERBATIM)
 603     add_custom_target(man
 604         COMMAND ${CMAKE_COMMAND} -E echo
 605             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 606         VERBATIM)
 607     add_custom_target(sphinx-create-texman
 608         COMMAND ${CMAKE_COMMAND} -E echo
 609             "Cannot prepare LaTeX input files because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 610         VERBATIM)
 611 endif()
 612
 613 if (MAN_PAGE_DIR)
 614     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 615     # Trailing slash on directory is significant for
 616     # install(DIRECTORY). See CMake docs.
 617     install(DIRECTORY ${MAN_PAGE_DIR}/
 618         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 619         COMPONENT man OPTIONAL
 620         FILES_MATCHING PATTERN "*.1")
 621 endif()
 622 gmx_cpack_add_generated_source_directory(man)
 623
 624 # Determine whether we can build all the HTML pages and content linked from
 625 # there.  If not, construct an informative message if the user tries to
 626 # build the target; most people never need to know, unless they've asked for
 627 # the webpage build.
 628 set(HTML_BUILD_IS_POSSIBLE ON)
 629 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 630 set(HTML_BUILD_WARNINGS)
 631
 632 # Next, turn it off if any of the preconditions are unsatisified
 633 if (NOT PYTHON_EXECUTABLE)
 634     set(HTML_BUILD_IS_POSSIBLE OFF)
 635     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 636 elseif (NOT SPHINX_FOUND)
 637     # Hardly anything gets built if Sphinx is not available, so don't bother.
 638     set(HTML_BUILD_IS_POSSIBLE OFF)
 639     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 640 endif()
 641 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 642     list(APPEND HTML_BUILD_WARNINGS
 643          "Reference PDF manual was not built, so links to it do not work")
 644 endif()
 645 if (NOT DOXYGEN_EXECUTABLE)
 646     list(APPEND HTML_BUILD_WARNINGS
 647         "Doxygen was not available, so links to Doxygen do not work")
 648 endif()
 649 if (NOT DOXYGEN_DOT_EXECUTABLE)
 650     list(APPEND HTML_BUILD_WARNINGS
 651         "dot/graphviz was not found, so some graphs are missing")
 652 endif()
 653
 654 if (HTML_BUILD_IS_POSSIBLE)
 655     set(_webpage_target_properties)
 656     if (HTML_BUILD_WARNINGS)
 657         list(APPEND _webpage_target_properties
 658              COMMAND ${CMAKE_COMMAND} -E echo
 659                  "webpage was built, but with the following limitations:")
 660         foreach(_warning ${HTML_BUILD_WARNINGS})
 661         list(APPEND _webpage_target_properties
 662              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 663         endforeach()
 664     endif()
 665
 666     if (MANUAL_BUILD_IS_POSSIBLE)
 667         # Make the PDF reference guide
 668         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 669         # TODO Make this depend on the output of the manual build, so that the
 670         # file actually gets copied multiple times.
 671         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 672         add_custom_command(
 673             OUTPUT ${_manual_target_location}
 674             COMMAND ${CMAKE_COMMAND}
 675                 -E remove -f ${_manual_target_location}
 676             COMMAND ${CMAKE_COMMAND}
 677                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 678             DEPENDS manual
 679             VERBATIM)
 680         list(APPEND _webpage_target_properties
 681              DEPENDS ${_manual_target_location})
 682     endif()
 683
 684     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 685     # makes all the Doxygen output directly in
 686     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 687     # to).
 688
 689     # Add a top-level target that builds everything related to the webpage,
 690     # for Jenkins (and possibly others) to use
 691     add_custom_target(webpage ${_webpage_target_properties}
 692         COMMENT "Building webpage"
 693         VERBATIM)
 694     add_dependencies(webpage webpage-sphinx doxygen-all)
 695 else()
 696     add_custom_target(webpage
 697         COMMAND ${CMAKE_COMMAND} -E echo
 698             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 699         COMMENT "Webpage build not possible"
 700         VERBATIM)
 701 endif()