CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98 include(gmxBuildTypeThreadSanitizer)
  99
 100 if(NOT CMAKE_BUILD_TYPE)
 101     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 102     # There's no need to offer a user the choice of ThreadSanitizer
 103     # Set the possible values of build type for cmake-gui
 104     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 105         "MinSizeRel" "RelWithDebInfo")
 106 endif(NOT CMAKE_BUILD_TYPE)
 107
 108 enable_language(C)
 109 enable_language(CXX)
 110
 111 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 112 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 113 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 114 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 115 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 116 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 117 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 118 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 119 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 120 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 121 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 122
 123 #must come after all cpack settings!
 124 include(CPack)
 125
 126 # Set a default valgrind suppression file.
 127 # This unfortunately needs to duplicate information from CTest to work as
 128 # expected...
 129 set(MEMORYCHECK_SUPPRESSIONS_FILE
 130     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 131     CACHE FILEPATH
 132     "File that contains suppressions for the memory checker")
 133 include(CTest)
 134
 135 set(SOURCE_IS_GIT_REPOSITORY OFF)
 136 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 137 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 138     set(SOURCE_IS_GIT_REPOSITORY ON)
 139 endif()
 140 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 141     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 142 endif()
 143
 144 ########################################################################
 145 # Check and warn if cache generated on a different host is being reused
 146 ########################################################################
 147 if(CMAKE_HOST_UNIX)
 148     execute_process(COMMAND hostname
 149                     OUTPUT_VARIABLE TMP_HOSTNAME
 150                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 151     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 152         message(WARNING "
 153             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 154             is being reused! This could lead to inconsitencies; therefore, it is
 155             recommended to regenerate the cache!")
 156     endif()
 157     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 158             "Hostname of the machine where the cache was generated.")
 159 endif()
 160
 161 ########################################################################
 162 # User input options                                                   #
 163 ########################################################################
 164 include(gmxOptionUtilities)
 165
 166 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 167
 168 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 169 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 170 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 171 gmx_dependent_option(
 172     GMX_MPI_IN_PLACE
 173     "Enable MPI_IN_PLACE for MPIs that have it defined"
 174     ON
 175     GMX_MPI)
 176 mark_as_advanced(GMX_MPI_IN_PLACE)
 177 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 178 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 179 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 180 mark_as_advanced(GMX_FAHCORE)
 181
 182 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 183 mark_as_advanced(GMX_COOL_QUOTES)
 184 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 185
 186 # decide on GPU settings based on user-settings and GPU/CUDA detection
 187 include(gmxManageGPU)
 188
 189 # Detect the architecture the compiler is targetting, detect
 190 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 191 # to use if none is specified, and populate the cache option for CPU
 192 # SIMD.
 193 include(gmxDetectTargetArchitecture)
 194 gmx_detect_target_architecture()
 195
 196 if(GMX_CPU_ACCELERATION)
 197     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 198     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 199 endif(GMX_CPU_ACCELERATION)
 200
 201 if(NOT GMX_TARGET_MIC)
 202     include(gmxDetectSimd)
 203     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 204 else()
 205     set(GMX_SUGGESTED_SIMD "None")
 206 endif()
 207
 208 gmx_option_multichoice(
 209     GMX_SIMD
 210     "SIMD instruction set for CPU kernels and compiler optimization"
 211     "${GMX_SUGGESTED_SIMD}"
 212     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 213
 214 gmx_option_multichoice(
 215     GMX_FFT_LIBRARY
 216     "FFT library"
 217     "fftw3"
 218     fftw3 mkl "fftpack[built-in]")
 219 gmx_dependent_option(
 220     GMX_BUILD_OWN_FFTW
 221     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 222     OFF
 223     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 224 gmx_dependent_option(
 225     GMX_DISABLE_FFTW_MEASURE
 226     "Do not optimize FFTW setups (not needed with SSE)"
 227     OFF
 228     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 229 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 230 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 231
 232 gmx_option_multichoice(
 233     GMX_QMMM_PROGRAM
 234     "QM package for QM/MM"
 235     None
 236     none gaussian mopac gamess orca)
 237
 238 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 239 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 240
 241 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 242
 243 if("${GMX_SIMD}" STREQUAL "REFERENCE")
 244     if(GMX_DOUBLE)
 245         set(KERNEL_WIDTH ${GMX_SIMD_REF_DOUBLE_WIDTH})
 246     else()
 247         set(KERNEL_WIDTH ${GMX_SIMD_REF_FLOAT_WIDTH})
 248     endif()
 249 endif()
 250
 251 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 252 mark_as_advanced(GMX_BROKEN_CALLOC)
 253 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 254 mark_as_advanced(GMX_LOAD_PLUGINS)
 255
 256 option(GMX_GPU  "Enable GPU acceleration" ON)
 257 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 258
 259 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 260
 261 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 262 mark_as_advanced(GMX_GIT_VERSION_INFO)
 263
 264 if(UNIX)
 265     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 266 endif()
 267 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 268
 269 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 270 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 271
 272 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 273 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 274
 275 option(GMX_BUILD_FOR_COVERAGE
 276        "Tune build for better code coverage metrics (e.g., disable asserts)"
 277        OFF)
 278 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 279
 280
 281 ######################################################################
 282 # Detect OpenMP support
 283 ######################################################################
 284 # The OpenMP detection _must_ come before tests for other CFLAGS.
 285 include(gmxManageOpenMP)
 286
 287
 288
 289 ######################################################################
 290 # Compiler tests
 291 # These need to be done early (before further tests).
 292 #####################################################################
 293
 294 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 295 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 296 # invalid options with the Intel Compilers.
 297 # These files should be removed from the source tree when a CMake version that
 298 # includes the features in question becomes required for building GROMACS.
 299 include(CheckCCompilerFlag)
 300 include(CheckCXXCompilerFlag)
 301
 302
 303 include(gmxCFlags)
 304 gmx_c_flags()
 305
 306 # This variable should be used for additional compiler flags which are not
 307 # generated in gmxCFlags nor are SIMD or MPI related.
 308 set(EXTRA_C_FLAGS "")
 309 set(EXTRA_CXX_FLAGS "")
 310
 311 # Run through a number of tests for buggy compilers and other issues
 312 include(gmxTestCompilerProblems)
 313 gmx_test_compiler_problems()
 314
 315
 316 set(PKG_CFLAGS "")
 317 if(GMX_DOUBLE)
 318     add_definitions(-DGMX_DOUBLE)
 319     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 320 endif(GMX_DOUBLE)
 321 if(GMX_SOFTWARE_INVSQRT)
 322   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 323 endif(GMX_SOFTWARE_INVSQRT)
 324
 325
 326
 327 ########################################################################
 328 # Basic system tests (standard libraries, headers, functions, types)   #
 329 ########################################################################
 330 include(CheckIncludeFiles)
 331 include(CheckIncludeFileCXX)
 332 check_include_files(unistd.h     HAVE_UNISTD_H)
 333 check_include_files(pwd.h        HAVE_PWD_H)
 334 check_include_files(dirent.h     HAVE_DIRENT_H)
 335 check_include_files(time.h       HAVE_TIME_H)
 336 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 337 check_include_files(io.h         HAVE_IO_H)
 338 check_include_files(sched.h      HAVE_SCHED_H)
 339
 340 check_include_files(regex.h      HAVE_POSIX_REGEX)
 341 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 342 # TODO: It could be nice to inform the user if no regex support is found,
 343 # as selections won't be fully functional.
 344
 345 include(CheckFunctionExists)
 346 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 347 check_function_exists(memalign          HAVE_MEMALIGN)
 348 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 349 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 350 check_function_exists(fsync             HAVE_FSYNC)
 351 check_function_exists(_fileno           HAVE__FILENO)
 352 check_function_exists(fileno            HAVE_FILENO)
 353 check_function_exists(_commit           HAVE__COMMIT)
 354 check_function_exists(sigaction         HAVE_SIGACTION)
 355 check_function_exists(sysconf           HAVE_SYSCONF)
 356 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 357 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 358 check_function_exists(rsqrt             HAVE_RSQRT)
 359 check_function_exists(rsqrtf            HAVE_RSQRTF)
 360 check_function_exists(sqrtf             HAVE_SQRTF)
 361
 362 include(CheckLibraryExists)
 363 check_library_exists(m sqrt "" HAVE_LIBM)
 364 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 365
 366 include(TestBigEndian)
 367 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 368
 369 # Management of GROMACS options for specific toolchains should go
 370 # here. Because the initial settings for some of the main options have
 371 # already happened, but things like library detection and MPI compiler
 372 # feature detection have not, the docstrings for any over-rides of
 373 # GROMACS defaults or user settings will make sense. Also, any
 374 # toolchain-related reasons for choosing whether to detect various
 375 # things can be sorted out now, before the detection takes place.
 376 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 377     include(gmxManageBlueGene)
 378 endif()
 379
 380 ########################################################################
 381 #Process MPI settings
 382 ########################################################################
 383 include(gmxManageMPI)
 384
 385
 386 ########################################################################
 387 #Process shared/static library settings
 388 ########################################################################
 389 include(gmxManageSharedLibraries)
 390
 391
 392 ########################################################################
 393 # Find external packages                                               #
 394 ########################################################################
 395
 396 # Unconditionally find the package, as it is also required for unit
 397 # tests. This exports LIBXML2_FOUND, which we should not use because
 398 # it does not tell us that linking will succeed. Instead, we test that
 399 # next.
 400 find_package(LibXml2)
 401 include(gmxTestLibXml2)
 402 gmx_test_libxml2(HAVE_LIBXML2)
 403 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 404 set(PKG_XML "")
 405 mark_as_advanced(GMX_XML)
 406 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 407 #if(GMX_XML AND NOT HAVE_LIBXML2)
 408 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 409 #endif()
 410 #if(GMX_XML)
 411 #    include_directories(${LIBXML2_INCLUDE_DIR})
 412 #    set(PKG_XML libxml-2.0)
 413 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 414 #endif(GMX_XML)
 415
 416 option(GMX_GSL "Add support for gsl" OFF)
 417 if (GMX_GSL)
 418   find_package(GSL)
 419   set(PKG_GSL "")
 420   if(GSL_FOUND)
 421     include_directories(${GSL_INCLUDE_DIR})
 422     set(PKG_GSL gsl)
 423     set(HAVE_LIBGSL 1)
 424   endif(GSL_FOUND)
 425 endif (GMX_GSL)
 426
 427 option(GMX_X11 "Use X window system" OFF)
 428 if (GMX_X11)
 429     find_package(X11)
 430     # X11 includes/libraries are only set in the ngmx subdirectory!
 431     if(NOT X11_FOUND)
 432         message(FATAL_ERROR
 433                 "X11 include files and/or libraries were not found. "
 434                 "Set GMX_X11=OFF to compile without X11 support. "
 435                 "gmx view will not be available.")
 436     endif()
 437     include_directories(${X11_INCLUDE_DIR})
 438 endif(GMX_X11)
 439
 440 include(ThreadMPI)
 441 set(THREAD_MPI_LIB thread_mpi)
 442 # Enable core threading facilities
 443 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 444 # Enable tMPI C++ support
 445 tmpi_enable_cxx()
 446 if(GMX_THREAD_MPI)
 447     # enable MPI functions
 448     tmpi_enable()
 449     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 450     set(GMX_MPI 1)
 451     set(MPI_IN_PLACE_EXISTS 1)
 452 endif(GMX_THREAD_MPI)
 453 tmpi_get_source_list(THREAD_MPI_SRC)
 454 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 455 if (TMPI_ATOMICS_DISABLED)
 456    add_definitions(-DTMPI_ATOMICS_DISABLED)
 457 endif()
 458
 459 if(GMX_GPU)
 460     # now that we have detected the dependencies, do the second configure pass
 461     gmx_gpu_setup()
 462 endif(GMX_GPU)
 463
 464 if(CYGWIN)
 465     set(GMX_CYGWIN 1)
 466 endif(CYGWIN)
 467
 468 if(WIN32 AND NOT CYGWIN)
 469     set(GMX_NATIVE_WINDOWS 1)
 470     # This makes windows.h not declare min/max as macros that would break
 471     # C++ code using std::min/std::max.
 472     add_definitions(-DNOMINMAX)
 473 endif()
 474
 475 # only bother with finding git and using version.h if the source is a git repo
 476 if(GMX_GIT_VERSION_INFO)
 477     if (NOT SOURCE_IS_GIT_REPOSITORY)
 478         message(FATAL_ERROR
 479             "Cannot generate git version information from source tree not under git. "
 480             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 481     endif ()
 482     # We need at least git v1.5.3 be able to parse git's date output. If not
 483     # found or the version is too small, we can't generate version information.
 484     find_package(Git)
 485
 486     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 487         message(FATAL_ERROR
 488             "No compatible git version found (>= 1.5.3 required). "
 489             "Won't be able to generate development version information. "
 490             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 491     endif()
 492 endif()
 493
 494 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 495 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 496 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 497     find_package(Boost 1.44.0)
 498     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 499         set(Boost_FOUND FALSE)
 500     endif()
 501     # Print the notification only on first run, when determining the default
 502     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 503         message("Boost >= 1.44 not found. Using minimal internal version. "
 504                 "This may cause trouble if you plan on compiling/linking other "
 505                 "software that uses Boost against Gromacs.")
 506     endif()
 507 endif()
 508 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 509        ${Boost_FOUND})
 510 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 511     message(FATAL_ERROR
 512         "Boost >= 1.44 not found. "
 513         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 514         "version of Boost included with Gromacs.")
 515 endif()
 516
 517 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 518 mark_as_advanced(GMX_BUILD_UNITTESTS)
 519 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 520 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 521     message(FATAL_ERROR
 522         "Cannot build unit tests without libxml2. "
 523         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 524 endif()
 525
 526 ########################################################################
 527 # Generate development version info for cache
 528 ########################################################################
 529 # set(GEN_VERSION_INFO_INTERNAL "ON")
 530 # include(gmxGenerateVersionString)
 531
 532 ########################################################################
 533 # Our own GROMACS tests
 534 ########################################################################
 535
 536 add_definitions( -DHAVE_CONFIG_H )
 537 include_directories(${CMAKE_SOURCE_DIR}/src)
 538 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 539 include_directories(${CMAKE_BINARY_DIR}/src)
 540 # Required for gmx_header_config_gen.h to be found before installation
 541 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 542 # Required for now to make old code compile
 543 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 544
 545 include(gmxTestInlineASM)
 546 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 547
 548 include(gmxSetBuildInformation)
 549 gmx_set_build_information()
 550 # Turn on RDTSCP if:
 551 # - the build system's CPU supports it
 552 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 553 #   at this point means that the user set it).
 554 # Note: it's better to not use the later set value of GMX_SIMD because
 555 # it reflects the system's capability of both compiling and running AVX code.
 556 # TODO: After merge with 5.0 one could implement a cache variable dependency
 557 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 558 # after the first cmake pass.
 559 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 560     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 561 else()
 562     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 563 endif()
 564 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 565 mark_as_advanced(GMX_USE_RDTSCP)
 566 if(GMX_USE_RDTSCP)
 567     set(HAVE_RDTSCP 1)
 568 endif()
 569
 570 include(gmxTestFloatFormat)
 571 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 572                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 573                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 574
 575 include(gmxTestLargeFiles)
 576 gmx_test_large_files(GMX_LARGEFILES)
 577
 578 include(gmxTestSignal)
 579 gmx_test_sigusr1(HAVE_SIGUSR1)
 580
 581 include(gmxTestInline)
 582 gmx_test_inline(INLINE_KEYWORD)
 583
 584 include(gmxTestRestrict)
 585 gmx_test_restrict(RESTRICT_KEYWORD)
 586
 587 include(gmxTestPipes)
 588 gmx_test_pipes(HAVE_PIPES)
 589
 590 include(gmxTestIsfinite)
 591 gmx_test_isfinite(HAVE_ISFINITE)
 592 gmx_test__isfinite(HAVE__ISFINITE)
 593 gmx_test__finite(HAVE__FINITE)
 594
 595 include(gmxTestCXX11)
 596 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 597 include(CMakeDependentOption)
 598 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 599 # entirely to keep the compilation environment uniform.
 600 cmake_dependent_option(GMX_CXX11
 601     "Use C++11 features"
 602     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 603 mark_as_advanced(GMX_CXX11)
 604 if(GMX_CXX11)
 605     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 606 endif()
 607
 608
 609 include(gmxTestXDR)
 610 gmx_test_xdr(GMX_SYSTEM_XDR)
 611 if(NOT GMX_SYSTEM_XDR)
 612     set(GMX_INTERNAL_XDR 1)
 613 endif(NOT GMX_SYSTEM_XDR)
 614
 615
 616 ##################################################
 617 # Process SIMD instruction settings
 618 ##################################################
 619 # This checks what flags to add in order to
 620 # support the SIMD instructions we need, and sets
 621 # correct defines for the SIMD instructions supported.
 622 include(gmxTestSimd)
 623 gmx_test_simd()
 624
 625
 626 # Process QM/MM Settings
 627 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 628     set(GMX_QMMM_GAUSSIAN 1)
 629 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 630     set(GMX_QMMM_MOPAC 1)
 631 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 632     set(GMX_QMMM_GAMESS 1)
 633 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 634     set(GMX_QMMM_ORCA 1)
 635 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 636     # nothing to do
 637 else()
 638     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 639 endif()
 640
 641
 642 ##################################################
 643 # Process FFT library settings
 644 ##################################################
 645 include(gmxManageFFTLibraries)
 646
 647
 648 include(gmxManageLinearAlgebraLibraries)
 649
 650 # Whether GROMACS will really try to compile support for VMD plugins
 651 set(GMX_USE_PLUGINS OFF)
 652
 653 if(GMX_LOAD_PLUGINS)
 654   if(CYGWIN OR NOT WIN32)
 655     # Native Windows does not have, nor need dlopen
 656     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 657     include(gmxTestdlopen)
 658     gmx_test_dlopen(HAVE_DLOPEN)
 659   endif()
 660
 661   # so, should we use plug-ins?
 662   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 663     if(NOT VMD_QUIETLY)
 664       MESSAGE(STATUS
 665           "Found the ability to use plug-ins when building shared libaries, "
 666           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 667           "formats).")
 668     endif()
 669     if(NOT GMX_VMD_PLUGIN_PATH)
 670       find_package(VMD)
 671     endif()
 672     set(GMX_USE_PLUGINS ON)
 673     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 674     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 675   else()
 676     set(PKG_DL_LIBS)
 677   endif()
 678 endif(GMX_LOAD_PLUGINS)
 679 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 680
 681 # Link real-time library for POSIX timers. The check for clock_gettime
 682 # confirms the linkability of rt.
 683 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 684     list(APPEND GMX_EXTRA_LIBRARIES rt)
 685 endif()
 686
 687 # Math and thread libraries must often come after all others when linking...
 688 if(HAVE_LIBM)
 689     list(APPEND GMX_EXTRA_LIBRARIES m)
 690 endif(HAVE_LIBM)
 691
 692 option(GMX_NACL "Configure for Native Client builds" OFF)
 693 if (GMX_NACL)
 694   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 695   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 696   set(GMX_NO_NICE 1)
 697   set(GMX_NO_RENAME 1)
 698 endif()
 699 mark_as_advanced(GMX_NACL)
 700
 701 if(GMX_FAHCORE)
 702   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 703       "Path to swindirect.h")
 704   include_directories(${COREWRAP_INCLUDE_DIR})
 705 endif(GMX_FAHCORE)
 706
 707 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 708 mark_as_advanced(GMX_BUILD_HELP)
 709 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 710     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 711
 712     message(FATAL_ERROR
 713         "Rebuilding HTML and man pages is not supported for in-source "
 714         "builds from a source distribution. "
 715         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 716 endif()
 717
 718 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 719 # these are set after everything else
 720 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 721     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 722     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 723     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 724     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 725 else()
 726     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 727     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 728     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 729     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 730     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 731     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 732     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 733     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 734     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 735 endif()
 736
 737 if(NOT GMX_OPENMP)
 738     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 739     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 740     unset(OpenMP_C_FLAGS CACHE)
 741     unset(OpenMP_CXX_FLAGS CACHE)
 742 else()
 743     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 744     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 745 endif()
 746 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 747
 748 ########################################################################
 749 # Specify install locations
 750 ########################################################################
 751 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 752     "Library installation directory (default: lib)")
 753 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 754     "Data installation directory under share/ (default: gromacs)")
 755 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 756
 757 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 758 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 759 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 760 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 761 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 762
 763 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 764 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 765
 766 # Binary and library suffix options
 767 include(gmxManageSuffixes)
 768
 769 ##################################################################
 770 # Shared library settings
 771 ##################################################################
 772 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 773     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 774         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 775     endif()
 776     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 777     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 778 else()
 779     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 780         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 781         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 782     else()
 783         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 784     endif()
 785 endif()
 786
 787 #COPYING file: Only necessary for binary distributions.
 788 #Simpler to always install.
 789 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 790
 791 if(GMX_EXTERNAL_BOOST)
 792     include_directories(${Boost_INCLUDE_DIRS})
 793     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 794 else()
 795     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 796     # typeid not supported for minimal internal version
 797     # (would add significant amount of code)
 798     add_definitions(-DBOOST_NO_TYPEID)
 799     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 800     # (from share/template/)
 801     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 802     if (NOT GMX_BUILD_MDRUN_ONLY)
 803         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 804                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 805                 COMPONENT development)
 806     endif ()
 807 endif()
 808
 809 if(GMX_USE_TNG)
 810     find_package(ZLIB)
 811     include(gmxTestZLib)
 812     gmx_test_zlib(HAVE_ZLIB)
 813     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 814     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 815     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 816     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 817     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 818     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 819     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 820     set(GMX_TNG_LIBRARIES tng_io)
 821 endif()
 822 mark_as_advanced(TNG_BUILD_FORTRAN)
 823 mark_as_advanced(TNG_BUILD_EXAMPLES)
 824 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 825 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 826 mark_as_advanced(TNG_BUILD_TEST)
 827 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 828
 829 if (GMX_BUILD_FOR_COVERAGE)
 830     # Code heavy with asserts makes conditional coverage close to useless metric,
 831     # as by design most of the false branches are impossible to trigger in
 832     # correctly functioning code.  And the benefit of testing those that could
 833     # be triggered by using an API against its specification isn't usually
 834     # worth the effort.
 835     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 836 endif ()
 837
 838 if (BUILD_TESTING)
 839     # "tests" target builds all the separate test binaries.
 840     add_custom_target(tests)
 841     # "run-ctest" is an internal target that actually runs the tests.
 842     # This is necessary to be able to add separate targets that execute as part
 843     # of 'make check', but are ensured to be executed after the actual tests.
 844     add_custom_target(run-ctest
 845                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 846                       COMMENT "Running all tests"
 847                       VERBATIM)
 848     add_dependencies(run-ctest tests)
 849     # "check" target builds and runs all tests.
 850     add_custom_target(check DEPENDS run-ctest)
 851 endif()
 852
 853 if (NOT GMX_BUILD_MDRUN_ONLY)
 854     add_subdirectory(doxygen)
 855     add_subdirectory(share)
 856     add_subdirectory(scripts)
 857 endif ()
 858 add_subdirectory(src)
 859
 860 if (BUILD_TESTING)
 861     add_subdirectory(tests)
 862 endif()
 863
 864 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 865 # Don't bother the user after the first configure pass.
 866 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 867     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 868 endif()
 869 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 870
 871 #######################
 872 ## uninstall target
 873 #######################
 874     CONFIGURE_FILE(
 875                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 876                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 877                    IMMEDIATE @ONLY)
 878 ###########################
 879 ADD_CUSTOM_TARGET(uninstall
 880                   "${CMAKE_COMMAND}" -P
 881                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 882 ###########################
 883
 884 ########################################################################
 885 # Manual                                                               #
 886 ########################################################################
 887
 888 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 889 mark_as_advanced(GMX_BUILD_MANUAL)
 890 if(GMX_BUILD_MANUAL)
 891     # Make sure we only do detection of manual-building dependencies
 892     # when the user opted in for that.
 893     add_subdirectory(manual)
 894 endif()