api/nblib/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 # \author Victor Holanda <victor.holanda@cscs.ch>
  36 # \author Joe Jordan <ejjordan@kth.se>
  37 # \author Prashanth Kanduri <kanduri@cscs.ch>
  38 # \author Sebastian Keller <keller@cscs.ch>
  39 #
  40
  41 # The following are copied directly from src/CMakeLists.txt
  42 set(IGNORED_CLANG_ALL_WARNINGS
  43         "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  44         "-Wno-source-uses-openmp" #Don't warn for no-omp build
  45         "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  46         "-Wno-documentation-unknown-command" #Custom commands are used
  47         "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  48         "-Wno-switch-enum" # default statement for enum is OK
  49
  50         # These are all needed, mostly for testing code
  51         "-Wno-conversion"
  52         "-Wno-documentation"
  53         "-Wno-double-promotion"
  54         "-Wno-exit-time-destructors"
  55         "-Wno-float-equal"
  56         "-Wno-global-constructors"
  57         "-Wno-padded"
  58         "-Wno-reserved-id-macro"
  59         "-Wno-shadow"
  60         "-Wno-unused-macros"
  61         "-Wno-weak-vtables"
  62         )
  63
  64 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
  65
  66 set(TESTUTILS_DIR ${PROJECT_SOURCE_DIR}/src/testutils)
  67 if (BUILD_TESTING)
  68     if(NOT GMX_DEVELOPER_BUILD)
  69         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
  70     endif()
  71     include(${TESTUTILS_DIR}/TestMacros.cmake)
  72 endif()
  73
  74 # this allows all nblib tests to be run with "make check-nblib"
  75 add_custom_target(check-nblib
  76         COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure -R NbLib
  77         COMMENT "Running nblib tests"
  78         USES_TERMINAL VERBATIM)
  79
  80 set(NBLIB_MAJOR 0)
  81 set(NBLIB_MINOR 1)
  82 set(NBLIB_RELEASE ${NBLIB_MAJOR}.${NBLIB_MINOR}.0)
  83
  84 add_library(nblib)
  85 set_target_properties(nblib PROPERTIES
  86         VERSION_MAJOR ${NBLIB_MAJOR}
  87         VERSION_MINOR ${NBLIB_MINOR}
  88         SOVERSION ${NBLIB_MAJOR}
  89         RELEASE ${NBLIB_RELEASE}
  90         VERSION ${NBLIB_RELEASE}
  91         LINKER_LANGUAGE CXX
  92         OUTPUT_NAME "nblib")
  93
  94 target_sources(nblib
  95         PRIVATE
  96         box.cpp
  97         forcecalculator.cpp
  98         gmxcalculator.cpp
  99         gmxsetup.cpp
 100         integrator.cpp
 101         interactions.cpp
 102         molecules.cpp
 103         particletype.cpp
 104         simulationstate.cpp
 105         topologyhelpers.cpp
 106         topology.cpp
 107         )
 108
 109 gmx_target_compile_options(nblib)
 110
 111 target_link_libraries(nblib PRIVATE libgromacs)
 112 target_include_directories(nblib PRIVATE ${PROJECT_SOURCE_DIR}/api)
 113 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/api)
 114 target_link_libraries(nblib PRIVATE common)
 115 # There are transitive dependencies on the legacy GROMACS headers.
 116 target_link_libraries(nblib PUBLIC legacy_api)
 117 # TODO: Explicitly link specific modules.
 118 target_link_libraries(nblib PRIVATE legacy_modules)
 119
 120 install(TARGETS nblib
 121         EXPORT nblib
 122         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 123         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 124         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 125         INCLUDES DESTINATION include
 126         )
 127
 128 if(GMX_INSTALL_NBLIB_API)
 129     install(FILES
 130             basicdefinitions.h
 131             box.h
 132             exception.h
 133             forcecalculator.h
 134             integrator.h
 135             interactions.h
 136             molecules.h
 137             kerneloptions.h
 138             nblib.h
 139             particletype.h
 140             ppmap.h
 141             simulationstate.h
 142             topology.h
 143             topologyhelpers.h
 144             DESTINATION include/nblib)
 145 endif()
 146
 147 add_subdirectory(listed_forces)
 148 add_subdirectory(samples)
 149 add_subdirectory(util)
 150
 151 if(BUILD_TESTING)
 152     add_subdirectory(tests)
 153 endif()