api/nblib/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 # \author Victor Holanda <victor.holanda@cscs.ch>
  36 # \author Joe Jordan <ejjordan@kth.se>
  37 # \author Prashanth Kanduri <kanduri@cscs.ch>
  38 # \author Sebastian Keller <keller@cscs.ch>
  39 #
  40
  41 # The following are copied directly from src/CMakeLists.txt
  42 set(IGNORED_CLANG_ALL_WARNINGS
  43         "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  44         "-Wno-source-uses-openmp" #Don't warn for no-omp build
  45         "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  46         "-Wno-documentation-unknown-command" #Custom commands are used
  47         "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  48         "-Wno-switch-enum" # default statement for enum is OK
  49
  50         # We need to use macros like
  51         # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  52         # if they don't have a semicolon after them, and might confuse
  53         # tools like IDEs also.
  54         "-Wno-extra-semi-stmt"
  55
  56         #Following ones are undecided/TODO
  57         "-Wno-disabled-macro-expansion"
  58         "-Wno-cast-align"
  59         "-Wno-reserved-id-macro"
  60         "-Wno-global-constructors"
  61         "-Wno-exit-time-destructors"
  62         "-Wno-unused-macros"
  63         "-Wno-weak-vtables"
  64         "-Wno-conditional-uninitialized"
  65         "-Wno-format-nonliteral"
  66         "-Wno-shadow"
  67         "-Wno-cast-qual"
  68         "-Wno-documentation"
  69         "-Wno-used-but-marked-unused"
  70         "-Wno-padded"
  71         "-Wno-float-equal"
  72         "-Wno-old-style-cast"
  73         "-Wno-conversion"
  74         "-Wno-double-promotion")
  75 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
  76
  77 set(TESTUTILS_DIR ${PROJECT_SOURCE_DIR}/src/testutils)
  78 if (BUILD_TESTING)
  79     if(NOT GMX_DEVELOPER_BUILD)
  80         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
  81     endif()
  82     include(${TESTUTILS_DIR}/TestMacros.cmake)
  83 endif()
  84
  85 # this allows all nblib tests to be run with "make check-nblib"
  86 add_custom_target(check-nblib
  87         COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure -R NbLib
  88         COMMENT "Running nblib tests"
  89         USES_TERMINAL VERBATIM)
  90
  91 set(NBLIB_MAJOR 0)
  92 set(NBLIB_MINOR 1)
  93 set(NBLIB_RELEASE ${NBLIB_MAJOR}.${NBLIB_MINOR}.0)
  94
  95 add_library(nblib)
  96 set_target_properties(nblib PROPERTIES
  97         VERSION_MAJOR ${NBLIB_MAJOR}
  98         VERSION_MINOR ${NBLIB_MINOR}
  99         SOVERSION ${NBLIB_MAJOR}
 100         RELEASE ${NBLIB_RELEASE}
 101         VERSION ${NBLIB_RELEASE}
 102         LINKER_LANGUAGE CXX
 103         OUTPUT_NAME "nblib")
 104
 105 target_sources(nblib
 106         PRIVATE
 107         box.cpp
 108         forcecalculator.cpp
 109         gmxcalculator.cpp
 110         gmxsetup.cpp
 111         integrator.cpp
 112         interactions.cpp
 113         molecules.cpp
 114         particletype.cpp
 115         simulationstate.cpp
 116         topologyhelpers.cpp
 117         topology.cpp
 118         )
 119
 120 gmx_target_compile_options(nblib)
 121
 122 target_link_libraries(nblib PRIVATE libgromacs)
 123 target_include_directories(nblib PRIVATE ${PROJECT_SOURCE_DIR}/api)
 124 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/api)
 125 # There are transitive dependencies on the legacy GROMACS headers.
 126 target_link_libraries(nblib PUBLIC legacy_api)
 127
 128 install(TARGETS nblib
 129         EXPORT nblib
 130         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 131         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 132         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 133         INCLUDES DESTINATION include
 134         )
 135
 136 if(GMX_INSTALL_NBLIB_API)
 137     install(FILES
 138             basicdefinitions.h
 139             box.h
 140             exception.h
 141             forcecalculator.h
 142             integrator.h
 143             interactions.h
 144             molecules.h
 145             kerneloptions.h
 146             nblib.h
 147             particletype.h
 148             ppmap.h
 149             simulationstate.h
 150             topology.h
 151             topologyhelpers.h
 152             DESTINATION include/nblib)
 153 endif()
 154
 155 add_subdirectory(listed_forces)
 156 add_subdirectory(samples)
 157 add_subdirectory(util)
 158
 159 if(BUILD_TESTING)
 160     add_subdirectory(tests)
 161 endif()