CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # The MD5 checksum of the regressiontest tarball. Only used if "-dev"
  68 # is not present in the PROJECT_VERSION
  69 set(REGRESSIONTEST_MD5SUM "a07524afebca5013540d4f2f72df2dce")
  70 # If this is not a released tarball, "-dev" will be present in
  71 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  72 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  73 # code contains all recent fixes from the corresponding code branch.
  74 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  75
  76 set(CUSTOM_VERSION_STRING ""
  77     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  78 mark_as_advanced(CUSTOM_VERSION_STRING)
  79 if (CUSTOM_VERSION_STRING)
  80     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  81 endif()
  82 set(LIBRARY_SOVERSION 0)
  83 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  84 # It is a bit irritating, but this has to be set separately for now!
  85 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  86 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  87 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  88
  89 # The numerical gromacs version. It is 40600 for 4.6.0.
  90 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  91 math(EXPR NUM_VERSION
  92     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  93 if(CPACK_PACKAGE_VERSION_PATCH)
  94     math(EXPR NUM_VERSION
  95          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  96 endif()
  97
  98 # The API version tracks the numerical Gromacs version (for now).
  99 # It is potentially different from the Gromacs version in the future, if
 100 # the programs/libraries diverge from the presumably more stable API.
 101 # The #define GMX_API_VERSION in version.h is set to this value to
 102 # provide backward compatibility of software written against the Gromacs API.
 103 set(API_VERSION ${NUM_VERSION})
 104
 105 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 106     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 107 endif()
 108
 109 include(gmxBuildTypeReference)
 110 include(gmxBuildTypeTSAN)
 111 include(gmxBuildTypeASAN)
 112 include(gmxBuildTypeReleaseWithAssert)
 113
 114 if(NOT CMAKE_BUILD_TYPE)
 115     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 116     # There's no need to offer a user the choice of ThreadSanitizer
 117     # Set the possible values of build type for cmake-gui
 118     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 119         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 120 endif()
 121 if(CMAKE_CONFIGURATION_TYPES)
 122     # Add appropriate GROMACS-specific build types for the Visual
 123     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 124     # are already present by default).
 125     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 126     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 127     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 128         "List of configuration types"
 129         FORCE)
 130 endif()
 131 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 132
 133 enable_language(C)
 134 enable_language(CXX)
 135 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 136
 137 set(CPACK_PACKAGE_NAME "gromacs")
 138 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 139 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 140 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 141 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 142 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 143 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 144 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 145 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 146 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 147 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 148 # CPack source archives include only the directories we list here.
 149 # This variable is a list of pairs of names of source and destination
 150 # directories. Most of these are used for content GROMACS generates as
 151 # part of the configuration or build.
 152 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/docs/man/man1;docs/man/man1;${CMAKE_BINARY_DIR}/docs/man/man7;docs/man/man7;${CMAKE_BINARY_DIR}/docs/old-html/final;docs/old-html/final;${CMAKE_BINARY_DIR}/docs/install-guide/final;/")
 153 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 154 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 155
 156 #must come after all cpack settings!
 157 include(CPack)
 158
 159 # Set a default valgrind suppression file.
 160 # This unfortunately needs to duplicate information from CTest to work as
 161 # expected...
 162 set(MEMORYCHECK_SUPPRESSIONS_FILE
 163     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 164     CACHE FILEPATH
 165     "File that contains suppressions for the memory checker")
 166 include(CTest)
 167
 168 set(SOURCE_IS_GIT_REPOSITORY OFF)
 169 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 170 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 171     set(SOURCE_IS_GIT_REPOSITORY ON)
 172 endif()
 173 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 174     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 175 endif()
 176
 177 ########################################################################
 178 # Check and warn if cache generated on a different host is being reused
 179 ########################################################################
 180 if(CMAKE_HOST_UNIX)
 181     execute_process(COMMAND hostname
 182                     OUTPUT_VARIABLE TMP_HOSTNAME
 183                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 184     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 185         message(WARNING "
 186             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 187             is being reused! This could lead to inconsitencies; therefore, it is
 188             recommended to regenerate the cache!")
 189     endif()
 190     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 191             "Hostname of the machine where the cache was generated.")
 192 endif()
 193
 194 ########################################################################
 195 # User input options                                                   #
 196 ########################################################################
 197 include(gmxOptionUtilities)
 198
 199 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 200
 201 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 202 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 203 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 204 gmx_dependent_option(
 205     GMX_MPI_IN_PLACE
 206     "Enable MPI_IN_PLACE for MPIs that have it defined"
 207     ON
 208     GMX_MPI)
 209 mark_as_advanced(GMX_MPI_IN_PLACE)
 210 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 211 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 212 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 213 mark_as_advanced(GMX_FAHCORE)
 214
 215 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 216 mark_as_advanced(GMX_COOL_QUOTES)
 217 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 218
 219 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 220 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 221 if(MSVC)
 222     set(REQUIRED_CUDA_VERSION 4.1)
 223 else()
 224     set(REQUIRED_CUDA_VERSION 4.0)
 225 endif()
 226 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 227 include(gmxManageGPU)
 228
 229 # Detect the architecture the compiler is targetting, detect
 230 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 231 # to use if none is specified, and populate the cache option for CPU
 232 # SIMD.
 233 include(gmxDetectTargetArchitecture)
 234 gmx_detect_target_architecture()
 235
 236 if(GMX_CPU_ACCELERATION)
 237     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 238     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 239     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 240     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 241 endif()
 242
 243 if(NOT GMX_TARGET_MIC)
 244     include(gmxDetectSimd)
 245     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 246 else()
 247     set(GMX_SUGGESTED_SIMD "None")
 248 endif()
 249
 250 gmx_option_multichoice(
 251     GMX_SIMD
 252     "SIMD instruction set for CPU kernels and compiler optimization"
 253     "${GMX_SUGGESTED_SIMD}"
 254     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 255
 256 gmx_option_multichoice(
 257     GMX_FFT_LIBRARY
 258     "FFT library"
 259     "fftw3"
 260     fftw3 mkl "fftpack[built-in]")
 261 gmx_dependent_option(
 262     GMX_BUILD_OWN_FFTW
 263     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 264     OFF
 265     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 266 gmx_dependent_option(
 267     GMX_DISABLE_FFTW_MEASURE
 268     "Do not optimize FFTW setups (not needed with SSE)"
 269     OFF
 270     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 271 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 272 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 273
 274 gmx_option_multichoice(
 275     GMX_QMMM_PROGRAM
 276     "QM package for QM/MM"
 277     None
 278     none gaussian mopac gamess orca)
 279
 280 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 281 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 282
 283 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 284
 285 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 286 mark_as_advanced(GMX_BROKEN_CALLOC)
 287 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 288 mark_as_advanced(GMX_LOAD_PLUGINS)
 289
 290 option(GMX_GPU  "Enable GPU acceleration" ON)
 291 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 292
 293 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 294
 295 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 296 mark_as_advanced(GMX_GIT_VERSION_INFO)
 297
 298 if(UNIX)
 299     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 300 endif()
 301 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 302
 303 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 304 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 305
 306 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 307 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 308
 309 option(GMX_BUILD_FOR_COVERAGE
 310        "Tune build for better code coverage metrics (e.g., disable asserts)"
 311        OFF)
 312 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 313
 314 option(GMX_DEVELOPER_BUILD
 315     "Enable Developer convenience features: always build unit-tests"
 316     OFF)
 317 mark_as_advanced(GMX_DEVELOPER_BUILD)
 318
 319 ######################################################################
 320 # Detect OpenMP support
 321 ######################################################################
 322 # The OpenMP detection _must_ come before tests for other CFLAGS.
 323 include(gmxManageOpenMP)
 324
 325
 326
 327 ######################################################################
 328 # Compiler tests
 329 # These need to be done early (before further tests).
 330 #####################################################################
 331
 332 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 333 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 334 # invalid options with the Intel Compilers, and we have added a line
 335 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 336 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 337 # a semicolon. Since this is also used as a separator in lists inside CMake,
 338 # that string ends up being split into two separate patterns, and the last
 339 # part is just a single word that also matches other messages. We solved this
 340 # by replacing the semicolon with a period that matches any character.
 341 #
 342 # These files should be removed from the source tree when a CMake version that
 343 # includes the features in question becomes required for building GROMACS.
 344 include(CheckCCompilerFlag)
 345 include(CheckCXXCompilerFlag)
 346
 347 include(gmxCFlags)
 348 gmx_c_flags()
 349
 350 # This variable should be used for additional compiler flags which are not
 351 # generated in gmxCFlags nor are SIMD or MPI related.
 352 set(EXTRA_C_FLAGS "")
 353 set(EXTRA_CXX_FLAGS "")
 354
 355 # Run through a number of tests for buggy compilers and other issues
 356 include(gmxTestCompilerProblems)
 357 gmx_test_compiler_problems()
 358 # GMX_SIMD will not be set automatically until the second
 359 # pass (which is not strictly guaranteed to occur), so putting this
 360 # check here among logically-related tests is inefficient, but the
 361 # potential loss is likely zero.
 362 if(GMX_SIMD STREQUAL "AVX_256"
 363         AND CMAKE_COMPILER_IS_GNUCC
 364         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 365             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 366     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 367     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 368 endif()
 369
 370
 371
 372 set(PKG_CFLAGS "")
 373 if(GMX_DOUBLE)
 374     add_definitions(-DGMX_DOUBLE)
 375     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 376 endif()
 377 if(GMX_SOFTWARE_INVSQRT)
 378   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 379 endif()
 380
 381 if(WIN32 AND NOT CYGWIN)
 382     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 383     add_definitions(-DGMX_HAVE_WINSOCK)
 384 endif()
 385
 386
 387
 388 ########################################################################
 389 # Basic system tests (standard libraries, headers, functions, types)   #
 390 ########################################################################
 391 include(CheckIncludeFiles)
 392 include(CheckIncludeFileCXX)
 393 check_include_files(unistd.h     HAVE_UNISTD_H)
 394 check_include_files(pwd.h        HAVE_PWD_H)
 395 check_include_files(dirent.h     HAVE_DIRENT_H)
 396 check_include_files(time.h       HAVE_TIME_H)
 397 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 398 check_include_files(io.h         HAVE_IO_H)
 399 check_include_files(sched.h      HAVE_SCHED_H)
 400
 401 check_include_files(regex.h      HAVE_POSIX_REGEX)
 402 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 403 # TODO: It could be nice to inform the user if no regex support is found,
 404 # as selections won't be fully functional.
 405
 406 include(CheckFunctionExists)
 407 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 408 check_function_exists(memalign          HAVE_MEMALIGN)
 409 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 410 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 411 check_function_exists(fsync             HAVE_FSYNC)
 412 check_function_exists(_fileno           HAVE__FILENO)
 413 check_function_exists(fileno            HAVE_FILENO)
 414 check_function_exists(_commit           HAVE__COMMIT)
 415 check_function_exists(sigaction         HAVE_SIGACTION)
 416 check_function_exists(sysconf           HAVE_SYSCONF)
 417 check_function_exists(rsqrt             HAVE_RSQRT)
 418 check_function_exists(rsqrtf            HAVE_RSQRTF)
 419 check_function_exists(sqrtf             HAVE_SQRTF)
 420
 421 include(CheckLibraryExists)
 422 check_library_exists(m sqrt "" HAVE_LIBM)
 423 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 424
 425 include(TestSchedAffinity)
 426 test_sched_affinity(HAVE_SCHED_AFFINITY)
 427
 428 include(TestBigEndian)
 429 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 430
 431 # Management of GROMACS options for specific toolchains should go
 432 # here. Because the initial settings for some of the main options have
 433 # already happened, but things like library detection and MPI compiler
 434 # feature detection have not, the docstrings for any over-rides of
 435 # GROMACS defaults or user settings will make sense. Also, any
 436 # toolchain-related reasons for choosing whether to detect various
 437 # things can be sorted out now, before the detection takes place.
 438 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 439     include(gmxManageBlueGene)
 440 endif()
 441
 442 ########################################################################
 443 #Process MPI settings
 444 ########################################################################
 445 include(gmxManageMPI)
 446
 447
 448 ########################################################################
 449 #Process shared/static library settings
 450 ########################################################################
 451 include(gmxManageSharedLibraries)
 452
 453
 454 ########################################################################
 455 # Find external packages                                               #
 456 ########################################################################
 457
 458 # Unconditionally find the package, as it is also required for unit
 459 # tests. This exports LIBXML2_FOUND, which we should not use because
 460 # it does not tell us that linking will succeed. Instead, we test that
 461 # next.
 462 if(DEFINED LIBXML2_LIBRARIES)
 463   set(LibXml2_FIND_QUIETLY TRUE)
 464 endif()
 465 find_package(LibXml2)
 466 include(gmxTestLibXml2)
 467 gmx_test_libxml2(HAVE_LIBXML2)
 468 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 469 set(PKG_XML "")
 470 mark_as_advanced(GMX_XML)
 471 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 472 #if(GMX_XML AND NOT HAVE_LIBXML2)
 473 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 474 #endif()
 475 #if(GMX_XML)
 476 #    include_directories(${LIBXML2_INCLUDE_DIR})
 477 #    set(PKG_XML libxml-2.0)
 478 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 479 #endif()
 480
 481 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 482 mark_as_advanced(GMX_EXTRAE)
 483
 484 if (GMX_EXTRAE)
 485   find_package(EXTRAE)
 486   if(EXTRAE_FOUND)
 487     include_directories(${EXTRAE_INCLUDE_DIR})
 488     set(HAVE_EXTRAE 1)
 489   else()
 490     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 491   endif()
 492 endif()
 493
 494 option(GMX_X11 "Use X window system" OFF)
 495 if (GMX_X11)
 496     find_package(X11)
 497     # X11 includes/libraries are only set in the ngmx subdirectory!
 498     if(NOT X11_FOUND)
 499         message(FATAL_ERROR
 500                 "X11 include files and/or libraries were not found. "
 501                 "Set GMX_X11=OFF to compile without X11 support. "
 502                 "gmx view will not be available.")
 503     endif()
 504     include_directories(${X11_INCLUDE_DIR})
 505 endif()
 506
 507 include(ThreadMPI)
 508 # Enable core threading facilities
 509 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 510 # Enable tMPI C++ support
 511 tmpi_enable_cxx()
 512 if(GMX_THREAD_MPI)
 513     # enable MPI functions
 514     tmpi_enable()
 515     set(GMX_MPI 1)
 516     set(MPI_IN_PLACE_EXISTS 1)
 517 endif()
 518 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 519 if (TMPI_ATOMICS_DISABLED)
 520    add_definitions(-DTMPI_ATOMICS_DISABLED)
 521 endif()
 522
 523 if(GMX_GPU)
 524     # now that we have detected the dependencies, do the second configure pass
 525     gmx_gpu_setup()
 526 endif()
 527
 528 if(CYGWIN)
 529     set(GMX_CYGWIN 1)
 530 endif()
 531
 532 if(WIN32 AND NOT CYGWIN)
 533     set(GMX_NATIVE_WINDOWS 1)
 534     # This makes windows.h not declare min/max as macros that would break
 535     # C++ code using std::min/std::max.
 536     add_definitions(-DNOMINMAX)
 537 endif()
 538
 539 # only bother with finding git and using version.h if the source is a git repo
 540 if(GMX_GIT_VERSION_INFO)
 541     if (NOT SOURCE_IS_GIT_REPOSITORY)
 542         message(FATAL_ERROR
 543             "Cannot generate git version information from source tree not under git. "
 544             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 545     endif()
 546     # We need at least git v1.5.3 be able to parse git's date output. If not
 547     # found or the version is too small, we can't generate version information.
 548     find_package(Git)
 549
 550     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 551         message(FATAL_ERROR
 552             "No compatible git version found (>= 1.5.3 required). "
 553             "Won't be able to generate development version information. "
 554             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 555     endif()
 556 endif()
 557
 558 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 559 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 560 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 561     find_package(Boost 1.44.0)
 562     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 563         set(Boost_FOUND FALSE)
 564     endif()
 565     # Print the notification only on first run, when determining the default
 566     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 567         message("Boost >= 1.44 not found. Using minimal internal version. "
 568                 "This may cause trouble if you plan on compiling/linking other "
 569                 "software that uses Boost against Gromacs.")
 570     endif()
 571 endif()
 572 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 573        ${Boost_FOUND})
 574 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 575     message(FATAL_ERROR
 576         "Boost >= 1.44 not found. "
 577         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 578         "version of Boost included with Gromacs.")
 579 endif()
 580
 581 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 582     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 583 endif()
 584 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 585 mark_as_advanced(GMX_BUILD_UNITTESTS)
 586 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 587 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 588     message(FATAL_ERROR
 589         "Cannot build unit tests without libxml2. "
 590         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 591 endif()
 592
 593 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 594     # TNG wants zlib if it is available
 595     find_package(ZLIB QUIET)
 596     include(gmxTestZLib)
 597     gmx_test_zlib(HAVE_ZLIB)
 598 endif()
 599
 600 ########################################################################
 601 # Generate development version info for cache
 602 ########################################################################
 603 # set(GEN_VERSION_INFO_INTERNAL "ON")
 604 # include(gmxGenerateVersionString)
 605
 606 ########################################################################
 607 # Our own GROMACS tests
 608 ########################################################################
 609
 610 add_definitions( -DHAVE_CONFIG_H )
 611 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 612 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 613 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 614 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 615 # Required for gmx_header_config_gen.h to be found before installation
 616 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 617 # Required for now to make old code compile
 618 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 619
 620 include(gmxTestInlineASM)
 621 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 622
 623 include(gmxSetBuildInformation)
 624 gmx_set_build_information()
 625 # Turn on RDTSCP if:
 626 # - the build system's CPU supports it
 627 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 628 #   at this point means that the user set it).
 629 # Note: it's better to not use the later set value of GMX_SIMD because
 630 # it reflects the system's capability of both compiling and running AVX code.
 631 # TODO: After merge with 5.0 one could implement a cache variable dependency
 632 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 633 # after the first cmake pass.
 634 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 635     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 636 else()
 637     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 638 endif()
 639 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 640 mark_as_advanced(GMX_USE_RDTSCP)
 641 if(GMX_USE_RDTSCP)
 642     set(HAVE_RDTSCP 1)
 643 endif()
 644
 645 include(gmxTestFloatFormat)
 646 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 647                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 648                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 649
 650 include(gmxTestLargeFiles)
 651 gmx_test_large_files(GMX_LARGEFILES)
 652
 653 include(gmxTestSignal)
 654 gmx_test_sigusr1(HAVE_SIGUSR1)
 655
 656 include(gmxTestPipes)
 657 gmx_test_pipes(HAVE_PIPES)
 658
 659 include(gmxTestIsfinite)
 660 gmx_test_isfinite(HAVE_ISFINITE)
 661 gmx_test__isfinite(HAVE__ISFINITE)
 662 gmx_test__finite(HAVE__FINITE)
 663
 664 include(gmxTestCXX11)
 665 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 666 include(CMakeDependentOption)
 667 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 668 # entirely to keep the compilation environment uniform.
 669 cmake_dependent_option(GMX_CXX11
 670     "Use C++11 features"
 671     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 672 mark_as_advanced(GMX_CXX11)
 673 if(GMX_CXX11)
 674     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 675 endif()
 676
 677
 678 include(gmxTestXDR)
 679 gmx_test_xdr(GMX_SYSTEM_XDR)
 680 if(NOT GMX_SYSTEM_XDR)
 681     set(GMX_INTERNAL_XDR 1)
 682 endif()
 683
 684
 685 ##################################################
 686 # Process SIMD instruction settings
 687 ##################################################
 688 # This checks what flags to add in order to
 689 # support the SIMD instructions we need, and sets
 690 # correct defines for the SIMD instructions supported.
 691 include(gmxTestSimd)
 692 gmx_test_simd()
 693
 694
 695 # Process QM/MM Settings
 696 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 697     set(GMX_QMMM_GAUSSIAN 1)
 698 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 699     set(GMX_QMMM_MOPAC 1)
 700 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 701     set(GMX_QMMM_GAMESS 1)
 702 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 703     set(GMX_QMMM_ORCA 1)
 704 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 705     # nothing to do
 706 else()
 707     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 708 endif()
 709
 710
 711 ##################################################
 712 # Process FFT library settings
 713 ##################################################
 714 include(gmxManageFFTLibraries)
 715
 716
 717 include(gmxManageLinearAlgebraLibraries)
 718
 719 # Whether GROMACS will really try to compile support for VMD plugins
 720 set(GMX_USE_PLUGINS OFF)
 721
 722 if(GMX_LOAD_PLUGINS)
 723   if(CYGWIN OR NOT WIN32)
 724     # Native Windows does not have, nor need dlopen
 725     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 726     include(gmxTestdlopen)
 727     gmx_test_dlopen(HAVE_DLOPEN)
 728   endif()
 729
 730   # so, should we use plug-ins?
 731   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 732     if(NOT VMD_QUIETLY)
 733       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 734     endif()
 735     if(NOT GMX_VMD_PLUGIN_PATH)
 736       find_package(VMD)
 737     endif()
 738     set(GMX_USE_PLUGINS ON)
 739     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 740     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 741   else()
 742     set(PKG_DL_LIBS)
 743   endif()
 744 endif()
 745 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 746
 747 # Link real-time library for POSIX timers. The check for clock_gettime
 748 # confirms the linkability of rt.
 749 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 750     list(APPEND GMX_EXTRA_LIBRARIES rt)
 751 endif()
 752
 753 # Math and thread libraries must often come after all others when linking...
 754 if(HAVE_LIBM)
 755     list(APPEND GMX_EXTRA_LIBRARIES m)
 756 endif()
 757
 758 option(GMX_NACL "Configure for Native Client builds" OFF)
 759 if (GMX_NACL)
 760   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 761   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 762   set(GMX_NO_NICE 1)
 763   set(GMX_NO_RENAME 1)
 764 endif()
 765 mark_as_advanced(GMX_NACL)
 766
 767 if(GMX_FAHCORE)
 768   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 769       "Path to swindirect.h")
 770   include_directories(${COREWRAP_INCLUDE_DIR})
 771 endif()
 772
 773 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 774 mark_as_advanced(GMX_BUILD_HELP)
 775 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 776     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 777
 778     message(FATAL_ERROR
 779         "Rebuilding HTML and man pages is not supported for in-source "
 780         "builds from a source distribution. "
 781         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 782 endif()
 783
 784 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 785 # these are set after everything else
 786 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 787     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 788     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 789     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 790     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 791 else()
 792     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 793     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 794     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 795     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 796     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 797     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 798     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 799     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 800     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 801 endif()
 802
 803 if(NOT GMX_OPENMP)
 804     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 805     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 806     unset(OpenMP_C_FLAGS CACHE)
 807     unset(OpenMP_CXX_FLAGS CACHE)
 808 else()
 809     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 810     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 811 endif()
 812 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 813
 814 ########################################################################
 815 # Specify install locations
 816 ########################################################################
 817 # Use GNUInstallDirs to set paths on multiarch systems.
 818 include(GNUInstallDirs)
 819
 820 # Customization for the installation tree paths.
 821 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 822     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 823 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 824     "Data installation directory under share/ (default: gromacs)")
 825 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 826
 827 # These variables are used internally to provide a central location for
 828 # customizing the install locations.
 829 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 830 set(BIN_INSTALL_DIR  bin)
 831 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 832 set(MAN_INSTALL_DIR  share/man)
 833 set(INCL_INSTALL_DIR include)
 834
 835 # These variables get written into config.h for use in finding the data
 836 # directories.
 837 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 838 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 839
 840 # Binary and library suffix options
 841 include(gmxManageSuffixes)
 842
 843 ################################################################
 844 # Shared library load path settings
 845 ################################################################
 846 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 847 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 848 # was added.
 849 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 850    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 851     # The build folder always has bin/ and lib/; if we are also going to
 852     # install to lib/, then the installation RPATH works also in the build
 853     # tree.  This makes installation slightly faster (no need to rewrite the
 854     # RPATHs), and makes the binaries in the build tree relocatable.
 855     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 856         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 857     endif()
 858     # Set the RPATH as relative to the executable location to make the
 859     # binaries relocatable.
 860     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 861         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 862     else()
 863         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 864     endif()
 865     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 866     set(CMAKE_MACOSX_RPATH 1)
 867 else()
 868     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 869     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 870         # Set the RPATH options manually.
 871         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 872         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 873     else()
 874         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 875         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 876     endif()
 877 endif()
 878
 879 #COPYING file: Only necessary for binary distributions.
 880 #Simpler to always install.
 881 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 882
 883 if(GMX_EXTERNAL_BOOST)
 884     include_directories(${Boost_INCLUDE_DIRS})
 885     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 886 else()
 887     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 888     # typeid not supported for minimal internal version
 889     # (would add significant amount of code)
 890     add_definitions(-DBOOST_NO_TYPEID)
 891     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 892     # (from share/template/)
 893     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 894     if (NOT GMX_BUILD_MDRUN_ONLY)
 895         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 896                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 897                 COMPONENT development)
 898     endif()
 899 endif()
 900
 901 if (GMX_BUILD_FOR_COVERAGE)
 902     # Code heavy with asserts makes conditional coverage close to useless metric,
 903     # as by design most of the false branches are impossible to trigger in
 904     # correctly functioning code.  And the benefit of testing those that could
 905     # be triggered by using an API against its specification isn't usually
 906     # worth the effort.
 907     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 908 endif()
 909
 910 if (BUILD_TESTING)
 911     # "tests" target builds all the separate test binaries.
 912     add_custom_target(tests)
 913     # "run-ctest" is an internal target that actually runs the tests.
 914     # This is necessary to be able to add separate targets that execute as part
 915     # of 'make check', but are ensured to be executed after the actual tests.
 916     add_custom_target(run-ctest
 917                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 918                       COMMENT "Running all tests"
 919                       VERBATIM)
 920     add_dependencies(run-ctest tests)
 921     # "check" target builds and runs all tests.
 922     add_custom_target(check DEPENDS run-ctest)
 923 endif()
 924
 925 if (NOT GMX_BUILD_MDRUN_ONLY)
 926     add_subdirectory(docs)
 927     add_subdirectory(share)
 928     add_subdirectory(scripts)
 929 endif()
 930 add_subdirectory(src)
 931
 932 if (BUILD_TESTING)
 933     add_subdirectory(tests)
 934 endif()
 935
 936 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 937 # Don't bother the user after the first configure pass.
 938 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 939     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 940 endif()
 941 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 942
 943 #######################
 944 ## uninstall target
 945 #######################
 946 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 947                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 948                   IMMEDIATE @ONLY)
 949 ###########################
 950 ADD_CUSTOM_TARGET(uninstall
 951                   "${CMAKE_COMMAND}" -P
 952                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 953 ###########################
 954 set_directory_properties(PROPERTIES
 955             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")