cmake/gmxDetectSimd.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Check the username performing the build, as well as date and time
  36 #
  37 # gmx_detect_simd(GMX_SUGGESTED_SIMD)
  38 #
  39 # Try to detect CPU information and suggest SIMD instruction set
  40 # that fits the current CPU. This should work on all architectures
  41 # where we are not cross-compiling; depending on the architecture the
  42 # detection will either use special assembly instructions (like cpuid),
  43 # preprocessor defines, or probing /proc/cpuinfo on Linux.
  44 #
  45 # This assumes gmx_detect_target_architecture() has already been run,
  46 # so that things like GMX_TARGET_X86 are already available.
  47 # (otherwise we cannot use inline ASM on x86).
  48 #
  49 # Sets ${GMX_SUGGESTED_SIMD} in the parent scope if
  50 # GMX_SIMD is not set (e.g. by the user, or a previous run
  51 # of CMake).
  52 #
  53
  54 # we rely on inline asm support for GNU!
  55 include(gmxTestInlineASM)
  56
  57 function(gmx_suggest_simd _suggested_simd)
  58     if(${_suggested_simd})
  59         # There's already been a suggestion made, which can't change
  60         return()
  61     endif()
  62
  63     # for x86 we need inline asm to use cpuid
  64     gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
  65
  66     if(GMX_X86_GCC_INLINE_ASM)
  67         set(GCC_INLINE_ASM_DEFINE "-DGMX_X86_GCC_INLINE_ASM")
  68     else()
  69         set(GCC_INLINE_ASM_DEFINE "")
  70     endif()
  71
  72     message(STATUS "Detecting best SIMD instructions for this CPU")
  73
  74     # Get CPU SIMD properties information
  75     set(_compile_definitions "${GCC_INLINE_ASM_DEFINE} -I${CMAKE_SOURCE_DIR}/src -DGMX_CPUID_STANDALONE")
  76     if(GMX_TARGET_X86)
  77         set(_compile_definitions "${_compile_definitions} -DGMX_TARGET_X86")
  78     endif()
  79
  80     # Prepare a default suggestion
  81     set(OUTPUT_SIMD "None")
  82
  83     # We need to execute the binary, so this only works if not cross-compiling.
  84     # However, note that we are NOT limited to x86.
  85     if(NOT CMAKE_CROSSCOMPILING)
  86         # TODO Extract this try_compile to a helper function, because
  87         # it duplicates code in gmxDetectSimd.cmake
  88         set(GMX_DETECTSIMD_BINARY "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/GmxDetectSimd${CMAKE_EXECUTABLE_SUFFIX}")
  89         try_compile(GMX_DETECTSIMD_COMPILED
  90             "${CMAKE_CURRENT_BINARY_DIR}"
  91             "${CMAKE_CURRENT_SOURCE_DIR}/src/gromacs/gmxlib/gmx_cpuid.c"
  92             COMPILE_DEFINITIONS "${_compile_definitions}"
  93             OUTPUT_VARIABLE GMX_DETECTSIMD_COMPILED_OUTPUT
  94             COPY_FILE ${GMX_DETECTSIMD_BINARY})
  95         unset(_compile_definitions)
  96
  97         if(GMX_DETECTSIMD_COMPILED)
  98             # TODO Extract this duplication of
  99             # gmxSetBuildInformation.cmake to a helper function
 100             if(NOT DEFINED GMX_DETECTSIMD_RUN)
 101                 execute_process(COMMAND ${GMX_DETECTSIMD_BINARY} "-simd"
 102                     RESULT_VARIABLE GMX_DETECTSIMD_RUN
 103                     OUTPUT_VARIABLE OUTPUT_TMP
 104                     ERROR_QUIET)
 105                 set(GMX_DETECTSIMD_RUN "${GMX_DETECTSIMD_RUN}" CACHE INTERNAL "Result of running CPUID code with arg -simd")
 106                 if(GMX_DETECTSIMD_RUN EQUAL 0)
 107                     # Make a concrete suggestion of SIMD level
 108                     string(STRIP "${OUTPUT_TMP}" OUTPUT_SIMD)
 109                     message(STATUS "Detected best SIMD instructions for this CPU - ${OUTPUT_SIMD}")
 110                 else()
 111                     message(WARNING "Cannot run CPUID code, which means no SIMD suggestion can be made.")
 112                     message(STATUS "Run output: ${OUTPUT_TMP}")
 113                 endif()
 114             endif()
 115         else()
 116             message(WARNING "Cannot compile CPUID code, which means no SIMD instructions.")
 117             message(STATUS "Compile output: ${GMX_CPUID_COMPILE_OUTPUT}")
 118         endif()
 119     else()
 120         message(WARNING "Cannot detect SIMD architecture for this cross-compile; you should check it manually.")
 121     endif()
 122
 123     set(${_suggested_simd} "${OUTPUT_SIMD}" CACHE INTERNAL "Suggested SIMD")
 124 endfunction()
 125
 126 function(gmx_detect_simd _suggested_simd)
 127     if(NOT DEFINED GMX_SIMD)
 128         if(GMX_TARGET_BGQ)
 129             set(${_suggested_simd} "IBM_QPX")
 130         elseif(GMX_TARGET_FUJITSU_SPARC64)
 131             # HPC-ACE is always present. In the future we
 132             # should add detection for HPC-ACE2 here.
 133             set(${_suggested_simd} "Sparc64_HPC_ACE")
 134         elseif(GMX_TARGET_MIC)
 135             set(${_suggested_simd} "MIC")
 136         else()
 137             gmx_suggest_simd(${_suggested_simd})
 138         endif()
 139
 140         set(${_suggested_simd} ${${_suggested_simd}} PARENT_SCOPE)
 141     endif()
 142 endfunction()