cmake/gmxManageNvccConfig.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Manage CUDA nvcc compilation configuration, try to be smart to ease the users'
  36 # pain as much as possible:
  37 # - use the CUDA_HOST_COMPILER if defined by the user, otherwise
  38 # - check if nvcc works with CUDA_HOST_COMPILER and the generated nvcc and C++ flags
  39 #
  40 # - (advanced) variables set:
  41 #   * CUDA_HOST_COMPILER_OPTIONS    - the full host-compiler related option list passed to nvcc
  42 #
  43 # Note that from CMake 2.8.10 FindCUDA defines CUDA_HOST_COMPILER internally,
  44 # so we won't set it ourselves, but hope that the module does a good job.
  45
  46 # glibc 2.23 changed string.h in a way that breaks CUDA compilation in
  47 # many projects, but which has a trivial workaround. It would be nicer
  48 # to compile with nvcc and see that the workaround is necessary and
  49 # effective, but it is unclear how to do that. Also, grepping in the
  50 # glibc source shows that _FORCE_INLINES is only used in this string.h
  51 # feature and performance of memcpy variants is unimportant for CUDA
  52 # code in GROMACS. So this workaround is good enough to keep problems
  53 # away from users installing GROMACS. See Redmine 1942.
  54 function(work_around_glibc_2_23)
  55     try_compile(IS_GLIBC_2_23_OR_HIGHER ${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}/cmake/TestGlibcVersion.cpp)
  56     if(IS_GLIBC_2_23_OR_HIGHER)
  57         message(STATUS "Adding work-around for issue compiling CUDA code with glibc 2.23 string.h")
  58         list(APPEND CUDA_HOST_COMPILER_OPTIONS "-D_FORCE_INLINES")
  59         set(CUDA_HOST_COMPILER_OPTIONS ${CUDA_HOST_COMPILER_OPTIONS} PARENT_SCOPE)
  60     endif()
  61 endfunction()
  62
  63 gmx_check_if_changed(CUDA_HOST_COMPILER_CHANGED CUDA_HOST_COMPILER)
  64
  65 # set up host compiler and its options
  66 if(CUDA_HOST_COMPILER_CHANGED)
  67     set(CUDA_HOST_COMPILER_OPTIONS "")
  68
  69     if(APPLE AND CMAKE_C_COMPILER_ID MATCHES "GNU")
  70         # Some versions of gcc-4.8 and gcc-4.9 produce errors (in particular on OS X)
  71         # if we do not use -D__STRICT_ANSI__. It is harmless, so we might as well add it for all versions.
  72         list(APPEND CUDA_HOST_COMPILER_OPTIONS "-D__STRICT_ANSI__")
  73     endif()
  74
  75     work_around_glibc_2_23()
  76
  77     set(CUDA_HOST_COMPILER_OPTIONS "${CUDA_HOST_COMPILER_OPTIONS}"
  78         CACHE STRING "Options for nvcc host compiler (do not edit!).")
  79
  80     mark_as_advanced(CUDA_HOST_COMPILER CUDA_HOST_COMPILER_OPTIONS)
  81 endif()
  82
  83 # If any of these manual override variables for target CUDA GPU architectures
  84 # or virtual architecture is set, parse the values and assemble the nvcc
  85 # command line for these. Otherwise use our defaults.
  86 # Note that the manual override variables require a semicolon separated
  87 # architectures codes.
  88 if (GMX_CUDA_TARGET_SM OR GMX_CUDA_TARGET_COMPUTE)
  89     set(GMX_CUDA_NVCC_GENCODE_FLAGS)
  90     set(_target_sm_list ${GMX_CUDA_TARGET_SM})
  91     foreach(_target ${_target_sm_list})
  92         list(APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_${_target},code=sm_${_target}")
  93     endforeach()
  94     set(_target_compute_list ${GMX_CUDA_TARGET_COMPUTE})
  95     foreach(_target ${_target_compute_list})
  96         list(APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_${_target},code=compute_${_target}")
  97     endforeach()
  98 else()
  99     # Set the CUDA GPU architectures to compile for:
 100     # - with CUDA >=5.0 <6.5:   CC <=3.5 is supported
 101     #     => compile sm_30, sm_35 SASS, and compute_35 PTX
 102     # - with CUDA ==6.5:        CC <=3.7 and 5.0 are supported
 103     #     => compile sm_30, sm_35, sm_37 sm_50, SASS, and compute_50 PTX
 104     # - with CUDA >=7.0         CC 5.2 is supported (5.3, Tegra X1 we don't generate code for)
 105     #     => compile sm_30, sm_35, sm_37, sm_50, & sm_52 SASS, and compute_52 PTX
 106     # - with CUDA >=8.0         CC 6.0-6.2 is supported (but we know nothing about CC 6.2, so we won't generate code or it)
 107     #     => compile sm_30, sm_35, sm_37, sm_50, sm_52, sm_60, sm_61 SASS, and compute_60 and compute_61 PTX
 108     # - with CUDA >=9.0         CC 7.0 is supported and CC 2.0 is no longer supported
 109     #     => compile sm_30, sm_35, sm_37, sm_50, sm_52, sm_60, sm_61, sm_70 SASS, and compute_70 PTX
 110     #
 111     #   Note that CUDA 6.5.19 second patch release supports cc 5.2 too, but
 112     #   CUDA_VERSION does not contain patch version and having PTX 5.0 JIT-ed is
 113     #   equally fast as compiling with sm_5.2 anyway.
 114
 115     # First add flags that trigger SASS (binary) code generation for physical arch
 116     list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_30,code=sm_30")
 117     list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_35,code=sm_35")
 118
 119     if(NOT CUDA_VERSION VERSION_LESS "6.5") # >= 6.5
 120         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_37,code=sm_37")
 121         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_50,code=sm_50")
 122     endif()
 123     if(NOT CUDA_VERSION VERSION_LESS "7.0") # >= 7.0
 124         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_52,code=sm_52")
 125     endif()
 126     if(NOT CUDA_VERSION VERSION_LESS "8.0") # >= 8.0
 127         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_60,code=sm_60")
 128         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_61,code=sm_61")
 129     endif()
 130     if(NOT CUDA_VERSION VERSION_LESS "9.0") # >= 9.0
 131         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_70,code=sm_70")
 132     endif()
 133
 134     # Next add flags that trigger PTX code generation for the newest supported virtual arch
 135     # that's useful to JIT to future architectures
 136     if(CUDA_VERSION VERSION_LESS "6.5")
 137         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_35,code=compute_35")
 138     elseif(CUDA_VERSION VERSION_LESS "7.0")
 139         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_50,code=compute_50")
 140     elseif(CUDA_VERSION VERSION_LESS "8.0")
 141         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_52,code=compute_52")
 142     elseif(CUDA_VERSION VERSION_LESS "9.0")
 143         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_60,code=compute_60")
 144         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_61,code=compute_61")
 145     elseif(CUDA_VERSION VERSION_LESS "10.0")
 146         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_70,code=compute_70")
 147     else() # version >= 10.0
 148         list (APPEND GMX_CUDA_NVCC_GENCODE_FLAGS "-gencode;arch=compute_75,code=compute_75")
 149     endif()
 150 endif()
 151
 152 if (GMX_CUDA_TARGET_SM)
 153     set_property(CACHE GMX_CUDA_TARGET_SM PROPERTY HELPSTRING "List of CUDA GPU architecture codes to compile for (without the sm_ prefix)")
 154     set_property(CACHE GMX_CUDA_TARGET_SM PROPERTY TYPE STRING)
 155 endif()
 156 if (GMX_CUDA_TARGET_COMPUTE)
 157     set_property(CACHE GMX_CUDA_TARGET_COMPUTE PROPERTY HELPSTRING "List of CUDA virtual architecture codes to compile for (without the compute_ prefix)")
 158     set_property(CACHE GMX_CUDA_TARGET_COMPUTE PROPERTY TYPE STRING)
 159 endif()
 160
 161 # assemble the CUDA flags
 162 list(APPEND GMX_CUDA_NVCC_FLAGS "${GMX_CUDA_NVCC_GENCODE_FLAGS}")
 163 list(APPEND GMX_CUDA_NVCC_FLAGS "-use_fast_math")
 164
 165 # assemble the CUDA host compiler flags
 166 list(APPEND GMX_CUDA_NVCC_FLAGS "${CUDA_HOST_COMPILER_OPTIONS}")
 167
 168 string(TOUPPER "${CMAKE_BUILD_TYPE}" _build_type)
 169 gmx_check_if_changed(_cuda_nvcc_executable_or_flags_changed CUDA_NVCC_EXECUTABLE CUDA_NVCC_FLAGS CUDA_NVCC_FLAGS_${_build_type})
 170
 171 if(_cuda_nvcc_executable_or_flags_changed OR CUDA_HOST_COMPILER_CHANGED OR NOT GMX_NVCC_WORKS)
 172     message(STATUS "Check for working NVCC/C compiler combination")
 173     execute_process(COMMAND ${CUDA_NVCC_EXECUTABLE} -ccbin ${CUDA_HOST_COMPILER} -c ${CUDA_NVCC_FLAGS} ${CUDA_NVCC_FLAGS_${_build_type}} ${CMAKE_SOURCE_DIR}/cmake/TestCUDA.cu
 174         RESULT_VARIABLE _cuda_test_res
 175         OUTPUT_VARIABLE _cuda_test_out
 176         ERROR_VARIABLE  _cuda_test_err
 177         OUTPUT_STRIP_TRAILING_WHITESPACE)
 178
 179     if(${_cuda_test_res})
 180         message(${_cuda_test_err})
 181         message(STATUS "Check for working NVCC/C compiler combination - broken")
 182         if(${_cuda_test_err} MATCHES "nsupported")
 183             message(FATAL_ERROR "NVCC/C compiler combination does not seem to be supported. CUDA frequently does not support the latest versions of the host compiler, so you might want to try an earlier C/C++ compiler version and make sure your CUDA compiler and driver are as recent as possible.")
 184         else()
 185             message(FATAL_ERROR "CUDA compiler does not seem to be functional.")
 186         endif()
 187     elseif(NOT GMX_CUDA_TEST_COMPILER_QUIETLY)
 188         message(STATUS "Check for working NVCC/C compiler combination - works")
 189         set(GMX_NVCC_WORKS TRUE CACHE INTERNAL "Nvcc can compile a trivial test program")
 190     endif()
 191 endif() # GMX_CHECK_NVCC
 192
 193
 194 # The flags are set as local variables which shadow the cache variables. The cache variables
 195 # (can be set by the user) are appended. This is done in a macro to set the flags when all
 196 # host compiler flags are already set.
 197 macro(GMX_SET_CUDA_NVCC_FLAGS)
 198     set(CUDA_NVCC_FLAGS "${GMX_CUDA_NVCC_FLAGS};${CUDA_NVCC_FLAGS}")
 199 endmacro()