docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 option(GMX_BUILD_WEBPAGE "Whether to try to configure to build the GROMACS static webpages" OFF)
  55 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
  56 mark_as_advanced(GMX_BUILD_WEBPAGE GMX_BUILD_MANUAL)
  57
  58 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  59
  60 find_package(PythonInterp)
  61 find_package(Sphinx 1.2.3 COMPONENTS pygments)
  62
  63 # Even if we aren't going to make the full webpage, set up to put all
  64 # the documentation output in the same place, for convenience
  65 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  66 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  67
  68 # The directory from which man pages will be installed; if it remains
  69 # empty, they will be silently skipped.
  70 set(MAN_PAGE_DIR)
  71 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  72     # When building from the tarball, install the bundled man pages
  73     # (unless overridden).
  74     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  75 endif()
  76
  77 add_subdirectory(doxygen)
  78
  79 set(SOURCE_MD5SUM "unknown" CACHE STRING "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  80 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  81 mark_as_advanced(SOURCE_MD5SUM)
  82
  83 if(GMX_BUILD_MANUAL)
  84     # Make sure we only do detection of manual-building dependencies
  85     # when the user opted in for that.
  86     add_subdirectory(manual)
  87 endif()
  88
  89 if (SPHINX_FOUND)
  90     # We need to have all the Sphinx input files in a single directory, and
  91     # since some of them are generated, we copy everything into the build tree,
  92     # to this directory.
  93     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  94     set(SPHINX_CONFIG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/conf.py)
  95     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
  96     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  97     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_TARBALL)
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     else()
 102         # But for testing the webpage build (e.g. from the repo) we
 103         # need a default value.
 104         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 105     endif()
 106     set(SPHINX_SOURCE_FILES
 107         index.rst
 108         download.rst
 109         dev-manual/index.rst
 110         dev-manual/codelayout.rst
 111         dev-manual/doxygen.rst
 112         dev-manual/formatting.rst
 113         dev-manual/gmxtree.rst
 114         dev-manual/includestyle.rst
 115         dev-manual/naming.rst
 116         dev-manual/overview.rst
 117         dev-manual/style.rst
 118         dev-manual/testutils.rst
 119         dev-manual/tools.rst
 120         dev-manual/uncrustify.rst
 121         fragments/doxygen-links.rst
 122         install-guide/index.rst
 123         user-guide/index.rst
 124         user-guide/getting-started.rst
 125         user-guide/flow.rst
 126         user-guide/cutoff-schemes.rst
 127         user-guide/mdrun-features.rst
 128         user-guide/mdrun-performance.rst
 129         user-guide/mdp-options.rst
 130         user-guide/file-formats.rst
 131         user-guide/tools.rst
 132         user-guide/environment-variables.rst
 133         user-guide/plotje.gif
 134         user-guide/xvgr.gif
 135         conf.py
 136         links.dat
 137         )
 138
 139     # Remove other rst files from the build tree, since they confuse Sphinx.
 140     file(GLOB_RECURSE _obsolete_sources RELATIVE ${SPHINX_INPUT_DIR}
 141          ${SPHINX_INPUT_DIR}/*.rst)
 142     list(REMOVE_ITEM _obsolete_sources ${SPHINX_SOURCE_FILES})
 143     foreach(_file ${_obsolete_sources})
 144         # Skip generated files in onlinehelp/, and fragments.
 145         # The latter do not cause issues with obsolete files, as they
 146         # are not considered as Sphinx input files, but will only be
 147         # included using an explicit .. include::.
 148         if (NOT _file MATCHES "^(onlinehelp|fragments)/.*\\.rst$")
 149             message(STATUS "Removing obsolete Sphinx input ${_file}")
 150             file(REMOVE ${SPHINX_INPUT_DIR}/${_file})
 151         endif()
 152     endforeach()
 153
 154     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 155         EXTRA_VARS
 156             SPHINX_EXTENSION_PATH
 157             EXPECTED_DOXYGEN_VERSION
 158             GMX_CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 159             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 160             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 161         COMMENT "Configuring Sphinx configuration file")
 162     set(SPHINX_INPUT_FILES ${SPHINX_CONFIG_VARS_FILE})
 163     foreach(_file ${SPHINX_SOURCE_FILES})
 164         add_custom_command(
 165             OUTPUT ${SPHINX_INPUT_DIR}/${_file}
 166             COMMAND ${CMAKE_COMMAND} -E copy
 167                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 168                 ${SPHINX_INPUT_DIR}/${_file}
 169             DEPENDS
 170                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 171             COMMENT "Copying Sphinx input file ${_file}"
 172             VERBATIM)
 173         list(APPEND SPHINX_INPUT_FILES ${SPHINX_INPUT_DIR}/${_file})
 174     endforeach()
 175     gmx_add_custom_output_target(sphinx-input OUTPUT STAMP
 176         DEPENDS ${SPHINX_INPUT_FILES})
 177     # TODO: Make this remove obsolete .rst files.
 178     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 179         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 180         COMMAND gmx -quiet help -export rst
 181         DEPENDS gmx
 182         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 183         COMMENT "Generating reStructuredText help")
 184     # This dependency ensures that the directories exist before the
 185     # executable tries to write things there.
 186     add_dependencies(sphinx-programs sphinx-input)
 187
 188     # Make the INSTALL file for CPack for the tarball. This gets put
 189     # into the tarball via the CPack rules below, which requires that
 190     # the INSTALL file is in a separate directory by itself.
 191     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 192     add_custom_target(install-guide
 193         COMMAND
 194             ${SPHINX_EXECUTABLE}
 195             -q -b text
 196             -w sphinx-install.log
 197             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 198             -c ${SPHINX_INPUT_DIR}
 199             "${SPHINX_INPUT_DIR}/install-guide"
 200             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 201         COMMAND
 202             ${CMAKE_COMMAND} -E rename
 203             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 204             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 205         WORKING_DIRECTORY
 206             ${CMAKE_CURRENT_BINARY_DIR}
 207         COMMENT "Building INSTALL with Sphinx"
 208         VERBATIM
 209         )
 210     add_dependencies(install-guide sphinx-input)
 211     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 212
 213     # Sphinx cache with pickled ReST documents
 214     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 215
 216     add_custom_target(webpage-sphinx
 217         COMMAND
 218             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 219         COMMAND
 220             ${SPHINX_EXECUTABLE}
 221             -q -b html
 222             -w sphinx-html.log
 223             -d "${SPHINX_CACHE_DIR}"
 224             "${SPHINX_INPUT_DIR}"
 225             "${HTML_OUTPUT_DIR}"
 226         WORKING_DIRECTORY
 227             ${CMAKE_CURRENT_BINARY_DIR}
 228         COMMENT "Building HTML documentation with Sphinx"
 229         VERBATIM
 230         )
 231     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 232
 233     add_custom_target(man
 234         COMMAND
 235             ${SPHINX_EXECUTABLE}
 236             -q -b man
 237             -w sphinx-man.log
 238             -d ${SPHINX_CACHE_DIR}
 239             -t do_man
 240             ${SPHINX_INPUT_DIR}
 241             ${CMAKE_CURRENT_BINARY_DIR}/man
 242         COMMENT "Building man pages with Sphinx"
 243         VERBATIM)
 244     add_dependencies(man sphinx-input sphinx-programs)
 245     if (GMX_BUILD_HELP)
 246         # If requested, install the man pages built by the 'man' target
 247         # created above.  Nothing will be installed if the user did not
 248         # manually build the target.
 249         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 250     endif()
 251 endif()
 252
 253 if (MAN_PAGE_DIR)
 254     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 255     # Trailing slash on directory is significant for
 256     # install(DIRECTORY). See CMake docs.
 257     install(DIRECTORY ${MAN_PAGE_DIR}/
 258         DESTINATION ${MAN_INSTALL_DIR}/man1
 259         COMPONENT man OPTIONAL
 260         FILES_MATCHING PATTERN "*.1")
 261     install(DIRECTORY ${MAN_PAGE_DIR}/
 262         DESTINATION ${MAN_INSTALL_DIR}/man7
 263         COMPONENT man OPTIONAL
 264         FILES_MATCHING PATTERN "*.7")
 265 endif()
 266 gmx_cpack_add_generated_source_directory(man)
 267
 268 set(HTML_BUILD_IS_POSSIBLE OFF)
 269 # We can only configure to build the webpage if the user asked for it,
 270 # the build is outside of the source dir, and all the components can
 271 # be built. There's no intrinsic need to be talkative if we fail -
 272 # most people never need to know, unless they've asked for the webpage
 273 # build.
 274 if(GMX_BUILD_WEBPAGE)
 275     set(HTML_BUILD_IS_POSSIBLE ON)
 276     # Next, turn it off in any of the preconditions are unsatisified
 277
 278     if(NOT MANUAL_BUILD_IS_POSSIBLE)
 279         set(HTML_BUILD_IS_POSSIBLE OFF)
 280         message(STATUS "Cannot build webpage without being able to build the reference PDF manual")
 281     endif()
 282
 283     if(NOT PYTHON_EXECUTABLE)
 284         set(HTML_BUILD_IS_POSSIBLE OFF)
 285         message(STATUS "Cannot build webpage without python")
 286     endif()
 287
 288     if(NOT SPHINX_FOUND)
 289         set(HTML_BUILD_IS_POSSIBLE OFF)
 290         message(STATUS "Cannot build webpage without sphinx")
 291     endif()
 292
 293     if(NOT DOXYGEN_EXECUTABLE)
 294         set(HTML_BUILD_IS_POSSIBLE OFF)
 295         message(STATUS "Cannot build webpage without doxygen")
 296     endif()
 297
 298     if(NOT DOXYGEN_MSCGEN_EXECUTABLE)
 299         set(HTML_BUILD_IS_POSSIBLE OFF)
 300         message(STATUS "Cannot build webpage without mscgen")
 301     endif()
 302 endif()
 303
 304 if(HTML_BUILD_IS_POSSIBLE)
 305     # Make the PDF reference guide
 306     # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 307     add_custom_command(
 308         OUTPUT ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 309         COMMAND ${CMAKE_COMMAND}
 310             -E remove -f ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 311         COMMAND ${CMAKE_COMMAND}
 312             -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 313         # UseLATEX.cmake makes a target called pdf, not ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf
 314         DEPENDS pdf
 315         VERBATIM
 316         )
 317
 318     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 319     # makes all the Doxygen output directly in
 320     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 321     # to).
 322
 323     # Add a top-level target for the others to hook onto
 324     add_custom_target(webpage
 325         DEPENDS ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 326     add_dependencies(webpage webpage-sphinx doxygen-all)
 327 else()
 328     add_custom_target(webpage
 329         COMMAND ${CMAKE_COMMAND} -E echo "Cannot build webpage because of missing requirements. Check cmake status output for reasons"
 330         COMMENT "Webpage build disabled"
 331         )
 332 endif()