cmake/gmxManageGPU.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # If the user did not set GMX_GPU we'll consider this option to be
  36 # in "auto" mode meaning that we will:
  37 # - search for CUDA and set GMX_GPU=ON we find it
  38 # - check whether GPUs are present
  39 # - if CUDA is not found but GPUs were detected issue a warning
  40 if (NOT DEFINED GMX_GPU)
  41     set(GMX_GPU_AUTO TRUE CACHE INTERNAL "GPU acceleration will be selected automatically")
  42 else()
  43     set(GMX_GPU_AUTO FALSE CACHE INTERNAL "GPU acceleration will be selected automatically")
  44 endif()
  45 option(GMX_GPU "Enable GPU acceleration" OFF)
  46
  47 option(GMX_CLANG_CUDA "Use clang for CUDA" OFF)
  48
  49 if(GMX_GPU AND GMX_DOUBLE)
  50     message(FATAL_ERROR "GPU acceleration is not available in double precision!")
  51 endif()
  52 if(GMX_GPU_AUTO AND GMX_DOUBLE)
  53     message(WARNING "GPU acceleration is not available in double precision, disabled!")
  54     set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
  55     set_property(CACHE GMX_GPU_AUTO PROPERTY VALUE OFF)
  56 endif()
  57
  58 # detect GPUs in the build host machine
  59 if ((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
  60     include(gmxDetectGpu)
  61     gmx_detect_gpu()
  62 endif()
  63
  64 # We need to call find_package even when we've already done the detection/setup
  65 if(GMX_GPU OR GMX_GPU_AUTO)
  66     if(NOT GMX_GPU AND NOT GMX_DETECT_GPU_AVAILABLE)
  67         # Stay quiet when detection has occured and found no GPU.
  68         # Noise is acceptable when there is a GPU or the user required one.
  69         set(FIND_CUDA_QUIETLY QUIET)
  70     endif()
  71
  72     # Cmake tries to use the static cuda runtime by default,
  73     # but this leads to unusable GPU builds on OS X.
  74     if(APPLE)
  75         set(CUDA_USE_STATIC_CUDA_RUNTIME OFF CACHE STRING "Use the static version of the CUDA runtime library if available")
  76     endif()
  77
  78     find_package(CUDA ${REQUIRED_CUDA_VERSION} ${FIND_CUDA_QUIETLY})
  79 endif()
  80
  81 # Depending on the current vale of GMX_GPU and GMX_GPU_AUTO:
  82 # - OFF, FALSE: Will skip this detection/setup.
  83 # - OFF, TRUE : Will keep GMX_GPU=OFF if no CUDA is detected, but will assemble
  84 #               a warning message which will be issued at the end of the
  85 #               configuration if GPU(s) were found in the build system.
  86 # - ON , FALSE: The user requested GPU build and this requires CUDA, so we will
  87 #               fail if it is not available.
  88 # - ON , TRUE : Can't happen (GMX_GPU=ON can only be user-set at this point)
  89 if((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
  90     # assemble warning/error message
  91     if (GMX_DETECT_GPU_AVAILABLE)
  92         set(_msg "${GMX_DETECT_GPU_COUNT} NVIDIA GPU(s) found in the system")
  93
  94         # append GPU names
  95         if (NOT GMX_DETECT_GPU_INFO STREQUAL "")
  96             set(_msg "${_msg}:")
  97             foreach(gpu ${GMX_DETECT_GPU_INFO})
  98                 set(_msg "${_msg}
  99 ${gpu}")
 100             endforeach()
 101         endif()
 102
 103         # TODO remove the second part of the message when we'll have compute
 104         # capability information from the detection.
 105         set(_msg "${_msg}
 106 Compute capability information not available, consult the NVIDIA website:
 107 https://developer.nvidia.com/cuda-gpus")
 108     endif()
 109
 110         set(CUDA_NOTFOUND_MESSAGE "mdrun supports native GPU acceleration on NVIDIA hardware with compute capability >= ${REQUIRED_CUDA_COMPUTE_CAPABILITY} (Kepler or later). This requires the NVIDIA CUDA toolkit, which was not found. Its location can be hinted by setting the CUDA_TOOLKIT_ROOT_DIR CMake option (does not work as an environment variable). The typical location would be /usr/local/cuda[-version]. Note that CPU or GPU acceleration can be selected at runtime.
 111
 112 ${_msg}")
 113         unset(_msg)
 114
 115     if (NOT CUDA_FOUND)
 116         if (GMX_GPU_AUTO)
 117             # Disable GPU acceleration in auto mode
 118             message(STATUS "No compatible CUDA toolkit found (v5.0+), disabling native GPU acceleration")
 119             set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
 120             set(CUDA_NOTFOUND_AUTO ON)
 121         else()
 122             # the user requested CUDA, but it wasn't found
 123             message(FATAL_ERROR "${CUDA_NOTFOUND_MESSAGE}")
 124         endif()
 125     else()
 126         if (GMX_GPU_AUTO)
 127             message(STATUS "Enabling native GPU acceleration")
 128             set_property(CACHE GMX_GPU PROPERTY VALUE ON)
 129         endif()
 130     endif()
 131 endif()
 132
 133 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 134 # We need to mark these advanced outside the conditional, otherwise, if the
 135 # user turns GMX_GPU=OFF after a failed cmake pass, these variables will be
 136 # left behind in the cache.
 137 mark_as_advanced(CUDA_SDK_ROOT_DIR
 138                  CUDA_USE_STATIC_CUDA_RUNTIME
 139                  CUDA_dl_LIBRARY CUDA_rt_LIBRARY
 140                  )
 141 if(NOT GMX_GPU)
 142     mark_as_advanced(CUDA_TOOLKIT_ROOT_DIR)
 143     mark_as_advanced(CUDA_HOST_COMPILER)
 144 endif()
 145
 146 # Try to execute ${CUDA_NVCC_EXECUTABLE} --version and set the output
 147 # (or an error string) in the argument variable.
 148 # Note that semicolon is used as separator for nvcc.
 149 #
 150 # Parameters:
 151 #   COMPILER_INFO         - [output variable] string with compiler path, ID and
 152 #                           some compiler-provided information
 153 #   DEVICE_COMPILER_FLAGS - [output variable] device flags for the compiler
 154 #   HOST_COMPILER_FLAGS   - [output variable] host flags for the compiler, if propagated
 155 #
 156 macro(get_cuda_compiler_info COMPILER_INFO DEVICE_COMPILER_FLAGS HOST_COMPILER_FLAGS)
 157     if(NOT GMX_CLANG_CUDA)
 158         if(CUDA_NVCC_EXECUTABLE)
 159
 160             # Get the nvcc version string. This is multi-line, but since it is only 4 lines
 161             # and might change in the future it is better to store than trying to parse out
 162             # the version from the current format.
 163             execute_process(COMMAND ${CUDA_NVCC_EXECUTABLE} --version
 164                 RESULT_VARIABLE _nvcc_version_res
 165                 OUTPUT_VARIABLE _nvcc_version_out
 166                 ERROR_VARIABLE  _nvcc_version_err
 167                 OUTPUT_STRIP_TRAILING_WHITESPACE)
 168             if (${_nvcc_version_res} EQUAL 0)
 169                 # Fix multi-line mess: Replace newline with ";" so we can use it in a define
 170                 string(REPLACE "\n" ";" _nvcc_info_singleline ${_nvcc_version_out})
 171                 SET(${COMPILER_INFO} "${CUDA_NVCC_EXECUTABLE} ${_nvcc_info_singleline}")
 172                 string(TOUPPER ${CMAKE_BUILD_TYPE} _build_type)
 173                 SET(_compiler_flags "${CUDA_NVCC_FLAGS_${_build_type}}")
 174                 if(CUDA_PROPAGATE_HOST_FLAGS)
 175                     set(${HOST_COMPILER_FLAGS} BUILD_CXXFLAGS)
 176                 else()
 177                     set(${HOST_COMPILER_FLAGS} "")
 178                 endif()
 179                 SET(${DEVICE_COMPILER_FLAGS} "${CUDA_NVCC_FLAGS}${CUDA_NVCC_FLAGS_${_build_type}}")
 180             else()
 181                 SET(${COMPILER_INFO} "N/A")
 182                 SET(${COMPILER_FLAGS} "N/A")
 183             endif()
 184         endif()
 185     else()
 186         # CXX compiler is the CUDA compiler
 187         set(${COMPILER_INFO} "${CMAKE_CXX_COMPILER}  ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}")
 188         # there are some extra flags
 189         set(${COMPILER_FLAGS} "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_${_build_type}} ${GMX_CUDA_CLANG_FLAGS}")
 190     endif()
 191 endmacro ()
 192
 193 macro(enable_multiple_cuda_compilation_units)
 194     message(STATUS "Enabling multiple compilation units for the CUDA non-bonded module.")
 195     set_property(CACHE GMX_CUDA_NB_SINGLE_COMPILATION_UNIT PROPERTY VALUE OFF)
 196 endmacro()
 197
 198 include(CMakeDependentOption)
 199 include(gmxOptionUtilities)
 200 macro(gmx_gpu_setup)
 201     if(GMX_GPU)
 202         if(NOT GMX_CLANG_CUDA)
 203             if(NOT CUDA_NVCC_EXECUTABLE)
 204                 message(FATAL_ERROR "nvcc is required for a CUDA build, please set CUDA_TOOLKIT_ROOT_DIR appropriately")
 205             endif()
 206             # set up nvcc options
 207             include(gmxManageNvccConfig)
 208         else()
 209             include(gmxManageClangCudaConfig)
 210         endif()
 211
 212         # no OpenMP is no good!
 213         if(NOT GMX_OPENMP)
 214             message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading. Without OpenMP a single CPU core can be used with a GPU which is not optimal. Note that with MPI multiple processes can be forced to use a single GPU, but this is typically inefficient. You need to set both C and C++ compilers that support OpenMP (CC and CXX environment variables, respectively) when using GPUs.")
 215         endif()
 216     endif() # GMX_GPU
 217
 218     option(GMX_CUDA_NB_SINGLE_COMPILATION_UNIT "Whether to compile the CUDA non-bonded module using a single compilation unit." OFF)
 219     mark_as_advanced(GMX_CUDA_NB_SINGLE_COMPILATION_UNIT)
 220
 221 endmacro()