api/nblib/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2020,2021, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # \author Victor Holanda <victor.holanda@cscs.ch>
  36 # \author Joe Jordan <ejjordan@kth.se>
  37 # \author Prashanth Kanduri <kanduri@cscs.ch>
  38 # \author Sebastian Keller <keller@cscs.ch>
  39 #
  40
  41 add_custom_target(nblib-tests
  42         COMMENT "Target to build all nblib tests including samples"
  43         )
  44 # Ensure that "make tests" builds all nblib tests so the top-level
  45 # "make check" will work.
  46 if (BUILD_TESTING)
  47         add_dependencies(tests nblib-tests)
  48
  49         # this allows all nblib tests to be run with "make check-nblib"
  50         add_custom_target(check-nblib
  51                 COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure -R NbLib
  52                 COMMENT "Running nblib tests"
  53                 USES_TERMINAL VERBATIM)
  54         add_dependencies(check-nblib nblib-tests)
  55 endif()
  56
  57 set(NBLIB_MAJOR 0)
  58 set(NBLIB_MINOR 1)
  59 set(NBLIB_RELEASE ${NBLIB_MAJOR}.${NBLIB_MINOR}.0)
  60
  61 add_library(nblib)
  62 set_target_properties(nblib PROPERTIES
  63         VERSION_MAJOR ${NBLIB_MAJOR}
  64         VERSION_MINOR ${NBLIB_MINOR}
  65         SOVERSION ${NBLIB_MAJOR}
  66         RELEASE ${NBLIB_RELEASE}
  67         VERSION ${NBLIB_RELEASE}
  68         LINKER_LANGUAGE CXX
  69         OUTPUT_NAME "nblib")
  70
  71 if (GMX_GPU_CUDA)
  72     if(${CMAKE_VERSION} VERSION_LESS "3.17.0")
  73         find_package(CUDA)
  74         target_include_directories(nblib PRIVATE "${CUDA_INCLUDE_DIRS}")
  75     else()
  76         find_package(CUDAToolkit)
  77         target_link_libraries(nblib PRIVATE CUDA::cudart)
  78     endif()
  79 endif()
  80
  81 target_sources(nblib
  82         PRIVATE
  83         box.cpp
  84         gmxcalculatorcpu.cpp
  85         integrator.cpp
  86         interactions.cpp
  87         molecules.cpp
  88         nbnxmsetuphelpers.cpp
  89         particlesequencer.cpp
  90         particletype.cpp
  91         simulationstate.cpp
  92         topologyhelpers.cpp
  93         topology.cpp
  94         tpr.cpp
  95         virials.cpp
  96         )
  97
  98 gmx_target_compile_options(nblib)
  99
 100 target_link_libraries(nblib PRIVATE libgromacs)
 101 target_include_directories(nblib PRIVATE ${PROJECT_SOURCE_DIR}/api)
 102 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/api)
 103 target_link_libraries(nblib PRIVATE common)
 104 target_link_libraries(nblib PRIVATE
 105                       fileio
 106                       gmxlib
 107                       listed_forces
 108                       mdtypes
 109                       mdlib
 110                       topology
 111                       utility)
 112
 113 # There are transitive interface dependencies on the legacy GROMACS headers.
 114 # TODO(#3288): Explicitly link specific modules for public API dependencies as legacy_api is removed.
 115 target_link_libraries(nblib PUBLIC legacy_api)
 116 # TODO: Explicitly link specific modules.
 117 target_link_libraries(nblib PRIVATE legacy_modules)
 118 if (GMX_OPENMP)
 119     target_link_libraries(nblib PUBLIC OpenMP::OpenMP_CXX)
 120 endif()
 121
 122 install(TARGETS nblib
 123         EXPORT nblib
 124         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 125         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 126         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 127         INCLUDES DESTINATION include
 128         )
 129
 130 if(GMX_INSTALL_NBLIB_API)
 131     install(FILES
 132             basicdefinitions.h
 133             box.h
 134             exception.h
 135             gmxcalculatorcpu.h
 136             integrator.h
 137             interactions.h
 138             molecules.h
 139             kerneloptions.h
 140             nblib.h
 141             nbnxmsetuphelpers.h
 142             particlesequencer.h
 143             particletype.h
 144             simulationstate.h
 145             topology.h
 146             tpr.h
 147             vector.h
 148             DESTINATION include/nblib)
 149 endif()
 150
 151 add_subdirectory(listed_forces)
 152 add_subdirectory(samples)
 153 add_subdirectory(util)
 154
 155 if(BUILD_TESTING)
 156     add_subdirectory(tests)
 157 endif()