api/nblib/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2020,2021, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # \author Victor Holanda <victor.holanda@cscs.ch>
  36 # \author Joe Jordan <ejjordan@kth.se>
  37 # \author Prashanth Kanduri <kanduri@cscs.ch>
  38 # \author Sebastian Keller <keller@cscs.ch>
  39 #
  40
  41 set(TESTUTILS_DIR ${PROJECT_SOURCE_DIR}/src/testutils)
  42 if (BUILD_TESTING)
  43     if(NOT GMX_DEVELOPER_BUILD)
  44         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
  45     endif()
  46     include(${TESTUTILS_DIR}/TestMacros.cmake)
  47 endif()
  48
  49 add_custom_target(nblib-tests
  50         COMMENT "Target to build all nblib tests including samples"
  51         )
  52 # Ensure that "make tests" builds all nblib tests so the top-level
  53 # "make check" will work.
  54 if (BUILD_TESTING)
  55         add_dependencies(tests nblib-tests)
  56
  57         # this allows all nblib tests to be run with "make check-nblib"
  58         add_custom_target(check-nblib
  59                 COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure -R NbLib
  60                 COMMENT "Running nblib tests"
  61                 USES_TERMINAL VERBATIM)
  62         add_dependencies(check-nblib nblib-tests)
  63 endif()
  64
  65 set(NBLIB_MAJOR 0)
  66 set(NBLIB_MINOR 1)
  67 set(NBLIB_RELEASE ${NBLIB_MAJOR}.${NBLIB_MINOR}.0)
  68
  69 add_library(nblib)
  70 set_target_properties(nblib PROPERTIES
  71         VERSION_MAJOR ${NBLIB_MAJOR}
  72         VERSION_MINOR ${NBLIB_MINOR}
  73         SOVERSION ${NBLIB_MAJOR}
  74         RELEASE ${NBLIB_RELEASE}
  75         VERSION ${NBLIB_RELEASE}
  76         LINKER_LANGUAGE CXX
  77         OUTPUT_NAME "nblib")
  78
  79 if (GMX_GPU_CUDA)
  80     if(${CMAKE_VERSION} VERSION_LESS "3.17.0")
  81         find_package(CUDA)
  82         target_include_directories(nblib PRIVATE "${CUDA_INCLUDE_DIRS}")
  83     else()
  84         find_package(CUDAToolkit)
  85         target_link_libraries(nblib PRIVATE CUDA::cudart)
  86     endif()
  87 endif()
  88
  89 target_sources(nblib
  90         PRIVATE
  91         box.cpp
  92         forcecalculator.cpp
  93         gmxcalculator.cpp
  94         gmxsetup.cpp
  95         integrator.cpp
  96         interactions.cpp
  97         molecules.cpp
  98         nbnxmsetuphelpers.cpp
  99         particlesequencer.cpp
 100         particletype.cpp
 101         simulationstate.cpp
 102         topologyhelpers.cpp
 103         topology.cpp
 104         virials.cpp
 105         )
 106
 107 gmx_target_compile_options(nblib)
 108
 109 target_link_libraries(nblib PRIVATE libgromacs)
 110 target_include_directories(nblib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 111 target_include_directories(nblib PRIVATE ${PROJECT_SOURCE_DIR}/api)
 112 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/api)
 113 target_link_libraries(nblib PRIVATE common)
 114 # There are transitive dependencies on the legacy GROMACS headers.
 115 target_link_libraries(nblib PUBLIC legacy_api)
 116 # TODO: Explicitly link specific modules.
 117 target_link_libraries(nblib PRIVATE legacy_modules)
 118 if (GMX_OPENMP)
 119     target_link_libraries(nblib PUBLIC OpenMP::OpenMP_CXX)
 120 endif()
 121
 122 install(TARGETS nblib
 123         EXPORT nblib
 124         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 125         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 126         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 127         INCLUDES DESTINATION include
 128         )
 129
 130 if(GMX_INSTALL_NBLIB_API)
 131     install(FILES
 132             basicdefinitions.h
 133             box.h
 134             exception.h
 135             forcecalculator.h
 136             integrator.h
 137             interactions.h
 138             molecules.h
 139             kerneloptions.h
 140             nblib.h
 141             particlesequencer.h
 142             particletype.h
 143             simulationstate.h
 144             topology.h
 145             DESTINATION include/nblib)
 146 endif()
 147
 148 add_subdirectory(listed_forces)
 149 add_subdirectory(samples)
 150 add_subdirectory(util)
 151
 152 if(BUILD_TESTING)
 153     add_subdirectory(tests)
 154 endif()