api/nblib/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 # \author Victor Holanda <victor.holanda@cscs.ch>
  36 # \author Joe Jordan <ejjordan@kth.se>
  37 # \author Prashanth Kanduri <kanduri@cscs.ch>
  38 # \author Sebastian Keller <keller@cscs.ch>
  39 #
  40
  41 # The following are copied directly from src/CMakeLists.txt
  42 set(IGNORED_CLANG_ALL_WARNINGS
  43         "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  44         "-Wno-source-uses-openmp" #Don't warn for no-omp build
  45         "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  46         "-Wno-documentation-unknown-command" #Custom commands are used
  47         "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  48         "-Wno-switch-enum" # default statement for enum is OK
  49
  50         # We need to use macros like
  51         # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  52         # if they don't have a semicolon after them, and might confuse
  53         # tools like IDEs also.
  54         "-Wno-extra-semi-stmt"
  55
  56         #Following ones are undecided/TODO
  57         "-Wno-disabled-macro-expansion"
  58         "-Wno-cast-align"
  59         "-Wno-reserved-id-macro"
  60         "-Wno-global-constructors"
  61         "-Wno-exit-time-destructors"
  62         "-Wno-unused-macros"
  63         "-Wno-weak-vtables"
  64         "-Wno-conditional-uninitialized"
  65         "-Wno-format-nonliteral"
  66         "-Wno-shadow"
  67         "-Wno-cast-qual"
  68         "-Wno-documentation"
  69         "-Wno-used-but-marked-unused"
  70         "-Wno-padded"
  71         "-Wno-float-equal"
  72         "-Wno-old-style-cast"
  73         "-Wno-conversion"
  74         "-Wno-double-promotion")
  75 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
  76
  77 set(TESTUTILS_DIR ${PROJECT_SOURCE_DIR}/src/testutils)
  78 include(${PROJECT_SOURCE_DIR}/src/testutils/TestMacros.cmake)
  79
  80 # this allows all nblib tests to be run with "make check-nblib"
  81 add_custom_target(check-nblib
  82         COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure -R NbLib
  83         COMMENT "Running nblib tests"
  84         USES_TERMINAL VERBATIM)
  85
  86 add_library(nblib SHARED "")
  87
  88 target_sources(nblib
  89         PRIVATE
  90         box.cpp
  91         forcecalculator.cpp
  92         gmxcalculator.cpp
  93         gmxsetup.cpp
  94         integrator.cpp
  95         interactions.cpp
  96         molecules.cpp
  97         particletype.cpp
  98         simulationstate.cpp
  99         topologyhelpers.cpp
 100         topology.cpp
 101         )
 102
 103
 104 set_target_properties(nblib
 105         PROPERTIES
 106         LINKER_LANGUAGE CXX
 107         OUTPUT_NAME "nblib"
 108         )
 109
 110 target_link_libraries(nblib PRIVATE libgromacs)
 111 target_include_directories(nblib PRIVATE ${PROJECT_SOURCE_DIR}/api)
 112 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/api)
 113
 114 install(TARGETS nblib
 115         EXPORT nblib
 116         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 117         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 118         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 119         INCLUDES DESTINATION include
 120         )
 121
 122 if(GMX_INSTALL_NBLIB_API)
 123     install(FILES
 124             basicdefinitions.h
 125             box.h
 126             exception.h
 127             forcecalculator.h
 128             integrator.h
 129             interactions.h
 130             molecules.h
 131             kerneloptions.h
 132             nblib.h
 133             particletype.h
 134             simulationstate.h
 135             topology.h
 136             topologyhelpers.h
 137             DESTINATION include/nblib)
 138 endif()
 139
 140 add_subdirectory(samples)
 141 add_subdirectory(util)
 142
 143 if(BUILD_TESTING)
 144     add_subdirectory(tests)
 145 endif()