CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif()
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98 include(gmxBuildTypeThreadSanitizer)
  99 include(gmxBuildTypeReleaseWithAssert)
 100
 101 if(NOT CMAKE_BUILD_TYPE)
 102     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 103     # There's no need to offer a user the choice of ThreadSanitizer
 104     # Set the possible values of build type for cmake-gui
 105     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 106         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 107 endif()
 108 if(CMAKE_CONFIGURATION_TYPES)
 109     # Add appropriate GROMACS-specific build types for the Visual
 110     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 111     # are already present by default).
 112     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 113     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 114     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 115         "List of configuration types"
 116         FORCE)
 117 endif()
 118 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 119
 120 enable_language(C)
 121 enable_language(CXX)
 122
 123 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 124 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 125 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 126 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 127 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 128 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 129 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 130 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 131 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 132 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 133 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 134
 135 #must come after all cpack settings!
 136 include(CPack)
 137
 138 # Set a default valgrind suppression file.
 139 # This unfortunately needs to duplicate information from CTest to work as
 140 # expected...
 141 set(MEMORYCHECK_SUPPRESSIONS_FILE
 142     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 143     CACHE FILEPATH
 144     "File that contains suppressions for the memory checker")
 145 include(CTest)
 146
 147 set(SOURCE_IS_GIT_REPOSITORY OFF)
 148 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 149 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 150     set(SOURCE_IS_GIT_REPOSITORY ON)
 151 endif()
 152 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 153     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 154 endif()
 155
 156 ########################################################################
 157 # Check and warn if cache generated on a different host is being reused
 158 ########################################################################
 159 if(CMAKE_HOST_UNIX)
 160     execute_process(COMMAND hostname
 161                     OUTPUT_VARIABLE TMP_HOSTNAME
 162                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 163     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 164         message(WARNING "
 165             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 166             is being reused! This could lead to inconsitencies; therefore, it is
 167             recommended to regenerate the cache!")
 168     endif()
 169     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 170             "Hostname of the machine where the cache was generated.")
 171 endif()
 172
 173 ########################################################################
 174 # User input options                                                   #
 175 ########################################################################
 176 include(gmxOptionUtilities)
 177
 178 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 179
 180 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 181 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 182 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 183 gmx_dependent_option(
 184     GMX_MPI_IN_PLACE
 185     "Enable MPI_IN_PLACE for MPIs that have it defined"
 186     ON
 187     GMX_MPI)
 188 mark_as_advanced(GMX_MPI_IN_PLACE)
 189 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 190 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 # decide on GPU settings based on user-settings and GPU/CUDA detection
 199 include(gmxManageGPU)
 200
 201 # Detect the architecture the compiler is targetting, detect
 202 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 203 # to use if none is specified, and populate the cache option for CPU
 204 # SIMD.
 205 include(gmxDetectTargetArchitecture)
 206 gmx_detect_target_architecture()
 207
 208 if(GMX_CPU_ACCELERATION)
 209     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 210     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 211 endif()
 212
 213 if(NOT GMX_TARGET_MIC)
 214     include(gmxDetectSimd)
 215     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 216 else()
 217     set(GMX_SUGGESTED_SIMD "None")
 218 endif()
 219
 220 gmx_option_multichoice(
 221     GMX_SIMD
 222     "SIMD instruction set for CPU kernels and compiler optimization"
 223     "${GMX_SUGGESTED_SIMD}"
 224     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 225
 226 gmx_option_multichoice(
 227     GMX_FFT_LIBRARY
 228     "FFT library"
 229     "fftw3"
 230     fftw3 mkl "fftpack[built-in]")
 231 gmx_dependent_option(
 232     GMX_BUILD_OWN_FFTW
 233     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 234     OFF
 235     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 236 gmx_dependent_option(
 237     GMX_DISABLE_FFTW_MEASURE
 238     "Do not optimize FFTW setups (not needed with SSE)"
 239     OFF
 240     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 241 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 242 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 243
 244 gmx_option_multichoice(
 245     GMX_QMMM_PROGRAM
 246     "QM package for QM/MM"
 247     None
 248     none gaussian mopac gamess orca)
 249
 250 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 251 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 252
 253 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 254
 255 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 256 mark_as_advanced(GMX_BROKEN_CALLOC)
 257 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 258 mark_as_advanced(GMX_LOAD_PLUGINS)
 259
 260 option(GMX_GPU  "Enable GPU acceleration" ON)
 261 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 262
 263 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 264
 265 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 266 mark_as_advanced(GMX_GIT_VERSION_INFO)
 267
 268 if(UNIX)
 269     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 270 endif()
 271 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 272
 273 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 274 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 275
 276 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 277 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 278
 279 option(GMX_BUILD_FOR_COVERAGE
 280        "Tune build for better code coverage metrics (e.g., disable asserts)"
 281        OFF)
 282 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 283
 284
 285 ######################################################################
 286 # Detect OpenMP support
 287 ######################################################################
 288 # The OpenMP detection _must_ come before tests for other CFLAGS.
 289 include(gmxManageOpenMP)
 290
 291
 292
 293 ######################################################################
 294 # Compiler tests
 295 # These need to be done early (before further tests).
 296 #####################################################################
 297
 298 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 299 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 300 # invalid options with the Intel Compilers.
 301 # These files should be removed from the source tree when a CMake version that
 302 # includes the features in question becomes required for building GROMACS.
 303 include(CheckCCompilerFlag)
 304 include(CheckCXXCompilerFlag)
 305
 306
 307 include(gmxCFlags)
 308 gmx_c_flags()
 309
 310 # This variable should be used for additional compiler flags which are not
 311 # generated in gmxCFlags nor are SIMD or MPI related.
 312 set(EXTRA_C_FLAGS "")
 313 set(EXTRA_CXX_FLAGS "")
 314
 315 # Run through a number of tests for buggy compilers and other issues
 316 include(gmxTestCompilerProblems)
 317 gmx_test_compiler_problems()
 318
 319
 320 set(PKG_CFLAGS "")
 321 if(GMX_DOUBLE)
 322     add_definitions(-DGMX_DOUBLE)
 323     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 324 endif()
 325 if(GMX_SOFTWARE_INVSQRT)
 326   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 327 endif()
 328
 329
 330
 331 ########################################################################
 332 # Basic system tests (standard libraries, headers, functions, types)   #
 333 ########################################################################
 334 include(CheckIncludeFiles)
 335 include(CheckIncludeFileCXX)
 336 check_include_files(unistd.h     HAVE_UNISTD_H)
 337 check_include_files(pwd.h        HAVE_PWD_H)
 338 check_include_files(dirent.h     HAVE_DIRENT_H)
 339 check_include_files(time.h       HAVE_TIME_H)
 340 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 341 check_include_files(io.h         HAVE_IO_H)
 342 check_include_files(sched.h      HAVE_SCHED_H)
 343
 344 check_include_files(regex.h      HAVE_POSIX_REGEX)
 345 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 346 # TODO: It could be nice to inform the user if no regex support is found,
 347 # as selections won't be fully functional.
 348
 349 include(CheckFunctionExists)
 350 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 351 check_function_exists(memalign          HAVE_MEMALIGN)
 352 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 353 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 354 check_function_exists(fsync             HAVE_FSYNC)
 355 check_function_exists(_fileno           HAVE__FILENO)
 356 check_function_exists(fileno            HAVE_FILENO)
 357 check_function_exists(_commit           HAVE__COMMIT)
 358 check_function_exists(sigaction         HAVE_SIGACTION)
 359 check_function_exists(sysconf           HAVE_SYSCONF)
 360 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 361 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 362 check_function_exists(rsqrt             HAVE_RSQRT)
 363 check_function_exists(rsqrtf            HAVE_RSQRTF)
 364 check_function_exists(sqrtf             HAVE_SQRTF)
 365
 366 include(CheckLibraryExists)
 367 check_library_exists(m sqrt "" HAVE_LIBM)
 368 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 369
 370 include(TestBigEndian)
 371 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 372
 373 # Management of GROMACS options for specific toolchains should go
 374 # here. Because the initial settings for some of the main options have
 375 # already happened, but things like library detection and MPI compiler
 376 # feature detection have not, the docstrings for any over-rides of
 377 # GROMACS defaults or user settings will make sense. Also, any
 378 # toolchain-related reasons for choosing whether to detect various
 379 # things can be sorted out now, before the detection takes place.
 380 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 381     include(gmxManageBlueGene)
 382 endif()
 383
 384 ########################################################################
 385 #Process MPI settings
 386 ########################################################################
 387 include(gmxManageMPI)
 388
 389
 390 ########################################################################
 391 #Process shared/static library settings
 392 ########################################################################
 393 include(gmxManageSharedLibraries)
 394
 395
 396 ########################################################################
 397 # Find external packages                                               #
 398 ########################################################################
 399
 400 # Unconditionally find the package, as it is also required for unit
 401 # tests. This exports LIBXML2_FOUND, which we should not use because
 402 # it does not tell us that linking will succeed. Instead, we test that
 403 # next.
 404 find_package(LibXml2)
 405 include(gmxTestLibXml2)
 406 gmx_test_libxml2(HAVE_LIBXML2)
 407 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 408 set(PKG_XML "")
 409 mark_as_advanced(GMX_XML)
 410 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 411 #if(GMX_XML AND NOT HAVE_LIBXML2)
 412 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 413 #endif()
 414 #if(GMX_XML)
 415 #    include_directories(${LIBXML2_INCLUDE_DIR})
 416 #    set(PKG_XML libxml-2.0)
 417 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 418 #endif()
 419
 420 option(GMX_GSL "Add support for gsl" OFF)
 421 if (GMX_GSL)
 422   find_package(GSL)
 423   set(PKG_GSL "")
 424   if(GSL_FOUND)
 425     include_directories(${GSL_INCLUDE_DIR})
 426     set(PKG_GSL gsl)
 427     set(HAVE_LIBGSL 1)
 428   endif()
 429 endif()
 430
 431 option(GMX_X11 "Use X window system" OFF)
 432 if (GMX_X11)
 433     find_package(X11)
 434     # X11 includes/libraries are only set in the ngmx subdirectory!
 435     if(NOT X11_FOUND)
 436         message(FATAL_ERROR
 437                 "X11 include files and/or libraries were not found. "
 438                 "Set GMX_X11=OFF to compile without X11 support. "
 439                 "gmx view will not be available.")
 440     endif()
 441     include_directories(${X11_INCLUDE_DIR})
 442 endif()
 443
 444 include(ThreadMPI)
 445 set(THREAD_MPI_LIB thread_mpi)
 446 # Enable core threading facilities
 447 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 448 # Enable tMPI C++ support
 449 tmpi_enable_cxx()
 450 if(GMX_THREAD_MPI)
 451     # enable MPI functions
 452     tmpi_enable()
 453     set(GMX_MPI 1)
 454     set(MPI_IN_PLACE_EXISTS 1)
 455 endif()
 456 tmpi_get_source_list(THREAD_MPI_SRC)
 457 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 458 if (TMPI_ATOMICS_DISABLED)
 459    add_definitions(-DTMPI_ATOMICS_DISABLED)
 460 endif()
 461
 462 if(GMX_GPU)
 463     # now that we have detected the dependencies, do the second configure pass
 464     gmx_gpu_setup()
 465 endif()
 466
 467 if(CYGWIN)
 468     set(GMX_CYGWIN 1)
 469 endif()
 470
 471 if(WIN32 AND NOT CYGWIN)
 472     set(GMX_NATIVE_WINDOWS 1)
 473     # This makes windows.h not declare min/max as macros that would break
 474     # C++ code using std::min/std::max.
 475     add_definitions(-DNOMINMAX)
 476 endif()
 477
 478 # only bother with finding git and using version.h if the source is a git repo
 479 if(GMX_GIT_VERSION_INFO)
 480     if (NOT SOURCE_IS_GIT_REPOSITORY)
 481         message(FATAL_ERROR
 482             "Cannot generate git version information from source tree not under git. "
 483             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 484     endif()
 485     # We need at least git v1.5.3 be able to parse git's date output. If not
 486     # found or the version is too small, we can't generate version information.
 487     find_package(Git)
 488
 489     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 490         message(FATAL_ERROR
 491             "No compatible git version found (>= 1.5.3 required). "
 492             "Won't be able to generate development version information. "
 493             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 494     endif()
 495 endif()
 496
 497 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 498 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 499 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 500     find_package(Boost 1.44.0)
 501     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 502         set(Boost_FOUND FALSE)
 503     endif()
 504     # Print the notification only on first run, when determining the default
 505     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 506         message("Boost >= 1.44 not found. Using minimal internal version. "
 507                 "This may cause trouble if you plan on compiling/linking other "
 508                 "software that uses Boost against Gromacs.")
 509     endif()
 510 endif()
 511 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 512        ${Boost_FOUND})
 513 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 514     message(FATAL_ERROR
 515         "Boost >= 1.44 not found. "
 516         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 517         "version of Boost included with Gromacs.")
 518 endif()
 519
 520 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 521 mark_as_advanced(GMX_BUILD_UNITTESTS)
 522 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 523 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 524     message(FATAL_ERROR
 525         "Cannot build unit tests without libxml2. "
 526         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 527 endif()
 528
 529 ########################################################################
 530 # Generate development version info for cache
 531 ########################################################################
 532 # set(GEN_VERSION_INFO_INTERNAL "ON")
 533 # include(gmxGenerateVersionString)
 534
 535 ########################################################################
 536 # Our own GROMACS tests
 537 ########################################################################
 538
 539 add_definitions( -DHAVE_CONFIG_H )
 540 include_directories(${CMAKE_SOURCE_DIR}/src)
 541 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 542 include_directories(${CMAKE_BINARY_DIR}/src)
 543 # Required for gmx_header_config_gen.h to be found before installation
 544 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 545 # Required for now to make old code compile
 546 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 547
 548 include(gmxTestInlineASM)
 549 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 550
 551 include(gmxSetBuildInformation)
 552 gmx_set_build_information()
 553 # Turn on RDTSCP if:
 554 # - the build system's CPU supports it
 555 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 556 #   at this point means that the user set it).
 557 # Note: it's better to not use the later set value of GMX_SIMD because
 558 # it reflects the system's capability of both compiling and running AVX code.
 559 # TODO: After merge with 5.0 one could implement a cache variable dependency
 560 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 561 # after the first cmake pass.
 562 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 563     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 564 else()
 565     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 566 endif()
 567 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 568 mark_as_advanced(GMX_USE_RDTSCP)
 569 if(GMX_USE_RDTSCP)
 570     set(HAVE_RDTSCP 1)
 571 endif()
 572
 573 include(gmxTestFloatFormat)
 574 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 575                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 576                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 577
 578 include(gmxTestLargeFiles)
 579 gmx_test_large_files(GMX_LARGEFILES)
 580
 581 include(gmxTestSignal)
 582 gmx_test_sigusr1(HAVE_SIGUSR1)
 583
 584 include(gmxTestPipes)
 585 gmx_test_pipes(HAVE_PIPES)
 586
 587 include(gmxTestIsfinite)
 588 gmx_test_isfinite(HAVE_ISFINITE)
 589 gmx_test__isfinite(HAVE__ISFINITE)
 590 gmx_test__finite(HAVE__FINITE)
 591
 592 include(gmxTestCXX11)
 593 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 594 include(CMakeDependentOption)
 595 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 596 # entirely to keep the compilation environment uniform.
 597 cmake_dependent_option(GMX_CXX11
 598     "Use C++11 features"
 599     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 600 mark_as_advanced(GMX_CXX11)
 601 if(GMX_CXX11)
 602     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 603 endif()
 604
 605
 606 include(gmxTestXDR)
 607 gmx_test_xdr(GMX_SYSTEM_XDR)
 608 if(NOT GMX_SYSTEM_XDR)
 609     set(GMX_INTERNAL_XDR 1)
 610 endif()
 611
 612
 613 ##################################################
 614 # Process SIMD instruction settings
 615 ##################################################
 616 # This checks what flags to add in order to
 617 # support the SIMD instructions we need, and sets
 618 # correct defines for the SIMD instructions supported.
 619 include(gmxTestSimd)
 620 gmx_test_simd()
 621
 622
 623 # Process QM/MM Settings
 624 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 625     set(GMX_QMMM_GAUSSIAN 1)
 626 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 627     set(GMX_QMMM_MOPAC 1)
 628 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 629     set(GMX_QMMM_GAMESS 1)
 630 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 631     set(GMX_QMMM_ORCA 1)
 632 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 633     # nothing to do
 634 else()
 635     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 636 endif()
 637
 638
 639 ##################################################
 640 # Process FFT library settings
 641 ##################################################
 642 include(gmxManageFFTLibraries)
 643
 644
 645 include(gmxManageLinearAlgebraLibraries)
 646
 647 # Whether GROMACS will really try to compile support for VMD plugins
 648 set(GMX_USE_PLUGINS OFF)
 649
 650 if(GMX_LOAD_PLUGINS)
 651   if(CYGWIN OR NOT WIN32)
 652     # Native Windows does not have, nor need dlopen
 653     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 654     include(gmxTestdlopen)
 655     gmx_test_dlopen(HAVE_DLOPEN)
 656   endif()
 657
 658   # so, should we use plug-ins?
 659   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 660     if(NOT VMD_QUIETLY)
 661       MESSAGE(STATUS
 662           "Found the ability to use plug-ins when building shared libaries, "
 663           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 664           "formats).")
 665     endif()
 666     if(NOT GMX_VMD_PLUGIN_PATH)
 667       find_package(VMD)
 668     endif()
 669     set(GMX_USE_PLUGINS ON)
 670     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 671     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 672   else()
 673     set(PKG_DL_LIBS)
 674   endif()
 675 endif()
 676 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 677
 678 # Link real-time library for POSIX timers. The check for clock_gettime
 679 # confirms the linkability of rt.
 680 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 681     list(APPEND GMX_EXTRA_LIBRARIES rt)
 682 endif()
 683
 684 # Math and thread libraries must often come after all others when linking...
 685 if(HAVE_LIBM)
 686     list(APPEND GMX_EXTRA_LIBRARIES m)
 687 endif()
 688
 689 option(GMX_NACL "Configure for Native Client builds" OFF)
 690 if (GMX_NACL)
 691   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 692   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 693   set(GMX_NO_NICE 1)
 694   set(GMX_NO_RENAME 1)
 695 endif()
 696 mark_as_advanced(GMX_NACL)
 697
 698 if(GMX_FAHCORE)
 699   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 700       "Path to swindirect.h")
 701   include_directories(${COREWRAP_INCLUDE_DIR})
 702 endif()
 703
 704 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 705 mark_as_advanced(GMX_BUILD_HELP)
 706 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 707     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 708
 709     message(FATAL_ERROR
 710         "Rebuilding HTML and man pages is not supported for in-source "
 711         "builds from a source distribution. "
 712         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 713 endif()
 714
 715 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 716 # these are set after everything else
 717 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 718     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 719     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 720     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 721     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 722 else()
 723     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 724     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 725     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 726     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 727     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 728     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 729     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 730     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 731     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 732 endif()
 733
 734 if(NOT GMX_OPENMP)
 735     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 736     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 737     unset(OpenMP_C_FLAGS CACHE)
 738     unset(OpenMP_CXX_FLAGS CACHE)
 739 else()
 740     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 741     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 742 endif()
 743 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 744
 745 ########################################################################
 746 # Specify install locations
 747 ########################################################################
 748 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 749     "Library installation directory (default: lib)")
 750 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 751     "Data installation directory under share/ (default: gromacs)")
 752 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 753
 754 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 755 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 756 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 757 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 758 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 759
 760 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 761 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 762
 763 # Binary and library suffix options
 764 include(gmxManageSuffixes)
 765
 766 ##################################################################
 767 # Shared library settings
 768 ##################################################################
 769 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 770     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 771         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 772     endif()
 773     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 774     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 775 else()
 776     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 777         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 778         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 779     else()
 780         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 781     endif()
 782 endif()
 783
 784 #COPYING file: Only necessary for binary distributions.
 785 #Simpler to always install.
 786 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 787
 788 if(GMX_EXTERNAL_BOOST)
 789     include_directories(${Boost_INCLUDE_DIRS})
 790     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 791 else()
 792     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 793     # typeid not supported for minimal internal version
 794     # (would add significant amount of code)
 795     add_definitions(-DBOOST_NO_TYPEID)
 796     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 797     # (from share/template/)
 798     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 799     if (NOT GMX_BUILD_MDRUN_ONLY)
 800         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 801                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 802                 COMPONENT development)
 803     endif()
 804 endif()
 805
 806 if(GMX_USE_TNG)
 807     find_package(ZLIB QUIET)
 808     include(gmxTestZLib)
 809     gmx_test_zlib(HAVE_ZLIB)
 810     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 811     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 812     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 813     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 814     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 815     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 816     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 817     set(GMX_TNG_LIBRARIES tng_io)
 818 endif()
 819 mark_as_advanced(TNG_BUILD_FORTRAN)
 820 mark_as_advanced(TNG_BUILD_EXAMPLES)
 821 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 822 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 823 mark_as_advanced(TNG_BUILD_TEST)
 824 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 825
 826 if (GMX_BUILD_FOR_COVERAGE)
 827     # Code heavy with asserts makes conditional coverage close to useless metric,
 828     # as by design most of the false branches are impossible to trigger in
 829     # correctly functioning code.  And the benefit of testing those that could
 830     # be triggered by using an API against its specification isn't usually
 831     # worth the effort.
 832     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 833 endif()
 834
 835 if (BUILD_TESTING)
 836     # "tests" target builds all the separate test binaries.
 837     add_custom_target(tests)
 838     # "run-ctest" is an internal target that actually runs the tests.
 839     # This is necessary to be able to add separate targets that execute as part
 840     # of 'make check', but are ensured to be executed after the actual tests.
 841     add_custom_target(run-ctest
 842                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 843                       COMMENT "Running all tests"
 844                       VERBATIM)
 845     add_dependencies(run-ctest tests)
 846     # "check" target builds and runs all tests.
 847     add_custom_target(check DEPENDS run-ctest)
 848 endif()
 849
 850 if (NOT GMX_BUILD_MDRUN_ONLY)
 851     add_subdirectory(doxygen)
 852     add_subdirectory(share)
 853     add_subdirectory(scripts)
 854 endif()
 855 add_subdirectory(src)
 856
 857 if (BUILD_TESTING)
 858     add_subdirectory(tests)
 859 endif()
 860
 861 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 862 # Don't bother the user after the first configure pass.
 863 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 864     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 865 endif()
 866 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 867
 868 #######################
 869 ## uninstall target
 870 #######################
 871     CONFIGURE_FILE(
 872                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 873                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 874                    IMMEDIATE @ONLY)
 875 ###########################
 876 ADD_CUSTOM_TARGET(uninstall
 877                   "${CMAKE_COMMAND}" -P
 878                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 879 ###########################
 880
 881 ########################################################################
 882 # Manual                                                               #
 883 ########################################################################
 884
 885 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 886 mark_as_advanced(GMX_BUILD_MANUAL)
 887 if(GMX_BUILD_MANUAL)
 888     # Make sure we only do detection of manual-building dependencies
 889     # when the user opted in for that.
 890     add_subdirectory(manual)
 891 endif()