docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   5 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 # This directory provides a unified place for building all kinds of
  37 # GROMACS documentation. This includes some "static" content (Doxygen
  38 # code documentation, reference manual, install guide, old online HTML
  39 # images), and content generated from the gmx program for the various
  40 # tools (man and HTML pages). It also provides the "webpage" target,
  41 # that combines all of the above (except man pages in man format) into
  42 # a form suitable for automated deployment to the GROMACS website. It
  43 # also provides the INSTALL file for the tarball.
  44 #
  45 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  46 # substitutions are configured by CMake (for things like version numbers),
  47 # using gmx_configure_version_file().  This happens during build time instead
  48 # of configure time, because 1) some of the version variables are only
  49 # available during build time, and 2) we don't want to do all the Sphinx setup
  50 # during configuration to save some time when not building the content.
  51 # All of the generated values get put into conf.py (generated from
  52 # conf.cmakein.py).
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.6.1)
  62
  63 # By default, suppress output after first configuration.
  64 if(SPHINX_ALREADY_SEARCHED)
  65     set(Sphinx_FIND_QUIETLY ON)
  66 endif()
  67 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} COMPONENTS pygments)
  68 set(SPHINX_ALREADY_SEARCHED TRUE CACHE BOOL "True if a search for Sphinx has already been done")
  69 mark_as_advanced(SPHINX_ALREADY_SEARCHED)
  70
  71 # Even if we aren't going to make the full webpage, set up to put all
  72 # the documentation output in the same place, for convenience
  73 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  74 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  75
  76 # Prepare directories for pdf/tex output
  77 set(TEX_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/manual")
  78 set(SPHINX_LATEX_FILE "${TEX_OUTPUT_DIR}/gromacs.tex")
  79 file(MAKE_DIRECTORY ${TEX_OUTPUT_DIR})
  80
  81 # The directory from which man pages will be installed; if it remains
  82 # empty, they will be silently skipped.
  83 set(MAN_PAGE_DIR)
  84 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  85     # When building from the tarball, install the bundled man pages
  86     # (unless overridden).
  87     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  88 endif()
  89
  90 add_subdirectory(doxygen)
  91
  92 # TODO: Consider whether this could just be replaced by using
  93 # GMX_DEVELOPER_BUILD to control this as well.
  94 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
  95 mark_as_advanced(GMX_BUILD_MANUAL)
  96
  97 set(MANUAL_BUILD_IS_POSSIBLE ON)
  98 set(MANUAL_BUILD_NOT_POSSIBLE_REASON)
  99 set(NO_IMAGE_CONVERT_REASON)
 100 if (NOT GMX_BUILD_MANUAL)
 101     # Make sure we only do detection of manual-building dependencies
 102     # when the user opted in for that.
 103     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 104     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "GMX_BUILD_MANUAL is not ON")
 105 elseif (BUILD_IS_INSOURCE)
 106     # UseLATEX.cmake does not work with an in-source build
 107     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 108     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "the build is in-source")
 109 else()
 110     include(manual/UseLATEX.cmake)
 111     if(NOT SPHINX_FOUND)
 112         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 113         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx has not been found and is needed to create the LaTex input files")
 114     elseif(NOT PDFLATEX_COMPILER)
 115         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 116         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "pdflatex is not available")
 117     elseif(NOT IMAGE_CONVERT_POSSIBLE)
 118         set(MANUAL_BUILD_IS_POSSIBLE OFF)
 119         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "a working form of ImageMagick convert is not available")
 120         set(NO_IMAGE_CONVERT_REASON "Can not convert files for online or pdf manual")
 121         # TODO Later, identify other dependencies like bibtex,
 122         # make_index, date, some graphics conversion program,
 123         # etc. Perhaps patch UseLATEX.cmake and contribute upstream.
 124     endif()
 125
 126 endif()
 127
 128 if (SPHINX_FOUND)
 129     # We need to have all the Sphinx input files in a single directory, and
 130     # since some of them are generated, we copy everything into the build tree,
 131     # to this directory.
 132     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
 133     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 134     # As the manual build now depends also on Sphinx, the inclusion path needs
 135     # to be set after we know the basic information for Sphinx.
 136     add_subdirectory(manual)
 137     if (SOURCE_MD5SUM STREQUAL "unknown")
 138         # But for testing the webpage build (e.g. from the repo) we
 139         # need a default value.
 140         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 141     else()
 142         # The real build of the webpage happens from the tarball, and
 143         # this should be set to the matching MD5 sum.
 144         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 145     endif()
 146     # The reference manual still contains the individual sections from the
 147     # LaTeX document, with the files below grouped and annotated by chapter.
 148     set(REFERENCEMANUAL_SPHINX_FILES_GENERAL
 149         # Main index file, preface and introduction.
 150         reference-manual/index.rst
 151         reference-manual/preface.rst
 152         reference-manual/introduction.rst
 153         # Definitions and Units chapter
 154         reference-manual/definitions.rst
 155         # Topologies chapter
 156         reference-manual/topologies.rst
 157         reference-manual/topologies/particle-type.rst
 158         reference-manual/topologies/parameter-files.rst
 159         reference-manual/topologies/molecule-definition.rst
 160         reference-manual/topologies/constraint-algorithm-section.rst
 161         reference-manual/topologies/pdb2gmx-input-files.rst
 162         reference-manual/topologies/topology-file-formats.rst
 163         reference-manual/topologies/force-field-organization.rst
 164         # File formats chapter
 165         reference-manual/file-formats.rst
 166         # Run parameters and programs chapter
 167         reference-manual/run-parameters.rst
 168         # Implementation details chapter
 169         reference-manual/details.rst
 170         # Averages and fluctations chapter
 171         reference-manual/averages.rst
 172         # References
 173         reference-manual/references.rst
 174         # PNG formated plot files that don't need to be converted into PNG
 175         # for the web page.
 176         reference-manual/plots/GMX_logos/gmx_falcon_blue.png
 177         reference-manual/plots/adress.png
 178         reference-manual/plots/plotje.png
 179         reference-manual/plots/xvgr.png
 180         )
 181     set(REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES
 182         # Algorithms chapter
 183         reference-manual/algorithms.rst
 184         reference-manual/algorithms/periodic-boundary-conditions.rst
 185         reference-manual/algorithms/group-concept.rst
 186         reference-manual/algorithms/molecular-dynamics.rst
 187         reference-manual/algorithms/shell-molecular-dynamics.rst
 188         reference-manual/algorithms/constraint-algorithms.rst
 189         reference-manual/algorithms/simulated-annealing.rst
 190         reference-manual/algorithms/stochastic-dynamics.rst
 191         reference-manual/algorithms/brownian-dynamics.rst
 192         reference-manual/algorithms/energy-minimization.rst
 193         reference-manual/algorithms/normal-mode-analysis.rst
 194         reference-manual/algorithms/free-energy-calculations.rst
 195         reference-manual/algorithms/replica-exchange.rst
 196         reference-manual/algorithms/essential-dynamics.rst
 197         reference-manual/algorithms/expanded-ensemble.rst
 198         reference-manual/algorithms/parallelization-domain-decomp.rst
 199         # Interaction functions and force fields chapter
 200         reference-manual/functions.rst
 201         reference-manual/functions/bonded-interactions.rst
 202         reference-manual/functions/force-field.rst
 203         reference-manual/functions/free-energy-interactions.rst
 204         reference-manual/functions/interaction-methods.rst
 205         reference-manual/functions/long-range-electrostatics.rst
 206         reference-manual/functions/long-range-vdw.rst
 207         reference-manual/functions/nonbonded-interactions.rst
 208         reference-manual/functions/polarization.rst
 209         reference-manual/functions/restraints.rst
 210         # Special topics chapter
 211         reference-manual/special.rst
 212         reference-manual/special/free-energy-implementation.rst
 213         reference-manual/special/pulling.rst
 214         reference-manual/special/awh.rst
 215         reference-manual/special/enforced-rotation.rst
 216         reference-manual/special/electric-fields.rst
 217         reference-manual/special/comp-electrophys.rst
 218         reference-manual/special/free-energy-pmf.rst
 219         reference-manual/special/remove-fast-dgf.rst
 220         reference-manual/special/viscosity-calculation.rst
 221         reference-manual/special/tabulated-interaction-functions.rst
 222         reference-manual/special/qmmm.rst
 223         reference-manual/special/vmd-imd.rst
 224         reference-manual/special/membrane-embedding.rst
 225         reference-manual/special/mimic-qmmm.rst
 226         reference-manual/special/density-guided-simulation.rst
 227         # Analysis chapter
 228         reference-manual/analysis.rst
 229         reference-manual/analysis/using-groups.rst
 230         reference-manual/analysis/looking-at-trajectory.rst
 231         reference-manual/analysis/general-properties.rst
 232         reference-manual/analysis/radial-distribution-function.rst
 233         reference-manual/analysis/correlation-function.rst
 234         reference-manual/analysis/curve-fitting.rst
 235         reference-manual/analysis/mean-square-displacement.rst
 236         reference-manual/analysis/bond-angle-dihedral.rst
 237         reference-manual/analysis/radius-of-gyration.rst
 238         reference-manual/analysis/rmsd.rst
 239         reference-manual/analysis/covariance-analysis.rst
 240         reference-manual/analysis/dihedral-pca.rst
 241         reference-manual/analysis/hydrogen-bonds.rst
 242         reference-manual/analysis/protein-related.rst
 243         reference-manual/analysis/interface-related.rst)
 244     # The image files have also been ordered by the respective
 245     # chapter they are included in in the reference manual
 246     set(REFERENCEMANUAL_IMAGE_FILES
 247         # General folder
 248         reference-manual/plots/decomp.pdf
 249         reference-manual/plots/dih.pdf
 250         reference-manual/plots/drift-all.pdf
 251         reference-manual/plots/f-angle.pdf
 252         reference-manual/plots/f-bond.pdf
 253         reference-manual/plots/fp-highres.pdf
 254         reference-manual/plots/int-mat.pdf
 255         reference-manual/plots/mdpar.pdf
 256         reference-manual/plots/parsort.pdf
 257         reference-manual/plots/ring.pdf
 258         reference-manual/plots/shiftf.pdf
 259         # Algorithms chapter
 260         reference-manual/algorithms/plots/dd-cells.pdf
 261         reference-manual/algorithms/plots/dd-tric.pdf
 262         reference-manual/algorithms/plots/flowchart.pdf
 263         reference-manual/algorithms/plots/free1.pdf
 264         reference-manual/algorithms/plots/free2.pdf
 265         reference-manual/algorithms/plots/leapfrog.pdf
 266         reference-manual/algorithms/plots/lincs.pdf
 267         reference-manual/algorithms/plots/maxwell.pdf
 268         reference-manual/algorithms/plots/mpmd-pme.pdf
 269         reference-manual/algorithms/plots/nstric.pdf
 270         reference-manual/algorithms/plots/par-lincs2.pdf
 271         reference-manual/algorithms/plots/pbctric.pdf
 272         reference-manual/algorithms/plots/rhododec.pdf
 273         reference-manual/algorithms/plots/truncoct.pdf
 274         reference-manual/algorithms/plots/verlet-drift.pdf
 275         # Interaction functions chapter
 276         reference-manual/functions/plots/angle.pdf
 277         reference-manual/functions/plots/bstretch.pdf
 278         reference-manual/functions/plots/chain.pdf
 279         reference-manual/functions/plots/dummies.pdf
 280         reference-manual/functions/plots/f-bham.pdf
 281         reference-manual/functions/plots/fbposres.pdf
 282         reference-manual/functions/plots/f-dih.pdf
 283         reference-manual/functions/plots/f-dr.pdf
 284         reference-manual/functions/plots/fig-02.pdf
 285         reference-manual/functions/plots/fig-04.pdf
 286         reference-manual/functions/plots/f-imps.pdf
 287         reference-manual/functions/plots/f-lj.pdf
 288         reference-manual/functions/plots/f-morse.pdf
 289         reference-manual/functions/plots/f-pr.pdf
 290         reference-manual/functions/plots/f-rbs.pdf
 291         reference-manual/functions/plots/ring-imp.pdf
 292         reference-manual/functions/plots/softcore.pdf
 293         reference-manual/functions/plots/subst-im.pdf
 294         reference-manual/functions/plots/tetra-im.pdf
 295         reference-manual/functions/plots/vcrf.pdf
 296         reference-manual/functions/plots/vsite-4fdn.pdf
 297         # Special topics chapter
 298         reference-manual/special/plots/awh-invN.pdf
 299         reference-manual/special/plots/awh-pmfs.pdf
 300         reference-manual/special/plots/awh-sampleweights.pdf
 301         reference-manual/special/plots/awh-traj.pdf
 302         reference-manual/special/plots/compelsetup.pdf
 303         reference-manual/special/plots/dumaro.pdf
 304         reference-manual/special/plots/dumtypes.pdf
 305         reference-manual/special/plots/equipotential.pdf
 306         reference-manual/special/plots/field.pdf
 307         reference-manual/special/plots/gaussians.pdf
 308         reference-manual/special/plots/lambda-values.pdf
 309         reference-manual/special/plots/pulldirrel.pdf
 310         reference-manual/special/plots/pull.pdf
 311         reference-manual/special/plots/pullref.pdf
 312         reference-manual/special/plots/rotation.pdf
 313         # Analysis chapter
 314         reference-manual/analysis/plots/dih-def.pdf
 315         reference-manual/analysis/plots/distm.pdf
 316         reference-manual/analysis/plots/dssp.pdf
 317         reference-manual/analysis/plots/hbond-insert.pdf
 318         reference-manual/analysis/plots/hbond.pdf
 319         reference-manual/analysis/plots/hpr-wheel.pdf
 320         reference-manual/analysis/plots/msdwater.pdf
 321         reference-manual/analysis/plots/ngmxdump.pdf
 322         reference-manual/analysis/plots/phipsi.pdf
 323         reference-manual/analysis/plots/rama.pdf
 324         reference-manual/analysis/plots/rdfO-O.pdf
 325         reference-manual/analysis/plots/rdf.pdf
 326         reference-manual/analysis/plots/sgangle.pdf
 327         )
 328     set(SPHINX_SOURCE_FILES
 329         index.rst
 330         download.rst
 331         links.dat
 332         dev-manual/build-system.rst
 333         dev-manual/change-management.rst
 334         dev-manual/commitstyle.rst
 335         dev-manual/containers.rst
 336         dev-manual/documentation-generation.rst
 337         dev-manual/contribute.rst
 338         dev-manual/doxygen.rst
 339         dev-manual/error-handling.rst
 340         dev-manual/formatting.rst
 341         dev-manual/gitlab.rst
 342         dev-manual/gmxtree.rst
 343         dev-manual/includestyle.rst
 344         dev-manual/index.rst
 345         dev-manual/infrastructure.rst
 346         dev-manual/jenkins.rst
 347         dev-manual/known-issues.rst
 348         dev-manual/language-features.rst
 349         dev-manual/naming.rst
 350         dev-manual/overview.rst
 351         dev-manual/physical_validation.rst
 352         dev-manual/redmine-states.png
 353         dev-manual/relocatable-binaries.rst
 354         dev-manual/reportstyle.rst
 355         dev-manual/style.rst
 356         dev-manual/testutils.rst
 357         dev-manual/tools.rst
 358         dev-manual/code-formatting.rst
 359         fragments/doxygen-links.rst
 360         how-to/index.rst
 361         how-to/beginners.rst
 362         how-to/topology.rst
 363         how-to/special.rst
 364         how-to/visualize.rst
 365         install-guide/index.rst
 366         release-notes/index.rst
 367         release-notes/2021/2021.3.rst
 368         release-notes/2021/2021.2.rst
 369         release-notes/2021/2021.1.rst
 370         release-notes/2021/major/highlights.rst
 371         release-notes/2021/major/features.rst
 372         release-notes/2021/major/performance.rst
 373         release-notes/2021/major/tools.rst
 374         release-notes/2021/major/bugs-fixed.rst
 375         release-notes/2021/major/removed-functionality.rst
 376         release-notes/2021/major/deprecated-functionality.rst
 377         release-notes/2021/major/portability.rst
 378         release-notes/2021/major/miscellaneous.rst
 379         release-notes/2020/2020.1.rst
 380         release-notes/2020/2020.2.rst
 381         release-notes/2020/2020.3.rst
 382         release-notes/2020/2020.4.rst
 383         release-notes/2020/2020.5.rst
 384         release-notes/2020/2020.6.rst
 385         release-notes/2020/major/highlights.rst
 386         release-notes/2020/major/features.rst
 387         release-notes/2020/major/performance.rst
 388         release-notes/2020/major/tools.rst
 389         release-notes/2020/major/bugs-fixed.rst
 390         release-notes/2020/major/removed-functionality.rst
 391         release-notes/2020/major/deprecated-functionality.rst
 392         release-notes/2020/major/portability.rst
 393         release-notes/2020/major/miscellaneous.rst
 394         release-notes/2019/2019.6.rst
 395         release-notes/2019/2019.5.rst
 396         release-notes/2019/2019.4.rst
 397         release-notes/2019/2019.3.rst
 398         release-notes/2019/2019.2.rst
 399         release-notes/2019/2019.1.rst
 400         release-notes/2019/major/highlights.rst
 401         release-notes/2019/major/features.rst
 402         release-notes/2019/major/performance.rst
 403         release-notes/2019/major/tools.rst
 404         release-notes/2019/major/bugs-fixed.rst
 405         release-notes/2019/major/removed-functionality.rst
 406         release-notes/2019/major/deprecated-functionality.rst
 407         release-notes/2019/major/portability.rst
 408         release-notes/2019/major/miscellaneous.rst
 409         release-notes/2018/2018.7.rst
 410         release-notes/2018/2018.6.rst
 411         release-notes/2018/2018.5.rst
 412         release-notes/2018/2018.4.rst
 413         release-notes/2018/2018.3.rst
 414         release-notes/2018/2018.2.rst
 415         release-notes/2018/2018.1.rst
 416         release-notes/2018/major/highlights.rst
 417         release-notes/2018/major/features.rst
 418         release-notes/2018/major/performance.rst
 419         release-notes/2018/major/tools.rst
 420         release-notes/2018/major/bugs-fixed.rst
 421         release-notes/2018/major/removed-features.rst
 422         release-notes/2018/major/portability.rst
 423         release-notes/2018/major/miscellaneous.rst
 424         release-notes/2016/2016.5.rst
 425         release-notes/2016/2016.4.rst
 426         release-notes/2016/2016.3.rst
 427         release-notes/2016/2016.2.rst
 428         release-notes/2016/2016.1.rst
 429         release-notes/2016/major/highlights.rst
 430         release-notes/2016/major/new-features.rst
 431         release-notes/2016/major/performance.rst
 432         release-notes/2016/major/tools.rst
 433         release-notes/2016/major/bugs-fixed.rst
 434         release-notes/2016/major/removed-features.rst
 435         release-notes/2016/major/miscellaneous.rst
 436         release-notes/older/index.rst
 437         # the entry for user-guide/index.rst should not appear here,
 438         # as it will be included conditionally further down depending on
 439         # if the documentation will be build with the full reference
 440         # manual or without.
 441         user-guide/cmdline.rst
 442         user-guide/deprecation-policy.rst
 443         user-guide/environment-variables.rst
 444         user-guide/faq.rst
 445         user-guide/floating-point.rst
 446         user-guide/flow.rst
 447         user-guide/force-fields.rst
 448         user-guide/getting-started.rst
 449         user-guide/index.rst
 450         user-guide/known-issues.rst
 451         user-guide/managing-simulations.rst
 452         user-guide/mdp-options.rst
 453         user-guide/mdrun-features.rst
 454         user-guide/mdrun-performance.rst
 455         user-guide/run-time-errors.rst
 456         user-guide/security.rst
 457         user-guide/system-preparation.rst
 458         user-guide/terminology.rst
 459         )
 460
 461     include(SphinxMacros.cmake)
 462     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 463
 464     # set temporary variables for doi inclusion
 465     # into the manual, plain string + some wrapping
 466     # for release builds, and dummy string for non-release
 467     # builds
 468     if("${GMX_MANUAL_DOI}" STREQUAL "")
 469       # empty string means no doi, set dummy text
 470       set(GMX_MANUAL_DOI_STRING "This is not a release build of GROMACS, so please reference")
 471       set(GMX_MANUAL_DOI_STRING "${GMX_MANUAL_DOI_STRING} one of the GROMACS papers and the base release of the manual.")
 472     else()
 473       # release version, set plain old boring string
 474       set(GMX_MANUAL_DOI_STRING "Please reference this documentation as https://doi.org/${GMX_MANUAL_DOI}.")
 475     endif()
 476     # same for source doi, but modify the text
 477     if("${GMX_SOURCE_DOI}" STREQUAL "")
 478       # empty string means no release build
 479       set(GMX_SOURCE_DOI_STRING "This is not a release build of GROMACS. Please reference one of the")
 480       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} GROMACS papers, as well as the base release that this version is built from.")
 481       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} Also, please state what modifcations have been performed or where the version")
 482       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} was sourced from.")
 483     else()
 484       # release version, give them a doi url string
 485       set(GMX_SOURCE_DOI_STRING "To cite the source code for this release, please cite")
 486       set(GMX_SOURCE_DOI_STRING "${GMX_SOURCE_DOI_STRING} https://doi.org/${GMX_SOURCE_DOI}.")
 487     endif()
 488
 489     if(IMAGE_CONVERT_POSSIBLE)
 490         set(IMAGE_CONVERT_STRING "possible")
 491     else()
 492         set(IMAGE_CONVERT_STRING "impossible")
 493     endif()
 494
 495     set(SPHINX_CONFIG_FILE ${SPHINX_INPUT_DIR}/conf.py)
 496     if (GMX_PYTHON_PACKAGE)
 497         set(GMXAPI_PYTHON_STAGING_DIR ${CMAKE_BINARY_DIR}/python_packaging/src/gmxapi_staging)
 498         # TODO: Resolve circular reference. We would like to get the CMake build-time directory for
 499         # the gmxapi Python package from the _gmxapi target, as we do when building sample_restraint.
 500         # Instead of the above hard-coded path, how can we do
 501         # get_target_property(GMXAPI_PYTHON_STAGING_DIR _gmxapi staging_dir)
 502         # in this context?
 503     endif ()
 504
 505     gmx_configure_version_file(
 506         conf.cmakein.py ${SPHINX_CONFIG_FILE}
 507         EXTRA_VARS
 508             CMAKE_MINIMUM_REQUIRED_VERSION
 509             EXPECTED_DOXYGEN_VERSION
 510             EXPECTED_SPHINX_VERSION
 511             GMX_ADMIN_DIR
 512             GMX_LMFIT_REQUIRED_VERSION
 513             GMX_MANUAL_DOI_STRING
 514             GMX_TNG_MINIMUM_REQUIRED_VERSION
 515             GMX_SOURCE_DOI_STRING
 516             GMXAPI_PYTHON_STAGING_DIR
 517             IMAGE_CONVERT_STRING
 518             REGRESSIONTEST_VERSION
 519             REQUIRED_CUDA_COMPUTE_CAPABILITY
 520             REQUIRED_CUDA_VERSION
 521             REQUIRED_OPENCL_MIN_VERSION
 522             REGRESSIONTEST_MD5SUM_STRING
 523             RELENG_PATH
 524             SOURCE_MD5SUM
 525             SPHINX_EXTENSION_PATH
 526         COMMENT "Configuring Sphinx configuration file")
 527     gmx_add_sphinx_input_file(${SPHINX_CONFIG_FILE})
 528     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 529     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 530         include(${RELENG_PATH}/docs/FileList.cmake)
 531         gmx_add_sphinx_source_files(
 532             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 533             FILES ${RELENG_SPHINX_FILES})
 534     else()
 535         gmx_add_sphinx_source_files(FILES
 536             dev-manual/releng/index.rst
 537             )
 538     endif()
 539
 540     gmx_add_sphinx_source_files(
 541             FILES
 542             gmxapi/index.rst
 543             gmxapi/userguide/install.rst
 544             gmxapi/userguide/usage.rst
 545             gmxapi/userguide/userguide.rst
 546     )
 547
 548     if (GMX_PYTHON_PACKAGE)
 549         gmx_add_sphinx_source_files(
 550             FILES
 551             gmxapi/userguide/pythonreference.rst
 552             )
 553     else()
 554         gmx_add_sphinx_source_files(
 555             FROM ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi/userguide-stub
 556             TO gmxapi/userguide/
 557             FILES pythonreference.rst
 558             )
 559     endif ()
 560
 561     gmx_add_sphinx_source_files(
 562             FILES
 563             nblib/index.rst
 564             nblib/guide-to-writing-MD-programs.rst
 565     )
 566
 567     gmx_add_sphinx_source_files(
 568         FILES
 569         ${REFERENCEMANUAL_SPHINX_FILES_GENERAL})
 570     if (IMAGE_CONVERT_POSSIBLE)
 571         gmx_add_sphinx_source_files(
 572             FILES
 573             ${REFERENCEMANUAL_SPHINX_FILES_WITH_IMAGES}
 574             ${REFERENCEMANUAL_IMAGE_FILES})
 575         gmx_add_sphinx_image_conversion_files(
 576             FILES
 577             ${REFERENCEMANUAL_IMAGE_FILES})
 578     endif()
 579     gmx_add_sphinx_input_target(sphinx-input-rst)
 580     gmx_add_sphinx_image_conversion_target(sphinx-image-conversion)
 581     add_custom_target(sphinx-input)
 582     add_dependencies(sphinx-input sphinx-input-rst sphinx-image-conversion)
 583     if (GMX_PYTHON_PACKAGE)
 584         add_dependencies(sphinx-input _gmxapi)
 585     endif()
 586     # Remove other rst files from the build tree, since they confuse Sphinx.
 587     # Skip generated files in onlinehelp/, and fragments.
 588     # The latter do not cause issues with obsolete files, as they
 589     # are not considered as Sphinx input files, but will only be
 590     # included using an explicit .. include::.
 591     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 592
 593     # TODO: Make this remove obsolete .rst files.
 594     # TODO: This does not work in cross-compilation scenarios; disable up to
 595     # the necessary level.
 596     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 597         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 598         COMMAND gmx -quiet help -export rst
 599         DEPENDS gmx
 600         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 601         COMMENT "Generating reStructuredText help")
 602     # This dependency ensures that the directories exist before the
 603     # executable tries to write things there.
 604     add_dependencies(sphinx-programs sphinx-input)
 605
 606     # Make the INSTALL file for CPack for the tarball. This gets put
 607     # into the tarball via the CPack rules below, which requires that
 608     # the INSTALL file is in a separate directory by itself.
 609     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 610     add_custom_target(install-guide
 611         COMMAND
 612             ${SPHINX_EXECUTABLE}
 613             -q -b text
 614             -w sphinx-install.log
 615             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 616             -c ${SPHINX_INPUT_DIR}
 617             "${SPHINX_INPUT_DIR}/install-guide"
 618             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 619         COMMAND
 620             ${CMAKE_COMMAND} -E rename
 621             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 622             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 623         WORKING_DIRECTORY
 624             ${CMAKE_CURRENT_BINARY_DIR}
 625         COMMENT "Building INSTALL with Sphinx"
 626         VERBATIM
 627         )
 628     add_dependencies(install-guide sphinx-input)
 629     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 630
 631     # Sphinx cache with pickled ReST documents
 632     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 633     set(SPHINX_CONFIG_OVERRIDES "")
 634     if (GMX_DEVELOPER_BUILD)
 635         set(SPHINX_CONFIG_OVERRIDES "-Dtodo_include_todos=1")
 636     endif()
 637     add_custom_target(webpage-sphinx
 638         DEPENDS sphinx-programs
 639         DEPENDS sphinx-input
 640         DEPENDS sphinx-image-conversion
 641         DEPENDS manual
 642         COMMAND
 643             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 644         COMMAND
 645             ${SPHINX_EXECUTABLE}
 646             -q -b html
 647             -w sphinx-html.log
 648             -d "${SPHINX_CACHE_DIR}"
 649             ${SPHINX_CONFIG_OVERRIDES}
 650             "${SPHINX_INPUT_DIR}"
 651             "${HTML_OUTPUT_DIR}"
 652         WORKING_DIRECTORY
 653             ${CMAKE_CURRENT_BINARY_DIR}
 654         COMMENT "Building HTML documentation with Sphinx"
 655         VERBATIM
 656         )
 657
 658     add_custom_target(man
 659         COMMAND
 660             ${SPHINX_EXECUTABLE}
 661             -q -b man
 662             -w sphinx-man.log
 663             -d ${SPHINX_CACHE_DIR}
 664             -t do_man
 665             ${SPHINX_INPUT_DIR}
 666             ${CMAKE_CURRENT_BINARY_DIR}/man
 667         COMMENT "Building man pages with Sphinx"
 668         VERBATIM)
 669     add_dependencies(man sphinx-input sphinx-programs)
 670     if (GMX_BUILD_HELP)
 671         # If requested, install the man pages built by the 'man' target
 672         # created above.  Nothing will be installed if the user did not
 673         # manually build the target.
 674         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 675     endif()
 676
 677 else()
 678     set(MANUAL_BUILD_IS_POSSIBLE OFF)
 679     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available")
 680
 681     add_custom_target(webpage-sphinx
 682         COMMAND ${CMAKE_COMMAND} -E echo
 683             "HTML pages cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 684         VERBATIM)
 685     add_custom_target(install-guide
 686         COMMAND ${CMAKE_COMMAND} -E echo
 687             "INSTALL cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 688         VERBATIM)
 689     add_custom_target(man
 690         COMMAND ${CMAKE_COMMAND} -E echo
 691             "man pages cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 692         VERBATIM)
 693     add_custom_target(sphinx-create-texman
 694         COMMAND ${CMAKE_COMMAND} -E echo
 695             "Cannot prepare LaTeX input files because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available"
 696         VERBATIM)
 697     add_custom_target(manual
 698         COMMAND ${CMAKE_COMMAND} -E echo
 699             "manual cannot be built because Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is not available")
 700 endif()
 701
 702 if (MAN_PAGE_DIR)
 703     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 704     # Trailing slash on directory is significant for
 705     # install(DIRECTORY). See CMake docs.
 706     install(DIRECTORY ${MAN_PAGE_DIR}/
 707         DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
 708         COMPONENT man OPTIONAL
 709         FILES_MATCHING PATTERN "*.1")
 710 endif()
 711 gmx_cpack_add_generated_source_directory(man)
 712
 713 # Determine whether we can build all the HTML pages and content linked from
 714 # there.  If not, construct an informative message if the user tries to
 715 # build the target; most people never need to know, unless they've asked for
 716 # the webpage build.
 717 set(HTML_BUILD_IS_POSSIBLE ON)
 718 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 719 set(HTML_BUILD_WARNINGS)
 720
 721 # Next, turn it off if any of the preconditions are unsatisified
 722 if (NOT Python3_Interpreter_FOUND)
 723     set(HTML_BUILD_IS_POSSIBLE OFF)
 724     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 725 elseif (NOT SPHINX_FOUND)
 726     # Hardly anything gets built if Sphinx is not available, so don't bother.
 727     set(HTML_BUILD_IS_POSSIBLE OFF)
 728     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx expected minimum version ${EXPECTED_SPHINX_VERSION} is required")
 729 endif()
 730 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 731     list(APPEND HTML_BUILD_WARNINGS
 732          "Reference PDF manual was not built, so links to it do not work")
 733 endif()
 734 if (NOT DOXYGEN_EXECUTABLE)
 735     list(APPEND HTML_BUILD_WARNINGS
 736         "Doxygen was not available, so links to Doxygen do not work")
 737 endif()
 738 if (NOT DOXYGEN_DOT_EXECUTABLE)
 739     list(APPEND HTML_BUILD_WARNINGS
 740         "dot/graphviz was not found, so some graphs are missing")
 741 endif()
 742
 743 if (HTML_BUILD_IS_POSSIBLE)
 744     set(_webpage_target_properties)
 745     if (HTML_BUILD_WARNINGS)
 746         list(APPEND _webpage_target_properties
 747              COMMAND ${CMAKE_COMMAND} -E echo
 748                  "webpage was built, but with the following limitations:")
 749         foreach(_warning ${HTML_BUILD_WARNINGS})
 750         list(APPEND _webpage_target_properties
 751              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 752         endforeach()
 753     endif()
 754
 755     if (MANUAL_BUILD_IS_POSSIBLE)
 756         # Make the PDF reference guide
 757         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 758         # TODO Make this depend on the output of the manual build, so that the
 759         # file actually gets copied multiple times.
 760         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 761         add_custom_command(
 762             OUTPUT ${_manual_target_location}
 763             COMMAND ${CMAKE_COMMAND}
 764                 -E remove -f ${_manual_target_location}
 765             COMMAND ${CMAKE_COMMAND}
 766                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 767             DEPENDS manual
 768             VERBATIM)
 769         list(APPEND _webpage_target_properties
 770              DEPENDS ${_manual_target_location})
 771     endif()
 772
 773     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 774     # makes all the Doxygen output directly in
 775     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 776     # to).
 777
 778     # Add a top-level target that builds everything related to the webpage,
 779     # for Jenkins (and possibly others) to use
 780     add_custom_target(webpage ${_webpage_target_properties}
 781         COMMENT "Building webpage"
 782         VERBATIM)
 783     add_dependencies(webpage webpage-sphinx doxygen-all)
 784 else()
 785     add_custom_target(webpage
 786         COMMAND ${CMAKE_COMMAND} -E echo
 787             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 788         COMMENT "Webpage build not possible"
 789         VERBATIM)
 790 endif()