cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_${build_type}}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Used for, e.g., -Wno-array-bounds in Release to work around
  72         # gcc-4.8 being a little too vocal about some perfectly good code,
  73         # while using RelWithAssert (ie. without that suppression) in Jenkins.
  74         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  75
  76         # Modify the real CMake variables for compiler flags for all
  77         # builds and language types, and also those common to all
  78         # build types.
  79         foreach(build_type "" ${build_types_with_explicit_flags})
  80             if("${build_type}" STREQUAL "")
  81                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  82             else()
  83                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  84             endif()
  85
  86             # Append to the variables for the given build type for
  87             # each language, in the parent scope. We add our new variables at the end, so
  88             # compiler-specific choices are more likely to override default CMake choices.
  89             # This is for instance useful for RelWithDebInfo builds, where we want to use the full
  90             # set of our optimization flags detected in this file, rather than having -O2 override them.
  91             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  92                 "${CMAKE_${language}_FLAGS${punctuation}${build_type}} ${GMXC_${language}FLAGS${punctuation}${build_type}}"
  93                 PARENT_SCOPE)
  94         endforeach()
  95     endforeach()
  96 endfunction()
  97
  98 # This is the actual exported function to be called
  99 macro (gmx_c_flags)
 100
 101     include(CheckCCompilerFlag)
 102     include(CheckCXXCompilerFlag)
 103
 104     # gcc
 105     if(CMAKE_COMPILER_IS_GNUCC)
 106         #flags are added in reverse order and -Wno* need to appear after -Wall
 107         if(NOT GMX_OPENMP)
 108             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 109         endif()
 110         if (GMX_COMPILER_WARNINGS)
 111             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 112             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 113             GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 114             # Since 4.8 on by default. For previous version disabling is a no-op. Only disabling for Release because with assert
 115             # the warnings are OK.
 116             GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 117             if(CYGWIN)
 118                 GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 119             endif()
 120             GMX_TEST_CFLAG(CFLAGS_STRINGOP_TRUNCATION "-Werror=stringop-truncation" GMXC_CFLAGS)
 121             GMX_TEST_CFLAG(CFLAGS_FORMAT_OVERFLOW "-Werror=format-overflow" GMXC_CFLAGS)
 122         endif()
 123         # new in gcc 4.5
 124         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 125         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 126                        GMXC_CFLAGS_RELEASE)
 127         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 128     endif()
 129     # g++
 130     if(CMAKE_COMPILER_IS_GNUCXX)
 131         if(NOT GMX_OPENMP)
 132             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 133         endif()
 134         if (GMX_COMPILER_WARNINGS)
 135             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 136             # Problematic with CUDA
 137             # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 138             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith -Wmissing-declarations" GMXC_CXXFLAGS)
 139             # CUDA versions prior to 7.5 come with a header (math_functions.h) which uses the _MSC_VER macro
 140             # unconditionally, so we don't use -Wundef for earlier CUDA versions.
 141             if(NOT(GMX_GPU AND CUDA_VERSION VERSION_LESS "7.5"))
 142                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 143             endif()
 144             GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 145             GMX_TEST_CXXFLAG(CXXFLAGS_STRINGOP_TRUNCATION "-Wstringop-truncation" GMXC_CXXFLAGS)
 146             if (CXXFLAGS_STRINGOP_TRUNCATION)
 147                 set(CXXFLAGS_NO_STRINGOP_TRUNCATION "-Wno-stringop-truncation")
 148             endif()
 149             GMX_TEST_CXXFLAG(CXXFLAGS_FORMAT_OVERFLOW "-Wformat-overflow" GMXC_CXXFLAGS)
 150         endif()
 151         # new in gcc 4.5
 152         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 153         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 154                          GMXC_CXXFLAGS_RELEASE)
 155         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 156     endif()
 157
 158     # icc
 159     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 160         if (NOT WIN32)
 161             if(NOT GMX_OPENMP)
 162 # 3180: unrecognized OpenMP #pragma
 163                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 164             endif()
 165             if (GMX_COMPILER_WARNINGS)
 166 # -w3 enables a lot of useful diagnostics but we don't care about all. -wd disables some selectively.
 167 # 177: function/variable ".." was declared but never referenced
 168 # 411: class defines no constructor to initialize the following (incorrect for struct, initializer list works)
 169 # 593: variable ".." was set but never used
 170 # 981: operands are evaluated in unspecified order
 171 #1418: external function definition with no prior declaration
 172 #1419: external declaration in primary source file
 173 #1572: floating-point equality and inequality comparisons are unreliable
 174 #1599: declaration hides variable ".."
 175 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 176 #2415: variable ".." of static storage duration was declared but never referenced
 177 #2547: ".." was specified as both a system and non-system include directory
 178 #2557: comparison between signed and unsigned operands
 179 #3280: declaration hides member ".."
 180 #11074: Inlining inhibited by limit max-size(/max-total-size)
 181 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 182                 GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd177 -wd411 -wd593 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd11074 -wd11076" GMXC_CFLAGS)
 183             endif()
 184             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 185             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -qoverride-limits" GMXC_CFLAGS_RELEASE)
 186             GMX_TEST_CFLAG(CFLAGS_DEBUG "-O0" GMXC_CFLAGS_DEBUG) #icc defaults to -O2 even with -g
 187             GMX_TEST_CFLAG(CFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CFLAGS_RELWITHASSERT)
 188         else()
 189             if(NOT GMX_OPENMP)
 190                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 191             endif()
 192             if (GMX_COMPILER_WARNINGS)
 193 #only on Windows
 194 #161: unrecognized pragma
 195 #1786 function was declared deprecated (is issued for stdlib function such as strncpy which have a _s version)
 196 GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd161 /wd177 /wd411 /wd593 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd1786 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280" GMXC_CFLAGS)
 197             endif()
 198             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 199         endif()
 200     endif()
 201
 202     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 203         if (NOT WIN32)
 204             if(NOT GMX_OPENMP)
 205                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 206             endif()
 207             if (GMX_COMPILER_WARNINGS)
 208                 if (GMX_GPU)
 209 # Suppress warnings from CUDA headers
 210 # 7:   unrecognized token
 211 # 82:  storage class is not first
 212 # The below are also required for math_functions.h / math_functions.hpp at least until CUDA 8.0-RC
 213 # 193: zero used for undefined preprocessing identifer
 214 # 3346:dynamic exception specifiers are deprecated
 215                     GMX_TEST_CXXFLAG(CXXFLAGS_WARN_OLD_GPU "-wd7 -wd82 -wd193 -wd3346" GMXC_CXXFLAGS)
 216                 endif()
 217 #All but the following warnings are identical for the C-compiler (see above)
 218 # 304: access control not specified
 219 # 383: value copied to temporary, reference to temporary used
 220 # 444: destructor for base class ".." is not virtual
 221 # 869: was never referenced (false positives)
 222 #2282: unrecognized GCC pragma
 223                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd177 -wd304 -wd383 -wd411 -wd444 -wd869 -wd981 -wd1418 -wd1572 -wd1599 -wd2259 -wd2547 -wd3280 -wd11074 -wd11076 -wd2282" GMXC_CXXFLAGS)
 224             endif()
 225             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -qoverride-limits" GMXC_CXXFLAGS_RELEASE)
 226             GMX_TEST_CXXFLAG(CXXFLAGS_DEBUG "-O0" GMXC_CXXFLAGS_DEBUG)
 227             GMX_TEST_CXXFLAG(CXXFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CXXFLAGS_RELWITHASSERT)
 228         else()
 229             if(NOT GMX_OPENMP)
 230                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 231             endif()
 232             if (GMX_COMPILER_WARNINGS)
 233 #161: unrecognized pragma
 234 #809: exception specification for virtual function X is incompatible with that of overridden function
 235                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd161 /wd177 /wd304 /wd383 /wd411 /wd444 /wd809 /wd869 /wd981 /wd1418 /wd1572 /wd1599 /wd1786 /wd2259 /wd2547 /wd3280 /wd11074 /wd11076 /wd2282" GMXC_CXXFLAGS)
 236             endif()
 237             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 238         endif()
 239     endif()
 240
 241     # PGI
 242     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 243     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 244         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 245     endif()
 246     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 247         # Using ipa exposes internal PGI-15.7 compiler bugs at compile time
 248         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 249         # PGI identifies itself as GCC, but does not understand the GCC
 250         # pragmas that occur in parser.cpp. Since that file is generated
 251         # we cannot add a define there, but supress the warning instead.
 252         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "--diag_suppress=1675" GMXC_CXXFLAGS)
 253     endif()
 254
 255     # Pathscale
 256     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 257         if(NOT GMX_OPENMP)
 258             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 259         endif()
 260         if (GMX_COMPILER_WARNINGS)
 261             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 262         endif()
 263         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 264                          GMXC_CFLAGS_RELEASE)
 265         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 266     endif()
 267     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 268         if(NOT GMX_OPENMP)
 269             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 270         endif()
 271         if (GMX_COMPILER_WARNINGS)
 272             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 273         endif()
 274         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 275                          GMXC_CXXFLAGS_RELEASE)
 276     endif()
 277
 278     # xlc
 279     # The suppressions below stop
 280     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 281     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 282     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 283     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 284         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 285         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 286         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 287         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CFLAGS)
 288     endif()
 289     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 290         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 291         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 292         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CXXFLAGS)
 293     endif()
 294
 295     # msvc
 296     if (MSVC)
 297         # disable warnings for:
 298         #      forcing value to bool
 299         #      "this" in initializer list
 300         #      deprecated (posix, secure) functions
 301         #      truncation (double -> float)
 302         #      conversion from 'double' to 'real', possible loss of data
 303         #      unreferenced local variable (only C)
 304         #      conversion from 'size_t' to 'int', possible loss of data
 305         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 306         #      unknown pragma (4068)
 307         if(NOT CMAKE_CONFIGURATION_TYPES)
 308             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090 /wd4068" GMXC_CFLAGS)
 309             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267 /wd4068" GMXC_CXXFLAGS)
 310         else() # MSVC projects only use the C++ flags
 311             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090 /wd4068" GMXC_CXXFLAGS)
 312         endif()
 313     endif()
 314
 315     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 316         if(NOT GMX_OPENMP)
 317             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 318         endif()
 319         if (GMX_COMPILER_WARNINGS)
 320             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 321             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 322         endif()
 323     endif()
 324
 325     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 326         if(NOT GMX_OPENMP)
 327             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 328         endif()
 329         if (GMX_COMPILER_WARNINGS)
 330             if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "6.0") #LLVM BUG #21629
 331                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_BRACES "-Wno-missing-braces" GMXC_CXXFLAGS)
 332             endif()
 333             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 334             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith -Wmissing-prototypes" GMXC_CXXFLAGS)
 335             GMX_TEST_CXXFLAG(CXXFLAGS_DEPRECATED "-Wdeprecated" GMXC_CXXFLAGS)
 336         endif()
 337     endif()
 338
 339     # Fujitsu compilers on PrimeHPC/Sparc64
 340     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 341        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 342         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 343         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 344     endif()
 345
 346     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 347        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 348         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 349         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 350     endif()
 351
 352     # now actually set the flags:
 353     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 354         gmx_set_cmake_compiler_flags()
 355     endif()
 356
 357 endmacro()