cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_${build_type}}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Used for, e.g., -Wno-array-bounds in Release to work around
  72         # gcc-4.8 being a little too vocal about some perfectly good code,
  73         # while using RelWithAssert (ie. without that suppression) in Jenkins.
  74         #
  75         # TODO check the behaviour of more recent gcc on the improved code
  76         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  77
  78         # Modify the real CMake variables for compiler flags for all
  79         # builds and language types, and also those common to all
  80         # build types.
  81         foreach(build_type "" ${build_types_with_explicit_flags})
  82             if("${build_type}" STREQUAL "")
  83                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  84             else()
  85                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  86             endif()
  87
  88             # Append to the variables for the given build type for
  89             # each language, in the parent scope. We add our new variables at the end, so
  90             # compiler-specific choices are more likely to override default CMake choices.
  91             # This is for instance useful for RelWithDebInfo builds, where we want to use the full
  92             # set of our optimization flags detected in this file, rather than having -O2 override them.
  93             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  94                 "${CMAKE_${language}_FLAGS${punctuation}${build_type}} ${GMXC_${language}FLAGS${punctuation}${build_type}}"
  95                 PARENT_SCOPE)
  96         endforeach()
  97     endforeach()
  98 endfunction()
  99
 100 # This is the actual exported function to be called
 101 macro (gmx_c_flags)
 102
 103     include(CheckCCompilerFlag)
 104     include(CheckCXXCompilerFlag)
 105
 106     # gcc
 107     if(CMAKE_COMPILER_IS_GNUCC)
 108         #flags are added in reverse order and -Wno* need to appear after -Wall
 109         if(NOT GMX_OPENMP)
 110             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 111         endif()
 112         if (GMX_COMPILER_WARNINGS)
 113             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 114             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 115             GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 116             GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 117             if(CYGWIN)
 118                 GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 119             endif()
 120             GMX_TEST_CFLAG(CFLAGS_STRINGOP_TRUNCATION "-Werror=stringop-truncation" GMXC_CFLAGS)
 121         endif()
 122         # new in gcc 4.5
 123         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 124         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 125                        GMXC_CFLAGS_RELEASE)
 126         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 127     endif()
 128     # g++
 129     if(CMAKE_COMPILER_IS_GNUCXX)
 130         if(NOT GMX_OPENMP)
 131             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 132         endif()
 133         if (GMX_COMPILER_WARNINGS)
 134             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 135             # Problematic with CUDA
 136             # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 137             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith -Wmissing-declarations" GMXC_CXXFLAGS)
 138             # CUDA versions prior to 7.5 come with a header (math_functions.h) which uses the _MSC_VER macro
 139             # unconditionally, so we don't use -Wundef for earlier CUDA versions.
 140             if(NOT(GMX_GPU AND CUDA_VERSION VERSION_LESS "7.5"))
 141                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 142             endif()
 143             GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 144             GMX_TEST_CXXFLAG(CXXFLAGS_STRINGOP_TRUNCATION "-Wstringop-truncation" GMXC_CXXFLAGS)
 145             if (CXXFLAGS_STRINGOP_TRUNCATION)
 146                 set(CXXFLAGS_NO_STRINGOP_TRUNCATION "-Wno-stringop-truncation")
 147             endif()
 148         endif()
 149         # new in gcc 4.5
 150         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 151         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 152                          GMXC_CXXFLAGS_RELEASE)
 153         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 154     endif()
 155
 156     # icc
 157     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 158         if (NOT WIN32)
 159             if(NOT GMX_OPENMP)
 160 # 3180: unrecognized OpenMP #pragma
 161                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 162             endif()
 163             if (GMX_COMPILER_WARNINGS)
 164 # -w3 enables a lot of useful diagnostics but we don't care about all. -wd disables some selectively.
 165 # 177: function/variable ".." was declared but never referenced
 166 # 411: class defines no constructor to initialize the following (incorrect for struct, initializer list works)
 167 # 593: variable ".." was set but never used
 168 # 981: operands are evaluated in unspecified order
 169 #1418: external function definition with no prior declaration
 170 #1419: external declaration in primary source file
 171 #1572: floating-point equality and inequality comparisons are unreliable
 172 #1599: declaration hides variable ".."
 173 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 174 #2415: variable ".." of static storage duration was declared but never referenced
 175 #2547: ".." was specified as both a system and non-system include directory
 176 #2557: comparison between signed and unsigned operands
 177 #3280: declaration hides member ".."
 178 #11074: Inlining inhibited by limit max-size(/max-total-size)
 179 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 180                 GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd177 -wd411 -wd593 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd11074 -wd11076" GMXC_CFLAGS)
 181             endif()
 182             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 183             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -qoverride-limits" GMXC_CFLAGS_RELEASE)
 184             GMX_TEST_CFLAG(CFLAGS_DEBUG "-O0" GMXC_CFLAGS_DEBUG) #icc defaults to -O2 even with -g
 185             GMX_TEST_CFLAG(CFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CFLAGS_RELWITHASSERT)
 186         else()
 187             if(NOT GMX_OPENMP)
 188                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 189             endif()
 190             if (GMX_COMPILER_WARNINGS)
 191 #only on Windows
 192 #161: unrecognized pragma
 193 #1786 function was declared deprecated (is issued for stdlib function such as strncpy which have a _s version)
 194 GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd161 /wd177 /wd411 /wd593 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd1786 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280" GMXC_CFLAGS)
 195             endif()
 196             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 197         endif()
 198     endif()
 199
 200     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 201         if (NOT WIN32)
 202             if(NOT GMX_OPENMP)
 203                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 204             endif()
 205             if (GMX_COMPILER_WARNINGS)
 206 #All but the following warnings are identical for the C-compiler (see above)
 207 # 304: access control not specified
 208 # 383: value copied to temporary, reference to temporary used
 209 # 444: destructor for base class ".." is not virtual
 210 # 869: was never referenced (false positives)
 211 #2282: unrecognized GCC pragma
 212                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd177 -wd304 -wd383 -wd411 -wd444 -wd869 -wd981 -wd1418 -wd1572 -wd1599 -wd2259 -wd2547 -wd3280 -wd11074 -wd11076 -wd2282" GMXC_CXXFLAGS)
 213             endif()
 214             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -qoverride-limits" GMXC_CXXFLAGS_RELEASE)
 215             GMX_TEST_CXXFLAG(CXXFLAGS_DEBUG "-O0" GMXC_CXXFLAGS_DEBUG)
 216             GMX_TEST_CXXFLAG(CXXFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CXXFLAGS_RELWITHASSERT)
 217         else()
 218             if(NOT GMX_OPENMP)
 219                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 220             endif()
 221             if (GMX_COMPILER_WARNINGS)
 222 #161: unrecognized pragma
 223 #809: exception specification for virtual function X is incompatible with that of overridden function
 224                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd161 /wd177 /wd304 /wd383 /wd411 /wd444 /wd809 /wd869 /wd981 /wd1418 /wd1572 /wd1599 /wd1786 /wd2259 /wd2547 /wd3280 /wd11074 /wd11076 /wd2282" GMXC_CXXFLAGS)
 225             endif()
 226             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 227         endif()
 228     endif()
 229
 230     # PGI
 231     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 232     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 233         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 234     endif()
 235     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 236         # Using ipa exposes internal PGI-15.7 compiler bugs at compile time
 237         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 238         # PGI identifies itself as GCC, but does not understand the GCC
 239         # pragmas that occur in parser.cpp. Since that file is generated
 240         # we cannot add a define there, but supress the warning instead.
 241         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "--diag_suppress=1675" GMXC_CXXFLAGS)
 242     endif()
 243
 244     # Pathscale
 245     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 246         if(NOT GMX_OPENMP)
 247             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 248         endif()
 249         if (GMX_COMPILER_WARNINGS)
 250             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 251         endif()
 252         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 253                          GMXC_CFLAGS_RELEASE)
 254         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 255     endif()
 256     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 257         if(NOT GMX_OPENMP)
 258             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 259         endif()
 260         if (GMX_COMPILER_WARNINGS)
 261             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 262         endif()
 263         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 264                          GMXC_CXXFLAGS_RELEASE)
 265     endif()
 266
 267     # xlc
 268     # The suppressions below stop
 269     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 270     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 271     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 272     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 273         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 274         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 275         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 276         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CFLAGS)
 277     endif()
 278     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 279         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 280         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 281         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CXXFLAGS)
 282     endif()
 283
 284     # msvc
 285     if (MSVC)
 286         # disable warnings for:
 287         #      forcing value to bool
 288         #      "this" in initializer list
 289         #      deprecated (posix, secure) functions
 290         #      truncation (double -> float)
 291         #      conversion from 'double' to 'real', possible loss of data
 292         #      unreferenced local variable (only C)
 293         #      conversion from 'size_t' to 'int', possible loss of data
 294         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 295         #      unknown pragma (4068)
 296         if(NOT CMAKE_CONFIGURATION_TYPES)
 297             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090 /wd4068" GMXC_CFLAGS)
 298             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267 /wd4068" GMXC_CXXFLAGS)
 299         else() # MSVC projects only use the C++ flags
 300             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090 /wd4068" GMXC_CXXFLAGS)
 301         endif()
 302     endif()
 303
 304     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 305         if(NOT GMX_OPENMP)
 306             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 307         endif()
 308         if (GMX_COMPILER_WARNINGS)
 309             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 310             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 311         endif()
 312     endif()
 313
 314     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 315         if(NOT GMX_OPENMP)
 316             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 317         endif()
 318         if (GMX_COMPILER_WARNINGS)
 319             if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "6.0") #LLVM BUG #21629
 320                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_BRACES "-Wno-missing-braces" GMXC_CXXFLAGS)
 321             endif()
 322             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 323             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith -Wmissing-prototypes" GMXC_CXXFLAGS)
 324             GMX_TEST_CXXFLAG(CXXFLAGS_DEPRECATED "-Wdeprecated" GMXC_CXXFLAGS)
 325         endif()
 326     endif()
 327
 328     # Fujitsu compilers on PrimeHPC/Sparc64
 329     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 330        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 331         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 332         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 333     endif()
 334
 335     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 336        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 337         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 338         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 339     endif()
 340
 341     # now actually set the flags:
 342     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 343         gmx_set_cmake_compiler_flags()
 344     endif()
 345
 346 endmacro()