cmake/FindFFTW.cmake

   1 # - Find FFTW 3
   2 # Find the native FFTW headers and libraries.
   3 #
   4 #  ${FFTW}_INCLUDE_DIRS - where to find FFTW headers
   5 #  ${FFTW}_LIBRARIES    - List of libraries when using FFTW.
   6 #  ${FFTW}_PKG          - The name of the pkg-config package needed
   7 #  ${FFTW}_HAVE_SIMD    - True if FFTW was build with SIMD support
   8 #  ${FFTW}_FOUND        - True if FFTW was found
   9 #  where ${FFTW} is FFTW or FFTWF
  10 #
  11 #  This file is part of Gromacs        Copyright (c) 2012
  12
  13 #  This program is free software; you can redistribute it and/or
  14 #  modify it under the terms of the GNU General Public License
  15 #  as published by the Free Software Foundation; either version 2
  16 #  of the License, or (at your option) any later version.
  17
  18 #  To help us fund GROMACS development, we humbly ask that you cite
  19 #  the research papers on the package. Check out http://www.gromacs.org
  20
  21 list(LENGTH FFTW_FIND_COMPONENTS FFTW_NUM_COMPONENTS_WANTED)
  22 if(${FFTW_NUM_COMPONENTS_WANTED} LESS 1)
  23   message(FATAL_ERROR "No FFTW component to search given")
  24 elseif(${FFTW_NUM_COMPONENTS_WANTED} GREATER 1)
  25   message(FATAL_ERROR "We only support finding one FFTW component at the time, go and implement it ;-)")
  26 elseif(${FFTW_FIND_COMPONENTS} MATCHES "^fftw(f)?$")
  27   if (NOT FFTW_FIND_VERSION OR FFTW_FIND_VERSION EQUAL 3) #find FFTW3 by default
  28     string(TOUPPER "${FFTW_FIND_COMPONENTS}" FFTW)
  29     string(REGEX REPLACE "fftw" "fftw3" ${FFTW}_PKG "${FFTW_FIND_COMPONENTS}")
  30     set(${FFTW}_FUNCTION_PREFIX "${FFTW_FIND_COMPONENTS}")
  31   else()
  32     message(FATAL_ERROR "We only support finding FFTW version 3, go and implement it ;-)")
  33   endif()
  34 else()
  35   message(FATAL_ERROR "We do not support finding ${FFTW_FIND_COMPONENTS}, go and implement it ;-)")
  36 endif()
  37
  38 find_package(PkgConfig)
  39 if(NOT __pkg_config_checked_PC_${FFTW} OR NOT ${FFTW}_LIBRARY)
  40   pkg_check_modules(PC_${FFTW} "${${FFTW}_PKG}")
  41 endif(NOT __pkg_config_checked_PC_${FFTW} OR NOT ${FFTW}_LIBRARY)
  42
  43 find_path(${FFTW}_INCLUDE_DIR "fftw3.h" HINTS ${PC_${FFTW}_INCLUDE_DIRS})
  44 find_library(${FFTW}_LIBRARY NAMES "${${FFTW}_PKG}" HINTS ${PC_${FFTW}_LIBRARY_DIRS})
  45
  46 set(${FFTW}_LIBRARIES "${${FFTW}_LIBRARY}")
  47 set(${FFTW}_INCLUDE_DIRS "${${FFTW}_INCLUDE_DIR}")
  48
  49 #better error message than find_package_handle_standard_args
  50 if (${FFTW}_LIBRARY AND ${FFTW}_INCLUDE_DIR)
  51   set(${FFTW}_FOUND TRUE)
  52 elseif (NOT ${FFTW}_LIBRARY)
  53   message("Could not find ${${FFTW}_PKG} library named lib${${FFTW}_PKG}, please specify its location in CMAKE_PREFIX_PATH or ${FFTW}_LIBRARY by hand (e.g. -D${FFTW}_LIBRARY='/path/to/lib${${FFTW}_PKG}.so')")
  54 elseif (NOT ${FFTW}_INCLUDE_DIR)
  55   message("Could not the ${${FFTW}_PKG} header fftw3.h, please specify its path in ${FFTW}_INCLUDE_DIR by hand (e.g. -D${FFTW}_INCLUDE_DIR='/path/to/include')")
  56 endif()
  57
  58 if (${FFTW}_FOUND)
  59   #The user could specify trash in ${FFTW}_LIBRARY, so test if we can link it
  60   include(CheckLibraryExists)
  61   if (HAVE_LIBM)
  62     #adding MATH_LIBRARIES here to allow static libs, this does not harm us as we are anyway using it
  63     set(CMAKE_REQUIRED_LIBRARIES m)
  64   endif (HAVE_LIBM)
  65   check_library_exists("${${FFTW}_LIBRARIES}" "${${FFTW}_FUNCTION_PREFIX}_plan_r2r_1d" "" FOUND_${FFTW}_PLAN)
  66   if(NOT FOUND_${FFTW}_PLAN)
  67     message(FATAL_ERROR "Could not find ${${FFTW}_FUNCTION_PREFIX}_plan_r2r_1d in ${${FFTW}_LIBRARY}, take a look at the error message in ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log to find out what went wrong. If you are using a static lib (.a) make sure you have specified all dependencies of ${${FFTW}_PKG} in ${FFTW}_LIBRARY by hand (e.g. -D${FFTW}_LIBRARY='/path/to/lib${${FFTW}_PKG}.so;/path/to/libm.so') !")
  68   endif(NOT FOUND_${FFTW}_PLAN)
  69   #in 3.3 sse function name has changed
  70   foreach(SIMD_FCT ${${FFTW}_FUNCTION_PREFIX}_have_simd_sse2;${${FFTW}_FUNCTION_PREFIX}_have_simd_avx;${${FFTW}_FUNCTION_PREFIX}_have_simd_altivec;${${FFTW}_FUNCTION_PREFIX}_have_simd_neon;${${FFTW}_FUNCTION_PREFIX}_have_sse2;${${FFTW}_FUNCTION_PREFIX}_have_sse;${${FFTW}_FUNCTION_PREFIX}_have_altivec)
  71     check_library_exists("${${FFTW}_LIBRARIES}" "${SIMD_FCT}" "" ${FFTW}_HAVE_${SIMD_FCT})
  72     if(${FFTW}_HAVE_${SIMD_FCT})
  73       set(${FFTW}_HAVE_SIMD TRUE CACHE  BOOL "If ${${FFTW}_PKG} was built with SIMD support")
  74       break()
  75     endif(${FFTW}_HAVE_${SIMD_FCT})
  76   endforeach()
  77   #Verify FFTW is compiled with fPIC (necessary for shared libraries)
  78   if (CMAKE_OBJDUMP AND CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64" AND BUILD_SHARED_LIBS)
  79       execute_process(COMMAND ${CMAKE_OBJDUMP} --reloc ${${FFTW}_LIBRARY} OUTPUT_VARIABLE ${FFTW}_OBJDUMP)
  80       if (${${FFTW}_OBJDUMP} MATCHES "R_X86_64" #Should always be true for static libraries. Checks that objdump works properly and that the library isn't dynamic
  81               AND NOT ${${FFTW}_OBJDUMP} MATCHES "R_X86_64_PLT32")
  82           message(FATAL_ERROR "The FFTW library ${${FFTW}_LIBRARY} cannot be used with shared libraries. Provide a different FFTW library by setting ${FFTW}_LIBRARY. If you don't have a different one, recompile FFTW with \"--enable-shared\" or \"--with-pic\". Or disable shared libraries for Gromacs by setting BUILD_SHARED_LIBS to \"no\". Note: Disabling shared libraries requires up to 10x as much disk space.")
  83       endif ()
  84   endif ()
  85   set(CMAKE_REQUIRED_LIBRARIES)
  86 endif (${FFTW}_FOUND)
  87 set(${FFTW}_HAVE_SIMD FALSE CACHE BOOL "If ${${FFTW}_PKG} was built with SIMD support")
  88
  89 mark_as_advanced(${FFTW}_INCLUDE_DIR ${FFTW}_LIBRARY ${FFTW}_HAVE_SIMD)