CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 include(gmxManageCcache)
  44
  45 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  46 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  47 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  48
  49 # Set up common version variables, as well as general information about
  50 # the build tree (whether the build is from a source package or from a git
  51 # repository).  Also declares a few functions that will be used for generating
  52 # version info files later.
  53 include(gmxBuildTreeInfo)
  54 include(gmxVersionInfo)
  55
  56 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  57     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  58 endif()
  59 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  60     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  61 endif()
  62
  63 include(gmxBuildTypeReference)
  64 include(gmxBuildTypeProfile)
  65 include(gmxBuildTypeTSAN)
  66 include(gmxBuildTypeASAN)
  67 include(gmxBuildTypeMSAN)
  68 include(gmxBuildTypeReleaseWithAssert)
  69
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  72     # Set the possible values of build type for cmake-gui
  73     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  74         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  75 endif()
  76 if(CMAKE_CONFIGURATION_TYPES)
  77     # Add appropriate GROMACS-specific build types for the Visual
  78     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  79     # are already present by default).
  80     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  81     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  82     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  83         "List of configuration types"
  84         FORCE)
  85 endif()
  86 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  87
  88 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  89
  90 include(gmxCTestUtilities)
  91 gmx_ctest_init()
  92
  93 include(gmxCPackUtilities)
  94 gmx_cpack_init()
  95
  96 # Variables that accumulate stuff influencing the installed headers
  97 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  98 set(INSTALLED_HEADER_DEFINITIONS "")
  99
 100 ########################################################################
 101 # Global non-cache variables for implementing the build system
 102 ########################################################################
 103
 104 # These variables collect libraries that GROMACS requires for
 105 # linking. They should be appended to with list(APPEND ${name}
 106 # new-library) calls. They are:
 107 #  - Libraries that are required for libgromacs (only)
 108 set(GMX_EXTRA_LIBRARIES "")
 109 #  - Libraries that are required for all code in the repository
 110 set(GMX_COMMON_LIBRARIES "")
 111 #  - Libraries that all code linked against libgromacs needs
 112 #    (i.e., something that is exposed in installed headers).
 113 set(GMX_PUBLIC_LIBRARIES "")
 114
 115 ########################################################################
 116 # Check and warn if cache generated on a different host is being reused
 117 ########################################################################
 118 if(CMAKE_HOST_UNIX)
 119     execute_process(COMMAND hostname
 120                     OUTPUT_VARIABLE TMP_HOSTNAME
 121                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 122     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 123         message(WARNING "
 124             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 125             is being reused! This could lead to inconsistencies; therefore, it is
 126             recommended to regenerate the cache!")
 127     endif()
 128     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 129             "Hostname of the machine where the cache was generated.")
 130 endif()
 131
 132 ########################################################################
 133 # Detect architecture before setting options so we can alter defaults
 134 ########################################################################
 135 # Detect the architecture the compiler is targetting, detect
 136 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 137 # to use if none is specified, and populate the cache option for CPU
 138 # SIMD.
 139 include(gmxDetectTargetArchitecture)
 140 gmx_detect_target_architecture()
 141
 142 # Permit the user to specify a particular standard library, e.g. compiling
 143 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 144 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 145 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 146 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 147 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 148
 149 include(CheckCCompilerFlag)
 150 include(CheckCXXCompilerFlag)
 151
 152 # This must come early, since some of our configuration flag tests
 153 # depend on being able to compile C++11 source files.
 154 include(gmxTestCXX11)
 155 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 156
 157 # Make sure all C++ code will be compiled in C++11 mode, with the
 158 # expected standard library.
 159 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 160
 161 ########################################################################
 162 # User input options                                                   #
 163 ########################################################################
 164 include(gmxOptionUtilities)
 165
 166 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 167
 168 # Fujitsu only has SIMD in double precision, so this will be faster
 169 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 170 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 171 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 172 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 173
 174 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 175 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 176 gmx_dependent_option(
 177     GMX_MPI_IN_PLACE
 178     "Enable MPI_IN_PLACE for MPIs that have it defined"
 179     ON
 180     GMX_MPI)
 181 mark_as_advanced(GMX_MPI_IN_PLACE)
 182
 183 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 184
 185 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 186 mark_as_advanced(GMX_FAHCORE)
 187
 188 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 189 mark_as_advanced(GMX_COOL_QUOTES)
 190 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 191
 192 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 193
 194 # Decide on GPU settings based on user-settings and GPU/CUDA
 195 # detection. VS2017 requires CUDA 9.0, for the other arch/compilers
 196 # rest we require CUDA 7.0 or later (including for clang-CUDA).
 197 if(MSVC)
 198     set(REQUIRED_CUDA_VERSION 9.0)
 199 else()
 200     set(REQUIRED_CUDA_VERSION 7.0)
 201 endif()
 202 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 203
 204 # OpenCL required version: 1.2 or newer
 205 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 206 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 207 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 208
 209 if(NOT GMX_USE_OPENCL)
 210     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 211     include(gmxManageGPU)
 212     set(GMX_USE_CUDA ${GMX_GPU})
 213     if(GMX_GPU)
 214         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 215     else()
 216         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 217     endif()
 218 else()
 219     #Now the OpenCL path (for both AMD and NVIDIA)
 220     if(GMX_GPU)
 221         include(gmxManageOpenCL)
 222         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 223     else()
 224         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 225     endif()
 226 endif()
 227
 228 gmx_option_multichoice(
 229     GMX_SIMD
 230     "SIMD instruction set for CPU kernels and compiler optimization"
 231     "AUTO"
 232     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 233
 234 if(GMX_TARGET_MIC)
 235     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 236 else()
 237     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 238 endif()
 239
 240 gmx_option_multichoice(
 241     GMX_FFT_LIBRARY
 242     "FFT library"
 243     "${GMX_FFT_LIBRARY_DEFAULT}"
 244     fftw3 mkl "fftpack[built-in]")
 245 gmx_dependent_option(
 246     GMX_BUILD_OWN_FFTW
 247     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 248     OFF
 249     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 250 gmx_dependent_option(
 251     GMX_DISABLE_FFTW_MEASURE
 252     "Do not optimize FFTW setups (not needed with SSE)"
 253     OFF
 254     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 255 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 256 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 257
 258 gmx_option_multichoice(
 259     GMX_QMMM_PROGRAM
 260     "QM package for QM/MM"
 261     None
 262     none gaussian mopac gamess orca)
 263
 264 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 265 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 266
 267 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 268
 269 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 270 mark_as_advanced(GMX_BROKEN_CALLOC)
 271
 272 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 273
 274 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 275
 276 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 277
 278 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 279 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 280
 281 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 282 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 283
 284 option(GMX_BUILD_FOR_COVERAGE
 285        "Tune build for better code coverage metrics (e.g., disable asserts)"
 286        OFF)
 287 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 288
 289 option(GMX_DEVELOPER_BUILD
 290     "Enable Developer convenience features: always build unit-tests"
 291     OFF)
 292 mark_as_advanced(GMX_DEVELOPER_BUILD)
 293
 294 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 295 option(GMX_COMPILER_WARNINGS
 296     "Enable a default set of compiler warnings"
 297     ${GMX_COMPILER_WARNINGS_DEFAULT})
 298 mark_as_advanced(GMX_COMPILER_WARNINGS)
 299 # Always turn on compiler warnings with a developer build.
 300 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 301
 302 option(GMX_BUILD_SHARED_EXE
 303     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 304     ON)
 305 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 306
 307 option(GMX_PHYSICAL_VALIDATION
 308        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 309        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 310        OFF)
 311 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 312
 313 ######################################################################
 314 # Detect OpenMP support
 315 ######################################################################
 316 # The OpenMP detection _must_ come before tests for other CFLAGS.
 317 include(gmxManageOpenMP)
 318
 319
 320
 321 ######################################################################
 322 # Compiler tests
 323 # These need to be done early (before further tests).
 324 #####################################################################
 325
 326 include(gmxCFlags)
 327 gmx_c_flags()
 328
 329 # This variable should be used for additional compiler flags which are not
 330 # generated in gmxCFlags nor are SIMD or MPI related.
 331 #
 332 # TODO These variables should be consolidated into
 333 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 334 # things that work in C compilation (e.g. merging from old branches)
 335 # also work for C++ compilation.
 336 set(EXTRA_C_FLAGS "")
 337 set(EXTRA_CXX_FLAGS "")
 338
 339 # Run through a number of tests for buggy compilers and other issues
 340 include(gmxTestCompilerProblems)
 341 gmx_test_compiler_problems()
 342
 343 # Implement double-precision option. This is complicated because we
 344 # need installed headers to use the precision mode of the build that
 345 # produced the library, but cannot use config.h in that case. We also
 346 # want such variables to always have a definition, because #if is more
 347 # robust than #ifdef. So, we put this value on the compiler command
 348 # line in all cases.
 349 #
 350 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 351 # because no installed header needs it
 352 if(GMX_DOUBLE)
 353     set(GMX_DOUBLE_VALUE 1)
 354 else()
 355     set(GMX_DOUBLE_VALUE 0)
 356 endif()
 357 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 358 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 359
 360 if(WIN32)
 361     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 362     add_definitions(-DGMX_HAVE_WINSOCK)
 363 endif()
 364
 365
 366
 367 ########################################################################
 368 # Basic system tests (standard libraries, headers, functions, types)   #
 369 ########################################################################
 370 include(CheckIncludeFiles)
 371 include(CheckIncludeFileCXX)
 372 check_include_files(unistd.h     HAVE_UNISTD_H)
 373 check_include_files(pwd.h        HAVE_PWD_H)
 374 check_include_files(dirent.h     HAVE_DIRENT_H)
 375 check_include_files(time.h       HAVE_TIME_H)
 376 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 377 check_include_files(io.h         HAVE_IO_H)
 378 check_include_files(sched.h      HAVE_SCHED_H)
 379
 380 check_include_files(regex.h      HAVE_POSIX_REGEX)
 381 # TODO: It could be nice to inform the user if no regex support is found,
 382 # as selections won't be fully functional.
 383
 384 include(CheckCXXSymbolExists)
 385 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 386 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 387 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 388 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 389 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 390 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 391 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 392 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 393
 394 # We cannot check for the __builtins as symbols, but check if code compiles
 395 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 396 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 397 if(MSVC)
 398     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 399     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 400 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 401     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 402     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 403 endif()
 404
 405 include(CheckLibraryExists)
 406 find_library(HAVE_LIBM m)
 407 mark_as_advanced(HAVE_LIBM)
 408 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 409 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 410 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 411
 412 include(TestSchedAffinity)
 413 test_sched_affinity(HAVE_SCHED_AFFINITY)
 414
 415 # Aligned memory allocation. We need to check for both mm_malloc(),
 416 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 417 include(gmxTestMMMalloc)
 418 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 419 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 420 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 421 if(MSVC)
 422     # No need to waste time on this test on platforms where it will never be true
 423     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 424 endif()
 425
 426 include(TestBigEndian)
 427 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 428
 429 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 430
 431 # Management of GROMACS options for specific toolchains should go
 432 # here. Because the initial settings for some of the main options have
 433 # already happened, but things like library detection and MPI compiler
 434 # feature detection have not, the docstrings for any over-rides of
 435 # GROMACS defaults or user settings will make sense. Also, any
 436 # toolchain-related reasons for choosing whether to detect various
 437 # things can be sorted out now, before the detection takes place.
 438 if(GMX_TARGET_FUJITSU_SPARC64)
 439     include(gmxManageFujitsuSparc64)
 440 endif()
 441
 442 ########################################################################
 443 #Process MPI settings
 444 ########################################################################
 445 include(gmxManageMPI)
 446
 447 ########################################################################
 448 #Process MiMiC settings
 449 ########################################################################
 450 include(gmxManageMimic)
 451
 452 ########################################################################
 453 #Process shared/static library settings
 454 ########################################################################
 455 include(gmxManageSharedLibraries)
 456
 457
 458 ########################################################################
 459 # Find external packages                                               #
 460 ########################################################################
 461
 462 # Unconditionally find the package, as it is also required for unit
 463 # tests. This exports LIBXML2_FOUND, which we should not use because
 464 # it does not tell us that linking will succeed. Instead, we test that
 465 # next.
 466 #if(DEFINED LIBXML2_LIBRARIES)
 467 #  set(LibXml2_FIND_QUIETLY TRUE)
 468 #endif()
 469 #find_package(LibXml2)
 470 #include(gmxTestLibXml2)
 471 #gmx_test_libxml2(HAVE_LIBXML2)
 472 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 473 #set(PKG_XML "")
 474 #mark_as_advanced(GMX_XML)
 475 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 476 #if(GMX_XML AND NOT HAVE_LIBXML2)
 477 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 478 #endif()
 479 #if(GMX_XML)
 480 #    include_directories(${LIBXML2_INCLUDE_DIR})
 481 #    set(PKG_XML libxml-2.0)
 482 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 483 #endif()
 484
 485 gmx_option_trivalue(
 486     GMX_HWLOC
 487     "Use hwloc portable hardware locality library"
 488     "AUTO")
 489
 490 if (GMX_HWLOC)
 491     # Find quietly the second time.
 492     if(DEFINED HWLOC_LIBRARIES)
 493         set(Hwloc_FIND_QUIETLY TRUE)
 494     endif()
 495     find_package(Hwloc 1.5)
 496
 497     if (HWLOC_FOUND)
 498         if (HWLOC_LIBRARIES MATCHES ".a$")
 499             set(_STATIC_HWLOC TRUE)
 500         endif()
 501
 502         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 503         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 504             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 505             set(GMX_USE_HWLOC OFF)
 506         else()
 507             set(GMX_USE_HWLOC ON)
 508         endif()
 509
 510         if (GMX_USE_HWLOC)
 511             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 512             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 513         endif()
 514     elseif(GMX_HWLOC_FORCE)
 515         message(FATAL_ERROR "Hwloc package support required, but not found.")
 516     endif()
 517 endif()
 518
 519 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 520 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 521 if(GMX_EXTERNAL_TINYXML2)
 522     # Find an external TinyXML-2 library.
 523     find_package(TinyXML-2 3.0.0)
 524     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 525     if(NOT HAVE_TINYXML2)
 526         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 527     endif()
 528 endif()
 529
 530 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 531 mark_as_advanced(GMX_EXTRAE)
 532
 533 if (GMX_EXTRAE)
 534   find_package(EXTRAE)
 535   if(EXTRAE_FOUND)
 536     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 537     set(HAVE_EXTRAE 1)
 538   else()
 539     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 540   endif()
 541 endif()
 542
 543 option(GMX_X11 "Use X window system" OFF)
 544 if (GMX_X11)
 545     find_package(X11)
 546     # X11 includes/libraries are only set in the ngmx subdirectory!
 547     if(NOT X11_FOUND)
 548         message(FATAL_ERROR
 549                 "X11 include files and/or libraries were not found. "
 550                 "Set GMX_X11=OFF to compile without X11 support. "
 551                 "gmx view will not be available.")
 552     endif()
 553     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 554 endif()
 555
 556 include(ThreadMPI)
 557 # Enable core threading facilities
 558 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 559 if(GMX_THREAD_MPI)
 560     # enable MPI functions
 561     tmpi_enable()
 562     set(MPI_IN_PLACE_EXISTS 1)
 563 endif()
 564 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 565 if (TMPI_ATOMICS_DISABLED)
 566    add_definitions(-DTMPI_ATOMICS_DISABLED)
 567 endif()
 568
 569 include(gmxManageTNG)
 570
 571 include(gmxManageLmfit)
 572
 573 if(GMX_GPU)
 574     # now that we have detected the dependencies, do the second configure pass
 575     gmx_gpu_setup()
 576     if (GMX_CLANG_CUDA)
 577         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 578         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 579     endif()
 580 endif()
 581
 582 if(CYGWIN)
 583     set(GMX_CYGWIN 1)
 584 endif()
 585
 586 if(WIN32)
 587     set(GMX_NATIVE_WINDOWS 1)
 588     # This makes windows.h not declare min/max as macros that would break
 589     # C++ code using std::min/std::max.
 590     add_definitions(-DNOMINMAX)
 591 endif()
 592
 593 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 594     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 595         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 596     endif()
 597     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 598         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 599     endif()
 600 endif()
 601
 602 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 603 mark_as_advanced(GMX_BUILD_UNITTESTS)
 604 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 605
 606 ########################################################################
 607 # Our own GROMACS tests
 608 ########################################################################
 609
 610 add_definitions( -DHAVE_CONFIG_H )
 611 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 612 # TODO required at high level because both libgromacs and progs/mdrun
 613 # require it, both for thread-MPI and its atomics and mutexes.
 614 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 615 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 616 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 617
 618 include(gmxTestInlineASM)
 619 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 620
 621 include(gmxSetBuildInformation)
 622 gmx_set_build_information()
 623
 624 gmx_option_multichoice(
 625     GMX_USE_RDTSCP
 626     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 627     "AUTO"
 628     OFF ON AUTO DETECT)
 629 mark_as_advanced(GMX_USE_RDTSCP)
 630
 631 macro(gmx_check_rdtscp)
 632     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 633         set(HAVE_RDTSCP 1)
 634         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 635     else()
 636         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 637     endif()
 638 endmacro()
 639
 640 set(HAVE_RDTSCP 0)
 641 if (GMX_USE_RDTSCP STREQUAL "ON")
 642     set(HAVE_RDTSCP 1)
 643 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 644     gmx_check_rdtscp()
 645 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 646     # If the user specified automated SIMD selection, that the choice
 647     # is made based on detection on the build host. If so, then RDTSCP
 648     # should be chosen the same way.
 649     #
 650     # If the user specified an AVX SIMD level (e.g. when
 651     # cross-compiling GROMACS) then they will get our best guess, ie
 652     # that in practice AVX mostly correlates with rdtscp (and anyway
 653     # is only relevant in rather old x86 hardware).
 654     if (GMX_SIMD STREQUAL "AUTO")
 655         gmx_check_rdtscp()
 656     elseif (GMX_SIMD MATCHES "AVX")
 657         set(HAVE_RDTSCP 1)
 658     endif()
 659 endif()
 660 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 661 if (HAVE_RDTSCP_CHANGED)
 662     if (HAVE_RDTSCP)
 663         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 664     else()
 665         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 666     endif()
 667 endif()
 668
 669 include(gmxTestLargeFiles)
 670 gmx_test_large_files(GMX_LARGEFILES)
 671
 672 include(gmxTestSignal)
 673 gmx_test_sigusr1(HAVE_SIGUSR1)
 674
 675 include(gmxTestPipes)
 676 gmx_test_pipes(HAVE_PIPES)
 677
 678 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 679
 680 include(gmxTestXDR)
 681 gmx_test_xdr(GMX_SYSTEM_XDR)
 682 # Darwin has system XDR, but it uses a three-argument flavour of
 683 # xdrproc_t that it guarantees will still work if you pass the normal
 684 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 685 # to do that, so it's simpler to just use our own XDR library.
 686 #
 687 # TODO It would be better to craft a cmake test which fails if such
 688 # XDR operations cause warnings, and succeeds otherwise, because it is
 689 # generally preferable to use system libraries where possible.
 690 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 691     set(GMX_INTERNAL_XDR 1)
 692 endif()
 693
 694
 695 ##################################################
 696 # Process SIMD instruction settings
 697 ##################################################
 698 # This checks what flags to add in order to
 699 # support the SIMD instructions we need, it sets
 700 # correct defines for the SIMD instructions supported,
 701 # and adds advanced options to control accuracy
 702 # for SIMD math operations.
 703 include(gmxManageSimd)
 704 gmx_manage_simd()
 705
 706 include(gmxManageCycleCounters)
 707 gmx_manage_cycle_counters()
 708
 709 # Process QM/MM Settings
 710 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 711     set(GMX_QMMM_GAUSSIAN 1)
 712 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 713     set(GMX_QMMM_MOPAC 1)
 714 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 715     set(GMX_QMMM_GAMESS 1)
 716 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 717     set(GMX_QMMM_ORCA 1)
 718 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 719     # nothing to do
 720 else()
 721     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 722 endif()
 723
 724
 725 ##################################################
 726 # Process FFT library settings
 727 ##################################################
 728 include(gmxManageFFTLibraries)
 729
 730
 731 include(gmxManageLinearAlgebraLibraries)
 732
 733 include(gmxManagePluginSupport)
 734
 735 if (GMX_USE_PLUGINS)
 736     if(NOT GMX_VMD_PLUGIN_PATH)
 737         find_package(VMD)
 738     endif()
 739 endif()
 740
 741 # Link real-time library for POSIX timers. The check for clock_gettime
 742 # confirms the linkability of rt.
 743 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 744     list(APPEND GMX_EXTRA_LIBRARIES rt)
 745 endif()
 746
 747 # Math and thread libraries must often come after all others when linking...
 748 if (HAVE_LIBM)
 749     list(APPEND GMX_PUBLIC_LIBRARIES m)
 750 endif()
 751
 752 option(GMX_NACL "Configure for Native Client builds" OFF)
 753 if (GMX_NACL)
 754   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 755   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 756   # TODO: Is this still necessary with the check for its presence?
 757   set(GMX_USE_NICE 0)
 758   set(GMX_NO_RENAME 1)
 759 endif()
 760 mark_as_advanced(GMX_NACL)
 761
 762 if(GMX_FAHCORE)
 763   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 764       "Path to swindirect.h")
 765   include_directories(${COREWRAP_INCLUDE_DIR})
 766 endif()
 767
 768 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 769 # produce warnings if that fails.
 770 set(build_help_default AUTO)
 771 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 772     set(build_help_default OFF)
 773 endif()
 774 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 775 mark_as_advanced(GMX_BUILD_HELP)
 776 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 777     message(FATAL_ERROR
 778         "Rebuilding shell completions or man pages is not supported for "
 779         "in-source builds from a source distribution. "
 780         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 781 endif()
 782
 783 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 784 # these are set after everything else
 785 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 786     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 787     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 788     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 789     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 790 else()
 791     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 792     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 793     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 794     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 795     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 796     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 797     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 798     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 799     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 800 endif()
 801
 802 ########################################################################
 803 # Specify install locations
 804 ########################################################################
 805 # Use GNUInstallDirs to set paths on multiarch systems.
 806 include(GNUInstallDirs)
 807
 808 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 809 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 810
 811 # Internal convenience so we do not have to join two path segments in the code
 812 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 813
 814 # If the nesting level wrt. the installation root is changed,
 815 # gromacs-config.cmake.cmakein needs to be adapted.
 816 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 817
 818 # TODO: Make GMXRC adapt if this is changed
 819 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 820 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 821
 822 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 823
 824 # Binary and library suffix options
 825 include(gmxManageSuffixes)
 826
 827 ################################################################
 828 # Shared library load path settings
 829 ################################################################
 830 if(NOT GMX_BUILD_SHARED_EXE)
 831     # No rpath
 832     set(CMAKE_SKIP_RPATH TRUE)
 833     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 834     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 835 else()
 836     # The build folder always has bin/ and lib/; if we are also going to
 837     # install to lib/, then the installation RPATH works also in the build
 838     # tree.  This makes installation slightly faster (no need to rewrite the
 839     # RPATHs), and makes the binaries in the build tree relocatable.
 840     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 841         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 842         if(POLICY CMP0068)
 843             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 844             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 845         endif()
 846     endif()
 847     # Set the RPATH as relative to the executable location to make the
 848     # binaries relocatable.
 849     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 850         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 851         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 852     else()
 853         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 854     endif()
 855     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 856     set(CMAKE_MACOSX_RPATH 1)
 857 endif()
 858
 859 #COPYING file: Only necessary for binary distributions.
 860 #Simpler to always install.
 861 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 862
 863 if (GMX_BUILD_FOR_COVERAGE)
 864     # Code heavy with asserts makes conditional coverage close to useless metric,
 865     # as by design most of the false branches are impossible to trigger in
 866     # correctly functioning code.  And the benefit of testing those that could
 867     # be triggered by using an API against its specification isn't usually
 868     # worth the effort.
 869     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 870 endif()
 871
 872 if (BUILD_TESTING)
 873     include(tests/CheckTarget.cmake)
 874 endif()
 875
 876 if (NOT GMX_BUILD_MDRUN_ONLY)
 877     find_package(ImageMagick QUIET COMPONENTS convert)
 878     include(gmxTestImageMagick)
 879     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 880     add_subdirectory(docs)
 881     add_subdirectory(share)
 882     add_subdirectory(scripts)
 883 endif()
 884 add_subdirectory(src)
 885
 886 if (BUILD_TESTING)
 887     add_subdirectory(tests)
 888 endif()
 889
 890 gmx_cpack_write_config()
 891
 892 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 893 # Don't bother the user after the first configure pass.
 894 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 895     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 896 endif()
 897 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 898
 899 #######################
 900 ## uninstall target
 901 #######################
 902 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 903                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 904                   IMMEDIATE @ONLY)
 905 ###########################
 906 ADD_CUSTOM_TARGET(uninstall
 907                   "${CMAKE_COMMAND}" -P
 908                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 909 ###########################
 910 set_directory_properties(PROPERTIES
 911             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")