cmake/gmxCFlags.cmake

   1
   2 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
   3 # flags to CFLAGSVAR.
   4 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
   5     IF(NOT DEFINED ${VARIABLE})
   6         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
   7     ENDIF(NOT DEFINED ${VARIABLE})
   8     IF (${VARIABLE})
   9         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  10     ENDIF (${VARIABLE})
  11 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  12
  13 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  14 # flags to CXXFLAGSVAR.
  15 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  16     IF(NOT DEFINED ${VARIABLE})
  17         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  18     ENDIF(NOT DEFINED ${VARIABLE})
  19     IF (${VARIABLE})
  20         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  21     ENDIF (${VARIABLE})
  22 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  23
  24
  25 # This is the actual exported function to be called
  26 MACRO(gmx_c_flags)
  27
  28     include(CheckCCompilerFlag)
  29     include(CheckCXXCompilerFlag)
  30
  31     # gcc
  32     if(CMAKE_COMPILER_IS_GNUCC)
  33         #flags are added in reverse order and -Wno* need to appear after -Wall
  34         if(NOT GMX_OPENMP)
  35             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
  36         endif()
  37         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
  38         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare" GMXC_CFLAGS)
  39         # new in gcc 4.5
  40         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
  41         GMX_TEST_CFLAG(CFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
  42                        GMXC_CFLAGS_RELEASE)
  43         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
  44     endif()
  45     # g++
  46     if(CMAKE_COMPILER_IS_GNUCXX)
  47         if(NOT GMX_OPENMP)
  48             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
  49         endif()
  50         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
  51         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
  52         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers" GMXC_CXXFLAGS)
  53       # new in gcc 4.5
  54         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
  55         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
  56                          GMXC_CXXFLAGS_RELEASE)
  57         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
  58     endif()
  59
  60     # icc
  61     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
  62         if (NOT WIN32)
  63             if(NOT GMX_OPENMP)
  64                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
  65             endif()
  66             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall" GMXC_CFLAGS)
  67             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
  68             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops" GMXC_CFLAGS_RELEASE)
  69         else()
  70             GMX_TEST_CFLAG(CFLAGS_WARN "/W2" GMXC_CFLAGS)
  71             GMX_TEST_CFLAG(CFLAGS_X86 "/Qip" GMXC_CFLAGS_RELEASE)
  72         endif()
  73     endif()
  74
  75     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  76         if (NOT WIN32)
  77             if(NOT GMX_OPENMP)
  78                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
  79             endif()
  80             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
  81             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops" GMXC_CXXFLAGS_RELEASE)
  82         else()
  83             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W2" GMXC_CXXFLAGS)
  84             GMX_TEST_CXXFLAG(CXXFLAGS_X86 "/Qip" GMXC_CXXFLAGS_RELEASE)
  85         endif()
  86     endif()
  87
  88     # pgi
  89     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
  90         GMX_TEST_CFLAG(CFLAGS_OPT "-fastsse" GMXC_CFLAGS_RELEASE)
  91     endif()
  92     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
  93         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-fastsse" GMXC_CXXFLAGS_RELEASE)
  94     endif()
  95
  96     # Pathscale
  97     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
  98         if(NOT GMX_OPENMP)
  99             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 100         endif()
 101         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 102         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 103                          GMXC_CFLAGS_RELEASE)
 104         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 105     endif()
 106     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 107         if(NOT GMX_OPENMP)
 108             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 109         endif()
 110         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 111         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 112                          GMXC_CXXFLAGS_RELEASE)
 113     endif()
 114
 115     # xlc
 116     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 117         GMX_TEST_CFLAG(CFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 118         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 119     endif()
 120     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 121         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 122     endif()
 123
 124     # msvc
 125     if (MSVC)
 126         # disable warnings for:
 127         #      forcing value to bool
 128         #      "this" in initializer list
 129         #      deprecated (posix, secure) functions
 130         GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996" GMXC_CFLAGS)
 131         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996" GMXC_CXXFLAGS)
 132     endif()
 133
 134     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 135         if(NOT GMX_OPENMP)
 136             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 137         endif()
 138         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 139     endif()
 140
 141     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 142         if(NOT GMX_OPENMP)
 143             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 144         endif()
 145         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function -Wunused-value" GMXC_CXXFLAGS)
 146     endif()
 147
 148     # now actually set the flags:
 149     # C
 150     if ( NOT GMX_SKIP_DEFAULT_CFLAGS )
 151         set(CMAKE_C_FLAGS "${GMXC_CFLAGS} ${CMAKE_C_FLAGS}")
 152         set(CMAKE_C_FLAGS_RELEASE "${GMXC_CFLAGS_RELEASE} ${CMAKE_C_FLAGS_RELEASE}")
 153         set(CMAKE_C_FLAGS_DEBUG "${GMXC_CFLAGS_DEBUG} ${CMAKE_C_FLAGS_DEBUG}")
 154     endif()
 155
 156     # C++
 157     if ( NOT GMX_SKIP_DEFAULT_CFLAGS)
 158         set(CMAKE_CXX_FLAGS "${GMXC_CXXFLAGS} ${CMAKE_CXX_FLAGS}")
 159         set(CMAKE_CXX_FLAGS_RELEASE
 160             "${GMXC_CXXFLAGS_RELEASE} ${CMAKE_CXX_FLAGS_RELEASE}")
 161         set(CMAKE_CXX_FLAGS_DEBUG
 162             "${GMXC_CXXFLAGS_DEBUG} ${CMAKE_CXX_FLAGS_DEBUG}")
 163     endif()
 164 ENDMACRO(gmx_c_flags)
 165