cmake/gmxManageGPU.cmake

   1 # If the user did not set GMX_GPU we'll consider this option to be
   2 # in "auto" mode meaning that we will:
   3 # - search for CUDA and set GMX_GPU=ON we find it
   4 # - check whether GPUs are present
   5 # - if CUDA is not found but GPUs were detected issue a warning
   6 if (NOT DEFINED GMX_GPU)
   7     set(GMX_GPU_AUTO TRUE CACHE INTERNAL "GPU acceleration will be selected automatically")
   8 endif()
   9 option(GMX_GPU "Enable GPU acceleration" OFF)
  10
  11 if(GMX_GPU AND GMX_DOUBLE)
  12     message(FATAL_ERROR "GPU acceleration is not available in double precision!")
  13 endif()
  14 if(GMX_GPU_AUTO AND GMX_DOUBLE)
  15     message(WARNING "GPU acceleration is not available in double precision, disabled!")
  16     set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
  17     set_property(CACHE GMX_GPU_AUTO PROPERTY VALUE OFF)
  18 endif()
  19
  20 # detect GPUs in the build host machine
  21 if ((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
  22     include(gmxDetectGpu)
  23     gmx_detect_gpu()
  24 endif()
  25
  26 # We need to call find_package even when we've already done the detection/setup
  27 if(GMX_GPU OR GMX_GPU_AUTO)
  28     if(NOT GMX_GPU AND NOT GMX_DETECT_GPU_AVAILABLE)
  29         # Stay quiet when detection has occured and found no GPU.
  30         # Noise is acceptable when there is a GPU or the user required one.
  31         set(FIND_CUDA_QUIETLY QUIET)
  32     endif()
  33     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
  34     if(MSVC)
  35         find_package(CUDA 4.1 ${FIND_CUDA_QUIETLY})
  36     else()
  37         find_package(CUDA 3.2 ${FIND_CUDA_QUIETLY})
  38     endif()
  39 endif()
  40
  41 # Depending on the current vale of GMX_GPU and GMX_GPU_AUTO:
  42 # - OFF, FALSE: Will skip this detection/setup.
  43 # - OFF, TRUE : Will keep GMX_GPU=OFF if no CUDA is detected, but will assemble
  44 #               a warning message which will be issued at the end of the
  45 #               configuration if GPU(s) were found in the build system.
  46 # - ON , FALSE: The user requested GPU builds, will require CUDA and will fail
  47 #               if it is not available.
  48 # - ON , TRUE : Can't happen (GMX_GPU=ON can only be user-set at this point)
  49 if((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
  50     if (EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
  51         set(CUDA_FOUND TRUE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
  52     else()
  53         set(CUDA_FOUND FALSE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
  54     endif()
  55
  56     # assemble warning/error message
  57     if (GMX_DETECT_GPU_AVAILABLE)
  58         set(_msg "
  59     ${GMX_DETECT_GPU_COUNT} NVIDIA GPU(s) found in the system")
  60
  61         # append GPU names
  62         if (NOT GMX_DETECT_GPU_INFO STREQUAL "")
  63             set(_msg "${_msg}:")
  64             foreach(gpu ${GMX_DETECT_GPU_INFO})
  65                 set(_msg "${_msg}
  66                 ${gpu}")
  67             endforeach()
  68         endif()
  69
  70         # TODO remove the second part of the message when we'll have compute
  71         # capability information from the detection.
  72         set(_msg "${_msg}
  73     Compute capability information not available, consult the NVIDIA website:
  74     https://developer.nvidia.com/cuda-gpus
  75             ")
  76     endif()
  77
  78         set(CUDA_NOTFOUND_MESSAGE "
  79     mdrun supports native GPU acceleration on NVIDIA hardware with compute
  80     capability >=2.0. This requires the NVIDIA CUDA library, which was not
  81     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR as
  82     a CMake option (It does not work as an environment variable).
  83     The typical location would be /usr/local/cuda[-version].
  84     Note that CPU or GPU acceleration can be selected at runtime!
  85
  86     ${_msg}")
  87         unset(_msg)
  88
  89     if (NOT CUDA_FOUND)
  90         if (GMX_GPU_AUTO)
  91             # Disable GPU acceleration in auto mode
  92             message(STATUS "Disabling native GPU acceleration")
  93             set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
  94             set(CUDA_NOTFOUND_AUTO ON)
  95         else ()
  96             # the user requested CUDA, but it wasn't found
  97             message(FATAL_ERROR "${CUDA_NOTFOUND_MESSAGE}")
  98         endif()
  99     else()
 100         if (GMX_GPU_AUTO)
 101             message(STATUS "Enabling native GPU acceleration")
 102             set_property(CACHE GMX_GPU PROPERTY VALUE ON)
 103         endif()
 104     endif() # NOT CUDA_FOUND
 105 endif()
 106 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 107 # We need to mark these advanced outside the conditional, otherwise, if the
 108 # user turns GMX_GPU=OFF after a failed cmake pass, these variables will be
 109 # left behind in the cache.
 110 mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 111 if(NOT GMX_GPU)
 112     mark_as_advanced(CUDA_TOOLKIT_ROOT_DIR)
 113 endif()
 114
 115 macro(gmx_gpu_setup)
 116     # set up nvcc options
 117     include(gmxManageNvccConfig)
 118
 119     # Version info (semicolon used as line separator) for nvcc.
 120     get_nvcc_version_info()
 121
 122     # Atomic operations used for polling wait for GPU
 123     # (to avoid the cudaStreamSynchronize + ECC bug).
 124     # ThreadMPI is now always included. Thus, we don't check for Atomics anymore here.
 125
 126     # no OpenMP is no good!
 127     if(NOT GMX_OPENMP)
 128         message(WARNING "
 129     To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading.
 130     With no OpenMP a single CPU core can be used with a GPU which is not optimal.
 131     Note that with MPI multiple processes can be forced to use a single GPU, but this
 132     typically inefficient. Note that you need to set both C and C++ compilers that
 133     support OpenMP (CC and CXX environment variables, respectively) when using GPUs.")
 134     endif()
 135 endmacro()