cmake/FindMuparser.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2021, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This package tries to find an external muparser library, version
  36 # 2.3.
  37 #
  38 # MUPARSER_FOUND       - muparser was found
  39 # MUPARSER_INCLUDE_DIR - muparser include directory
  40 # MUPARSER_LIBRARY     - muparser library
  41 # MUPARSER_LINKS_OK    - muparser libraries link correctly
  42 # MUPARSER_VERSION     - muparser version string as "major.minor"
  43 #
  44 # CMake will search the CMAKE_PREFIX_PATH in the usual way, but if you
  45 # need more control then setting MUPARSER_INCLUDE_DIR and MUPARSER_LIBRARY
  46 # on the cmake command line to suitable values will work.
  47
  48 include(CMakePushCheckState)
  49 cmake_push_check_state()
  50
  51 find_package(PkgConfig QUIET)
  52 if(PKG_CONFIG_FOUND)
  53     if(MUPARSER_FIND_VERSION)
  54         if(MUPARSER_FIND_VERSION_EXACT)
  55             pkg_check_modules(PC_MUPARSER QUIET muparser=${MUPARSER_FIND_VERSION})
  56         else()
  57             pkg_check_modules(PC_MUPARSER QUIET muparser>=${MUPARSER_FIND_VERSION})
  58         endif()
  59     else()
  60         pkg_check_modules(PC_MUPARSER QUIET muparser)
  61         if (PC_MUPARSER_VERSION)
  62             string(REGEX REPLACE "^([0-9]+):([0-9]+)" "\\1.\\2" MUPARSER_VERSION "${PC_MUPARSER_VERSION}")
  63         endif()
  64     endif()
  65 endif()
  66
  67 # Try to find muparser, perhaps with help from pkg-config
  68 find_path(MUPARSER_INCLUDE_DIR muParser.h HINTS "${PC_MUPARSER_INCLUDE_DIRS}" PATH_SUFFIXES include)
  69 find_library(MUPARSER_LIBRARY NAMES muparser HINTS "${PC_MUPARSER_LIBRARY_DIRS}" PATH_SUFFIXES lib64 lib)
  70
  71 # Make sure we can also link, so that cross-compilation is properly supported
  72 if (MUPARSER_INCLUDE_DIR AND MUPARSER_LIBRARY)
  73     include(CheckCXXSourceCompiles)
  74     set(CMAKE_REQUIRED_INCLUDES ${MUPARSER_INCLUDE_DIR})
  75     set(CMAKE_REQUIRED_LIBRARIES ${MUPARSER_LIBRARY})
  76     check_cxx_source_compiles("#include <muParser.h>\nint main(){mu::Parser parser;}" MUPARSER_LINKS_OK)
  77 endif()
  78
  79 include(FindPackageHandleStandardArgs)
  80 find_package_handle_standard_args(muparser
  81     FOUND_VAR
  82     MUPARSER_FOUND
  83     REQUIRED_VARS
  84     MUPARSER_INCLUDE_DIR
  85     MUPARSER_LIBRARY
  86     MUPARSER_LINKS_OK
  87     VERSION_VAR
  88     MUPARSER_VERSION)
  89
  90 mark_as_advanced(MUPARSER_INCLUDE_DIR MUPARSER_LIBRARY)
  91
  92 # Make a target that other targets can depend on just like this was a
  93 # library built in the main project.
  94 if (MUPARSER_FOUND)
  95     add_library(muparser INTERFACE IMPORTED)
  96     set_target_properties(muparser PROPERTIES
  97         INTERFACE_INCLUDE_DIRECTORIES "${MUPARSER_INCLUDE_DIR}"
  98         INTERFACE_LINK_LIBRARIES "${MUPARSER_LIBRARY}"
  99         )
 100 endif()
 101
 102 cmake_pop_check_state()