cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  38 # flags to CFLAGSVAR.
  39 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  40     IF(NOT DEFINED ${VARIABLE})
  41         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  42     ENDIF()
  43     IF (${VARIABLE})
  44         list(APPEND ${CFLAGSVAR} "${FLAGS}")
  45     ENDIF ()
  46 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  47
  48 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  49 # flags to CXXFLAGSVAR.
  50 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  51     IF(NOT DEFINED ${VARIABLE})
  52         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  53     ENDIF()
  54     IF (${VARIABLE})
  55         list(APPEND ${CXXFLAGSVAR} "${FLAGS}")
  56     ENDIF ()
  57 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  58
  59 # Prepare some local variables so CUDA and non-CUDA code in targets
  60 # works the same way.
  61 function(gmx_target_compile_options_inner)
  62     set (CFLAGS "${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}" PARENT_SCOPE)
  63     # When SYCL support has been enabled (so the flag is non-empty), we still *disable* things
  64     # by default to avoid running each file three passes through the compiler. Then we'll explicitly
  65     # enable SYCL for the few files using it, as well as the linker.
  66     set (CXXFLAGS "${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${DISABLE_SYCL_CXX_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}" PARENT_SCOPE)
  67 endfunction()
  68
  69 # Implementation function to add compiler flags expected for all
  70 # GROMACS build configurations, and those expected for the current
  71 # CMake build type (e.g. Release) to TARGET. Other GROMACS CMake code
  72 # is expected to use either gmx_target_compile_options(name_of_target)
  73 # or gmx_cuda_target_compile_options(name_of_variable) because CUDA
  74 # compilation has special requirements.
  75 #
  76 # Most targets (ie. libraries, executables) need compiler flags that
  77 # are characteristic of the build configuration. This function
  78 # provides a central point for adding such flags. This approach is
  79 # more flexible than e.g. setting CMAKE_CXX_FLAGS globally, because
  80 # that setting will apply globally, which means it applies also to
  81 # "external" code that the build of GROMACS might also build.
  82 function(gmx_target_compile_options TARGET)
  83     if (GMX_SKIP_DEFAULT_CFLAGS)
  84         return()
  85     endif()
  86
  87     # Prepare the generic compiler options
  88     gmx_target_compile_options_inner()
  89     target_compile_options(${TARGET}
  90         PRIVATE
  91         $<$<COMPILE_LANGUAGE:C>:${CFLAGS}>
  92         $<$<COMPILE_LANGUAGE:CXX>:${CXXFLAGS}>
  93         )
  94     # Add compiler options for the build types
  95     foreach(build_type ${build_types_with_explicit_flags})
  96         target_compile_options(${TARGET}
  97             BEFORE PRIVATE
  98             $<$<AND:$<COMPILE_LANGUAGE:C>,$<CONFIG:${build_type}>>:${GMXC_CFLAGS_${build_type}}>
  99             $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:${build_type}>>:${GMXC_CXXFLAGS_${build_type}}>
 100             )
 101     endforeach()
 102     # Add the release-configuration compiler options to build
 103     # configurations that derive from it.
 104     foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 105         target_compile_options(${TARGET}
 106             BEFORE PRIVATE
 107             $<$<AND:$<COMPILE_LANGUAGE:C>,$<CONFIG:${build_type}>>:${GMXC_CFLAGS_RELEASE}>
 108             $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:${build_type}>>:${GMXC_CXXFLAGS_RELEASE}>
 109             )
 110     endforeach()
 111     # Add those flags that we only want in the proper release build
 112     # configuration.
 113     target_compile_options(${TARGET}
 114         BEFORE PRIVATE
 115         $<$<AND:$<COMPILE_LANGUAGE:C>,$<CONFIG:RELEASE>>:${GMXC_CFLAGS_RELEASE_ONLY}>
 116         $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:RELEASE>>:${GMXC_CXXFLAGS_RELEASE_ONLY}>
 117         )
 118 endfunction()
 119
 120 # The approach taken by FindCUDA.cmake is to require that the compiler
 121 # flags are known and present in a variable before creating the target
 122 # for the library. (Those get embedded in files that are generated at
 123 # the point of calling cuda_add_library, which does not create a
 124 # target that one could later call target_compile_options upon.) So,
 125 # this function instead returns appropriate content in
 126 # ${VARIABLE_NAME}, along with other such variables that are
 127 # specialized for the various build_types. Hopefully this will improve
 128 # when we use native CUDA language support in our CMake.
 129 function(gmx_cuda_target_compile_options VARIABLE_NAME)
 130     if (GMX_SKIP_DEFAULT_CFLAGS)
 131         set (CXXFLAGS "")
 132     else()
 133         # Prepare the generic compiler options
 134         gmx_target_compile_options_inner()
 135         # CUDA headers issue lots of warnings when compiled with
 136         # -Wundef because they use old-style #ifdef a lot. We'd prefer
 137         # to have FindCUDA.cmake treat CUDA internal headers with
 138         # -isystem so that these warnings are naturally suppressed,
 139         # but there's no way to do that without bundling a modified
 140         # form of FindCUDA.cmake. That creates its own problems,
 141         # because people either don't know we do that, or don't
 142         # remember that we don't do that in user tarballs.
 143         #
 144         # We have make check-source ensuring that we have included
 145         # config.h any time we use such symbols in commits in a merge
 146         # request. Local development could run that too. So, we can
 147         # tolerate any remaining risk from accidentally using
 148         # e.g. #ifdef GMX_MPI rather than #if GMX_MPI in CUDA source
 149         # files.
 150         #
 151         # So we disable -Wundef by the simple hack of appending
 152         # -Wno-undef after it. That's more maintainable than having
 153         # logic to avoid adding -Wundef to GMXC_CXXFLAGS, given the
 154         # current approach to adding them. Hopefully this will improve
 155         # if/when we have more CMake object libraries, and/or native
 156         # CUDA compilation.
 157         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NOUNDEF "-Wno-undef" CXXFLAGS)
 158     endif()
 159
 160     # Only C++ compilation is supported with CUDA code in GROMACS
 161     set(${VARIABLE_NAME} ${CXXFLAGS} PARENT_SCOPE)
 162
 163     # Now organize the flags for different build
 164     # configurations. First, the debug configuration.
 165     set(${VARIABLE_NAME}_DEBUG "${GMXC_CXXFLAGS_DEBUG}" PARENT_SCOPE)
 166     # Add those flags that we only want in the proper release build
 167     # configuration.
 168     set(${VARIABLE_NAME}_RELEASE "${GMXC_CXXFLAGS_RELEASE};${GMXC_CXXFLAGS_RELEASE_ONLY}" PARENT_SCOPE)
 169     # Add the release flags to build configurations that derive from it
 170     foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 171         set(${VARIABLE_NAME}_${build_type} "${GMXC_CXXFLAGS_RELEASE};${GMXC_CXXFLAGS_${build_type}}" PARENT_SCOPE)
 172     endforeach()
 173 endfunction()
 174
 175 # Add the WARNING_FLAG to the compile options for TARGET if the
 176 # compiler supports that flag. VARNAME is used to cache the result of
 177 # the check whether the compiler supports that flag, as multiple
 178 # targets may use the same suppression.
 179 #
 180 # This is generally used to suppress warnings judged not worth fixing
 181 # in code external to, or generated by, GROMACS, or code that is
 182 # more efficient to work around and later replace, rather than fix.
 183 function(gmx_target_warning_suppression TARGET WARNING_FLAG VARNAME)
 184     check_cxx_compiler_flag(${WARNING_FLAG} ${VARNAME})
 185     if(${VARNAME})
 186         target_compile_options(${TARGET} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:${WARNING_FLAG}>)
 187     endif()
 188 endfunction()
 189
 190 # Add the WARNING_FLAG to the compile flags for SOURCE_FILE if the
 191 # compiler supports that flag. VARNAME is used to cache the result of
 192 # the check whether the compiler supports that flag, as multiple
 193 # targets may use the same suppression.
 194 #
 195 # This is generally used to suppress warnings judged not worth fixing
 196 # in code external to, or generated by, GROMACS, or code that is
 197 # more efficient to work around and later replace, rather than fix.
 198 function(gmx_source_file_warning_suppression SOURCE_FILE WARNING_FLAG VARNAME)
 199     check_cxx_compiler_flag(${WARNING_FLAG} ${VARNAME})
 200     if(${VARNAME})
 201         set_source_files_properties(${SOURCE_FILE} PROPERTIES COMPILE_FLAGS ${WARNING_FLAG})
 202     endif()
 203 endfunction()
 204
 205 # This is the actual exported function to be called
 206 macro (gmx_c_flags)
 207
 208     include(CheckCCompilerFlag)
 209     include(CheckCXXCompilerFlag)
 210
 211     # gcc
 212     if(CMAKE_COMPILER_IS_GNUCC)
 213         #flags are added in reverse order and -Wno* need to appear after -Wall
 214         if(NOT GMX_OPENMP)
 215             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 216         endif()
 217         if (GMX_COMPILER_WARNINGS)
 218             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value;-Wunused-parameter" GMXC_CFLAGS)
 219             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra;-Wno-sign-compare;-Wpointer-arith" GMXC_CFLAGS)
 220             GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 221             GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 222             if(CYGWIN)
 223                 GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 224             endif()
 225             GMX_TEST_CFLAG(CFLAGS_STRINGOP_TRUNCATION "-Werror=stringop-truncation" GMXC_CFLAGS)
 226         endif()
 227         GMX_TEST_CFLAG(CFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CFLAGS)
 228         # new in gcc 4.5
 229         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 230         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 231                        GMXC_CFLAGS_RELEASE)
 232         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 233     endif()
 234     # g++
 235     if(CMAKE_COMPILER_IS_GNUCXX)
 236         if(NOT GMX_OPENMP)
 237             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 238         endif()
 239         if (GMX_COMPILER_WARNINGS)
 240             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 241             # Problematic with CUDA
 242             # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 243             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra;-Wpointer-arith;-Wmissing-declarations" GMXC_CXXFLAGS)
 244             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 245             GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 246             GMX_TEST_CXXFLAG(CXXFLAGS_STRINGOP_TRUNCATION "-Wstringop-truncation" GMXC_CXXFLAGS)
 247             if (CXXFLAGS_STRINGOP_TRUNCATION)
 248                 set(CXXFLAGS_NO_STRINGOP_TRUNCATION "-Wno-stringop-truncation")
 249             endif()
 250         endif()
 251         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CXXFLAGS)
 252         # new in gcc 4.5
 253         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 254         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 255                          GMXC_CXXFLAGS_RELEASE)
 256         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 257     endif()
 258
 259     # PGI
 260     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 261     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 262         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 263     endif()
 264     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 265         # Using ipa exposes internal PGI-15.7 compiler bugs at compile time
 266         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 267         # PGI identifies itself as GCC, but does not understand the GCC
 268         # pragmas that occur in parser.cpp. Since that file is generated
 269         # we cannot add a define there, but supress the warning instead.
 270         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "--diag_suppress=1675" GMXC_CXXFLAGS)
 271     endif()
 272
 273     # Pathscale
 274     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 275         if(NOT GMX_OPENMP)
 276             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 277         endif()
 278         if (GMX_COMPILER_WARNINGS)
 279             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value" GMXC_CFLAGS)
 280         endif()
 281         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast;-fno-math-errno;-ffast-math"
 282                          GMXC_CFLAGS_RELEASE)
 283         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 284     endif()
 285     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 286         if(NOT GMX_OPENMP)
 287             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 288         endif()
 289         if (GMX_COMPILER_WARNINGS)
 290             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value" GMXC_CXXFLAGS)
 291         endif()
 292         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast;-fno-math-errno;-ffast-math"
 293                          GMXC_CXXFLAGS_RELEASE)
 294     endif()
 295
 296     # xlc
 297     # The suppressions below stop
 298     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 299     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 300     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 301     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 302         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto;-qtune=auto" GMXC_CFLAGS)
 303         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 304         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 305         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036;-qsuppress=1500-010;-qsuppress=1500-030" GMXC_CFLAGS)
 306     endif()
 307     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 308         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto;-qtune=auto" GMXC_CXXFLAGS)
 309         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 310         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036;-qsuppress=1500-010;-qsuppress=1500-030" GMXC_CXXFLAGS)
 311     endif()
 312
 313     # msvc
 314     if (MSVC)
 315         # disable warnings for:
 316         #      forcing value to bool
 317         #      "this" in initializer list
 318         #      deprecated (posix, secure) functions
 319         #      C4305: truncation (double -> float)
 320         #      C4244: conversion from '.*' to '.*', possible loss of data
 321         #      unreferenced local variable (only C)
 322         #      C4267: conversion from 'size_t' to 'int', possible loss of data
 323         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 324         #      unknown pragma (4068)
 325         #      remark #280: selector expression is constant
 326         if(NOT CMAKE_CONFIGURATION_TYPES)
 327             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800;/wd4355;/wd4996;/wd4305;/wd4244;/wd4101;/wd4267;/wd4090;/wd4068;" GMXC_CFLAGS)
 328             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800;/wd4355;/wd4996;/wd4305;/wd4244;/wd4267;/wd4068;" GMXC_CXXFLAGS)
 329         else() # MSVC projects only use the C++ flags
 330             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800;/wd4355;/wd4996;/wd4305;/wd4244;/wd4101;/wd4267;/wd4090;/wd4068;" GMXC_CXXFLAGS)
 331         endif()
 332         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "/permissive-" GMXC_CXXFLAGS)
 333     endif()
 334
 335     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 336         if(NOT GMX_OPENMP)
 337             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 338         endif()
 339         if (GMX_COMPILER_WARNINGS)
 340             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall;-Wno-unused;-Wunused-value;-Wunused-parameter" GMXC_CFLAGS)
 341             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 342         endif()
 343         GMX_TEST_CFLAG(CFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CFLAGS)
 344     endif()
 345
 346     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 347         if (GMX_COMPILER_WARNINGS)
 348             # If used, -Wall should precede other options that silence warnings it enables
 349             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall" GMXC_CXXFLAGS)
 350             if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "6.0") #LLVM BUG #21629
 351                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_BRACES "-Wno-missing-braces" GMXC_CXXFLAGS)
 352             endif()
 353             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra;-Wpointer-arith;-Wmissing-prototypes" GMXC_CXXFLAGS)
 354             GMX_TEST_CXXFLAG(CXXFLAGS_DEPRECATED "-Wdeprecated" GMXC_CXXFLAGS)
 355             # Functions placed in headers for inlining are not always
 356             # used in every translation unit that includes the files,
 357             # so we must disable the warning that there are such
 358             # functions that are unused.
 359             GMX_TEST_CXXFLAG(CXXFLAGS_NO_UNUSED_FUNCTION "-Wno-unused-function" GMXC_CXXFLAGS)
 360         endif()
 361         if(NOT GMX_OPENMP)
 362             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 363         endif()
 364         GMX_TEST_CXXFLAG(CXXFLAGS_WARN_NO_MISSING_FIELD_INITIALIZERS "-Wno-missing-field-initializers" GMXC_CXXFLAGS)
 365     endif()
 366
 367     # Apple bastardized version of Clang
 368     if(${CMAKE_C_COMPILER_ID} MATCHES "AppleClang")
 369         if(${CMAKE_C_COMPILER_VERSION} VERSION_GREATER 11.0)
 370             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 371             # that checks stack alignment by default, but their own C library
 372             # does not align the stack properly. Embarrassing, Apple...
 373             GMX_TEST_CFLAG(CFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CFLAGS)
 374         endif()
 375     endif()
 376
 377     if(${CMAKE_CXX_COMPILER_ID} MATCHES "AppleClang")
 378         if(${CMAKE_CXX_COMPILER_VERSION} VERSION_GREATER 11.0)
 379             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 380             # that checks stack alignment by default, but their own C library
 381             # does not align the stack properly. Embarrassing, Apple...
 382             GMX_TEST_CXXFLAG(CXXFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CXXFLAGS)
 383         endif()
 384     endif()
 385
 386     # Apple bastardized version of Clang
 387     if(${CMAKE_C_COMPILER_ID} MATCHES "AppleClang")
 388         if(${CMAKE_C_COMPILER_VERSION} VERSION_GREATER 11.0)
 389             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 390             # that checks stack alignment by default, but their own C library
 391             # does not align the stack properly. Embarrassing, Apple...
 392             GMX_TEST_CFLAG(CFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CFLAGS)
 393         endif()
 394     endif()
 395
 396     if(${CMAKE_CXX_COMPILER_ID} MATCHES "AppleClang")
 397         if(${CMAKE_CXX_COMPILER_VERSION} VERSION_GREATER 11.0)
 398             # Mac OS Catalina ships with a horribly broken compiler (version 11.0.0.11000033)
 399             # that checks stack alignment by default, but their own C library
 400             # does not align the stack properly. Embarrassing, Apple...
 401             GMX_TEST_CXXFLAG(CXXFLAG_NO_STACK_CHECK "-fno-stack-check" GMXC_CXXFLAGS)
 402         endif()
 403     endif()
 404
 405 endmacro()