cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_${build_type}}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Used for, e.g., -Wno-array-bounds in Release to work around
  72         # gcc-4.8 being a little too vocal about some perfectly good code,
  73         # while using RelWithAssert (ie. without that suppression) in Jenkins.
  74         #
  75         # TODO check the behaviour of more recent gcc on the improved code
  76         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  77
  78         # Modify the real CMake variables for compiler flags for all
  79         # builds and language types, and also those common to all
  80         # build types.
  81         foreach(build_type "" ${build_types_with_explicit_flags})
  82             if("${build_type}" STREQUAL "")
  83                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  84             else()
  85                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  86             endif()
  87
  88             # Append to the variables for the given build type for
  89             # each language, in the parent scope. We add our new variables at the end, so
  90             # compiler-specific choices are more likely to override default CMake choices.
  91             # This is for instance useful for RelWithDebInfo builds, where we want to use the full
  92             # set of our optimization flags detected in this file, rather than having -O2 override them.
  93             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  94                 "${CMAKE_${language}_FLAGS${punctuation}${build_type}} ${GMXC_${language}FLAGS${punctuation}${build_type}}"
  95                 PARENT_SCOPE)
  96         endforeach()
  97     endforeach()
  98 endfunction()
  99
 100 function(gmx_target_warning_suppression TARGET WARNING_FLAG VARNAME)
 101     check_cxx_compiler_flag(${WARNING_FLAG} ${VARNAME})
 102     if(${VARNAME})
 103         target_compile_options(${TARGET} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:${WARNING_FLAG}>)
 104     endif()
 105 endfunction()
 106
 107 # This is the actual exported function to be called
 108 macro (gmx_c_flags)
 109
 110     include(CheckCCompilerFlag)
 111     include(CheckCXXCompilerFlag)
 112
 113     # gcc
 114     if(CMAKE_COMPILER_IS_GNUCC)
 115         #flags are added in reverse order and -Wno* need to appear after -Wall
 116         if(NOT GMX_OPENMP)
 117             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 118         endif()
 119         if (GMX_COMPILER_WARNINGS)
 120             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 121             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 122             GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 123             GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 124             if(CYGWIN)
 125                 GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 126             endif()
 127             GMX_TEST_CFLAG(CFLAGS_STRINGOP_TRUNCATION "-Werror=stringop-truncation" GMXC_CFLAGS)
 128         endif()
 129         # new in gcc 4.5
 130         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 131         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 132                        GMXC_CFLAGS_RELEASE)
 133         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 134     endif()
 135     # g++
 136     if(CMAKE_COMPILER_IS_GNUCXX)
 137         if(NOT GMX_OPENMP)
 138             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 139         endif()
 140         if (GMX_COMPILER_WARNINGS)
 141             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 142             # Problematic with CUDA
 143             # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 144             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith -Wmissing-declarations" GMXC_CXXFLAGS)
 145             # CUDA versions prior to 7.5 come with a header (math_functions.h) which uses the _MSC_VER macro
 146             # unconditionally, so we don't use -Wundef for earlier CUDA versions.
 147             if(NOT(GMX_GPU AND CUDA_VERSION VERSION_LESS "7.5"))
 148                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 149             endif()
 150             GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 151             GMX_TEST_CXXFLAG(CXXFLAGS_STRINGOP_TRUNCATION "-Wstringop-truncation" GMXC_CXXFLAGS)
 152             if (CXXFLAGS_STRINGOP_TRUNCATION)
 153                 set(CXXFLAGS_NO_STRINGOP_TRUNCATION "-Wno-stringop-truncation")
 154             endif()
 155         endif()
 156         # new in gcc 4.5
 157         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 158         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 159                          GMXC_CXXFLAGS_RELEASE)
 160         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 161     endif()
 162
 163     # icc
 164     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 165         if (NOT WIN32)
 166             if(NOT GMX_OPENMP)
 167 # 3180: unrecognized OpenMP #pragma
 168                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 169             endif()
 170             if (GMX_COMPILER_WARNINGS)
 171 # -w3 enables a lot of useful diagnostics but we don't care about all. -wd disables some selectively.
 172 # 177: function/variable ".." was declared but never referenced
 173 # 411: class defines no constructor to initialize the following (incorrect for struct, initializer list works)
 174 # 593: variable ".." was set but never used
 175 # 981: operands are evaluated in unspecified order
 176 #1418: external function definition with no prior declaration
 177 #1419: external declaration in primary source file
 178 #1572: floating-point equality and inequality comparisons are unreliable
 179 #1599: declaration hides variable ".."
 180 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 181 #2415: variable ".." of static storage duration was declared but never referenced
 182 #2547: ".." was specified as both a system and non-system include directory
 183 #2557: comparison between signed and unsigned operands
 184 #3280: declaration hides member ".."
 185 #11074: Inlining inhibited by limit max-size(/max-total-size)
 186 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 187                 GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd177 -wd411 -wd593 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd11074 -wd11076" GMXC_CFLAGS)
 188             endif()
 189             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 190             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -qoverride-limits" GMXC_CFLAGS_RELEASE)
 191             GMX_TEST_CFLAG(CFLAGS_DEBUG "-O0" GMXC_CFLAGS_DEBUG) #icc defaults to -O2 even with -g
 192             GMX_TEST_CFLAG(CFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CFLAGS_RELWITHASSERT)
 193         else()
 194             if(NOT GMX_OPENMP)
 195                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 196             endif()
 197             if (GMX_COMPILER_WARNINGS)
 198 #only on Windows
 199 #161: unrecognized pragma
 200 #1786 function was declared deprecated (is issued for stdlib function such as strncpy which have a _s version)
 201 GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd161 /wd177 /wd411 /wd593 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd1786 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280" GMXC_CFLAGS)
 202             endif()
 203             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 204         endif()
 205     endif()
 206
 207     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 208         if (NOT WIN32)
 209             if(NOT GMX_OPENMP)
 210                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 211             endif()
 212             if (GMX_COMPILER_WARNINGS)
 213 #All but the following warnings are identical for the C-compiler (see above)
 214 # 304: access control not specified
 215 # 383: value copied to temporary, reference to temporary used
 216 # 444: destructor for base class ".." is not virtual
 217 # 869: was never referenced (false positives)
 218 #2282: unrecognized GCC pragma
 219                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd177 -wd304 -wd383 -wd411 -wd444 -wd869 -wd981 -wd1418 -wd1572 -wd1599 -wd2259 -wd2547 -wd3280 -wd11074 -wd11076 -wd2282" GMXC_CXXFLAGS)
 220             endif()
 221             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -qoverride-limits" GMXC_CXXFLAGS_RELEASE)
 222             GMX_TEST_CXXFLAG(CXXFLAGS_DEBUG "-O0" GMXC_CXXFLAGS_DEBUG)
 223             GMX_TEST_CXXFLAG(CXXFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CXXFLAGS_RELWITHASSERT)
 224         else()
 225             if(NOT GMX_OPENMP)
 226                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 227             endif()
 228             if (GMX_COMPILER_WARNINGS)
 229 #161: unrecognized pragma
 230 #809: exception specification for virtual function X is incompatible with that of overridden function
 231                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd161 /wd177 /wd304 /wd383 /wd411 /wd444 /wd809 /wd869 /wd981 /wd1418 /wd1572 /wd1599 /wd1786 /wd2259 /wd2547 /wd3280 /wd11074 /wd11076 /wd2282" GMXC_CXXFLAGS)
 232             endif()
 233             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 234         endif()
 235     endif()
 236
 237     # PGI
 238     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 239     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 240         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 241     endif()
 242     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 243         # Using ipa exposes internal PGI-15.7 compiler bugs at compile time
 244         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 245         # PGI identifies itself as GCC, but does not understand the GCC
 246         # pragmas that occur in parser.cpp. Since that file is generated
 247         # we cannot add a define there, but supress the warning instead.
 248         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "--diag_suppress=1675" GMXC_CXXFLAGS)
 249     endif()
 250
 251     # Pathscale
 252     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 253         if(NOT GMX_OPENMP)
 254             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 255         endif()
 256         if (GMX_COMPILER_WARNINGS)
 257             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 258         endif()
 259         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 260                          GMXC_CFLAGS_RELEASE)
 261         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 262     endif()
 263     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 264         if(NOT GMX_OPENMP)
 265             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 266         endif()
 267         if (GMX_COMPILER_WARNINGS)
 268             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 269         endif()
 270         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 271                          GMXC_CXXFLAGS_RELEASE)
 272     endif()
 273
 274     # xlc
 275     # The suppressions below stop
 276     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 277     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 278     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 279     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 280         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 281         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 282         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 283         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CFLAGS)
 284     endif()
 285     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 286         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 287         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 288         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CXXFLAGS)
 289     endif()
 290
 291     # msvc
 292     if (MSVC)
 293         # disable warnings for:
 294         #      forcing value to bool
 295         #      "this" in initializer list
 296         #      deprecated (posix, secure) functions
 297         #      truncation (double -> float)
 298         #      conversion from 'double' to 'real', possible loss of data
 299         #      unreferenced local variable (only C)
 300         #      conversion from 'size_t' to 'int', possible loss of data
 301         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 302         #      unknown pragma (4068)
 303         if(NOT CMAKE_CONFIGURATION_TYPES)
 304             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090 /wd4068" GMXC_CFLAGS)
 305             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267 /wd4068" GMXC_CXXFLAGS)
 306         else() # MSVC projects only use the C++ flags
 307             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090 /wd4068" GMXC_CXXFLAGS)
 308         endif()
 309     endif()
 310
 311     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 312         if(NOT GMX_OPENMP)
 313             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 314         endif()
 315         if (GMX_COMPILER_WARNINGS)
 316             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 317             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 318         endif()
 319     endif()
 320
 321     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 322         if(NOT GMX_OPENMP)
 323             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 324         endif()
 325         if (GMX_COMPILER_WARNINGS)
 326             if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "6.0") #LLVM BUG #21629
 327                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_BRACES "-Wno-missing-braces" GMXC_CXXFLAGS)
 328             endif()
 329             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 330             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith -Wmissing-prototypes" GMXC_CXXFLAGS)
 331             GMX_TEST_CXXFLAG(CXXFLAGS_DEPRECATED "-Wdeprecated" GMXC_CXXFLAGS)
 332         endif()
 333     endif()
 334
 335     # Fujitsu compilers on PrimeHPC/Sparc64
 336     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 337        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 338         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 339         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 340     endif()
 341
 342     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 343        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 344         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 345         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 346     endif()
 347
 348     # now actually set the flags:
 349     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 350         gmx_set_cmake_compiler_flags()
 351     endif()
 352
 353 endmacro()