cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  38 # flags to CFLAGSVAR.
  39 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  40     IF(NOT DEFINED ${VARIABLE})
  41         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  42     ENDIF()
  43     IF (${VARIABLE})
  44         list(APPEND ${CFLAGSVAR} "${FLAGS}")
  45     ENDIF ()
  46 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  47
  48 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  49 # flags to CXXFLAGSVAR.
  50 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  51     IF(NOT DEFINED ${VARIABLE})
  52         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  53     ENDIF()
  54     IF (${VARIABLE})
  55         list(APPEND ${CXXFLAGSVAR} "${FLAGS}")
  56     ENDIF ()
  57 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  58
  59 # Prepare some local variables so CUDA and non-CUDA code in targets
  60 # works the same way.
  61 function(gmx_target_compile_options_inner)
  62     set (CFLAGS "${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}" PARENT_SCOPE)
  63     # When SYCL support has been enabled (so the flag is non-empty), we still *disable* things
  64     # by default to avoid running each file three passes through the compiler. Then we'll explicitly
  65     # enable SYCL for the few files using it, as well as the linker.
  66     set (CXXFLAGS "${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${DISABLE_SYCL_CXX_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}" PARENT_SCOPE)
  67 endfunction()
  68
  69 # Implementation function to add compiler flags expected for all
  70 # GROMACS build configurations, and those expected for the current
  71 # CMake build type (e.g. Release) to TARGET. Other GROMACS CMake code
  72 # is expected to use either gmx_target_compile_options(name_of_target)
  73 # or gmx_cuda_target_compile_options(name_of_variable) because CUDA
  74 # compilation has special requirements.
  75 #
  76 # Most targets (ie. libraries, executables) need compiler flags that
  77 # are characteristic of the build configuration. This function
  78 # provides a central point for adding such flags. This approach is
  79 # more flexible than e.g. setting CMAKE_CXX_FLAGS globally, because
  80 # that setting will apply globally, which means it applies also to
  81 # "external" code that the build of GROMACS might also build.
  82 function(gmx_target_compile_options TARGET)
  83     if (GMX_SKIP_DEFAULT_CFLAGS)
  84         return()
  85     endif()
  86
  87     # Prepare the generic compiler options
  88     gmx_target_compile_options_inner()
  89     target_compile_options(${TARGET}
  90         PRIVATE
  91         $<$<COMPILE_LANGUAGE:C>:${CFLAGS}>
  92         $<$<COMPILE_LANGUAGE:CXX>:${CXXFLAGS}>
  93         )
  94     # Add compiler options for the build types
  95     foreach(build_type ${build_types_with_explicit_flags})
  96         target_compile_options(${TARGET}
  97             BEFORE PRIVATE
  98             $<$<AND:$<COMPILE_LANGUAGE:C>,$<CONFIG:${build_type}>>:${GMXC_CFLAGS_${build_type}}>
  99             $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:${build_type}>>:${GMXC_CXXFLAGS_${build_type}}>
 100             )
 101     endforeach()
 102     # Add the release-configuration compiler options to build
 103     # configurations that derive from it.
 104     foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 105         target_compile_options(${TARGET}
 106             BEFORE PRIVATE
 107             $<$<AND:$<COMPILE_LANGUAGE:C>,$<CONFIG:${build_type}>>:${GMXC_CFLAGS_RELEASE}>
 108             $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:${build_type}>>:${GMXC_CXXFLAGS_RELEASE}>
 109             )
 110     endforeach()
 111     # Add those flags that we only want in the proper release build
 112     # configuration.
 113     target_compile_options(${TARGET}
 114         BEFORE PRIVATE
 115         $<$<AND:$<COMPILE_LANGUAGE:C>,$<CONFIG:RELEASE>>:${GMXC_CFLAGS_RELEASE_ONLY}>
 116         $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:RELEASE>>:${GMXC_CXXFLAGS_RELEASE_ONLY}>
 117         )
 118 endfunction()
 119
 120 # The approach taken by FindCUDA.cmake is to require that the compiler
 121 # flags are known and present in a variable before creating the target
 122 # for the library. (Those get embedded in files that are generated at
 123 # the point of calling cuda_add_library, which does not create a
 124 # target that one could later call target_compile_options upon.) So,
 125 # this function instead returns appropriate content in
 126 # ${VARIABLE_NAME}, along with other such variables that are
 127 # specialized for the various build_types. Hopefully this will improve
 128 # when we use native CUDA language support in our CMake.
 129 function(gmx_cuda_target_compile_options VARIABLE_NAME)
 130     if (GMX_SKIP_DEFAULT_CFLAGS)
 131         set (CXXFLAGS "")
 132     else()
 133         # Prepare the generic compiler options
 134         gmx_target_compile_options_inner()
 135         # CUDA headers issue lots of warnings when compiled with
 136         # -Wundef because they use old-style #ifdef a lot. We'd prefer
 137         # to have FindCUDA.cmake treat CUDA internal headers with
 138         # -isystem so that these warnings are naturally suppressed,
 139         # but there's no way to do that without bundling a modified
 140         # form of FindCUDA.cmake. That creates its own problems,
 141         # because people either don't know we do that, or don't
 142         # remember that we don't do that in user tarballs.
 143         #
 144         # We have make check-source ensuring that we have included
 145         # config.h any time we use such symbols in commits in a merge
 146         # request. Local development could run that too. So, we can
 147         # tolerate any remaining risk from accidentally using
 148         # e.g. #ifdef GMX_MPI rather than #if GMX_MPI in CUDA source
 149         # files.
 150         #
 151         # So we disable -Wundef by the simple hack of appending
 152         # -Wno-undef after it. That's more maintainable than having
 153         # logic to avoid adding -Wundef to GMXC_CXXFLAGS, given the
 154         # current approach to adding them. Hopefully this will improve
 155         # if/when we have more CMake object libraries, and/or native
 156         # CUDA compilation.
 157         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NOUNDEF "-Wno-undef" CXXFLAGS)
 158     endif()
 159
 160     # Only C++ compilation is supported with CUDA code in GROMACS
 161     set(${VARIABLE_NAME} ${CXXFLAGS} PARENT_SCOPE)
 162
 163     # Now organize the flags for different build
 164     # configurations. First, the debug configuration.
 165     set(${VARIABLE_NAME}_DEBUG "${GMXC_CXXFLAGS_DEBUG}" PARENT_SCOPE)
 166     # Add those flags that we only want in the proper release build
 167     # configuration.
 168     set(${VARIABLE_NAME}_RELEASE "${GMXC_CXXFLAGS_RELEASE};${GMXC_CXXFLAGS_RELEASE_ONLY}" PARENT_SCOPE)
 169     # Add the release flags to build configurations that derive from it
 170     foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 171         set(${VARIABLE_NAME}_${build_type} "${GMXC_CXXFLAGS_RELEASE};${GMXC_CXXFLAGS_${build_type}}" PARENT_SCOPE)
 172     endforeach()
 173 endfunction()
 174
 175 # Add the WARNING_FLAG to the compile options for TARGET if the
 176 # compiler supports that flag. VARNAME is used to cache the result of
 177 # the check whether the compiler supports that flag, as multiple
 178 # targets may use the same suppression.
 179 #
 180 # This is generally used to suppress warnings judged not worth fixing
 181 # in code external to, or generated by, GROMACS, or code that is
 182 # more efficient to work around and later replace, rather than fix.
 183 function(gmx_target_warning_suppression TARGET WARNING_FLAG VARNAME)
 184     check_cxx_compiler_flag(${WARNING_FLAG} ${VARNAME})
 185     if(${VARNAME})
 186         target_compile_options(${TARGET} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:${WARNING_FLAG}>)
 187     endif()
 188 endfunction()
 189
 190 # Add the WARNING_FLAG to the compile flags for SOURCE_FILE if the
 191 # compiler supports that flag. VARNAME is used to cache the result of
 192 # the check whether the compiler supports that flag, as multiple
 193 # targets may use the same suppression.
 194 #
 195 # This is generally used to suppress warnings judged not worth fixing
 196 # in code external to, or generated by, GROMACS, or code that is
 197 # more efficient to work around and later replace, rather than fix.
 198 function(gmx_source_file_warning_suppression SOURCE_FILE WARNING_FLAG VARNAME)
 199     check_cxx_compiler_flag(${WARNING_FLAG} ${VARNAME})
 200     if(${VARNAME})
 201         set_source_files_properties(${SOURCE_FILE} PROPERTIES COMPILE_FLAGS ${WARNING_FLAG})
 202     endif()
 203 endfunction()
 204
 205 # This is the actual exported function to be called
 206 macro (gmx_c_flags)
 207
 208     include(CheckCCompilerFlag)
 209     include(CheckCXXCompilerFlag)
 210
 211     # gcc
 212     if(CMAKE_COMPILER_IS_GNUCC)
 213         #flags are added in reverse order and -Wno* need to appear after -Wall
 214         if(NOT GMX_OPENMP)
 215             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 216         endif()
 217         if (GMX_COMPILER_WARNINGS)
 218             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value;-Wunused-parameter" GMXC_CFLAGS)
 219             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra;-Wno-sign-compare;-Wpointer-arith" GMXC_CFLAGS)
 220             GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 221             GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 222             if(CYGWIN)
 223                 GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 224             endif()
 225             GMX_TEST_CFLAG(CFLAGS_STRINGOP_TRUNCATION "-Werror=stringop-truncation" GMXC_CFLAGS)
 226         endif()
 227         GMX_TEST_CFLAG(CFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CFLAGS)
 228         # new in gcc 4.5
 229         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 230         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 231                        GMXC_CFLAGS_RELEASE)
 232         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 233     endif()
 234     # g++
 235     if(CMAKE_COMPILER_IS_GNUCXX)
 236         if(NOT GMX_OPENMP)
 237             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 238         endif()
 239         if (GMX_COMPILER_WARNINGS)
 240             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 241             # Problematic with CUDA
 242             # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 243             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra;-Wpointer-arith;-Wmissing-declarations" GMXC_CXXFLAGS)
 244             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 245             GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 246             GMX_TEST_CXXFLAG(CXXFLAGS_STRINGOP_TRUNCATION "-Wstringop-truncation" GMXC_CXXFLAGS)
 247             if (CXXFLAGS_STRINGOP_TRUNCATION)
 248                 set(CXXFLAGS_NO_STRINGOP_TRUNCATION "-Wno-stringop-truncation")
 249             endif()
 250         endif()
 251         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CXXFLAGS)
 252         # new in gcc 4.5
 253         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 254         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 255                          GMXC_CXXFLAGS_RELEASE)
 256         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 257     endif()
 258
 259     # icc
 260     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 261         if (NOT WIN32)
 262             if(NOT GMX_OPENMP)
 263 # 3180: unrecognized OpenMP #pragma
 264                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 265             endif()
 266             if (GMX_COMPILER_WARNINGS)
 267 # -w3 enables a lot of useful diagnostics but we don't care about all. -wd disables some selectively.
 268 # 177: function/variable ".." was declared but never referenced
 269 # 280: selector expression is constant
 270 # 411: class defines no constructor to initialize the following (incorrect for struct, initializer list works)
 271 # 593: variable ".." was set but never used
 272 # 981: operands are evaluated in unspecified order
 273 #1418: external function definition with no prior declaration
 274 #1419: external declaration in primary source file
 275 #1572: floating-point equality and inequality comparisons are unreliable
 276 #1599: declaration hides variable ".."
 277 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 278 #2415: variable ".." of static storage duration was declared but never referenced
 279 #2547: ".." was specified as both a system and non-system include directory
 280 #2557: comparison between signed and unsigned operands
 281 #3280: declaration hides member ".."
 282 #11074: Inlining inhibited by limit max-size(/max-total-size)
 283 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 284                 GMX_TEST_CFLAG(CFLAGS_WARN "-w3;-wd177;-wd280;-wd411;-wd593;-wd981;-wd1418;-wd1419;-wd1572;-wd1599;-wd2259;-wd2415;-wd2547;-wd2557;-wd3280;-wd11074;-wd11076" GMXC_CFLAGS)
 285             endif()
 286             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 287             GMX_TEST_CFLAG(CFLAGS_OPT "-ip;-funroll-all-loops;-alias-const;-ansi-alias;-no-prec-div;-fimf-domain-exclusion=14;-qoverride-limits" GMXC_CFLAGS_RELEASE)
 288             GMX_TEST_CFLAG(CFLAGS_DEBUG "-O0" GMXC_CFLAGS_DEBUG) #icc defaults to -O2 even with -g
 289             # The "except" fp-model requires something other than the
 290             # default "fast" model, so we test and use it with
 291             # "precise".
 292             GMX_TEST_CFLAG(CFLAGS_FP_MODEL_RELASSERT "-fp-model=except;-fp-model=precise" GMXC_CFLAGS_RELWITHASSERT)
 293         else()
 294             if(NOT GMX_OPENMP)
 295                 GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 296             endif()
 297             if (GMX_COMPILER_WARNINGS)
 298 #only on Windows
 299 #161: unrecognized pragma
 300 #1786 function was declared deprecated (is issued for stdlib function such as strncpy which have a _s version)
 301 GMX_TEST_CFLAG(CFLAGS_WARN "/W3;/wd161;/wd177;/wd411;/wd593;/wd981;/wd1418;/wd1419;/wd1572;/wd1599;/wd1786;/wd2259;/wd2415;/wd2547;/wd2557;/wd3280" GMXC_CFLAGS)
 302             endif()
 303             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 304         endif()
 305     endif()
 306
 307     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 308         if (NOT WIN32)
 309             if(NOT GMX_OPENMP)
 310                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 311             endif()
 312             if (GMX_COMPILER_WARNINGS)
 313 #All but the following warnings are identical for the C-compiler (see above)
 314 # 304: access control not specified
 315 # 383: value copied to temporary, reference to temporary used
 316 # 444: destructor for base class ".." is not virtual
 317 # 869: was never referenced (false positives)
 318 #2282: unrecognized GCC pragma
 319                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3;-wd177;-wd280;-wd304;-wd383;-wd411;-wd444;-wd869;-wd981;-wd1418;-wd1572;-wd1599;-wd2259;-wd2547;-wd3280;-wd11074;-wd11076;-wd2282" GMXC_CXXFLAGS)
 320             endif()
 321             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip;-funroll-all-loops;-alias-const;-ansi-alias;-no-prec-div;-fimf-domain-exclusion=14;-qoverride-limits" GMXC_CXXFLAGS_RELEASE)
 322             GMX_TEST_CXXFLAG(CXXFLAGS_DEBUG "-O0" GMXC_CXXFLAGS_DEBUG)
 323             # The "except" fp-model requires something other than the
 324             # default "fast" model, so we test and use it with
 325             # "precise".
 326             GMX_TEST_CXXFLAG(CXXFLAGS_FP_MODEL_RELASSERT "-fp-model=except;-fp-model=precise" GMXC_CXXFLAGS_RELWITHASSERT)
 327         else()
 328             if(NOT GMX_OPENMP)
 329                 GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 330             endif()
 331             if (GMX_COMPILER_WARNINGS)
 332 #161: unrecognized pragma
 333 #809: exception specification for virtual function X is incompatible with that of overridden function
 334                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3;/wd161;/wd177;/wd280;/wd304;/wd383;/wd411;/wd444;/wd809;/wd869;/wd981;/wd1418;/wd1572;/wd1599;/wd1786;/wd2259;/wd2547;/wd3280;/wd11074;/wd11076;/wd2282" GMXC_CXXFLAGS)
 335             endif()
 336             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 337         endif()
 338     endif()
 339
 340     # PGI
 341     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 342     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 343         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 344     endif()
 345     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 346         # Using ipa exposes internal PGI-15.7 compiler bugs at compile time
 347         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 348         # PGI identifies itself as GCC, but does not understand the GCC
 349         # pragmas that occur in parser.cpp. Since that file is generated
 350         # we cannot add a define there, but supress the warning instead.
 351         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "--diag_suppress=1675" GMXC_CXXFLAGS)
 352     endif()
 353
 354     # Pathscale
 355     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 356         if(NOT GMX_OPENMP)
 357             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 358         endif()
 359         if (GMX_COMPILER_WARNINGS)
 360             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value" GMXC_CFLAGS)
 361         endif()
 362         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast;-fno-math-errno;-ffast-math"
 363                          GMXC_CFLAGS_RELEASE)
 364         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 365     endif()
 366     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 367         if(NOT GMX_OPENMP)
 368             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 369         endif()
 370         if (GMX_COMPILER_WARNINGS)
 371             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value" GMXC_CXXFLAGS)
 372         endif()
 373         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast;-fno-math-errno;-ffast-math"
 374                          GMXC_CXXFLAGS_RELEASE)
 375     endif()
 376
 377     # xlc
 378     # The suppressions below stop
 379     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 380     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 381     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 382     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 383         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto;-qtune=auto" GMXC_CFLAGS)
 384         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 385         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 386         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036;-qsuppress=1500-010;-qsuppress=1500-030" GMXC_CFLAGS)
 387     endif()
 388     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 389         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto;-qtune=auto" GMXC_CXXFLAGS)
 390         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 391         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036;-qsuppress=1500-010;-qsuppress=1500-030" GMXC_CXXFLAGS)
 392     endif()
 393
 394     # msvc
 395     if (MSVC)
 396         # disable warnings for:
 397         #      forcing value to bool
 398         #      "this" in initializer list
 399         #      deprecated (posix, secure) functions
 400         #      C4305: truncation (double -> float)
 401         #      C4244: conversion from '.*' to '.*', possible loss of data
 402         #      unreferenced local variable (only C)
 403         #      C4267: conversion from 'size_t' to 'int', possible loss of data
 404         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 405         #      unknown pragma (4068)
 406         #      remark #280: selector expression is constant
 407         if(NOT CMAKE_CONFIGURATION_TYPES)
 408             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800;/wd4355;/wd4996;/wd4305;/wd4244;/wd4101;/wd4267;/wd4090;/wd4068;" GMXC_CFLAGS)
 409             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800;/wd4355;/wd4996;/wd4305;/wd4244;/wd4267;/wd4068;" GMXC_CXXFLAGS)
 410         else() # MSVC projects only use the C++ flags
 411             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800;/wd4355;/wd4996;/wd4305;/wd4244;/wd4101;/wd4267;/wd4090;/wd4068;" GMXC_CXXFLAGS)
 412         endif()
 413         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "/permissive-" GMXC_CXXFLAGS)
 414     endif()
 415
 416     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 417         if(NOT GMX_OPENMP)
 418             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 419         endif()
 420         if (GMX_COMPILER_WARNINGS)
 421             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value;-Wunused-parameter" GMXC_CFLAGS)
 422             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 423         endif()
 424         GMX_TEST_CFLAG(CFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CFLAGS)
 425     endif()
 426
 427     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 428         if (GMX_COMPILER_WARNINGS)
 429             # If used, -Wall should precede other options that silence warnings it enables
 430             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 431             if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "6.0") #LLVM BUG #21629
 432                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_BRACES "-Wno-missing-braces" GMXC_CXXFLAGS)
 433             endif()
 434             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra;-Wpointer-arith;-Wmissing-prototypes" GMXC_CXXFLAGS)
 435             GMX_TEST_CXXFLAG(CXXFLAGS_DEPRECATED "-Wdeprecated" GMXC_CXXFLAGS)
 436             # Functions placed in headers for inlining are not always
 437             # used in every translation unit that includes the files,
 438             # so we must disable the warning that there are such
 439             # functions that are unused.
 440             GMX_TEST_CXXFLAG(CXXFLAGS_NO_UNUSED_FUNCTION "-Wno-unused-function" GMXC_CXXFLAGS)
 441         endif()
 442         if(NOT GMX_OPENMP)
 443             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 444         endif()
 445         if(GMX_GPU_CUDA)
 446             # CUDA header cuda_runtime_api.h in at least CUDA 10.1
 447             # uses 0 where nullptr would be preferable, and this is
 448             # the simplest way to avoid seeing it when it can't be
 449             # readily fixed.
 450             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-zero-as-null-pointer-constant" GMXC_CXXFLAGS)
 451         endif()
 452         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CXXFLAGS)
 453     endif()
 454
 455     # Apple bastardized version of Clang
 456     if(${CMAKE_C_COMPILER_ID} MATCHES "AppleClang")
 457         if(${CMAKE_C_COMPILER_VERSION} VERSION_GREATER 11.0)
 458             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 459             # that checks stack alignment by default, but their own C library
 460             # does not align the stack properly. Embarrassing, Apple...
 461             GMX_TEST_CFLAG(CFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CFLAGS)
 462         endif()
 463     endif()
 464
 465     if(${CMAKE_CXX_COMPILER_ID} MATCHES "AppleClang")
 466         if(${CMAKE_CXX_COMPILER_VERSION} VERSION_GREATER 11.0)
 467             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 468             # that checks stack alignment by default, but their own C library
 469             # does not align the stack properly. Embarrassing, Apple...
 470             GMX_TEST_CXXFLAG(CXXFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CXXFLAGS)
 471         endif()
 472     endif()
 473
 474     # Apple bastardized version of Clang
 475     if(${CMAKE_C_COMPILER_ID} MATCHES "AppleClang")
 476         if(${CMAKE_C_COMPILER_VERSION} VERSION_GREATER 11.0)
 477             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 478             # that checks stack alignment by default, but their own C library
 479             # does not align the stack properly. Embarrassing, Apple...
 480             GMX_TEST_CFLAG(CFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CFLAGS)
 481         endif()
 482     endif()
 483
 484     if(${CMAKE_CXX_COMPILER_ID} MATCHES "AppleClang")
 485         if(${CMAKE_CXX_COMPILER_VERSION} VERSION_GREATER 11.0)
 486             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 487             # that checks stack alignment by default, but their own C library
 488             # does not align the stack properly. Embarrassing, Apple...
 489             GMX_TEST_CXXFLAG(CXXFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CXXFLAGS)
 490         endif()
 491     endif()
 492
 493     # Fujitsu compilers on PrimeHPC/Sparc64
 494     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 495        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 496         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg;-w" GMXC_CFLAGS)
 497         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple;-x100" GMXC_CFLAGS)
 498     endif()
 499
 500     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 501        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 502         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg;-w" GMXC_CXXFLAGS)
 503         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple;-x100" GMXC_CXXFLAGS)
 504     endif()
 505
 506 endmacro()