api/nblib/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2020,2021, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # \author Victor Holanda <victor.holanda@cscs.ch>
  36 # \author Joe Jordan <ejjordan@kth.se>
  37 # \author Prashanth Kanduri <kanduri@cscs.ch>
  38 # \author Sebastian Keller <keller@cscs.ch>
  39 #
  40
  41 set(TESTUTILS_DIR ${PROJECT_SOURCE_DIR}/src/testutils)
  42 if (BUILD_TESTING)
  43     if(NOT GMX_DEVELOPER_BUILD)
  44         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
  45     endif()
  46     include(${TESTUTILS_DIR}/TestMacros.cmake)
  47 endif()
  48
  49 add_custom_target(nblib-tests
  50         COMMENT "Target to build all nblib tests including samples"
  51         )
  52 # Ensure that "make tests" builds all nblib tests so the top-level
  53 # "make check" will work.
  54 add_dependencies(tests nblib-tests)
  55
  56 # this allows all nblib tests to be run with "make check-nblib"
  57 add_custom_target(check-nblib
  58         COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure -R NbLib
  59         COMMENT "Running nblib tests"
  60         USES_TERMINAL VERBATIM)
  61 add_dependencies(check-nblib nblib-tests)
  62
  63 set(NBLIB_MAJOR 0)
  64 set(NBLIB_MINOR 1)
  65 set(NBLIB_RELEASE ${NBLIB_MAJOR}.${NBLIB_MINOR}.0)
  66
  67 add_library(nblib)
  68 set_target_properties(nblib PROPERTIES
  69         VERSION_MAJOR ${NBLIB_MAJOR}
  70         VERSION_MINOR ${NBLIB_MINOR}
  71         SOVERSION ${NBLIB_MAJOR}
  72         RELEASE ${NBLIB_RELEASE}
  73         VERSION ${NBLIB_RELEASE}
  74         LINKER_LANGUAGE CXX
  75         OUTPUT_NAME "nblib")
  76
  77 if (GMX_GPU_CUDA)
  78     if(${CMAKE_VERSION} VERSION_LESS "3.17.0")
  79         find_package(CUDA)
  80         target_include_directories(nblib PRIVATE "${CUDA_INCLUDE_DIRS}")
  81     else()
  82         find_package(CUDAToolkit)
  83         target_link_libraries(nblib PRIVATE CUDA::cudart)
  84     endif()
  85 endif()
  86
  87 target_sources(nblib
  88         PRIVATE
  89         box.cpp
  90         forcecalculator.cpp
  91         gmxcalculator.cpp
  92         gmxsetup.cpp
  93         integrator.cpp
  94         interactions.cpp
  95         molecules.cpp
  96         nbnxmsetuphelpers.cpp
  97         particlesequencer.cpp
  98         particletype.cpp
  99         simulationstate.cpp
 100         topologyhelpers.cpp
 101         topology.cpp
 102         )
 103
 104 gmx_target_compile_options(nblib)
 105
 106 target_link_libraries(nblib PRIVATE libgromacs)
 107 target_include_directories(nblib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 108 target_include_directories(nblib PRIVATE ${PROJECT_SOURCE_DIR}/api)
 109 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/api)
 110 target_link_libraries(nblib PRIVATE common)
 111 # There are transitive dependencies on the legacy GROMACS headers.
 112 target_link_libraries(nblib PUBLIC legacy_api)
 113 # TODO: Explicitly link specific modules.
 114 target_link_libraries(nblib PRIVATE legacy_modules)
 115 if (GMX_OPENMP)
 116     target_link_libraries(nblib PUBLIC OpenMP::OpenMP_CXX)
 117 endif()
 118
 119 install(TARGETS nblib
 120         EXPORT nblib
 121         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 122         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 123         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 124         INCLUDES DESTINATION include
 125         )
 126
 127 if(GMX_INSTALL_NBLIB_API)
 128     install(FILES
 129             basicdefinitions.h
 130             box.h
 131             exception.h
 132             forcecalculator.h
 133             integrator.h
 134             interactions.h
 135             molecules.h
 136             kerneloptions.h
 137             nblib.h
 138             particlesequencer.h
 139             particletype.h
 140             simulationstate.h
 141             topology.h
 142             DESTINATION include/nblib)
 143 endif()
 144
 145 add_subdirectory(listed_forces)
 146 add_subdirectory(samples)
 147 add_subdirectory(util)
 148
 149 if(BUILD_TESTING)
 150     add_subdirectory(tests)
 151 endif()