cmake/ThreadMPI.cmake

   1 # This source code file is part of thread_mpi.
   2 # Written by Sander Pronk, Erik Lindahl, and possibly others.
   3 #
   4 # Copyright (c) 2009, Sander Pronk, Erik Lindahl.
   5 # All rights reserved.
   6 #
   7 # Redistribution and use in source and binary forms, with or without
   8 # modification, are permitted provided that the following conditions are met:
   9 # 1) Redistributions of source code must retain the above copyright
  10 # notice, this list of conditions and the following disclaimer.
  11 # 2) Redistributions in binary form must reproduce the above copyright
  12 # notice, this list of conditions and the following disclaimer in the
  13 # documentation and/or other materials provided with the distribution.
  14 # 3) Neither the name of the copyright holders nor the
  15 # names of its contributors may be used to endorse or promote products
  16 # derived from this software without specific prior written permission.
  17 #
  18 # THIS SOFTWARE IS PROVIDED BY US ''AS IS'' AND ANY
  19 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  21 # DISCLAIMED. IN NO EVENT SHALL WE BE LIABLE FOR ANY
  22 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  23 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  24 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  25 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  27 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28 #
  29 # If you want to redistribute modifications, please consider that
  30 # scientific software is very special. Version control is crucial -
  31 # bugs must be traceable. We will be happy to consider code for
  32 # inclusion in the official distribution, but derived work should not
  33 # be called official thread_mpi. Details are found in the README & COPYING
  34 # files.
  35
  36 include(CheckIncludeFiles)
  37 include(CheckFunctionExists)
  38 include(CheckCSourceCompiles)
  39
  40 # sets TMPI_ATOMICS to 1 if atomic operations are found, unset otherwise
  41 # Options:
  42 # include directory for thread_mpi/atomic.h
  43 MACRO(TMPI_TEST_ATOMICS INCDIR)
  44
  45     if (NOT DEFINED TMPI_ATOMICS)
  46         try_compile(TEST_ATOMICS "${CMAKE_BINARY_DIR}"
  47                 "${CMAKE_SOURCE_DIR}/cmake/TestAtomics.c"
  48                 COMPILE_DEFINITIONS "-I${INCDIR} -DTMPI_ATOMICS")
  49         if (TEST_ATOMICS)
  50             message(STATUS "Atomic operations found")
  51             # If the check fails, we want to be able to check again,
  52             # in case the user has been able to fix this without
  53             # needing to delete the cache. Thus we only cache
  54             # positive results.
  55             set(TMPI_ATOMICS ${TEST_ATOMICS} CACHE INTERNAL "Whether atomic operations are found")
  56             set(TMPI_ATOMICS_INCDIR ${INCDIR} CACHE INTERNAL "Atomic operations check include dir")
  57         else ()
  58             message(STATUS "Atomic operations not found")
  59             unset(TEST_ATOMICS)
  60         endif()
  61     endif()
  62
  63 ENDMACRO(TMPI_TEST_ATOMICS VARIABLE)
  64
  65 try_compile(HAVE_PROCESSOR_NUMBER ${CMAKE_BINARY_DIR} "${CMAKE_SOURCE_DIR}/cmake/TestWinProcNum.c")
  66
  67 include(FindThreads)
  68 if (CMAKE_USE_WIN32_THREADS_INIT AND HAVE_PROCESSOR_NUMBER)
  69     set(THREAD_WINDOWS 1)
  70     set(THREAD_LIB)
  71 elseif (CMAKE_USE_PTHREADS_INIT)
  72     check_include_files(pthread.h    HAVE_PTHREAD_H)
  73     set(THREAD_PTHREADS 1)
  74     set(THREAD_LIB ${CMAKE_THREAD_LIBS_INIT})
  75 else()
  76     message(FATAL_ERROR "Thread support required")
  77 endif ()
  78
  79 # Turns on thread_mpi core threading functions.
  80 MACRO(TMPI_ENABLE_CORE INCDIR)
  81     TMPI_TEST_ATOMICS(${INCDIR})
  82
  83 # affinity checks
  84     include(CheckFunctionExists)
  85     if (THREAD_PTHREADS)
  86         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_THREAD_LIBS_INIT})
  87         # check for sched_setaffinity
  88         check_c_source_compiles(
  89             "#define _GNU_SOURCE
  90 #include <pthread.h>
  91 #include <stdlib.h>
  92 #include <stdio.h>
  93 #include <errno.h>
  94     int main(void) { cpu_set_t set;
  95         CPU_ZERO(&set);
  96         CPU_SET(0, &set);
  97         pthread_setaffinity_np(pthread_self(), sizeof(set), &set);
  98         return 0;
  99     }"
 100             PTHREAD_SETAFFINITY
 101         )
 102         if (PTHREAD_SETAFFINITY)
 103             set(HAVE_PTHREAD_SETAFFINITY 1)
 104         endif ()
 105         set(CMAKE_REQUIRED_LIBRARIES)
 106     endif ()
 107
 108
 109 # this runs on POSIX systems
 110     check_include_files(unistd.h        HAVE_UNISTD_H)
 111     check_include_files(sched.h         HAVE_SCHED_H)
 112     check_include_files(sys/time.h      HAVE_SYS_TIME_H)
 113     check_function_exists(sysconf       HAVE_SYSCONF)
 114 # this runs on windows
 115 #check_include_files(windows.h          HAVE_WINDOWS_H)
 116 ENDMACRO(TMPI_ENABLE_CORE)
 117
 118 # enable C++ library build.
 119 MACRO(TMPI_ENABLE_CXX)
 120     set(TMPI_CXX_LIB 1)
 121 ENDMACRO(TMPI_ENABLE_CXX)
 122
 123 # Turns on thread_mpi MPI functions.
 124 MACRO(TMPI_ENABLE)
 125     TMPI_TEST_ATOMICS(TMPI_ATOMICS_INCDIR)
 126     if(NOT DEFINED TMPI_ATOMICS)
 127         message(WARNING "Atomic operations not found for this CPU+compiler combination. Thread support will be unbearably slow: disable threads. Atomic operations should work on all but the most obscure CPU+compiler combinations; if your system is not obscure -- like, for example, x86 with gcc --  please contact the developers.")
 128     endif()
 129
 130     set(TMPI_ENABLED 1)
 131
 132 # the spin-waiting option
 133     option(THREAD_MPI_WAIT_FOR_NO_ONE "Use busy waits without yielding to the OS scheduler. Turning this on might improve performance (very) slightly at the cost of very poor performance if the threads are competing for CPU time." OFF)
 134     mark_as_advanced(THREAD_MPI_WAIT_FOR_NO_ONE)
 135     if (THREAD_MPI_WAIT_FOR_NO_ONE)
 136         set(TMPI_WAIT_FOR_NO_ONE 1)
 137     else ()
 138         set(TMPI_WAIT_FOR_NO_ONE 0)
 139     endif ()
 140
 141 # the copy buffer option
 142     option(THREAD_MPI_COPY_BUFFER "Use an intermediate copy buffer for small message sizes, to allow blocking sends to return quickly. Only useful in programs with relatively uncoupled threads (infrequent MPI communication)" OFF)
 143     mark_as_advanced(THREAD_MPI_COPY_BUFFER)
 144     if (THREAD_MPI_COPY_BUFFER)
 145         set(TMPI_COPY_BUFFER 1)
 146     else ()
 147         set(TMPI_COPY_BUFFER 0)
 148     endif ()
 149
 150 # the profiling option
 151     option(THREAD_MPI_PROFILING "Turn on simple MPI profiling." OFF)
 152     mark_as_advanced(THREAD_MPI_PROFILING)
 153     if (THREAD_MPI_PROFILING)
 154         set(TMPI_PROFILE 1)
 155     else ()
 156         set(TMPI_PROFILE 0)
 157     endif ()
 158
 159 # tmpi warnings for testing
 160     option(THREAD_MPI_WARNINGS "Turn thread_mpi warnings for testing." OFF)
 161     mark_as_advanced(THREAD_MPI_WARNINGS)
 162     if (THREAD_MPI_WARNINGS)
 163         set(TMPI_WARNINGS 1)
 164     else ()
 165         set(TMPI_WARNINGS 0)
 166     endif ()
 167
 168     include(CheckCSourceCompiles)
 169 ENDMACRO(TMPI_ENABLE)
 170
 171
 172 MACRO(TMPI_GET_SOURCE_LIST SRC_VARIABLE SRC_ROOT)
 173     set(${SRC_VARIABLE}
 174         ${SRC_ROOT}/errhandler.c
 175         ${SRC_ROOT}/tmpi_malloc.c
 176         ${SRC_ROOT}/atomic.c
 177         ${SRC_ROOT}/lock.c)
 178
 179     if (THREAD_PTHREADS)
 180         list(APPEND ${SRC_VARIABLE} ${SRC_ROOT}/pthreads.c)
 181     elseif (THREAD_WINDOWS)
 182         list(APPEND ${SRC_VARIABLE} ${SRC_ROOT}/winthreads.c)
 183     endif ()
 184
 185     if (TMPI_CXX_LIB)
 186         list(APPEND ${SRC_VARIABLE} ${SRC_ROOT}/system_error.cpp)
 187     endif ()
 188
 189     if (TMPI_ENABLED)
 190         list(APPEND ${SRC_VARIABLE}
 191              ${SRC_ROOT}/alltoall.c      ${SRC_ROOT}/p2p_protocol.c
 192              ${SRC_ROOT}/barrier.c       ${SRC_ROOT}/p2p_send_recv.c
 193              ${SRC_ROOT}/bcast.c         ${SRC_ROOT}/p2p_wait.c
 194              ${SRC_ROOT}/collective.c    ${SRC_ROOT}/profile.c
 195              ${SRC_ROOT}/comm.c          ${SRC_ROOT}/reduce.c
 196              ${SRC_ROOT}/event.c         ${SRC_ROOT}/reduce_fast.c
 197              ${SRC_ROOT}/gather.c        ${SRC_ROOT}/scatter.c
 198              ${SRC_ROOT}/group.c         ${SRC_ROOT}/tmpi_init.c
 199              ${SRC_ROOT}/topology.c      ${SRC_ROOT}/list.c
 200              ${SRC_ROOT}/type.c          ${SRC_ROOT}/scan.c
 201              ${SRC_ROOT}/numa_malloc.c   ${SRC_ROOT}/once.c)
 202     endif()
 203 ENDMACRO(TMPI_GET_SOURCE_LIST)
 204