cmake/gmxCFlags.cmake

   1
   2 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
   3 # flags to CFLAGSVAR.
   4 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
   5     IF(NOT DEFINED ${VARIABLE})
   6         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
   7     ENDIF(NOT DEFINED ${VARIABLE})
   8     IF (${VARIABLE})
   9         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  10     ENDIF (${VARIABLE})
  11 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  12
  13 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  14 # flags to CXXFLAGSVAR.
  15 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  16     IF(NOT DEFINED ${VARIABLE} AND CMAKE_CXX_COMPILER_LOADED)
  17         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  18     ENDIF(NOT DEFINED ${VARIABLE} AND CMAKE_CXX_COMPILER_LOADED)
  19     IF (${VARIABLE})
  20         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  21     ENDIF (${VARIABLE})
  22 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  23
  24
  25 # This is the actual exported function to be called
  26 MACRO(gmx_c_flags)
  27
  28     include(CheckCCompilerFlag)
  29     include(CheckCXXCompilerFlag)
  30
  31     # gcc
  32     if(CMAKE_COMPILER_IS_GNUCC)
  33
  34         #Fix for LLVM OpenMP bug (redmine 900). Needs to run before OpenMP flags are set below.
  35         if(GMX_OPENMP)
  36             exec_program(${CMAKE_C_COMPILER} ARGS --version OUTPUT_VARIABLE _compiler_output)
  37             if(_compiler_output MATCHES "llvm.*4\\.2")
  38                 message(STATUS "OpenMP multithreading not supported with llvm-gcc 4.2, disabled")
  39                 set(GMX_OPENMP OFF CACHE BOOL
  40                     "OpenMP multithreading not not supported with llvm-gcc 4.2, disabled!" FORCE)
  41             endif()
  42         endif()
  43
  44         #flags are added in reverse order and -Wno* need to appear after -Wall
  45         if(NOT GMX_OPENMP)
  46             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
  47         endif()
  48         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
  49         GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare" GMXC_CFLAGS)
  50         # new in gcc 4.5
  51         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
  52         GMX_TEST_CFLAG(CFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
  53                        GMXC_CFLAGS_RELEASE)
  54         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
  55     endif()
  56     # g++
  57     if(CMAKE_COMPILER_IS_GNUCXX)
  58         if(NOT GMX_OPENMP)
  59             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
  60         endif()
  61         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
  62         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare" GMXC_CXXFLAGS)
  63       # new in gcc 4.5
  64         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
  65         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-fomit-frame-pointer -funroll-all-loops"
  66                          GMXC_CXXFLAGS_RELEASE)
  67         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
  68     endif()
  69
  70     # icc
  71     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
  72         if (NOT WIN32)
  73             if(NOT GMX_OPENMP)
  74                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
  75             endif()
  76             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall" GMXC_CFLAGS)
  77             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
  78             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops" GMXC_CFLAGS_RELEASE)
  79             GMX_TEST_CFLAG(CFLAGS_SSE2 "-msse2" GMXC_CFLAGS_RELEASE)
  80             GMX_TEST_CFLAG(CFLAGS_X86 "-mtune=core2" GMXC_CFLAGS_RELEASE)
  81             GMX_TEST_CFLAG(CFLAGS_IA64 "-mtune=itanium2" GMXC_CFLAGS_RELEASE)
  82         else()
  83             GMX_TEST_CFLAG(CFLAGS_WARN "/W2" GMXC_CFLAGS)
  84             GMX_TEST_CFLAG(CFLAGS_SSE2 "/arch:SSE2" GMXC_CFLAGS_RELEASE)
  85             GMX_TEST_CFLAG(CFLAGS_X86 "/Qip" GMXC_CFLAGS_RELEASE)
  86         endif()
  87     endif()
  88
  89     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  90         if (NOT WIN32)
  91             if(NOT GMX_OPENMP)
  92                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
  93             endif()
  94             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
  95             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops" GMXC_CXXFLAGS_RELEASE)
  96             GMX_TEST_CXXFLAG(CXXFLAGS_SSE2 "-msse2" GMXC_CXXFLAGS_RELEASE)
  97             GMX_TEST_CXXFLAG(CXXFLAGS_X86 "-mtune=core2" GMXC_CXXFLAGS_RELEASE)
  98             GMX_TEST_CXXFLAG(CXXFLAGS_IA64 "-mtune=itanium2"
  99                               GMXC_CXXFLAGS_RELEASE)
 100         else()
 101             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W2" GMXC_CXXFLAGS)
 102             GMX_TEST_CXXFLAG(CXXFLAGS_SSE2 "/arch:SSE2" GMXC_CXXFLAGS_RELEASE)
 103             GMX_TEST_CXXFLAG(CXXFLAGS_X86 "/Qip" GMXC_CXXFLAGS_RELEASE)
 104         endif()
 105     endif()
 106
 107     # pgi
 108     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 109         GMX_TEST_CFLAG(CFLAGS_OPT "-fastsse" GMXC_CFLAGS_RELEASE)
 110     endif()
 111     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 112         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-fastsse" GMXC_CXXFLAGS_RELEASE)
 113     endif()
 114
 115     # Pathscale
 116     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 117         if(NOT GMX_OPENMP)
 118             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 119         endif()
 120         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 121         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 122                          GMXC_CFLAGS_RELEASE)
 123         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 124     endif()
 125     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 126         if(NOT GMX_OPENMP)
 127             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 128         endif()
 129         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 130         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 131                          GMXC_CXXFLAGS_RELEASE)
 132     endif()
 133
 134     # xlc
 135     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 136         GMX_TEST_CFLAG(CFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 137         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 138     endif()
 139     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 140         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 141     endif()
 142
 143     #msvc
 144     if (MSVC)
 145         # disable warnings for:
 146         #      inconsistent dll linkage
 147         GMX_TEST_CFLAG(CFLAGS_WARN "/wd4273" GMXC_CFLAGS)
 148         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4273" GMXC_CXXFLAGS)
 149     endif()
 150
 151     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 152         if(NOT GMX_OPENMP)
 153             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 154         endif()
 155         GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 156     endif()
 157
 158     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 159         if(NOT GMX_OPENMP)
 160             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 161         endif()
 162         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 163     endif()
 164
 165     # now actually set the flags:
 166     # C
 167     if ( NOT DEFINED GMXCFLAGS_SET AND NOT DEFINED ENV{CFLAGS} )
 168         set(GMXCFLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 169             FORCE)
 170
 171         set(CMAKE_C_FLAGS "${GMXC_CFLAGS} ${CMAKE_C_FLAGS}"
 172             CACHE STRING "Flags used by the compiler during all build types."
 173             FORCE)
 174         set(CMAKE_C_FLAGS_RELEASE "${GMXC_CFLAGS_RELEASE} ${CMAKE_C_FLAGS_RELEASE}"
 175             CACHE STRING "Flags used by the compiler during release builds."
 176             FORCE)
 177         set(CMAKE_C_FLAGS_DEBUG "${GMXC_CFLAGS_DEBUG} ${CMAKE_C_FLAGS_DEBUG}"
 178             CACHE STRING "Flags used by the compiler during debug builds."
 179             FORCE)
 180     endif()
 181
 182     # C++
 183     if ( NOT DEFINED GMXCXXFLAGS_SET AND NOT DEFINED ENV{CXXFLAGS} AND CMAKE_CXX_COMPILER_LOADED)
 184         set(GMXCXXFLAGS_SET true CACHE INTERNAL "Whether to reset the C++ flags"
 185             FORCE)
 186         set(CMAKE_CXX_FLAGS "${GMXC_CXXFLAGS} ${CMAKE_CXX_FLAGS}"
 187             CACHE STRING "Flags used by the compiler during all build types."
 188             FORCE)
 189         set(CMAKE_CXX_FLAGS_RELEASE
 190             "${GMXC_CXXFLAGS_RELEASE} ${CMAKE_CXX_FLAGS_RELEASE}"
 191             CACHE STRING "Flags used by the compiler during release builds."
 192             FORCE)
 193         set(CMAKE_CXX_FLAGS_DEBUG
 194             "${GMXC_CXXFLAGS_DEBUG} ${CMAKE_CXX_FLAGS_DEBUG}"
 195             CACHE STRING "Flags used by the compiler during debug builds."
 196             FORCE)
 197     endif()
 198 ENDMACRO(gmx_c_flags)
 199