admin/includedeps.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 function (generate_module_file_list SRCDIR OUTFILE MODE)
  36     set(_module_list
  37         analysisdata commandline fft fileio linearalgebra onlinehelp options
  38         selection timing trajectoryanalysis utility)
  39     if (MODE STREQUAL "CHECK")
  40         list(APPEND _module_list gmxana gmxlib gmxpreprocess legacyheaders mdlib)
  41     endif()
  42     set(PATH_LIST)
  43     foreach (MODULE ${_module_list})
  44         list(APPEND PATH_LIST "${SRCDIR}/src/gromacs/${MODULE}/*.cpp")
  45         if (MODE STREQUAL "GRAPHS")
  46             list(APPEND PATH_LIST "${SRCDIR}/src/gromacs/${MODULE}/*.c")
  47         endif()
  48         list(APPEND PATH_LIST "${SRCDIR}/src/gromacs/${MODULE}/*.h")
  49     endforeach ()
  50     list(APPEND PATH_LIST "${SRCDIR}/src/testutils/*.cpp")
  51     list(APPEND PATH_LIST "${SRCDIR}/src/testutils/*.h")
  52     set(FILE_LIST)
  53     foreach (PATH_EXPR ${PATH_LIST})
  54         file(GLOB_RECURSE FOUND_FILES ${PATH_EXPR})
  55         list(APPEND FILE_LIST ${FOUND_FILES})
  56     endforeach ()
  57     string(REPLACE ";" "\n" FILE_LIST "${FILE_LIST}")
  58     file(WRITE ${OUTFILE} "${FILE_LIST}")
  59 endfunction ()
  60
  61 function (generate_installed_file_list SRCDIR BUILDDIR OUTFILE)
  62     file(GLOB_RECURSE INSTALL_FILE_LIST "${BUILDDIR}/cmake_install.cmake")
  63     set(MATCH_REGEX "${SRCDIR}/.*\\.h")
  64     set(HEADER_LIST)
  65     foreach (INSTALL_FILE ${INSTALL_FILE_LIST})
  66         file(STRINGS ${INSTALL_FILE} HEADER_LINES REGEX "${MATCH_REGEX}")
  67         foreach (HEADER_LINE ${HEADER_LINES})
  68             string (REGEX MATCH "${MATCH_REGEX}" HEADER "${HEADER_LINE}")
  69             list(APPEND HEADER_LIST "${HEADER}")
  70         endforeach ()
  71     endforeach ()
  72     string(REPLACE ";" "\n" HEADER_LIST "${HEADER_LIST}")
  73     file(WRITE ${OUTFILE} "${HEADER_LIST}")
  74 endfunction ()
  75
  76 if (NOT DEFINED SRCDIR OR NOT DEFINED BUILDDIR OR NOT DEFINED OUTDIR)
  77     message(FATAL_ERROR "Required input variable (SRCDIR, BUILDDIR, OUTDIR) not set")
  78 endif ()
  79
  80 if (NOT DEFINED PYTHON_EXECUTABLE)
  81     set(PYTHON_EXECUTABLE python)
  82 endif ()
  83
  84 if (NOT DEFINED MODE)
  85     set(MODE "CHECK")
  86 endif ()
  87
  88 if (MODE STREQUAL "CHECK")
  89     set(GRAPHOPTIONS --check)
  90 elseif (MODE STREQUAL "CHECKDOC")
  91     set(GRAPHOPTIONS --check --check-doc --warn-undoc)
  92 elseif (MODE STREQUAL "GRAPHS")
  93     set(GRAPHOPTIONS
  94         --module-graph module-deps.dot --module-file-graphs
  95         -o ${OUTDIR})
  96 else ()
  97     message(FATAL_ERROR "Unknown mode ${MODE}")
  98 endif ()
  99
 100 file(MAKE_DIRECTORY ${OUTDIR})
 101 generate_module_file_list(${SRCDIR} ${OUTDIR}/module-files.txt ${MODE})
 102 generate_installed_file_list(${SRCDIR} ${BUILDDIR} ${OUTDIR}/installed-headers.txt)
 103 execute_process(COMMAND ${PYTHON_EXECUTABLE} ${SRCDIR}/admin/includedeps.py
 104                         -f ${OUTDIR}/module-files.txt
 105                         --installed ${OUTDIR}/installed-headers.txt
 106                         -R ${SRCDIR}/src -R ${BUILDDIR}/src
 107                         -I ${SRCDIR}/src/gromacs/legacyheaders
 108                         -I ${BUILDDIR}/src/gromacs/utility
 109                         ${GRAPHOPTIONS})
 110
 111 if (MODE STREQUAL "GRAPHS" AND DOT_EXECUTABLE)
 112     file(GLOB DOT_INPUT_FILES ${OUTDIR}/*.dot)
 113     execute_process(COMMAND ${DOT_EXECUTABLE} -Tpng -O ${DOT_INPUT_FILES})
 114 endif ()