api/nblib/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2020,2021, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # \author Victor Holanda <victor.holanda@cscs.ch>
  36 # \author Joe Jordan <ejjordan@kth.se>
  37 # \author Prashanth Kanduri <kanduri@cscs.ch>
  38 # \author Sebastian Keller <keller@cscs.ch>
  39 #
  40
  41 # The following are copied directly from src/CMakeLists.txt
  42 set(IGNORED_CLANG_ALL_WARNINGS
  43         "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  44         "-Wno-source-uses-openmp" #Don't warn for no-omp build
  45         "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  46         "-Wno-documentation-unknown-command" #Custom commands are used
  47         "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  48         "-Wno-switch-enum" # default statement for enum is OK
  49
  50         # These are all needed, mostly for testing code
  51         "-Wno-conversion"
  52         "-Wno-documentation"
  53         "-Wno-double-promotion"
  54         "-Wno-exit-time-destructors"
  55         "-Wno-float-equal"
  56         "-Wno-global-constructors"
  57         "-Wno-padded"
  58         "-Wno-reserved-id-macro"
  59         "-Wno-shadow"
  60         "-Wno-unused-macros"
  61         "-Wno-weak-vtables"
  62         )
  63
  64 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
  65
  66 set(TESTUTILS_DIR ${PROJECT_SOURCE_DIR}/src/testutils)
  67 if (BUILD_TESTING)
  68     if(NOT GMX_DEVELOPER_BUILD)
  69         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
  70     endif()
  71     include(${TESTUTILS_DIR}/TestMacros.cmake)
  72 endif()
  73
  74 add_custom_target(nblib-tests
  75         COMMENT "Target to build all nblib tests including samples"
  76         )
  77 # Ensure that "make tests" builds all nblib tests so the top-level
  78 # "make check" will work.
  79 add_dependencies(tests nblib-tests)
  80
  81 # this allows all nblib tests to be run with "make check-nblib"
  82 add_custom_target(check-nblib
  83         COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure -R NbLib
  84         COMMENT "Running nblib tests"
  85         USES_TERMINAL VERBATIM)
  86 add_dependencies(check-nblib nblib-tests)
  87
  88 set(NBLIB_MAJOR 0)
  89 set(NBLIB_MINOR 1)
  90 set(NBLIB_RELEASE ${NBLIB_MAJOR}.${NBLIB_MINOR}.0)
  91
  92 add_library(nblib)
  93 set_target_properties(nblib PROPERTIES
  94         VERSION_MAJOR ${NBLIB_MAJOR}
  95         VERSION_MINOR ${NBLIB_MINOR}
  96         SOVERSION ${NBLIB_MAJOR}
  97         RELEASE ${NBLIB_RELEASE}
  98         VERSION ${NBLIB_RELEASE}
  99         LINKER_LANGUAGE CXX
 100         OUTPUT_NAME "nblib")
 101
 102 if (GMX_GPU_CUDA)
 103     if(${CMAKE_VERSION} VERSION_LESS "3.17.0")
 104         find_package(CUDA)
 105         target_include_directories(nblib PRIVATE "${CUDA_INCLUDE_DIRS}")
 106     else()
 107         find_package(CUDAToolkit)
 108         target_link_libraries(nblib PRIVATE CUDA::cudart)
 109     endif()
 110 endif()
 111
 112 target_sources(nblib
 113         PRIVATE
 114         box.cpp
 115         forcecalculator.cpp
 116         gmxcalculator.cpp
 117         gmxsetup.cpp
 118         integrator.cpp
 119         interactions.cpp
 120         molecules.cpp
 121         nbnxmsetuphelpers.cpp
 122         particlesequencer.cpp
 123         particletype.cpp
 124         simulationstate.cpp
 125         topologyhelpers.cpp
 126         topology.cpp
 127         )
 128
 129 gmx_target_compile_options(nblib)
 130
 131 target_link_libraries(nblib PRIVATE libgromacs)
 132 target_include_directories(nblib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 133 target_include_directories(nblib PRIVATE ${PROJECT_SOURCE_DIR}/api)
 134 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/api)
 135 target_link_libraries(nblib PRIVATE common)
 136 # There are transitive dependencies on the legacy GROMACS headers.
 137 target_link_libraries(nblib PUBLIC legacy_api)
 138 # TODO: Explicitly link specific modules.
 139 target_link_libraries(nblib PRIVATE legacy_modules)
 140
 141 install(TARGETS nblib
 142         EXPORT nblib
 143         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 144         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 145         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 146         INCLUDES DESTINATION include
 147         )
 148
 149 if(GMX_INSTALL_NBLIB_API)
 150     install(FILES
 151             basicdefinitions.h
 152             box.h
 153             exception.h
 154             forcecalculator.h
 155             integrator.h
 156             interactions.h
 157             molecules.h
 158             kerneloptions.h
 159             nblib.h
 160             particlesequencer.h
 161             particletype.h
 162             simulationstate.h
 163             topology.h
 164             DESTINATION include/nblib)
 165 endif()
 166
 167 add_subdirectory(listed_forces)
 168 add_subdirectory(samples)
 169 add_subdirectory(util)
 170
 171 if(BUILD_TESTING)
 172     add_subdirectory(tests)
 173 endif()