cmake/gmxManageFFTLibraries.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Manage setup of the different FFT libraries we can use in Gromacs.
  36 set(PKG_FFT "")
  37 set(PKG_FFT_LIBS "")
  38 # Intel 11 and up makes life somewhat easy if you just want to use
  39 # all their stuff. It's not easy if you only want some of their
  40 # stuff...
  41 set(MKL_MANUALLY FALSE)
  42 if (GMX_FFT_LIBRARY STREQUAL "MKL" AND
  43     NOT (CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "11"))
  44     # The user will have to provide the set of magic libraries in
  45     # MKL_LIBRARIES (see below), which we cache (non-advanced), so that they
  46     # don't have to keep specifying it, and can easily see that
  47     # CMake is still using that information.
  48     set(MKL_MANUALLY TRUE)
  49 endif()
  50 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
  51 gmx_dependent_cache_variable(
  52     MKL_LIBRARIES
  53     "List of libraries for linking to MKL. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}"
  54     STRING ""
  55     MKL_MANUALLY)
  56 gmx_dependent_cache_variable(
  57     MKL_INCLUDE_DIR
  58     "Path to mkl.h (non-inclusive)."
  59     PATH ""
  60     MKL_MANUALLY)
  61 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
  62     if(GMX_DOUBLE)
  63         set(FFTW fftw)
  64     else()
  65         set(FFTW fftwf)
  66     endif()
  67
  68     if(GMX_BUILD_OWN_FFTW)
  69       add_subdirectory(src/contrib/fftw)
  70     else()
  71       find_package(FFTW COMPONENTS ${FFTW})
  72     endif()
  73
  74     string(TOUPPER "${FFTW}" FFTW)
  75     if(NOT ${FFTW}_FOUND)
  76       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library (-DGMX_FFT_LIBRARY), enable the advanced option to let GROMACS build FFTW 3 for you (-GMX_BUILD_OWN_FFTW=ON), or use the really slow GROMACS built-in fftpack library (-DGMX_FFT_LIBRARY=fftpack).")
  77     endif()
  78
  79     set(PKG_FFT "${${FFTW}_PKG}")
  80     include_directories(${${FFTW}_INCLUDE_DIRS})
  81     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
  82     set(GMX_FFT_FFTW3 1)
  83
  84     if ((${GMX_SIMD} MATCHES "SSE" OR ${GMX_SIMD} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
  85       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
  86     endif()
  87
  88     if((${GMX_SIMD} MATCHES "SSE" OR ${GMX_SIMD} MATCHES "AVX") AND ${FFTW}_HAVE_AVX)
  89         # If we're not using SIMD instructions, we don't care about FFTW performance on x86 either
  90         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
  91     endif()
  92
  93     set(FFT_STATUS_MESSAGE "Using external FFT library - FFTW3")
  94 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
  95     # Intel 11 and up makes life somewhat easy if you just want to use
  96     # all their stuff. It's not easy if you only want some of their
  97     # stuff...
  98     if (NOT MKL_MANUALLY)
  99         # The next line takes care of everything for MKL
 100         if (WIN32)
 101             # This works according to the Intel MKL 10.3 for Windows
 102             # docs, but on Jenkins Win2k8, icl tries to interpret it
 103             # as a file. Shrug.
 104             set(FFT_LINKER_FLAGS "/Qmkl:sequential")
 105         else()
 106             set(FFT_LINKER_FLAGS "-mkl=sequential")
 107         endif()
 108         # Some versions of icc require this in order that mkl.h can be
 109         # found at compile time.
 110         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} ${FFT_LINKER_FLAGS}")
 111
 112         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 113     else()
 114         include_directories(${MKL_INCLUDE_DIR})
 115         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 116         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system: ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 117         # Convert the semi-colon separated list to a list of
 118         # command-line linker arguments so that code using our
 119         # pkgconfig setup can use it.
 120         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
 121     endif()
 122
 123     # Check MKL works. If we were in a non-global scope, we wouldn't
 124     # have to play nicely.
 125     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 126     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
 127     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
 128     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
 129
 130     check_function_exists(DftiCreateDescriptor TEST_MKL)
 131
 132     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
 133     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
 134
 135     if(NOT TEST_MKL)
 136         # Hack to help the user vary MKL settings until they work.
 137         # TODO Make this logic more useful.
 138         unset(TEST_MKL CACHE)
 139         message(FATAL_ERROR "Linking with MKL was requested, but was not successful: ${MKL_ERROR_MESSAGE}")
 140     endif()
 141
 142     # Set variables to signal that we have MKL available and should use it for FFTs.
 143     set(GMX_FFT_MKL 1)
 144     set(HAVE_LIBMKL 1)
 145
 146     set(FFT_STATUS_MESSAGE "Using external FFT library - Intel MKL")
 147 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 148     set(GMX_FFT_FFTPACK 1)
 149     set(FFT_STATUS_MESSAGE "Using internal FFT library - fftpack")
 150 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 151     gmx_invalid_option_value(GMX_FFT_LIBRARY)
 152 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 153 gmx_check_if_changed(FFT_CHANGED GMX_FFT_LIBRARY)
 154 if (FFT_CHANGED)
 155     message(STATUS "${FFT_STATUS_MESSAGE}")
 156 endif()
 157
 158 # enable threaded fftw3 if we've found it
 159 if(FFTW3_THREADS OR FFTW3F_THREADS)
 160     add_definitions(-DFFT5D_FFTW_THREADS)
 161 endif()
 162