cmake/gmxManageGPU.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # If the user did not set GMX_GPU we'll consider this option to be
  36 # in "auto" mode meaning that we will:
  37 # - search for CUDA and set GMX_GPU=ON we find it
  38 # - check whether GPUs are present
  39 # - if CUDA is not found but GPUs were detected issue a warning
  40 if (NOT DEFINED GMX_GPU)
  41     set(GMX_GPU_AUTO TRUE CACHE INTERNAL "GPU acceleration will be selected automatically")
  42 endif()
  43 option(GMX_GPU "Enable GPU acceleration" OFF)
  44
  45 if(GMX_GPU AND GMX_DOUBLE)
  46     message(FATAL_ERROR "GPU acceleration is not available in double precision!")
  47 endif()
  48 if(GMX_GPU_AUTO AND GMX_DOUBLE)
  49     message(WARNING "GPU acceleration is not available in double precision, disabled!")
  50     set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
  51     set_property(CACHE GMX_GPU_AUTO PROPERTY VALUE OFF)
  52 endif()
  53
  54 # detect GPUs in the build host machine
  55 if ((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
  56     include(gmxDetectGpu)
  57     gmx_detect_gpu()
  58 endif()
  59
  60 # CMake 3.0-3.1 has a bug in the following case, which breaks
  61 # configuration on at least BlueGene/Q. A patch for that bug has been
  62 # accepted for upcoming CMake 3.2.
  63 if ((NOT CMAKE_VERSION VERSION_LESS "3.0.0") AND
  64     (CMAKE_VERSION VERSION_LESS "3.2.0") AND
  65         (CMAKE_CROSSCOMPILING AND NOT CMAKE_SYSTEM_PROCESSOR))
  66     message(STATUS "Cannot search for CUDA because the CMake find package has a bug. Set a valid CMAKE_SYSTEM_PROCESSOR if you need to detect CUDA")
  67 else()
  68     set(CAN_RUN_CUDA_FIND_PACKAGE 1)
  69 endif()
  70
  71 # We need to call find_package even when we've already done the detection/setup
  72 if(GMX_GPU OR GMX_GPU_AUTO AND CAN_RUN_CUDA_FIND_PACKAGE)
  73     if(NOT GMX_GPU AND NOT GMX_DETECT_GPU_AVAILABLE)
  74         # Stay quiet when detection has occured and found no GPU.
  75         # Noise is acceptable when there is a GPU or the user required one.
  76         set(FIND_CUDA_QUIETLY QUIET)
  77     endif()
  78     find_package(CUDA ${REQUIRED_CUDA_VERSION} ${FIND_CUDA_QUIETLY})
  79
  80     # Cmake 2.8.12 (and CMake 3.0) introduced a new bug where the cuda
  81     # library dir is added twice as an rpath on APPLE, which in turn causes
  82     # the install_name_tool to wreck the binaries when it tries to remove this
  83     # path. Since this is set inside the cuda module, we remove the extra rpath
  84     # added in the library string - an rpath is not a library anyway, and at
  85     # least for Gromacs this works on all CMake versions. This should be
  86     # reasonably future-proof, since newer versions of CMake appear to handle
  87     # the rpath automatically based on the provided library path, meaning
  88     # the explicit rpath specification is no longer needed.
  89     if(APPLE AND (CMAKE_VERSION VERSION_GREATER 2.8.11))
  90         foreach(elem ${CUDA_LIBRARIES})
  91             if(elem MATCHES "-Wl,.*")
  92                 list(REMOVE_ITEM CUDA_LIBRARIES ${elem})
  93             endif()
  94         endforeach(elem)
  95     endif()
  96 endif()
  97
  98 # Depending on the current vale of GMX_GPU and GMX_GPU_AUTO:
  99 # - OFF, FALSE: Will skip this detection/setup.
 100 # - OFF, TRUE : Will keep GMX_GPU=OFF if no CUDA is detected, but will assemble
 101 #               a warning message which will be issued at the end of the
 102 #               configuration if GPU(s) were found in the build system.
 103 # - ON , FALSE: The user requested GPU build and this requires CUDA, so we will
 104 #               fail if it is not available.
 105 # - ON , TRUE : Can't happen (GMX_GPU=ON can only be user-set at this point)
 106 if((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
 107     if (EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 108         set(CUDA_FOUND TRUE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
 109     else()
 110         set(CUDA_FOUND FALSE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
 111     endif()
 112
 113     # assemble warning/error message
 114     if (GMX_DETECT_GPU_AVAILABLE)
 115         set(_msg "${GMX_DETECT_GPU_COUNT} NVIDIA GPU(s) found in the system")
 116
 117         # append GPU names
 118         if (NOT GMX_DETECT_GPU_INFO STREQUAL "")
 119             set(_msg "${_msg}:")
 120             foreach(gpu ${GMX_DETECT_GPU_INFO})
 121                 set(_msg "${_msg}
 122 ${gpu}")
 123             endforeach()
 124         endif()
 125
 126         # TODO remove the second part of the message when we'll have compute
 127         # capability information from the detection.
 128         set(_msg "${_msg}
 129 Compute capability information not available, consult the NVIDIA website:
 130 https://developer.nvidia.com/cuda-gpus")
 131     endif()
 132
 133         set(CUDA_NOTFOUND_MESSAGE "mdrun supports native GPU acceleration on NVIDIA hardware with compute capability >= ${REQUIRED_CUDA_COMPUTE_CAPABILITY} (Fermi or later). This requires the NVIDIA CUDA toolkit, which was not found. Its location can be hinted by setting the CUDA_TOOLKIT_ROOT_DIR CMake option (does not work as an environment variable). The typical location would be /usr/local/cuda[-version]. Note that CPU or GPU acceleration can be selected at runtime.
 134
 135 ${_msg}")
 136         unset(_msg)
 137
 138     if (NOT CUDA_FOUND)
 139         if (GMX_GPU_AUTO)
 140             # Disable GPU acceleration in auto mode
 141             message(STATUS "No compatible CUDA toolkit found (v4.0+), disabling native GPU acceleration")
 142             set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
 143             set(CUDA_NOTFOUND_AUTO ON)
 144         else()
 145             # the user requested CUDA, but it wasn't found
 146             message(FATAL_ERROR "${CUDA_NOTFOUND_MESSAGE}")
 147         endif()
 148     else()
 149         if (GMX_GPU_AUTO)
 150             message(STATUS "Enabling native GPU acceleration")
 151             set_property(CACHE GMX_GPU PROPERTY VALUE ON)
 152         endif()
 153     endif() # NOT CUDA_FOUND
 154 endif()
 155 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 156 # We need to mark these advanced outside the conditional, otherwise, if the
 157 # user turns GMX_GPU=OFF after a failed cmake pass, these variables will be
 158 # left behind in the cache.
 159 mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 160 if(NOT GMX_GPU)
 161     mark_as_advanced(CUDA_TOOLKIT_ROOT_DIR)
 162 endif()
 163
 164 # Try to execute ${CUDA_NVCC_EXECUTABLE} --version and set the output
 165 # (or an error string) in the argument variable.
 166 # Note that semicolon is used as separator for nvcc.
 167 #
 168 # Parameters:
 169 #   COMPILER_INFO   - [output variable] string with compiler path, ID and
 170 #                     some compiler-provided information
 171 #   COMPILER_FLAGS  - [output variable] flags for the compiler
 172 #
 173 macro(get_cuda_compiler_info COMPILER_INFO COMPILER_FLAGS)
 174     if(CUDA_NVCC_EXECUTABLE)
 175
 176         # Get the nvcc version string. This is multi-line, but since it is only 4 lines
 177         # and might change in the future it is better to store than trying to parse out
 178         # the version from the current format.
 179         execute_process(COMMAND ${CUDA_NVCC_EXECUTABLE} --version
 180             RESULT_VARIABLE _nvcc_version_res
 181             OUTPUT_VARIABLE _nvcc_version_out
 182             ERROR_VARIABLE  _nvcc_version_err
 183             OUTPUT_STRIP_TRAILING_WHITESPACE)
 184         if (${_nvcc_version_res} EQUAL 0)
 185             # Fix multi-line mess: Replace newline with ";" so we can use it in a define
 186             string(REPLACE "\n" ";" _nvcc_info_singleline ${_nvcc_version_out})
 187             SET(${COMPILER_INFO} "${CUDA_NVCC_EXECUTABLE} ${_nvcc_info_singleline}")
 188             string(TOUPPER ${CMAKE_BUILD_TYPE} _build_type)
 189             SET(_compiler_flags "${CUDA_NVCC_FLAGS_${_build_type}}")
 190             if(CUDA_PROPAGATE_HOST_FLAGS)
 191                 string(REGEX REPLACE "[ ]+" ";" _cxx_flags_nospace "${BUILD_CXXFLAGS}")
 192             endif()
 193             SET(${COMPILER_FLAGS} "${CUDA_NVCC_FLAGS}${CUDA_NVCC_FLAGS_${_build_type}}; ${_cxx_flags_nospace}")
 194         else()
 195             SET(${COMPILER_INFO} "N/A")
 196             SET(${COMPILER_FLAGS} "N/A")
 197         endif()
 198     endif()
 199 endmacro ()
 200
 201 macro(gmx_gpu_setup)
 202     # set up nvcc options
 203     include(gmxManageNvccConfig)
 204
 205     # Atomic operations used for polling wait for GPU
 206     # (to avoid the cudaStreamSynchronize + ECC bug).
 207     # ThreadMPI is now always included. Thus, we don't check for Atomics anymore here.
 208
 209     # no OpenMP is no good!
 210     if(NOT GMX_OPENMP)
 211         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading. Without OpenMP a single CPU core can be used with a GPU which is not optimal. Note that with MPI multiple processes can be forced to use a single GPU, but this is typically inefficient. You need to set both C and C++ compilers that support OpenMP (CC and CXX environment variables, respectively) when using GPUs.")
 212     endif()
 213 endmacro()