67afbc171ff393de895f9363b882780d77b9b8ca
[alexxy/gromacs.git] / cmake / gmxTestCompilerProblems.cmake
1 #
2 # This file is part of the GROMACS molecular simulation package.
3 #
4 # Copyright (c) 2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
6 # and including many others, as listed in the AUTHORS file in the
7 # top-level source directory and at http://www.gromacs.org.
8 #
9 # GROMACS is free software; you can redistribute it and/or
10 # modify it under the terms of the GNU Lesser General Public License
11 # as published by the Free Software Foundation; either version 2.1
12 # of the License, or (at your option) any later version.
13 #
14 # GROMACS is distributed in the hope that it will be useful,
15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 # Lesser General Public License for more details.
18 #
19 # You should have received a copy of the GNU Lesser General Public
20 # License along with GROMACS; if not, see
21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
23 #
24 # If you want to redistribute modifications to GROMACS, please
25 # consider that scientific software is very special. Version
26 # control is crucial - bugs must be traceable. We will be happy to
27 # consider code for inclusion in the official distribution, but
28 # derived work must not be called official GROMACS. Details are found
29 # in the README & COPYING files - if they are missing, get the
30 # official version at http://www.gromacs.org.
31 #
32 # To help us fund GROMACS development, we humbly ask that you cite
33 # the research papers on the package. Check out http://www.gromacs.org.
34
35 include(CheckCXXSourceCompiles)
36
37 # Macro that runs through a number of tests for buggy compiler
38 # versions, or other potential problems.
39 macro(gmx_test_compiler_problems)
40
41     # Warn if C and C++ compilers do not match
42     if(NOT CMAKE_C_COMPILER_ID STREQUAL CMAKE_CXX_COMPILER_ID)
43         message(WARNING "The ids of the C and C++ compilers do not match (${CMAKE_C_COMPILER_ID} and ${CMAKE_CXX_COMPILER_ID}, respectively). Mixing different C/C++ compilers can cause problems.")
44     endif()
45     if(NOT CMAKE_C_COMPILER_VERSION STREQUAL CMAKE_CXX_COMPILER_VERSION)
46         message(WARNING "The versions of the C and C++ compilers do not match (${CMAKE_C_COMPILER_VERSION} and ${CMAKE_CXX_COMPILER_VERSION}, respectively). Mixing different C/C++ compilers can cause problems.")
47     endif()
48
49     # Error if compiler doesn't support required C++14 features. Relaxed constexpr is currently only required
50     # feature. It is also one of the last implemented C++14 features by all supported compilers.
51     if(NOT "cxx_relaxed_constexpr" IN_LIST CMAKE_CXX_COMPILE_FEATURES)
52         if(CMAKE_COMPILER_IS_GNUCXX)
53             set(cxx_required_version "GCC version 5")
54         elseif(MSVC)
55             if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.15) # cmake reports no support because of bugs but
56                 set(cxx_required_version "Visual Studio 2017") # we support it.
57             endif()
58         elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
59             set(cxx_required_version "Clang 3.6") # For feature complete C++14 only 3.4 is needed.
60                                                   # But prior version have bugs (e.g. debug symbol support)
61         elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
62             set(cxx_required_version "Intel Compiler 2017")
63         else()
64             message(FATAL_ERROR "The compiler doesn't have sufficient C++14 support.")
65         endif()
66         if (cxx_required_version)
67             message(FATAL_ERROR "${cxx_required_version} or later required. "
68                                 "Earlier versions don't have full C++14 support.")
69         endif()
70     endif()
71
72     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "XL")
73         check_cxx_source_compiles(
74 "// Test in-class array initalizers used with constructor initializer lists
75 struct TestStruct
76 {
77     float a[3][3] = {{0}}; // in-class initializer
78     float b; // not initialized until constructor initializer list
79     TestStruct();
80 };
81 TestStruct::TestStruct() : b(0) {}
82 }" XLC_COMPILES_CORRECTLY)
83         if (NOT XLC_COMPILES_CORRECTLY)
84             message(FATAL_ERROR "No known version of xlC can compile the normal C++11 code in GROMACS, highest version checked is 16.1.0")
85         endif()
86     endif()
87     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "PGI")
88         message(WARNING "Currently tested PGI compiler versions (up to 15.7) generate binaries that do not pass all regression test, and the generated binaries are significantly slower than with GCC, ICC or Clang. For now we do not recommend PGI beyond development testing - make sure to run the regressiontests.")
89     endif()
90
91 endmacro(gmx_test_compiler_problems)