cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Used for, e.g., -Wno-array-bounds in Release to work around
  72         # gcc-4.8 being a little too vocal about some perfectly good code,
  73         # while using RelWithAssert (ie. without that suppression) in Jenkins.
  74         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  75
  76         # Modify the real CMake variables for compiler flags for all
  77         # builds and language types, and also those common to all
  78         # build types.
  79         foreach(build_type "" ${build_types_with_explicit_flags})
  80             if("${build_type}" STREQUAL "")
  81                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  82             else()
  83                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  84             endif()
  85
  86             # Append to the variables for the given build type for
  87             # each language, in the parent scope. We add our new variables at the end, so
  88             # compiler-specific choices are more likely to override default CMake choices.
  89             # This is for instance useful for RelWithDebInfo builds, where we want to use the full
  90             # set of our optimization flags detected in this file, rather than having -O2 override them.
  91             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  92                 "${CMAKE_${language}_FLAGS${punctuation}${build_type}} ${GMXC_${language}FLAGS${punctuation}${build_type}}"
  93                 PARENT_SCOPE)
  94         endforeach()
  95     endforeach()
  96 endfunction()
  97
  98 # This is the actual exported function to be called
  99 macro (gmx_c_flags)
 100
 101     include(CheckCCompilerFlag)
 102     include(CheckCXXCompilerFlag)
 103
 104     # gcc
 105     if(CMAKE_COMPILER_IS_GNUCC)
 106         #flags are added in reverse order and -Wno* need to appear after -Wall
 107         if(NOT GMX_OPENMP)
 108             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 109         endif()
 110         if (GMX_COMPILER_WARNINGS)
 111             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 112             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 113             GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 114             # Since 4.8 on by default. For previous version disabling is a no-op. Only disabling for Release because with assert
 115             # the warnings are OK.
 116             GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 117             if(CYGWIN)
 118                 GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 119             endif()
 120         endif()
 121         # new in gcc 4.5
 122         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 123         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 124                        GMXC_CFLAGS_RELEASE)
 125         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 126     endif()
 127     # g++
 128     if(CMAKE_COMPILER_IS_GNUCXX)
 129         if(NOT GMX_OPENMP)
 130             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 131         endif()
 132         if (GMX_COMPILER_WARNINGS)
 133             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 134             # Problematic with CUDA
 135             # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 136             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 137             # CUDA versions prior to 7.5 come with a header (math_functions.h) which uses the _MSC_VER macro
 138             # unconditionally, so we don't use -Wundef for earlier CUDA versions.
 139             if(NOT(GMX_GPU AND CUDA_VERSION VERSION_LESS "7.5"))
 140                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 141             endif()
 142             GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 143         endif()
 144         # new in gcc 4.5
 145         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 146         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 147                          GMXC_CXXFLAGS_RELEASE)
 148         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 149     endif()
 150
 151     # icc
 152     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 153         if (NOT WIN32)
 154             if(NOT GMX_OPENMP)
 155 # 3180: unrecognized OpenMP #pragma
 156                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 157             endif()
 158             if (GMX_COMPILER_WARNINGS)
 159 # 177: function/variable ".." was declared but never referenced
 160 # 411: class defines no constructor to initialize the following (incorrect for struct, initializer list works)
 161 # 593: variable ".." was set but never used
 162 # 981: operands are evaluated in unspecified order
 163 #1418: external function definition with no prior declaration
 164 #1419: external declaration in primary source file
 165 #1572: floating-point equality and inequality comparisons are unreliable
 166 #1599: declaration hides variable ".."
 167 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 168 #2415: variable ".." of static storage duration was declared but never referenced
 169 #2547: ".." was specified as both a system and non-system include directory
 170 #2557: comparison between signed and unsigned operands
 171 #3280: declaration hides member ".."
 172 #11074: Inlining inhibited by limit max-size(/max-total-size)
 173 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 174                 GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd177 -wd411 -wd593 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd11074 -wd11076" GMXC_CFLAGS)
 175             endif()
 176             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 177             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -static-intel" GMXC_CFLAGS_RELEASE)
 178             GMX_TEST_CFLAG(CFLAGS_DEBUG "-O0" GMXC_CFLAGS_DEBUG) #icc defaults to -O2 even with -g
 179             GMX_TEST_CFLAG(CFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CFLAGS_RELWITHASSERT)
 180         else()
 181             if(NOT GMX_OPENMP)
 182                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 183             endif()
 184             if (GMX_COMPILER_WARNINGS)
 185 GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd177 /wd411 /wd593 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280" GMXC_CFLAGS)
 186             endif()
 187             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 188         endif()
 189     endif()
 190
 191     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 192         if (NOT WIN32)
 193             if(NOT GMX_OPENMP)
 194                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 195             endif()
 196             if (GMX_COMPILER_WARNINGS)
 197                 if (GMX_GPU)
 198 # Suppress warnings from CUDA headers
 199 # 7:   unrecognized token
 200 # 82:  storage class is not first
 201 # The below are also required for math_functions.h / math_functions.hpp at least until CUDA 8.0-RC
 202 # 193: zero used for undefined preprocessing identifer
 203 # 3346:dynamic exception specifiers are deprecated
 204                     GMX_TEST_CXXFLAG(CXXFLAGS_WARN_OLD_GPU "-wd7 -wd82 -wd193 -wd3346" GMXC_CXXFLAGS)
 205                 endif()
 206 #All but the following warnings are identical for the C-compiler (see above)
 207 # 383: value copied to temporary, reference to temporary used
 208 # 444: destructor for base class ".." is not virtual
 209 #2282: unrecognized GCC pragma
 210                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd177 -wd383 -wd411 -wd444 -wd981 -wd1418 -wd1572 -wd1599 -wd2259 -wd3280 -wd11074 -wd11076 -wd2282" GMXC_CXXFLAGS)
 211             endif()
 212             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias -no-prec-div -fimf-domain-exclusion=14 -static-intel" GMXC_CXXFLAGS_RELEASE)
 213             GMX_TEST_CXXFLAG(CXXFLAGS_DEBUG "-O0" GMXC_CXXFLAGS_DEBUG)
 214             GMX_TEST_CXXFLAG(CXXFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CXXFLAGS_RELWITHASSERT)
 215         else()
 216 #809: exception specification for virtual function X is incompatible with that of overridden function
 217             if(NOT GMX_OPENMP)
 218                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 219             endif()
 220             if (GMX_COMPILER_WARNINGS)
 221 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd177 /wd383 /wd411 /wd444 /wd809 /wd981 /wd1418 /wd1572 /wd1599 /wd2259 /wd3280 /wd11074 /wd11076 /wd2282" GMXC_CXXFLAGS)
 222             endif()
 223             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 224         endif()
 225     endif()
 226
 227     # PGI
 228     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 229     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 230         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 231     endif()
 232     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 233         # Using ipa exposes internal PGI-15.7 compiler bugs at compile time
 234         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 235         # PGI identifies itself as GCC, but does not understand the GCC
 236         # pragmas that occur in parser.cpp. Since that file is generated
 237         # we cannot add a define there, but supress the warning instead.
 238         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "--diag_suppress=1675" GMXC_CXXFLAGS)
 239     endif()
 240
 241     # Pathscale
 242     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 243         if(NOT GMX_OPENMP)
 244             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 245         endif()
 246         if (GMX_COMPILER_WARNINGS)
 247             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 248         endif()
 249         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 250                          GMXC_CFLAGS_RELEASE)
 251         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 252     endif()
 253     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 254         if(NOT GMX_OPENMP)
 255             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 256         endif()
 257         if (GMX_COMPILER_WARNINGS)
 258             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 259         endif()
 260         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 261                          GMXC_CXXFLAGS_RELEASE)
 262     endif()
 263
 264     # xlc
 265     # The suppressions below stop
 266     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 267     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 268     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 269     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 270         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 271         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 272         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 273         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CFLAGS)
 274     endif()
 275     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 276         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 277         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 278         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CXXFLAGS)
 279     endif()
 280
 281     # msvc
 282     if (MSVC)
 283         # disable warnings for:
 284         #      forcing value to bool
 285         #      "this" in initializer list
 286         #      deprecated (posix, secure) functions
 287         #      truncation (double -> float)
 288         #      conversion from 'double' to 'real', possible loss of data
 289         #      unreferenced local variable (only C)
 290         #      conversion from 'size_t' to 'int', possible loss of data
 291         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 292         if(NOT CMAKE_CONFIGURATION_TYPES)
 293             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CFLAGS)
 294             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267" GMXC_CXXFLAGS)
 295         else() #Projects only use the C++ flags
 296             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CXXFLAGS)
 297         endif()
 298     endif()
 299
 300     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 301         if(NOT GMX_OPENMP)
 302             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 303         endif()
 304         if (GMX_COMPILER_WARNINGS)
 305             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 306             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 307         endif()
 308     endif()
 309
 310     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 311         if(NOT GMX_OPENMP)
 312             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 313         endif()
 314         if (GMX_COMPILER_WARNINGS)
 315             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 316             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 317             GMX_TEST_CXXFLAG(CXXFLAGS_DEPRECATED "-Wdeprecated" GMXC_CXXFLAGS)
 318         endif()
 319     endif()
 320
 321     # Fujitsu compilers on PrimeHPC/Sparc64
 322     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 323        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 324         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 325         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 326     endif()
 327
 328     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 329        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 330         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 331         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 332     endif()
 333
 334     # now actually set the flags:
 335     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 336         gmx_set_cmake_compiler_flags()
 337     endif()
 338
 339 endmacro()