docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 find_package(PythonInterp)
  62 find_package(Sphinx 1.2.3 COMPONENTS pygments)
  63
  64 # Even if we aren't going to make the full webpage, set up to put all
  65 # the documentation output in the same place, for convenience
  66 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  67 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  68
  69 # The directory from which man pages will be installed; if it remains
  70 # empty, they will be silently skipped.
  71 set(MAN_PAGE_DIR)
  72 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  73     # When building from the tarball, install the bundled man pages
  74     # (unless overridden).
  75     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  76 endif()
  77
  78 add_subdirectory(doxygen)
  79 add_subdirectory(manual)
  80
  81 if (SPHINX_FOUND)
  82     # We need to have all the Sphinx input files in a single directory, and
  83     # since some of them are generated, we copy everything into the build tree,
  84     # to this directory.
  85     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  86     set(SPHINX_CONFIG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/conf.py)
  87     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
  88     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  89     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_TARBALL)
  90         # The real build of the webpage happens from the tarball, and
  91         # this should be set to the matching MD5 sum.
  92         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
  93     else()
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     endif()
  98     set(SPHINX_SOURCE_FILES
  99         index.rst
 100         download.rst
 101         dev-manual/index.rst
 102         dev-manual/doxygen.rst
 103         dev-manual/formatting.rst
 104         dev-manual/gmxtree.rst
 105         dev-manual/includestyle.rst
 106         dev-manual/naming.rst
 107         dev-manual/overview.rst
 108         dev-manual/relocatable-binaries.rst
 109         dev-manual/style.rst
 110         dev-manual/testutils.rst
 111         dev-manual/tools.rst
 112         dev-manual/uncrustify.rst
 113         fragments/doxygen-links.rst
 114         install-guide/index.rst
 115         user-guide/index.rst
 116         user-guide/getting-started.rst
 117         user-guide/flow.rst
 118         user-guide/cutoff-schemes.rst
 119         user-guide/mdrun-features.rst
 120         user-guide/mdrun-performance.rst
 121         user-guide/mdp-options.rst
 122         user-guide/file-formats.rst
 123         user-guide/tools.rst
 124         user-guide/environment-variables.rst
 125         user-guide/plotje.gif
 126         user-guide/xvgr.gif
 127         conf.py
 128         links.dat
 129         )
 130
 131     # Remove other rst files from the build tree, since they confuse Sphinx.
 132     file(GLOB_RECURSE _obsolete_sources RELATIVE ${SPHINX_INPUT_DIR}
 133          ${SPHINX_INPUT_DIR}/*.rst)
 134     list(REMOVE_ITEM _obsolete_sources ${SPHINX_SOURCE_FILES})
 135     foreach(_file ${_obsolete_sources})
 136         # Skip generated files in onlinehelp/, and fragments.
 137         # The latter do not cause issues with obsolete files, as they
 138         # are not considered as Sphinx input files, but will only be
 139         # included using an explicit .. include::.
 140         if (NOT _file MATCHES "^(onlinehelp|fragments)/.*\\.rst$")
 141             message(STATUS "Removing obsolete Sphinx input ${_file}")
 142             file(REMOVE ${SPHINX_INPUT_DIR}/${_file})
 143         endif()
 144     endforeach()
 145
 146     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 147         EXTRA_VARS
 148             SPHINX_EXTENSION_PATH
 149             EXPECTED_DOXYGEN_VERSION
 150             GMX_CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 151             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 152             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 153         COMMENT "Configuring Sphinx configuration file")
 154     set(SPHINX_INPUT_FILES ${SPHINX_CONFIG_VARS_FILE})
 155     foreach(_file ${SPHINX_SOURCE_FILES})
 156         add_custom_command(
 157             OUTPUT ${SPHINX_INPUT_DIR}/${_file}
 158             COMMAND ${CMAKE_COMMAND} -E copy
 159                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 160                 ${SPHINX_INPUT_DIR}/${_file}
 161             DEPENDS
 162                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 163             COMMENT "Copying Sphinx input file ${_file}"
 164             VERBATIM)
 165         list(APPEND SPHINX_INPUT_FILES ${SPHINX_INPUT_DIR}/${_file})
 166     endforeach()
 167     gmx_add_custom_output_target(sphinx-input OUTPUT STAMP
 168         DEPENDS ${SPHINX_INPUT_FILES})
 169     # TODO: Make this remove obsolete .rst files.
 170     # TODO: This does not work in cross-compilation scenarios; disable up to
 171     # the necessary level.
 172     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 173         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 174         COMMAND gmx -quiet help -export rst
 175         DEPENDS gmx
 176         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 177         COMMENT "Generating reStructuredText help")
 178     # This dependency ensures that the directories exist before the
 179     # executable tries to write things there.
 180     add_dependencies(sphinx-programs sphinx-input)
 181
 182     # Make the INSTALL file for CPack for the tarball. This gets put
 183     # into the tarball via the CPack rules below, which requires that
 184     # the INSTALL file is in a separate directory by itself.
 185     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 186     add_custom_target(install-guide
 187         COMMAND
 188             ${SPHINX_EXECUTABLE}
 189             -q -b text
 190             -w sphinx-install.log
 191             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 192             -c ${SPHINX_INPUT_DIR}
 193             "${SPHINX_INPUT_DIR}/install-guide"
 194             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 195         COMMAND
 196             ${CMAKE_COMMAND} -E rename
 197             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 198             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 199         WORKING_DIRECTORY
 200             ${CMAKE_CURRENT_BINARY_DIR}
 201         COMMENT "Building INSTALL with Sphinx"
 202         VERBATIM
 203         )
 204     add_dependencies(install-guide sphinx-input)
 205     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 206
 207     # Sphinx cache with pickled ReST documents
 208     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 209
 210     add_custom_target(webpage-sphinx
 211         COMMAND
 212             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 213         COMMAND
 214             ${SPHINX_EXECUTABLE}
 215             -q -b html
 216             -w sphinx-html.log
 217             -d "${SPHINX_CACHE_DIR}"
 218             "${SPHINX_INPUT_DIR}"
 219             "${HTML_OUTPUT_DIR}"
 220         WORKING_DIRECTORY
 221             ${CMAKE_CURRENT_BINARY_DIR}
 222         COMMENT "Building HTML documentation with Sphinx"
 223         VERBATIM
 224         )
 225     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 226
 227     add_custom_target(man
 228         COMMAND
 229             ${SPHINX_EXECUTABLE}
 230             -q -b man
 231             -w sphinx-man.log
 232             -d ${SPHINX_CACHE_DIR}
 233             -t do_man
 234             ${SPHINX_INPUT_DIR}
 235             ${CMAKE_CURRENT_BINARY_DIR}/man
 236         COMMENT "Building man pages with Sphinx"
 237         VERBATIM)
 238     add_dependencies(man sphinx-input sphinx-programs)
 239     if (GMX_BUILD_HELP)
 240         # If requested, install the man pages built by the 'man' target
 241         # created above.  Nothing will be installed if the user did not
 242         # manually build the target.
 243         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 244     endif()
 245 else()
 246     add_custom_target(webpage-sphinx
 247         COMMAND ${CMAKE_COMMAND} -E echo
 248             "HTML pages cannot be built because Sphinx is not available"
 249         VERBATIM)
 250     add_custom_target(man
 251         COMMAND ${CMAKE_COMMAND} -E echo
 252             "man pages cannot be built because Sphinx is not available"
 253         VERBATIM)
 254 endif()
 255
 256 if (MAN_PAGE_DIR)
 257     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 258     # Trailing slash on directory is significant for
 259     # install(DIRECTORY). See CMake docs.
 260     install(DIRECTORY ${MAN_PAGE_DIR}/
 261         DESTINATION ${MAN_INSTALL_DIR}/man1
 262         COMPONENT man OPTIONAL
 263         FILES_MATCHING PATTERN "*.1")
 264     install(DIRECTORY ${MAN_PAGE_DIR}/
 265         DESTINATION ${MAN_INSTALL_DIR}/man7
 266         COMPONENT man OPTIONAL
 267         FILES_MATCHING PATTERN "*.7")
 268 endif()
 269 gmx_cpack_add_generated_source_directory(man)
 270
 271 # Determine whether we can build all the HTML pages and content linked from
 272 # there.  If not, construct an informative message if the user tries to
 273 # build the target; most people never need to know, unless they've asked for
 274 # the webpage build.
 275 set(HTML_BUILD_IS_POSSIBLE ON)
 276 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 277 set(HTML_BUILD_WARNINGS)
 278
 279 # Next, turn it off if any of the preconditions are unsatisified
 280 if (NOT PYTHON_EXECUTABLE)
 281     set(HTML_BUILD_IS_POSSIBLE OFF)
 282     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 283 elseif (NOT SPHINX_FOUND)
 284     # Hardly anything gets built if Sphinx is not available, so don't bother.
 285     set(HTML_BUILD_IS_POSSIBLE OFF)
 286     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx is required")
 287 endif()
 288 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 289     list(APPEND HTML_BUILD_WARNINGS
 290          "Reference PDF manual was not built, so links to it do not work")
 291 endif()
 292 if (NOT DOXYGEN_EXECUTABLE)
 293     list(APPEND HTML_BUILD_WARNINGS
 294         "Doxygen was not available, so links to Doxygen do not work")
 295 endif()
 296 if (NOT DOXYGEN_DOT_EXECUTABLE)
 297     list(APPEND HTML_BUILD_WARNINGS
 298         "dot/graphviz was not found, so some graphs are missing")
 299 endif()
 300
 301 if (HTML_BUILD_IS_POSSIBLE)
 302     set(_webpage_target_properties)
 303     if (HTML_BUILD_WARNINGS)
 304         list(APPEND _webpage_target_properties
 305              COMMAND ${CMAKE_COMMAND} -E echo
 306                  "webpage was built, but with the following limitations:")
 307         foreach(_warning ${HTML_BUILD_WARNINGS})
 308         list(APPEND _webpage_target_properties
 309              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 310         endforeach()
 311     endif()
 312
 313     if (MANUAL_BUILD_IS_POSSIBLE)
 314         # Make the PDF reference guide
 315         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 316         # TODO Make this depend on the output of the manual build, so that the
 317         # file actually gets copied multiple times.
 318         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 319         add_custom_command(
 320             OUTPUT ${_manual_target_location}
 321             COMMAND ${CMAKE_COMMAND}
 322                 -E remove -f ${_manual_target_location}
 323             COMMAND ${CMAKE_COMMAND}
 324                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 325             DEPENDS manual
 326             VERBATIM)
 327         list(APPEND _webpage_target_properties
 328              DEPENDS ${_manual_target_location})
 329     endif()
 330
 331     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 332     # makes all the Doxygen output directly in
 333     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 334     # to).
 335
 336     # Add a top-level target that builds everything related to the webpage,
 337     # for Jenkins (and possibly others) to use
 338     add_custom_target(webpage ${_webpage_target_properties}
 339         COMMENT "Building webpage"
 340         VERBATIM)
 341     add_dependencies(webpage webpage-sphinx doxygen-all)
 342 else()
 343     add_custom_target(webpage
 344         COMMAND ${CMAKE_COMMAND} -E echo
 345             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 346         COMMENT "Webpage build not possible"
 347         VERBATIM)
 348 endif()