cmake/gmxManageGPU.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 # If the user did not set GMX_GPU we'll consider this option to be
  36 # in "auto" mode meaning that we will:
  37 # - search for CUDA and set GMX_GPU=ON we find it
  38 # - check whether GPUs are present
  39 # - if CUDA is not found but GPUs were detected issue a warning
  40 if (NOT DEFINED GMX_GPU)
  41     set(GMX_GPU_AUTO TRUE CACHE INTERNAL "GPU acceleration will be selected automatically")
  42 endif()
  43 option(GMX_GPU "Enable GPU acceleration" OFF)
  44
  45 if(GMX_GPU AND GMX_DOUBLE)
  46     message(FATAL_ERROR "GPU acceleration is not available in double precision!")
  47 endif()
  48 if(GMX_GPU_AUTO AND GMX_DOUBLE)
  49     message(WARNING "GPU acceleration is not available in double precision, disabled!")
  50     set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
  51     set_property(CACHE GMX_GPU_AUTO PROPERTY VALUE OFF)
  52 endif()
  53
  54 # detect GPUs in the build host machine
  55 if (GMX_GPU OR GMX_GPU_AUTO AND NOT GMX_GPU_DETECTION_DONE)
  56     include(gmxDetectGpu)
  57     gmx_detect_gpu()
  58 endif()
  59
  60 # We need to call find_package even when we've already done the detection/setup
  61 if(GMX_GPU OR GMX_GPU_AUTO)
  62     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
  63     if(MSVC)
  64         find_package(CUDA 4.1)
  65     else()
  66         find_package(CUDA 3.2)
  67     endif()
  68 endif()
  69
  70 # Depending on the current vale of GMX_GPU and GMX_GPU_AUTO:
  71 # - OFF, FALSE: Will skip this detection/setup.
  72 # - OFF, TRUE : Will keep GMX_GPU=OFF if no CUDA is detected, but will assemble
  73 #               a warning message which will be issued at the end of the
  74 #               configuration if GPU(s) were found in the build system.
  75 # - ON , FALSE: The user requested GPU builds, will require CUDA and will fail
  76 #               if it is not available.
  77 # - ON , TRUE : Can't happen (GMX_GPU=ON can only be user-set at this point)
  78 if(GMX_GPU OR GMX_GPU_AUTO AND NOT GMX_GPU_DETECTION_DONE)
  79     if (EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
  80         set(CUDA_FOUND TRUE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
  81     else()
  82         set(CUDA_FOUND FALSE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
  83     endif()
  84
  85     # assemble warning/error message
  86     if (GMX_DETECT_GPU_AVAILABLE)
  87         set(_msg "
  88     ${GMX_DETECT_GPU_COUNT} NVIDIA GPU(s) found in the system")
  89
  90         # append GPU names
  91         if (NOT GMX_DETECT_GPU_INFO STREQUAL "")
  92             set(_msg "${_msg}:")
  93             foreach(gpu ${GMX_DETECT_GPU_INFO})
  94                 set(_msg "${_msg}
  95                 ${gpu}")
  96             endforeach()
  97         endif()
  98
  99         # TODO remove the second part of the message when we'll have compute
 100         # capability information from the detection.
 101         set(_msg "${_msg}
 102     Compute capability information not available, consult the NVIDIA website:
 103     https://developer.nvidia.com/cuda-gpus
 104             ")
 105     endif()
 106
 107         set(CUDA_NOTFOUND_MESSAGE "
 108     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 109     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 110     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR as
 111     a CMake option (It does not work as an environment variable).
 112     The typical location would be /usr/local/cuda[-version].
 113     Note that CPU or GPU acceleration can be selected at runtime!
 114
 115     ${_msg}")
 116         unset(_msg)
 117
 118     if (NOT CUDA_FOUND)
 119         if (GMX_GPU_AUTO)
 120             # Disable GPU acceleration in auto mode
 121             message(STATUS "Disabling native GPU acceleration")
 122             set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
 123             set(CUDA_NOTFOUND_AUTO ON)
 124         else ()
 125             # the user requested CUDA, but it wasn't found
 126             message(FATAL_ERROR "${CUDA_NOTFOUND_MESSAGE}")
 127         endif()
 128     else()
 129         if (GMX_GPU_AUTO)
 130             message(STATUS "Enabling native GPU acceleration")
 131             set_property(CACHE GMX_GPU PROPERTY VALUE ON)
 132         endif()
 133     endif() # NOT CUDA_FOUND
 134 endif()
 135 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 136 # We need to mark these advanced outside the conditional, otherwise, if the
 137 # user turns GMX_GPU=OFF after a failed cmake pass, these variables will be
 138 # left behind in the cache.
 139 mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 140
 141 macro(gmx_gpu_setup)
 142     # set up nvcc options
 143     include(gmxManageNvccConfig)
 144
 145     # Version info (semicolon used as line separator) for nvcc.
 146     get_nvcc_version_info()
 147
 148     # Atomic operations used for polling wait for GPU
 149     # (to avoid the cudaStreamSynchronize + ECC bug).
 150     # ThreadMPI is now always included. Thus, we don't check for Atomics anymore here.
 151
 152     # no OpenMP is no good!
 153     if(NOT GMX_OPENMP)
 154         message(WARNING "
 155     To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading.
 156     With no OpenMP a single CPU core can be used with a GPU which is not optimal.
 157     Note that with MPI multiple processes can be forced to use a single GPU, but this
 158     typically inefficient. Note that you need to set both C and C++ compilers that
 159     support OpenMP (CC and CXX environment variables, respectively) when using GPUs.")
 160     endif()
 161 endmacro()