docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.4.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # The directory from which man pages will be installed; if it remains
  76 # empty, they will be silently skipped.
  77 set(MAN_PAGE_DIR)
  78 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  79     # When building from the tarball, install the bundled man pages
  80     # (unless overridden).
  81     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  82 endif()
  83
  84 add_subdirectory(doxygen)
  85 add_subdirectory(manual)
  86
  87 if (SPHINX_FOUND)
  88     # We need to have all the Sphinx input files in a single directory, and
  89     # since some of them are generated, we copy everything into the build tree,
  90     # to this directory.
  91     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  92     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  93     if (SOURCE_MD5SUM STREQUAL "unknown")
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     else()
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     endif()
 102     set(SPHINX_SOURCE_FILES
 103         index.rst
 104         download.rst
 105         dev-manual/index.rst
 106         dev-manual/build-system.rst
 107         dev-manual/commitstyle.rst
 108         dev-manual/documentation-generation.rst
 109         dev-manual/doxygen.rst
 110         dev-manual/error-handling.rst
 111         dev-manual/formatting.rst
 112         dev-manual/gmxtree.rst
 113         dev-manual/includestyle.rst
 114         dev-manual/jenkins.rst
 115         dev-manual/language-features.rst
 116         dev-manual/naming.rst
 117         dev-manual/overview.rst
 118         dev-manual/redmine-states.png
 119         dev-manual/relocatable-binaries.rst
 120         dev-manual/reportstyle.rst
 121         dev-manual/style.rst
 122         dev-manual/testutils.rst
 123         dev-manual/tools.rst
 124         dev-manual/uncrustify.rst
 125         fragments/doxygen-links.rst
 126         install-guide/index.rst
 127         release-notes/index.rst
 128         release-notes/2018/2018.4.rst
 129         release-notes/2018/2018.3.rst
 130         release-notes/2018/2018.2.rst
 131         release-notes/2018/2018.1.rst
 132         release-notes/2018/major/highlights.rst
 133         release-notes/2018/major/features.rst
 134         release-notes/2018/major/performance.rst
 135         release-notes/2018/major/tools.rst
 136         release-notes/2018/major/bugs-fixed.rst
 137         release-notes/2018/major/removed-features.rst
 138         release-notes/2018/major/portability.rst
 139         release-notes/2018/major/miscellaneous.rst
 140         release-notes/2016/2016.5.rst
 141         release-notes/2016/2016.4.rst
 142         release-notes/2016/2016.3.rst
 143         release-notes/2016/2016.2.rst
 144         release-notes/2016/2016.1.rst
 145         release-notes/2016/major/highlights.rst
 146         release-notes/2016/major/new-features.rst
 147         release-notes/2016/major/performance.rst
 148         release-notes/2016/major/tools.rst
 149         release-notes/2016/major/bugs-fixed.rst
 150         release-notes/2016/major/removed-features.rst
 151         release-notes/2016/major/miscellaneous.rst
 152         release-notes/older/index.rst
 153         user-guide/index.rst
 154         user-guide/cutoff-schemes.rst
 155         user-guide/getting-started.rst
 156         user-guide/force-fields.rst
 157         user-guide/faq.rst
 158         user-guide/flow.rst
 159         user-guide/floating-point.rst
 160         user-guide/system-preparation.rst
 161         user-guide/managing-simulations.rst
 162         user-guide/mdrun-features.rst
 163         user-guide/mdrun-performance.rst
 164         user-guide/mdp-options.rst
 165         user-guide/run-time-errors.rst
 166         user-guide/file-formats.rst
 167         user-guide/cmdline.rst
 168         user-guide/environment-variables.rst
 169         user-guide/terminology.rst
 170         user-guide/plotje.gif
 171         user-guide/xvgr.gif
 172         conf.py
 173         links.dat
 174         )
 175
 176     include(SphinxMacros.cmake)
 177     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 178
 179     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 180     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 181         EXTRA_VARS
 182             SPHINX_EXTENSION_PATH RELENG_PATH
 183             EXPECTED_DOXYGEN_VERSION
 184             EXPECTED_SPHINX_VERSION
 185             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 186             REQUIRED_OPENCL_MIN_VERSION
 187             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 188             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 189             GMX_TNG_MINIMUM_REQUIRED_VERSION
 190             GMX_LMFIT_MINIMUM_REQUIRED_VERSION
 191         COMMENT "Configuring Sphinx configuration file")
 192     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 193     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 194     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 195         include(${RELENG_PATH}/docs/FileList.cmake)
 196         gmx_add_sphinx_source_files(
 197             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 198             FILES ${RELENG_SPHINX_FILES})
 199     else()
 200         gmx_add_sphinx_source_files(FILES
 201             dev-manual/releng/index.rst
 202             dev-manual/releng/jenkins-howto.rst
 203             dev-manual/releng/jenkins-ui.rst
 204             )
 205     endif()
 206     gmx_add_sphinx_input_target(sphinx-input)
 207     # Remove other rst files from the build tree, since they confuse Sphinx.
 208     # Skip generated files in onlinehelp/, and fragments.
 209     # The latter do not cause issues with obsolete files, as they
 210     # are not considered as Sphinx input files, but will only be
 211     # included using an explicit .. include::.
 212     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 213
 214     # TODO: Make this remove obsolete .rst files.
 215     # TODO: This does not work in cross-compilation scenarios; disable up to
 216     # the necessary level.
 217     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 218         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 219         COMMAND gmx -quiet help -export rst
 220         DEPENDS gmx
 221         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 222         COMMENT "Generating reStructuredText help")
 223     # This dependency ensures that the directories exist before the
 224     # executable tries to write things there.
 225     add_dependencies(sphinx-programs sphinx-input)
 226
 227     # Make the INSTALL file for CPack for the tarball. This gets put
 228     # into the tarball via the CPack rules below, which requires that
 229     # the INSTALL file is in a separate directory by itself.
 230     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 231     add_custom_target(install-guide
 232         COMMAND
 233             ${SPHINX_EXECUTABLE}
 234             -q -b text
 235             -w sphinx-install.log
 236             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 237             -c ${SPHINX_INPUT_DIR}
 238             "${SPHINX_INPUT_DIR}/install-guide"
 239             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 240         COMMAND
 241             ${CMAKE_COMMAND} -E rename
 242             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 243             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 244         WORKING_DIRECTORY
 245             ${CMAKE_CURRENT_BINARY_DIR}
 246         COMMENT "Building INSTALL with Sphinx"
 247         VERBATIM
 248         )
 249     add_dependencies(install-guide sphinx-input)
 250     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 251
 252     # Sphinx cache with pickled ReST documents
 253     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 254
 255     add_custom_target(webpage-sphinx
 256         COMMAND
 257             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 258         COMMAND
 259             ${SPHINX_EXECUTABLE}
 260             -q -b html
 261             -w sphinx-html.log
 262             -d "${SPHINX_CACHE_DIR}"
 263             "${SPHINX_INPUT_DIR}"
 264             "${HTML_OUTPUT_DIR}"
 265         WORKING_DIRECTORY
 266             ${CMAKE_CURRENT_BINARY_DIR}
 267         COMMENT "Building HTML documentation with Sphinx"
 268         VERBATIM
 269         )
 270     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 271
 272     add_custom_target(man
 273         COMMAND
 274             ${SPHINX_EXECUTABLE}
 275             -q -b man
 276             -w sphinx-man.log
 277             -d ${SPHINX_CACHE_DIR}
 278             -t do_man
 279             ${SPHINX_INPUT_DIR}
 280             ${CMAKE_CURRENT_BINARY_DIR}/man
 281         COMMENT "Building man pages with Sphinx"
 282         VERBATIM)
 283     add_dependencies(man sphinx-input sphinx-programs)
 284     if (GMX_BUILD_HELP)
 285         # If requested, install the man pages built by the 'man' target
 286         # created above.  Nothing will be installed if the user did not
 287         # manually build the target.
 288         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 289     endif()
 290 else()
 291     add_custom_target(webpage-sphinx
 292         COMMAND ${CMAKE_COMMAND} -E echo
 293             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 294         VERBATIM)
 295     add_custom_target(install-guide
 296         COMMAND ${CMAKE_COMMAND} -E echo
 297             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 298         VERBATIM)
 299     add_custom_target(man
 300         COMMAND ${CMAKE_COMMAND} -E echo
 301             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 302         VERBATIM)
 303 endif()
 304
 305 if (MAN_PAGE_DIR)
 306     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 307     # Trailing slash on directory is significant for
 308     # install(DIRECTORY). See CMake docs.
 309     install(DIRECTORY ${MAN_PAGE_DIR}/
 310         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 311         COMPONENT man OPTIONAL
 312         FILES_MATCHING PATTERN "*.1")
 313 endif()
 314 gmx_cpack_add_generated_source_directory(man)
 315
 316 # Determine whether we can build all the HTML pages and content linked from
 317 # there.  If not, construct an informative message if the user tries to
 318 # build the target; most people never need to know, unless they've asked for
 319 # the webpage build.
 320 set(HTML_BUILD_IS_POSSIBLE ON)
 321 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 322 set(HTML_BUILD_WARNINGS)
 323
 324 # Next, turn it off if any of the preconditions are unsatisified
 325 if (NOT PYTHON_EXECUTABLE)
 326     set(HTML_BUILD_IS_POSSIBLE OFF)
 327     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 328 elseif (NOT SPHINX_FOUND)
 329     # Hardly anything gets built if Sphinx is not available, so don't bother.
 330     set(HTML_BUILD_IS_POSSIBLE OFF)
 331     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 332 endif()
 333 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 334     list(APPEND HTML_BUILD_WARNINGS
 335          "Reference PDF manual was not built, so links to it do not work")
 336 endif()
 337 if (NOT DOXYGEN_EXECUTABLE)
 338     list(APPEND HTML_BUILD_WARNINGS
 339         "Doxygen was not available, so links to Doxygen do not work")
 340 endif()
 341 if (NOT DOXYGEN_DOT_EXECUTABLE)
 342     list(APPEND HTML_BUILD_WARNINGS
 343         "dot/graphviz was not found, so some graphs are missing")
 344 endif()
 345
 346 if (HTML_BUILD_IS_POSSIBLE)
 347     set(_webpage_target_properties)
 348     if (HTML_BUILD_WARNINGS)
 349         list(APPEND _webpage_target_properties
 350              COMMAND ${CMAKE_COMMAND} -E echo
 351                  "webpage was built, but with the following limitations:")
 352         foreach(_warning ${HTML_BUILD_WARNINGS})
 353         list(APPEND _webpage_target_properties
 354              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 355         endforeach()
 356     endif()
 357
 358     if (MANUAL_BUILD_IS_POSSIBLE)
 359         # Make the PDF reference guide
 360         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 361         # TODO Make this depend on the output of the manual build, so that the
 362         # file actually gets copied multiple times.
 363         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 364         add_custom_command(
 365             OUTPUT ${_manual_target_location}
 366             COMMAND ${CMAKE_COMMAND}
 367                 -E remove -f ${_manual_target_location}
 368             COMMAND ${CMAKE_COMMAND}
 369                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 370             DEPENDS manual
 371             VERBATIM)
 372         list(APPEND _webpage_target_properties
 373              DEPENDS ${_manual_target_location})
 374     endif()
 375
 376     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 377     # makes all the Doxygen output directly in
 378     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 379     # to).
 380
 381     # Add a top-level target that builds everything related to the webpage,
 382     # for Jenkins (and possibly others) to use
 383     add_custom_target(webpage ${_webpage_target_properties}
 384         COMMENT "Building webpage"
 385         VERBATIM)
 386     add_dependencies(webpage webpage-sphinx doxygen-all)
 387 else()
 388     add_custom_target(webpage
 389         COMMAND ${CMAKE_COMMAND} -E echo
 390             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 391         COMMENT "Webpage build not possible"
 392         VERBATIM)
 393 endif()