cmake/gmxOptionUtilities.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 #
  36 # Helper functions for managing more complex options
  37 #
  38
  39 # Creates a string cache variable with multiple choices
  40 #
  41 # Usage:
  42 #   gmx_option_multichoice(VAR "Description" DEFAULT_VALUE
  43 #                          Value1 Value2 ... ValueN)
  44 # Output:
  45 #   VAR is set in the cache and in the caller's scope. The caller can assume
  46 #   that it is always one of the provided values, converted to uppercase.
  47 #
  48 # Main benefit is that the list of allowed values only needs to be provided
  49 # once, and gets used in multiple contexts:
  50 #   1. It is automatically added to the description.
  51 #   2. It is set as the STRINGS property of the created cache variable for use
  52 #      with CMake GUIs.
  53 #   3. The user-provided value is checked against the list, and a fatal error
  54 #      is produced if the value is not known.  The caller does not need to
  55 #      produce good error messages in cases where it may be necessary to check
  56 #      for the validity again.
  57 # As a special case, any "[built-in]" string in the allowed values is ignored
  58 # when checking the user-provided value, but is added to all user-visible
  59 # messages.
  60 #
  61 # It appears that ccmake does not use the STRINGS property, but perhaps some
  62 # day...
  63 #
  64 function(GMX_OPTION_MULTICHOICE NAME DESCRIPTION DEFAULT)
  65     # Some processing of the input values
  66     string(REPLACE ";" ", " _allowed_comma_separated "${ARGN}")
  67     set(_description "${DESCRIPTION}. Pick one of: ${_allowed_comma_separated}")
  68     string(REPLACE "[built-in]" "" _allowed "${ARGN}")
  69
  70     # Set the cache properties
  71     set(${NAME} ${DEFAULT} CACHE STRING ${_description})
  72     set_property(CACHE ${NAME} PROPERTY STRINGS ${_allowed})
  73
  74     # Check that the value is one of the allowed
  75     set(_org_value "${${NAME}}")
  76     string(TOUPPER "${${NAME}}" ${NAME})
  77     string(TOUPPER "${_allowed}" _allowed_as_upper)
  78     list(FIND _allowed_as_upper "${${NAME}}" _found_index)
  79     if (_found_index EQUAL -1)
  80         message(FATAL_ERROR "Invalid value for ${NAME}: ${_org_value}.  "
  81                             "Pick one of: ${_allowed_comma_separated}")
  82     endif ()
  83     # Always provide the upper-case value to the caller
  84     set(${NAME} "${${NAME}}" PARENT_SCOPE)
  85 endfunction()
  86
  87 # Convenience function for reporting a fatal error for an invalid input value
  88 function(GMX_INVALID_OPTION_VALUE NAME)
  89     message(FATAL_ERROR "Invalid value for ${NAME}: ${${NAME}}")
  90 endfunction()
  91
  92 # Hides or shows a cache value based on conditions
  93 #
  94 # Usage:
  95 #   gmx_add_cache_dependency(VAR TYPE CONDITIONS VALUE)
  96 # where
  97 #   VAR        is a name of a cached variable
  98 #   TYPE       is the type of VAR
  99 #   CONDITIONS is a list of conditional expressions (see below)
 100 #   VALUE      is a value that is set to VAR if CONDITIONS is not satisfied
 101 #
 102 # Evaluates each condition in CONDITIONS, and if any of them is false,
 103 # VAR is marked internal (hiding it from the user) and its value is set to
 104 # VALUE.  The previous user-set value of VAR is still remembered in the cache,
 105 # and used when CONDITIONS become true again.
 106 #
 107 # The conditions is a semicolon-separated list of conditions as specified for
 108 # CMake if() statements, such as "GMX_FFT_LIBRARY STREQUAL FFTW3",
 109 # "NOT GMX_MPI" or "GMX_MPI;NOT GMX_DOUBLE".  Note that quotes within the
 110 # expressions don't work for some reason (even if escaped).
 111 #
 112 # The logic is adapted from cmake_dependent_option().
 113 #
 114 function(GMX_ADD_CACHE_DEPENDENCY NAME TYPE CONDITIONS FORCED_VALUE)
 115     set(_available TRUE)
 116     foreach(_cond ${CONDITIONS})
 117         string(REGEX REPLACE " +" ";" _cond_as_list ${_cond})
 118         if (${_cond_as_list})
 119         else()
 120             set(_available FALSE)
 121         endif()
 122     endforeach()
 123     if (_available)
 124         set_property(CACHE ${NAME} PROPERTY TYPE ${TYPE})
 125     else()
 126         set(${NAME} "${FORCED_VALUE}" PARENT_SCOPE)
 127         set_property(CACHE ${NAME} PROPERTY TYPE INTERNAL)
 128     endif()
 129 endfunction()
 130
 131 # Works like cmake_dependent_option(), but allows for an arbitrary cache value
 132 # instead of only an ON/OFF option
 133 #
 134 # Usage:
 135 #   gmx_dependent_cache_variable(VAR "Description" TYPE DEFAULT CONDITIONS)
 136 #
 137 # Creates a cache variable VAR with the given description, type and default
 138 # value.  If any of the conditions listed in CONDITIONS is not true, then
 139 # the cache variable is marked internal (hiding it from the user) and the
 140 # value of VAR is set to DEFAULT.  The previous user-set value of VAR is still
 141 # remembered in the cache, and used when CONDITIONS become true again.
 142 # Any further changes to the variable can be done with simple set()
 143 # (or set_property(CACHE VAR PROPERTY VALUE ...) if the cache needs to be
 144 # modified).
 145 #
 146 # See gmx_add_cache_dependency() on how to specify the conditions.
 147 #
 148 macro(GMX_DEPENDENT_CACHE_VARIABLE NAME DESCRIPTION TYPE DEFAULT CONDITIONS)
 149     set(${NAME} "${DEFAULT}" CACHE ${TYPE} "${DESCRIPTION}")
 150     gmx_add_cache_dependency(${NAME} ${TYPE} "${CONDITIONS}" "${DEFAULT}")
 151 endmacro()
 152
 153 # Works like cmake_dependent_option(), but reuses the code from
 154 # gmx_dependent_cache_variable() to make sure both behave the same way.
 155 macro(GMX_DEPENDENT_OPTION NAME DESCRIPTION DEFAULT CONDITIONS)
 156     gmx_dependent_cache_variable(${NAME} "${DESCRIPTION}" BOOL "${DEFAULT}" "${CONDITIONS}")
 157 endmacro()
 158
 159 # Checks if one or more cache variables have changed
 160 #
 161 # Usage:
 162 #   gmx_check_if_changed(RESULT VAR1 VAR2 ... VARN)
 163 #
 164 # Sets RESULT to true if any of the given cache variables VAR1 ... VARN has
 165 # changes since the last call to this function for that variable.
 166 # Changes are tracked also across CMake runs.
 167 function(GMX_CHECK_IF_CHANGED RESULT)
 168     set(_result FALSE)
 169     foreach (_var ${ARGN})
 170         if (NOT "${_var}" STREQUAL "${_var}_PREVIOUS_VALUE")
 171             set(_result TRUE)
 172         endif()
 173         set(${_var}_PREVIOUS_VALUE "${${_var}}" CACHE INTERNAL
 174             "Previous value of ${_var} for change tracking")
 175     endforeach()
 176     set(${RESULT} ${_result} PARENT_SCOPE)
 177 endfunction()