cmake/FindFFTW.cmake

   1 # - Find FFTW 3
   2 # Find the native FFTW headers and libraries.
   3 #
   4 #  ${FFTW}_INCLUDE_DIRS - where to find FFTW headers
   5 #  ${FFTW}_LIBRARIES    - List of libraries when using FFTW.
   6 #  ${FFTW}_PKG          - The name of the pkg-config package needed
   7 #  ${FFTW}_HAVE_SIMD    - True if FFTW was built with SIMD support
   8 #  ${FFTW}_HAVE_AVX     - True if FFTW was built with AVX support
   9 #  ${FFTW}_FOUND        - True if FFTW was found
  10 #  where ${FFTW} is FFTW or FFTWF
  11 #
  12 #  This file is part of Gromacs        Copyright (c) 2012
  13
  14 #  This program is free software; you can redistribute it and/or
  15 #  modify it under the terms of the GNU General Public License
  16 #  as published by the Free Software Foundation; either version 2
  17 #  of the License, or (at your option) any later version.
  18
  19 #  To help us fund GROMACS development, we humbly ask that you cite
  20 #  the research papers on the package. Check out http://www.gromacs.org
  21
  22 list(LENGTH FFTW_FIND_COMPONENTS FFTW_NUM_COMPONENTS_WANTED)
  23 if(${FFTW_NUM_COMPONENTS_WANTED} LESS 1)
  24   message(FATAL_ERROR "No FFTW component to search given")
  25 elseif(${FFTW_NUM_COMPONENTS_WANTED} GREATER 1)
  26   message(FATAL_ERROR "We only support finding one FFTW component at the time, go and implement it ;-)")
  27 elseif(${FFTW_FIND_COMPONENTS} MATCHES "^fftw(f)?$")
  28   if (NOT FFTW_FIND_VERSION OR FFTW_FIND_VERSION EQUAL 3) #find FFTW3 by default
  29     string(TOUPPER "${FFTW_FIND_COMPONENTS}" FFTW)
  30     string(REGEX REPLACE "fftw" "fftw3" ${FFTW}_PKG "${FFTW_FIND_COMPONENTS}")
  31     set(${FFTW}_FUNCTION_PREFIX "${FFTW_FIND_COMPONENTS}")
  32   else()
  33     message(FATAL_ERROR "We only support finding FFTW version 3, go and implement it ;-)")
  34   endif()
  35 else()
  36   message(FATAL_ERROR "We do not support finding ${FFTW_FIND_COMPONENTS}, go and implement it ;-)")
  37 endif()
  38
  39 find_package(PkgConfig)
  40 if(NOT __pkg_config_checked_PC_${FFTW} OR NOT ${FFTW}_LIBRARY)
  41   pkg_check_modules(PC_${FFTW} "${${FFTW}_PKG}")
  42 endif(NOT __pkg_config_checked_PC_${FFTW} OR NOT ${FFTW}_LIBRARY)
  43
  44 find_path(${FFTW}_INCLUDE_DIR "fftw3.h" HINTS ${PC_${FFTW}_INCLUDE_DIRS})
  45 find_library(${FFTW}_LIBRARY NAMES "${${FFTW}_PKG}" HINTS ${PC_${FFTW}_LIBRARY_DIRS})
  46
  47 set(${FFTW}_LIBRARIES "${${FFTW}_LIBRARY}")
  48 set(${FFTW}_INCLUDE_DIRS "${${FFTW}_INCLUDE_DIR}")
  49
  50 #better error message than find_package_handle_standard_args
  51 if (${FFTW}_LIBRARY AND ${FFTW}_INCLUDE_DIR)
  52   set(${FFTW}_FOUND TRUE)
  53 elseif (NOT ${FFTW}_LIBRARY)
  54   message("Could not find ${${FFTW}_PKG} library named lib${${FFTW}_PKG}, please specify its location in CMAKE_PREFIX_PATH or ${FFTW}_LIBRARY by hand (e.g. -D${FFTW}_LIBRARY='/path/to/lib${${FFTW}_PKG}.so')")
  55 elseif (NOT ${FFTW}_INCLUDE_DIR)
  56   message("Could not the ${${FFTW}_PKG} header fftw3.h, please specify its path in ${FFTW}_INCLUDE_DIR by hand (e.g. -D${FFTW}_INCLUDE_DIR='/path/to/include')")
  57 endif()
  58
  59 if (${FFTW}_FOUND)
  60   #The user could specify trash in ${FFTW}_LIBRARY, so test if we can link it
  61   include(CheckLibraryExists)
  62   if (HAVE_LIBM)
  63     #adding MATH_LIBRARIES here to allow static libs, this does not harm us as we are anyway using it
  64     set(CMAKE_REQUIRED_LIBRARIES m)
  65   endif (HAVE_LIBM)
  66   check_library_exists("${${FFTW}_LIBRARIES}" "${${FFTW}_FUNCTION_PREFIX}_plan_r2r_1d" "" FOUND_${FFTW}_PLAN)
  67   if(NOT FOUND_${FFTW}_PLAN)
  68     message(FATAL_ERROR "Could not find ${${FFTW}_FUNCTION_PREFIX}_plan_r2r_1d in ${${FFTW}_LIBRARY}, take a look at the error message in ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log to find out what went wrong. If you are using a static lib (.a) make sure you have specified all dependencies of ${${FFTW}_PKG} in ${FFTW}_LIBRARY by hand (e.g. -D${FFTW}_LIBRARY='/path/to/lib${${FFTW}_PKG}.so;/path/to/libm.so') !")
  69   endif(NOT FOUND_${FFTW}_PLAN)
  70
  71   # Check for FFTW3 compiled with --enable-avx, which is slower for GROMACS than --enable-sse or --enable-sse2
  72   foreach(AVX_FUNCTION ${${FFTW}_FUNCTION_PREFIX}_have_simd_avx)
  73     check_library_exists("${${FFTW}_LIBRARIES}" "${AVX_FUNCTION}" "" ${FFTW}_HAVE_${AVX_FUNCTION})
  74     if(${FFTW}_HAVE_${AVX_FUNCTION})
  75       set(${FFTW}_HAVE_AVX TRUE CACHE BOOL "If ${${FFTW}_PKG} was built with AVX support")
  76       break()
  77     endif(${FFTW}_HAVE_${AVX_FUNCTION})
  78   endforeach()
  79
  80   #in 3.3 sse function name has changed
  81   foreach(SIMD_FCT ${${FFTW}_FUNCTION_PREFIX}_have_simd_sse2;${${FFTW}_FUNCTION_PREFIX}_have_simd_avx;${${FFTW}_FUNCTION_PREFIX}_have_simd_altivec;${${FFTW}_FUNCTION_PREFIX}_have_simd_neon;${${FFTW}_FUNCTION_PREFIX}_have_sse2;${${FFTW}_FUNCTION_PREFIX}_have_sse;${${FFTW}_FUNCTION_PREFIX}_have_altivec)
  82     check_library_exists("${${FFTW}_LIBRARIES}" "${SIMD_FCT}" "" ${FFTW}_HAVE_${SIMD_FCT})
  83     if(${FFTW}_HAVE_${SIMD_FCT})
  84       set(${FFTW}_HAVE_SIMD TRUE CACHE  BOOL "If ${${FFTW}_PKG} was built with SIMD support")
  85       break()
  86     endif(${FFTW}_HAVE_${SIMD_FCT})
  87   endforeach()
  88   #Verify FFTW is compiled with fPIC (necessary for shared libraries)
  89   if (CMAKE_OBJDUMP AND CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64" AND BUILD_SHARED_LIBS)
  90       execute_process(COMMAND ${CMAKE_OBJDUMP} --reloc ${${FFTW}_LIBRARY} OUTPUT_VARIABLE ${FFTW}_OBJDUMP)
  91       if (${${FFTW}_OBJDUMP} MATCHES "R_X86_64" #Should always be true for static libraries. Checks that objdump works properly and that the library isn't dynamic
  92               AND NOT ${${FFTW}_OBJDUMP} MATCHES "R_X86_64_PLT32")
  93           message(FATAL_ERROR "The FFTW library ${${FFTW}_LIBRARY} cannot be used with shared libraries. Provide a different FFTW library by setting ${FFTW}_LIBRARY. If you don't have a different one, recompile FFTW with \"--enable-shared\" or \"--with-pic\". Or disable shared libraries for Gromacs by setting BUILD_SHARED_LIBS to \"no\". Note: Disabling shared libraries requires up to 10x as much disk space.")
  94       endif ()
  95   endif ()
  96   set(CMAKE_REQUIRED_LIBRARIES)
  97 endif (${FFTW}_FOUND)
  98 set(${FFTW}_HAVE_SIMD FALSE CACHE BOOL "If ${${FFTW}_PKG} was built with SIMD support")
  99
 100 mark_as_advanced(${FFTW}_INCLUDE_DIR ${FFTW}_LIBRARY ${FFTW}_HAVE_SIMD)