CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98 include(gmxBuildTypeThreadSanitizer)
  99
 100 if(NOT CMAKE_BUILD_TYPE)
 101     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 102     # There's no need to offer a user the choice of ThreadSanitizer
 103     # Set the possible values of build type for cmake-gui
 104     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 105         "MinSizeRel" "RelWithDebInfo")
 106 endif(NOT CMAKE_BUILD_TYPE)
 107
 108 enable_language(C)
 109 enable_language(CXX)
 110
 111 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 112 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 113 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 114 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 115 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 116 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 117 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 118 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 119 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 120 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 121 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 122
 123 #must come after all cpack settings!
 124 include(CPack)
 125
 126 # Set a default valgrind suppression file.
 127 # This unfortunately needs to duplicate information from CTest to work as
 128 # expected...
 129 set(MEMORYCHECK_SUPPRESSIONS_FILE
 130     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 131     CACHE FILEPATH
 132     "File that contains suppressions for the memory checker")
 133 include(CTest)
 134
 135 set(SOURCE_IS_GIT_REPOSITORY OFF)
 136 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 137 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 138     set(SOURCE_IS_GIT_REPOSITORY ON)
 139 endif()
 140 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 141     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 142 endif()
 143
 144 ########################################################################
 145 # Check and warn if cache generated on a different host is being reused
 146 ########################################################################
 147 if(CMAKE_HOST_UNIX)
 148     execute_process(COMMAND hostname
 149                     OUTPUT_VARIABLE TMP_HOSTNAME
 150                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 151     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 152         message(WARNING "
 153             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 154             is being reused! This could lead to inconsitencies; therefore, it is
 155             recommended to regenerate the cache!")
 156     endif()
 157     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 158             "Hostname of the machine where the cache was generated.")
 159 endif()
 160
 161 ########################################################################
 162 # User input options                                                   #
 163 ########################################################################
 164 include(gmxOptionUtilities)
 165
 166 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 167
 168 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 169 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 170 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 171 gmx_dependent_option(
 172     GMX_MPI_IN_PLACE
 173     "Enable MPI_IN_PLACE for MPIs that have it defined"
 174     ON
 175     GMX_MPI)
 176 mark_as_advanced(GMX_MPI_IN_PLACE)
 177 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 178 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 179 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 180 mark_as_advanced(GMX_FAHCORE)
 181
 182 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 183 mark_as_advanced(GMX_COOL_QUOTES)
 184 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 185
 186 # decide on GPU settings based on user-settings and GPU/CUDA detection
 187 include(gmxManageGPU)
 188
 189 # Detect the architecture the compiler is targetting, detect
 190 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 191 # to use if none is specified, and populate the cache option for CPU
 192 # SIMD.
 193 include(gmxDetectTargetArchitecture)
 194 gmx_detect_target_architecture()
 195 include(gmxDetectSimd)
 196 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 197 if("${GMX_SUGGESTED_SIMD}" STREQUAL "AVX2_256")
 198     message(STATUS "Changing acceleration from AVX2 to AVX (until AVX2 patches commited).")
 199     set(GMX_SUGGESTED_SIMD "AVX_256")
 200 endif()
 201
 202 gmx_option_multichoice(
 203     GMX_SIMD
 204     "SIMD instruction set for CPU kernels and compiler optimization"
 205     "${GMX_SUGGESTED_SIMD}"
 206     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 207
 208 gmx_option_multichoice(
 209     GMX_FFT_LIBRARY
 210     "FFT library"
 211     "fftw3"
 212     fftw3 mkl "fftpack[built-in]")
 213 gmx_dependent_option(
 214     GMX_BUILD_OWN_FFTW
 215     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 216     OFF
 217     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 218 gmx_dependent_option(
 219     GMX_DISABLE_FFTW_MEASURE
 220     "Do not optimize FFTW setups (not needed with SSE)"
 221     OFF
 222     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 223 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 224 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 225
 226 gmx_option_multichoice(
 227     GMX_QMMM_PROGRAM
 228     "QM package for QM/MM"
 229     None
 230     none gaussian mopac gamess orca)
 231
 232 gmx_dependent_cache_variable(GMX_NBNXN_REF_KERNEL_TYPE "Reference kernel type (4xn or 2xnn)" STRING "4xn" "GMX_SIMD STREQUAL REFERENCE")
 233 gmx_dependent_cache_variable(GMX_NBNXN_REF_KERNEL_WIDTH "Reference kernel width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 234
 235 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 236 mark_as_advanced(GMX_BROKEN_CALLOC)
 237 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 238 mark_as_advanced(GMX_LOAD_PLUGINS)
 239
 240 option(GMX_GPU  "Enable GPU acceleration" ON)
 241 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 242
 243 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 244
 245 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 246 mark_as_advanced(GMX_GIT_VERSION_INFO)
 247
 248 if(UNIX)
 249     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 250 endif()
 251 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 252
 253 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 254 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 255
 256 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 257 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 258
 259 option(GMX_BUILD_FOR_COVERAGE
 260        "Tune build for better code coverage metrics (e.g., disable asserts)"
 261        OFF)
 262 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 263
 264
 265 ######################################################################
 266 # Detect OpenMP support
 267 ######################################################################
 268 # The OpenMP detection _must_ come before tests for other CFLAGS.
 269 include(gmxManageOpenMP)
 270
 271
 272
 273 ######################################################################
 274 # Compiler tests
 275 # These need to be done early (before further tests).
 276 #####################################################################
 277
 278 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 279 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 280 # invalid options with the Intel Compilers.
 281 # These files should be removed from the source tree when a CMake version that
 282 # includes the features in question becomes required for building GROMACS.
 283 include(CheckCCompilerFlag)
 284 include(CheckCXXCompilerFlag)
 285
 286
 287 include(gmxCFlags)
 288 gmx_c_flags()
 289
 290 # This variable should be used for additional compiler flags which are not
 291 # generated in gmxCFlags nor are SIMD or MPI related.
 292 set(EXTRA_C_FLAGS "")
 293 set(EXTRA_CXX_FLAGS "")
 294
 295 # Run through a number of tests for buggy compilers and other issues
 296 include(gmxTestCompilerProblems)
 297 gmx_test_compiler_problems()
 298
 299
 300 set(PKG_CFLAGS "")
 301 if(GMX_DOUBLE)
 302     add_definitions(-DGMX_DOUBLE)
 303     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 304 endif(GMX_DOUBLE)
 305 if(GMX_SOFTWARE_INVSQRT)
 306   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 307 endif(GMX_SOFTWARE_INVSQRT)
 308
 309
 310
 311 ########################################################################
 312 # Basic system tests (standard libraries, headers, functions, types)   #
 313 ########################################################################
 314 include(CheckIncludeFiles)
 315 include(CheckIncludeFileCXX)
 316 check_include_files(unistd.h     HAVE_UNISTD_H)
 317 check_include_files(pwd.h        HAVE_PWD_H)
 318 check_include_files(dirent.h     HAVE_DIRENT_H)
 319 check_include_files(time.h       HAVE_TIME_H)
 320 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 321 check_include_files(io.h         HAVE_IO_H)
 322 check_include_files(sched.h      HAVE_SCHED_H)
 323
 324 check_include_files(regex.h      HAVE_POSIX_REGEX)
 325 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 326 # TODO: It could be nice to inform the user if no regex support is found,
 327 # as selections won't be fully functional.
 328
 329 include(CheckFunctionExists)
 330 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 331 check_function_exists(memalign          HAVE_MEMALIGN)
 332 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 333 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 334 check_function_exists(fsync             HAVE_FSYNC)
 335 check_function_exists(_fileno           HAVE__FILENO)
 336 check_function_exists(fileno            HAVE_FILENO)
 337 check_function_exists(_commit           HAVE__COMMIT)
 338 check_function_exists(sigaction         HAVE_SIGACTION)
 339 check_function_exists(sysconf           HAVE_SYSCONF)
 340 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 341 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 342 check_function_exists(rsqrt             HAVE_RSQRT)
 343 check_function_exists(rsqrtf            HAVE_RSQRTF)
 344 check_function_exists(sqrtf             HAVE_SQRTF)
 345
 346 include(CheckLibraryExists)
 347 check_library_exists(m sqrt "" HAVE_LIBM)
 348 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 349
 350 include(TestBigEndian)
 351 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 352
 353 # Management of GROMACS options for specific toolchains should go
 354 # here. Because the initial settings for some of the main options have
 355 # already happened, but things like library detection and MPI compiler
 356 # feature detection have not, the docstrings for any over-rides of
 357 # GROMACS defaults or user settings will make sense. Also, any
 358 # toolchain-related reasons for choosing whether to detect various
 359 # things can be sorted out now, before the detection takes place.
 360 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 361     include(gmxManageBlueGene)
 362 endif()
 363
 364 ########################################################################
 365 #Process MPI settings
 366 ########################################################################
 367 include(gmxManageMPI)
 368
 369
 370 ########################################################################
 371 #Process shared/static library settings
 372 ########################################################################
 373 include(gmxManageSharedLibraries)
 374
 375
 376 ########################################################################
 377 # Find external packages                                               #
 378 ########################################################################
 379
 380 # Unconditionally find the package, as it is also required for unit
 381 # tests. This exports LIBXML2_FOUND, which we should not use because
 382 # it does not tell us that linking will succeed. Instead, we test that
 383 # next.
 384 find_package(LibXml2)
 385 include(gmxTestLibXml2)
 386 gmx_test_libxml2(HAVE_LIBXML2)
 387 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 388 set(PKG_XML "")
 389 mark_as_advanced(GMX_XML)
 390 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 391 #if(GMX_XML AND NOT HAVE_LIBXML2)
 392 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 393 #endif()
 394 #if(GMX_XML)
 395 #    include_directories(${LIBXML2_INCLUDE_DIR})
 396 #    set(PKG_XML libxml-2.0)
 397 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 398 #endif(GMX_XML)
 399
 400 option(GMX_GSL "Add support for gsl" OFF)
 401 if (GMX_GSL)
 402   find_package(GSL)
 403   set(PKG_GSL "")
 404   if(GSL_FOUND)
 405     include_directories(${GSL_INCLUDE_DIR})
 406     set(PKG_GSL gsl)
 407     set(HAVE_LIBGSL 1)
 408   endif(GSL_FOUND)
 409 endif (GMX_GSL)
 410
 411 option(GMX_X11 "Use X window system" OFF)
 412 if (GMX_X11)
 413     find_package(X11)
 414     # X11 includes/libraries are only set in the ngmx subdirectory!
 415     if(NOT X11_FOUND)
 416         message(FATAL_ERROR
 417                 "X11 include files and/or libraries were not found. "
 418                 "Set GMX_X11=OFF to compile without X11 support. "
 419                 "gmx view will not be available.")
 420     endif()
 421     include_directories(${X11_INCLUDE_DIR})
 422 endif(GMX_X11)
 423
 424 include(ThreadMPI)
 425 set(THREAD_MPI_LIB thread_mpi)
 426 # Enable core threading facilities
 427 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 428 # Enable tMPI C++ support
 429 tmpi_enable_cxx()
 430 if(GMX_THREAD_MPI)
 431     # enable MPI functions
 432     tmpi_enable()
 433     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 434     set(GMX_MPI 1)
 435     set(MPI_IN_PLACE_EXISTS 1)
 436 endif(GMX_THREAD_MPI)
 437 tmpi_get_source_list(THREAD_MPI_SRC)
 438 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 439 if (TMPI_ATOMICS_DISABLED)
 440    add_definitions(-DTMPI_ATOMICS_DISABLED)
 441 endif()
 442
 443 if(GMX_GPU)
 444     # now that we have detected the dependencies, do the second configure pass
 445     gmx_gpu_setup()
 446 endif(GMX_GPU)
 447
 448 if(CYGWIN)
 449     set(GMX_CYGWIN 1)
 450 endif(CYGWIN)
 451
 452 if(WIN32 AND NOT CYGWIN)
 453     set(GMX_NATIVE_WINDOWS 1)
 454     # This makes windows.h not declare min/max as macros that would break
 455     # C++ code using std::min/std::max.
 456     add_definitions(-DNOMINMAX)
 457 endif()
 458
 459 # only bother with finding git and using version.h if the source is a git repo
 460 if(GMX_GIT_VERSION_INFO)
 461     if (NOT SOURCE_IS_GIT_REPOSITORY)
 462         message(FATAL_ERROR
 463             "Cannot generate git version information from source tree not under git. "
 464             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 465     endif ()
 466     # We need at least git v1.5.3 be able to parse git's date output. If not
 467     # found or the version is too small, we can't generate version information.
 468     find_package(Git)
 469
 470     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 471         message(FATAL_ERROR
 472             "No compatible git version found (>= 1.5.3 required). "
 473             "Won't be able to generate development version information. "
 474             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 475     endif()
 476 endif()
 477
 478 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 479 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 480 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 481     find_package(Boost 1.44.0)
 482     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 483         set(Boost_FOUND FALSE)
 484     endif()
 485     # Print the notification only on first run, when determining the default
 486     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 487         message("Boost >= 1.44 not found. Using minimal internal version. "
 488                 "This may cause trouble if you plan on compiling/linking other "
 489                 "software that uses Boost against Gromacs.")
 490     endif()
 491 endif()
 492 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 493        ${Boost_FOUND})
 494 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 495     message(FATAL_ERROR
 496         "Boost >= 1.44 not found. "
 497         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 498         "version of Boost included with Gromacs.")
 499 endif()
 500
 501 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 502 mark_as_advanced(GMX_BUILD_UNITTESTS)
 503 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 504 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 505     message(FATAL_ERROR
 506         "Cannot build unit tests without libxml2. "
 507         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 508 endif()
 509
 510 ########################################################################
 511 # Generate development version info for cache
 512 ########################################################################
 513 # set(GEN_VERSION_INFO_INTERNAL "ON")
 514 # include(gmxGenerateVersionString)
 515
 516 ########################################################################
 517 # Our own GROMACS tests
 518 ########################################################################
 519
 520 add_definitions( -DHAVE_CONFIG_H )
 521 include_directories(${CMAKE_SOURCE_DIR}/src)
 522 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 523 include_directories(${CMAKE_BINARY_DIR}/src)
 524 # Required for gmx_header_config_gen.h to be found before installation
 525 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 526 # Required for now to make old code compile
 527 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 528
 529 include(gmxTestInlineASM)
 530 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 531
 532 include(gmxSetBuildInformation)
 533 gmx_set_build_information()
 534 # Turn on RDTSCP if:
 535 # - the build system's CPU supports it
 536 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 537 #   at this point means that the user set it).
 538 # Note: it's better to not use the later set value of GMX_SIMD because
 539 # it reflects the system's capability of both compiling and running AVX code.
 540 # TODO: After merge with 5.0 one could implement a cache variable dependency
 541 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 542 # after the first cmake pass.
 543 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 544     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 545 else()
 546     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 547 endif()
 548 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 549 mark_as_advanced(GMX_USE_RDTSCP)
 550 if(GMX_USE_RDTSCP)
 551     set(HAVE_RDTSCP 1)
 552 endif()
 553
 554 include(gmxTestFloatFormat)
 555 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 556                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 557                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 558
 559 include(gmxTestLargeFiles)
 560 gmx_test_large_files(GMX_LARGEFILES)
 561
 562 include(gmxTestSignal)
 563 gmx_test_sigusr1(HAVE_SIGUSR1)
 564
 565 include(gmxTestInline)
 566 gmx_test_inline(INLINE_KEYWORD)
 567
 568 include(gmxTestRestrict)
 569 gmx_test_restrict(RESTRICT_KEYWORD)
 570
 571 include(gmxTestPipes)
 572 gmx_test_pipes(HAVE_PIPES)
 573
 574 include(gmxTestIsfinite)
 575 gmx_test_isfinite(HAVE_ISFINITE)
 576 gmx_test__isfinite(HAVE__ISFINITE)
 577 gmx_test__finite(HAVE__FINITE)
 578
 579 include(gmxTestCXX11)
 580 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 581 include(CMakeDependentOption)
 582 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 583 # entirely to keep the compilation environment uniform.
 584 cmake_dependent_option(GMX_CXX11
 585     "Use C++11 features"
 586     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 587 mark_as_advanced(GMX_CXX11)
 588 if(GMX_CXX11)
 589     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 590 endif()
 591
 592
 593 include(gmxTestXDR)
 594 gmx_test_xdr(GMX_SYSTEM_XDR)
 595 if(NOT GMX_SYSTEM_XDR)
 596     set(GMX_INTERNAL_XDR 1)
 597 endif(NOT GMX_SYSTEM_XDR)
 598
 599
 600 ##################################################
 601 # Process SIMD instruction settings
 602 ##################################################
 603 # This checks what flags to add in order to
 604 # support the SIMD instructions we need, and sets
 605 # correct defines for the SIMD instructions supported.
 606 include(gmxTestSimd)
 607 gmx_test_simd()
 608
 609
 610 # Process QM/MM Settings
 611 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 612     set(GMX_QMMM_GAUSSIAN 1)
 613 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 614     set(GMX_QMMM_MOPAC 1)
 615 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 616     set(GMX_QMMM_GAMESS 1)
 617 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 618     set(GMX_QMMM_ORCA 1)
 619 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 620     # nothing to do
 621 else()
 622     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 623 endif()
 624
 625
 626 ##################################################
 627 # Process FFT library settings
 628 ##################################################
 629 include(gmxManageFFTLibraries)
 630
 631
 632 include(gmxManageLinearAlgebraLibraries)
 633
 634 # Whether GROMACS will really try to compile support for VMD plugins
 635 set(GMX_USE_PLUGINS OFF)
 636
 637 if(GMX_LOAD_PLUGINS)
 638   if(CYGWIN OR NOT WIN32)
 639     # Native Windows does not have, nor need dlopen
 640     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 641     include(gmxTestdlopen)
 642     gmx_test_dlopen(HAVE_DLOPEN)
 643   endif()
 644
 645   # so, should we use plug-ins?
 646   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 647     if(NOT VMD_QUIETLY)
 648       MESSAGE(STATUS
 649           "Found the ability to use plug-ins when building shared libaries, "
 650           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 651           "formats).")
 652     endif()
 653     if(NOT GMX_VMD_PLUGIN_PATH)
 654       find_package(VMD)
 655     endif()
 656     set(GMX_USE_PLUGINS ON)
 657     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 658     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 659   else()
 660     set(PKG_DL_LIBS)
 661   endif()
 662 endif(GMX_LOAD_PLUGINS)
 663 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 664
 665 # Link real-time library for POSIX timers. The check for clock_gettime
 666 # confirms the linkability of rt.
 667 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 668     list(APPEND GMX_EXTRA_LIBRARIES rt)
 669 endif()
 670
 671 # Math and thread libraries must often come after all others when linking...
 672 if(HAVE_LIBM)
 673     list(APPEND GMX_EXTRA_LIBRARIES m)
 674 endif(HAVE_LIBM)
 675 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 676     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 677     if(HAVE_MASS_SIMD)
 678         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 679     else()
 680         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 681     endif()
 682 endif()
 683
 684
 685 option(GMX_NACL "Configure for Native Client builds" OFF)
 686 if (GMX_NACL)
 687   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 688   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 689   set(GMX_NO_NICE 1)
 690   set(GMX_NO_RENAME 1)
 691 endif()
 692 mark_as_advanced(GMX_NACL)
 693
 694 if(GMX_FAHCORE)
 695   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 696       "Path to swindirect.h")
 697   include_directories(${COREWRAP_INCLUDE_DIR})
 698 endif(GMX_FAHCORE)
 699
 700 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 701 mark_as_advanced(GMX_BUILD_HELP)
 702 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 703     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 704
 705     message(FATAL_ERROR
 706         "Rebuilding HTML and man pages is not supported for in-source "
 707         "builds from a source distribution. "
 708         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 709 endif()
 710
 711 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 712 # these are set after everything else
 713 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 714     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 715     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 716     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 717     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 718 else()
 719     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 720     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 721     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 722     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 723     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 724     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 725     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 726     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 727     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 728 endif()
 729
 730 if(NOT GMX_OPENMP)
 731     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 732     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 733     unset(OpenMP_C_FLAGS CACHE)
 734     unset(OpenMP_CXX_FLAGS CACHE)
 735 else()
 736     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 737     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 738 endif()
 739 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 740
 741 ########################################################################
 742 # Specify install locations
 743 ########################################################################
 744 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 745     "Library installation directory (default: lib)")
 746 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 747     "Data installation directory under share/ (default: gromacs)")
 748 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 749
 750 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 751 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 752 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 753 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 754 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 755
 756 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 757 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 758
 759 # Binary and library suffix options
 760 include(gmxManageSuffixes)
 761
 762 ##################################################################
 763 # Shared library settings
 764 ##################################################################
 765 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 766     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 767         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 768     endif()
 769     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 770     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 771 else()
 772     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 773         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 774         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 775     else()
 776         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 777     endif()
 778 endif()
 779
 780 #COPYING file: Only necessary for binary distributions.
 781 #Simpler to always install.
 782 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 783
 784 if(GMX_EXTERNAL_BOOST)
 785     include_directories(${Boost_INCLUDE_DIRS})
 786     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 787 else()
 788     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 789     # typeid not supported for minimal internal version
 790     # (would add significant amount of code)
 791     add_definitions(-DBOOST_NO_TYPEID)
 792     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 793     # (from share/template/)
 794     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 795     if (NOT GMX_BUILD_MDRUN_ONLY)
 796         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 797                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 798                 COMPONENT development)
 799     endif ()
 800 endif()
 801
 802 if(GMX_USE_TNG)
 803     find_package(ZLIB)
 804     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 805     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 806     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 807     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 808     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 809     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 810     set(GMX_TNG_LIBRARIES tng_io)
 811 endif()
 812 mark_as_advanced(TNG_BUILD_FORTRAN)
 813 mark_as_advanced(TNG_BUILD_EXAMPLES)
 814 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 815 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 816 mark_as_advanced(TNG_BUILD_TEST)
 817 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 818
 819 if (GMX_BUILD_FOR_COVERAGE)
 820     # Code heavy with asserts makes conditional coverage close to useless metric,
 821     # as by design most of the false branches are impossible to trigger in
 822     # correctly functioning code.  And the benefit of testing those that could
 823     # be triggered by using an API against its specification isn't usually
 824     # worth the effort.
 825     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 826 endif ()
 827
 828 if (BUILD_TESTING)
 829     # "tests" target builds all the separate test binaries.
 830     add_custom_target(tests)
 831     # "run-ctest" is an internal target that actually runs the tests.
 832     # This is necessary to be able to add separate targets that execute as part
 833     # of 'make check', but are ensured to be executed after the actual tests.
 834     add_custom_target(run-ctest
 835                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 836                       COMMENT "Running all tests"
 837                       VERBATIM)
 838     add_dependencies(run-ctest tests)
 839     # "check" target builds and runs all tests.
 840     add_custom_target(check DEPENDS run-ctest)
 841 endif()
 842
 843 if (NOT GMX_BUILD_MDRUN_ONLY)
 844     add_subdirectory(doxygen)
 845     add_subdirectory(share)
 846     add_subdirectory(scripts)
 847 endif ()
 848 add_subdirectory(src)
 849
 850 if (BUILD_TESTING)
 851     add_subdirectory(tests)
 852 endif()
 853
 854 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 855 # Don't bother the user after the first configure pass.
 856 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 857     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 858 endif()
 859 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 860
 861 #######################
 862 ## uninstall target
 863 #######################
 864     CONFIGURE_FILE(
 865                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 866                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 867                    IMMEDIATE @ONLY)
 868 ###########################
 869 ADD_CUSTOM_TARGET(uninstall
 870                   "${CMAKE_COMMAND}" -P
 871                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 872 ###########################
 873
 874 ########################################################################
 875 # Manual                                                               #
 876 ########################################################################
 877
 878 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 879 mark_as_advanced(GMX_BUILD_MANUAL)
 880 if(GMX_BUILD_MANUAL)
 881     # Make sure we only do detection of manual-building dependencies
 882     # when the user opted in for that.
 883     add_subdirectory(manual)
 884 endif()