CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif()
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98 include(gmxBuildTypeThreadSanitizer)
  99 include(gmxBuildTypeReleaseWithAssert)
 100
 101 if(NOT CMAKE_BUILD_TYPE)
 102     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 103     # There's no need to offer a user the choice of ThreadSanitizer
 104     # Set the possible values of build type for cmake-gui
 105     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 106         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 107 endif()
 108 if(CMAKE_CONFIGURATION_TYPES)
 109     # Add appropriate GROMACS-specific build types for the Visual
 110     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 111     # are already present by default).
 112     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 113     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 114     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 115         "List of configuration types"
 116         FORCE)
 117 endif()
 118 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 119
 120 enable_language(C)
 121 enable_language(CXX)
 122
 123 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 124 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 125 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 126 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 127 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 128 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 129 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 130 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 131 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 132 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 133 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 134
 135 #must come after all cpack settings!
 136 include(CPack)
 137
 138 # Set a default valgrind suppression file.
 139 # This unfortunately needs to duplicate information from CTest to work as
 140 # expected...
 141 set(MEMORYCHECK_SUPPRESSIONS_FILE
 142     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 143     CACHE FILEPATH
 144     "File that contains suppressions for the memory checker")
 145 include(CTest)
 146
 147 set(SOURCE_IS_GIT_REPOSITORY OFF)
 148 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 149 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 150     set(SOURCE_IS_GIT_REPOSITORY ON)
 151 endif()
 152 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 153     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 154 endif()
 155
 156 ########################################################################
 157 # Check and warn if cache generated on a different host is being reused
 158 ########################################################################
 159 if(CMAKE_HOST_UNIX)
 160     execute_process(COMMAND hostname
 161                     OUTPUT_VARIABLE TMP_HOSTNAME
 162                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 163     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 164         message(WARNING "
 165             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 166             is being reused! This could lead to inconsitencies; therefore, it is
 167             recommended to regenerate the cache!")
 168     endif()
 169     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 170             "Hostname of the machine where the cache was generated.")
 171 endif()
 172
 173 ########################################################################
 174 # User input options                                                   #
 175 ########################################################################
 176 include(gmxOptionUtilities)
 177
 178 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 179
 180 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 181 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 182 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 183 gmx_dependent_option(
 184     GMX_MPI_IN_PLACE
 185     "Enable MPI_IN_PLACE for MPIs that have it defined"
 186     ON
 187     GMX_MPI)
 188 mark_as_advanced(GMX_MPI_IN_PLACE)
 189 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 190 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 # decide on GPU settings based on user-settings and GPU/CUDA detection
 199 include(gmxManageGPU)
 200
 201 # Detect the architecture the compiler is targetting, detect
 202 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 203 # to use if none is specified, and populate the cache option for CPU
 204 # SIMD.
 205 include(gmxDetectTargetArchitecture)
 206 gmx_detect_target_architecture()
 207
 208 if(GMX_CPU_ACCELERATION)
 209     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 210     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 211 endif()
 212
 213 if(NOT GMX_TARGET_MIC)
 214     include(gmxDetectSimd)
 215     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 216 else()
 217     set(GMX_SUGGESTED_SIMD "None")
 218 endif()
 219
 220 gmx_option_multichoice(
 221     GMX_SIMD
 222     "SIMD instruction set for CPU kernels and compiler optimization"
 223     "${GMX_SUGGESTED_SIMD}"
 224     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 225
 226 gmx_option_multichoice(
 227     GMX_FFT_LIBRARY
 228     "FFT library"
 229     "fftw3"
 230     fftw3 mkl "fftpack[built-in]")
 231 gmx_dependent_option(
 232     GMX_BUILD_OWN_FFTW
 233     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 234     OFF
 235     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 236 gmx_dependent_option(
 237     GMX_DISABLE_FFTW_MEASURE
 238     "Do not optimize FFTW setups (not needed with SSE)"
 239     OFF
 240     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 241 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 242 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 243
 244 gmx_option_multichoice(
 245     GMX_QMMM_PROGRAM
 246     "QM package for QM/MM"
 247     None
 248     none gaussian mopac gamess orca)
 249
 250 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 251 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 252
 253 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 254
 255 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 256 mark_as_advanced(GMX_BROKEN_CALLOC)
 257 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 258 mark_as_advanced(GMX_LOAD_PLUGINS)
 259
 260 option(GMX_GPU  "Enable GPU acceleration" ON)
 261 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 262
 263 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 264
 265 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 266 mark_as_advanced(GMX_GIT_VERSION_INFO)
 267
 268 if(UNIX)
 269     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 270 endif()
 271 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 272
 273 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 274 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 275
 276 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 277 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 278
 279 option(GMX_BUILD_FOR_COVERAGE
 280        "Tune build for better code coverage metrics (e.g., disable asserts)"
 281        OFF)
 282 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 283
 284
 285 ######################################################################
 286 # Detect OpenMP support
 287 ######################################################################
 288 # The OpenMP detection _must_ come before tests for other CFLAGS.
 289 include(gmxManageOpenMP)
 290
 291
 292
 293 ######################################################################
 294 # Compiler tests
 295 # These need to be done early (before further tests).
 296 #####################################################################
 297
 298 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 299 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 300 # invalid options with the Intel Compilers.
 301 # These files should be removed from the source tree when a CMake version that
 302 # includes the features in question becomes required for building GROMACS.
 303 include(CheckCCompilerFlag)
 304 include(CheckCXXCompilerFlag)
 305
 306
 307 include(gmxCFlags)
 308 gmx_c_flags()
 309
 310 # This variable should be used for additional compiler flags which are not
 311 # generated in gmxCFlags nor are SIMD or MPI related.
 312 set(EXTRA_C_FLAGS "")
 313 set(EXTRA_CXX_FLAGS "")
 314
 315 # Run through a number of tests for buggy compilers and other issues
 316 include(gmxTestCompilerProblems)
 317 gmx_test_compiler_problems()
 318
 319
 320 set(PKG_CFLAGS "")
 321 if(GMX_DOUBLE)
 322     add_definitions(-DGMX_DOUBLE)
 323     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 324 endif()
 325 if(GMX_SOFTWARE_INVSQRT)
 326   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 327 endif()
 328
 329 if(WIN32 AND NOT CYGWIN)
 330     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 331     mark_as_advanced(GMX_WSOCKLIB_PATH)
 332     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 333     if(WSOCK32_LIBRARY)
 334         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 335         add_definitions(-DGMX_HAVE_WINSOCK)
 336     else()
 337         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 338     endif(WSOCK32_LIBRARY)
 339 endif()
 340
 341
 342
 343 ########################################################################
 344 # Basic system tests (standard libraries, headers, functions, types)   #
 345 ########################################################################
 346 include(CheckIncludeFiles)
 347 include(CheckIncludeFileCXX)
 348 check_include_files(unistd.h     HAVE_UNISTD_H)
 349 check_include_files(pwd.h        HAVE_PWD_H)
 350 check_include_files(dirent.h     HAVE_DIRENT_H)
 351 check_include_files(time.h       HAVE_TIME_H)
 352 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 353 check_include_files(io.h         HAVE_IO_H)
 354 check_include_files(sched.h      HAVE_SCHED_H)
 355
 356 check_include_files(regex.h      HAVE_POSIX_REGEX)
 357 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 358 # TODO: It could be nice to inform the user if no regex support is found,
 359 # as selections won't be fully functional.
 360
 361 include(CheckFunctionExists)
 362 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 363 check_function_exists(memalign          HAVE_MEMALIGN)
 364 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 365 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 366 check_function_exists(fsync             HAVE_FSYNC)
 367 check_function_exists(_fileno           HAVE__FILENO)
 368 check_function_exists(fileno            HAVE_FILENO)
 369 check_function_exists(_commit           HAVE__COMMIT)
 370 check_function_exists(sigaction         HAVE_SIGACTION)
 371 check_function_exists(sysconf           HAVE_SYSCONF)
 372 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 373 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 374 check_function_exists(rsqrt             HAVE_RSQRT)
 375 check_function_exists(rsqrtf            HAVE_RSQRTF)
 376 check_function_exists(sqrtf             HAVE_SQRTF)
 377
 378 include(CheckLibraryExists)
 379 check_library_exists(m sqrt "" HAVE_LIBM)
 380 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 381
 382 include(TestBigEndian)
 383 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 384
 385 # Management of GROMACS options for specific toolchains should go
 386 # here. Because the initial settings for some of the main options have
 387 # already happened, but things like library detection and MPI compiler
 388 # feature detection have not, the docstrings for any over-rides of
 389 # GROMACS defaults or user settings will make sense. Also, any
 390 # toolchain-related reasons for choosing whether to detect various
 391 # things can be sorted out now, before the detection takes place.
 392 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 393     include(gmxManageBlueGene)
 394 endif()
 395
 396 ########################################################################
 397 #Process MPI settings
 398 ########################################################################
 399 include(gmxManageMPI)
 400
 401
 402 ########################################################################
 403 #Process shared/static library settings
 404 ########################################################################
 405 include(gmxManageSharedLibraries)
 406
 407
 408 ########################################################################
 409 # Find external packages                                               #
 410 ########################################################################
 411
 412 # Unconditionally find the package, as it is also required for unit
 413 # tests. This exports LIBXML2_FOUND, which we should not use because
 414 # it does not tell us that linking will succeed. Instead, we test that
 415 # next.
 416 find_package(LibXml2)
 417 include(gmxTestLibXml2)
 418 gmx_test_libxml2(HAVE_LIBXML2)
 419 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 420 set(PKG_XML "")
 421 mark_as_advanced(GMX_XML)
 422 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 423 #if(GMX_XML AND NOT HAVE_LIBXML2)
 424 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 425 #endif()
 426 #if(GMX_XML)
 427 #    include_directories(${LIBXML2_INCLUDE_DIR})
 428 #    set(PKG_XML libxml-2.0)
 429 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 430 #endif()
 431
 432 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 433 mark_as_advanced(GMX_EXTRAE)
 434
 435 if (GMX_EXTRAE)
 436   find_package(EXTRAE)
 437   if(EXTRAE_FOUND)
 438     include_directories(${EXTRAE_INCLUDE_DIR})
 439     set(HAVE_EXTRAE 1)
 440   else()
 441     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 442   endif()
 443 endif()
 444
 445 option(GMX_X11 "Use X window system" OFF)
 446 if (GMX_X11)
 447     find_package(X11)
 448     # X11 includes/libraries are only set in the ngmx subdirectory!
 449     if(NOT X11_FOUND)
 450         message(FATAL_ERROR
 451                 "X11 include files and/or libraries were not found. "
 452                 "Set GMX_X11=OFF to compile without X11 support. "
 453                 "gmx view will not be available.")
 454     endif()
 455     include_directories(${X11_INCLUDE_DIR})
 456 endif()
 457
 458 include(ThreadMPI)
 459 # Enable core threading facilities
 460 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 461 # Enable tMPI C++ support
 462 tmpi_enable_cxx()
 463 if(GMX_THREAD_MPI)
 464     # enable MPI functions
 465     tmpi_enable()
 466     set(GMX_MPI 1)
 467     set(MPI_IN_PLACE_EXISTS 1)
 468 endif()
 469 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 470 if (TMPI_ATOMICS_DISABLED)
 471    add_definitions(-DTMPI_ATOMICS_DISABLED)
 472 endif()
 473
 474 if(GMX_GPU)
 475     # now that we have detected the dependencies, do the second configure pass
 476     gmx_gpu_setup()
 477 endif()
 478
 479 if(CYGWIN)
 480     set(GMX_CYGWIN 1)
 481 endif()
 482
 483 if(WIN32 AND NOT CYGWIN)
 484     set(GMX_NATIVE_WINDOWS 1)
 485     # This makes windows.h not declare min/max as macros that would break
 486     # C++ code using std::min/std::max.
 487     add_definitions(-DNOMINMAX)
 488 endif()
 489
 490 # only bother with finding git and using version.h if the source is a git repo
 491 if(GMX_GIT_VERSION_INFO)
 492     if (NOT SOURCE_IS_GIT_REPOSITORY)
 493         message(FATAL_ERROR
 494             "Cannot generate git version information from source tree not under git. "
 495             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 496     endif()
 497     # We need at least git v1.5.3 be able to parse git's date output. If not
 498     # found or the version is too small, we can't generate version information.
 499     find_package(Git)
 500
 501     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 502         message(FATAL_ERROR
 503             "No compatible git version found (>= 1.5.3 required). "
 504             "Won't be able to generate development version information. "
 505             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 506     endif()
 507 endif()
 508
 509 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 510 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 511 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 512     find_package(Boost 1.44.0)
 513     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 514         set(Boost_FOUND FALSE)
 515     endif()
 516     # Print the notification only on first run, when determining the default
 517     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 518         message("Boost >= 1.44 not found. Using minimal internal version. "
 519                 "This may cause trouble if you plan on compiling/linking other "
 520                 "software that uses Boost against Gromacs.")
 521     endif()
 522 endif()
 523 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 524        ${Boost_FOUND})
 525 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 526     message(FATAL_ERROR
 527         "Boost >= 1.44 not found. "
 528         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 529         "version of Boost included with Gromacs.")
 530 endif()
 531
 532 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 533 mark_as_advanced(GMX_BUILD_UNITTESTS)
 534 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 535 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 536     message(FATAL_ERROR
 537         "Cannot build unit tests without libxml2. "
 538         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 539 endif()
 540
 541 ########################################################################
 542 # Generate development version info for cache
 543 ########################################################################
 544 # set(GEN_VERSION_INFO_INTERNAL "ON")
 545 # include(gmxGenerateVersionString)
 546
 547 ########################################################################
 548 # Our own GROMACS tests
 549 ########################################################################
 550
 551 add_definitions( -DHAVE_CONFIG_H )
 552 include_directories(${CMAKE_SOURCE_DIR}/src)
 553 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 554 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 555 include_directories(${CMAKE_BINARY_DIR}/src)
 556 # Required for gmx_header_config_gen.h to be found before installation
 557 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 558 # Required for now to make old code compile
 559 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 560
 561 include(gmxTestInlineASM)
 562 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 563
 564 include(gmxSetBuildInformation)
 565 gmx_set_build_information()
 566 # Turn on RDTSCP if:
 567 # - the build system's CPU supports it
 568 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 569 #   at this point means that the user set it).
 570 # Note: it's better to not use the later set value of GMX_SIMD because
 571 # it reflects the system's capability of both compiling and running AVX code.
 572 # TODO: After merge with 5.0 one could implement a cache variable dependency
 573 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 574 # after the first cmake pass.
 575 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 576     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 577 else()
 578     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 579 endif()
 580 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 581 mark_as_advanced(GMX_USE_RDTSCP)
 582 if(GMX_USE_RDTSCP)
 583     set(HAVE_RDTSCP 1)
 584 endif()
 585
 586 include(gmxTestFloatFormat)
 587 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 588                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 589                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 590
 591 include(gmxTestLargeFiles)
 592 gmx_test_large_files(GMX_LARGEFILES)
 593
 594 include(gmxTestSignal)
 595 gmx_test_sigusr1(HAVE_SIGUSR1)
 596
 597 include(gmxTestPipes)
 598 gmx_test_pipes(HAVE_PIPES)
 599
 600 include(gmxTestIsfinite)
 601 gmx_test_isfinite(HAVE_ISFINITE)
 602 gmx_test__isfinite(HAVE__ISFINITE)
 603 gmx_test__finite(HAVE__FINITE)
 604
 605 include(gmxTestCXX11)
 606 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 607 include(CMakeDependentOption)
 608 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 609 # entirely to keep the compilation environment uniform.
 610 cmake_dependent_option(GMX_CXX11
 611     "Use C++11 features"
 612     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 613 mark_as_advanced(GMX_CXX11)
 614 if(GMX_CXX11)
 615     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 616 endif()
 617
 618
 619 include(gmxTestXDR)
 620 gmx_test_xdr(GMX_SYSTEM_XDR)
 621 if(NOT GMX_SYSTEM_XDR)
 622     set(GMX_INTERNAL_XDR 1)
 623 endif()
 624
 625
 626 ##################################################
 627 # Process SIMD instruction settings
 628 ##################################################
 629 # This checks what flags to add in order to
 630 # support the SIMD instructions we need, and sets
 631 # correct defines for the SIMD instructions supported.
 632 include(gmxTestSimd)
 633 gmx_test_simd()
 634
 635
 636 # Process QM/MM Settings
 637 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 638     set(GMX_QMMM_GAUSSIAN 1)
 639 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 640     set(GMX_QMMM_MOPAC 1)
 641 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 642     set(GMX_QMMM_GAMESS 1)
 643 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 644     set(GMX_QMMM_ORCA 1)
 645 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 646     # nothing to do
 647 else()
 648     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 649 endif()
 650
 651
 652 ##################################################
 653 # Process FFT library settings
 654 ##################################################
 655 include(gmxManageFFTLibraries)
 656
 657
 658 include(gmxManageLinearAlgebraLibraries)
 659
 660 # Whether GROMACS will really try to compile support for VMD plugins
 661 set(GMX_USE_PLUGINS OFF)
 662
 663 if(GMX_LOAD_PLUGINS)
 664   if(CYGWIN OR NOT WIN32)
 665     # Native Windows does not have, nor need dlopen
 666     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 667     include(gmxTestdlopen)
 668     gmx_test_dlopen(HAVE_DLOPEN)
 669   endif()
 670
 671   # so, should we use plug-ins?
 672   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 673     if(NOT VMD_QUIETLY)
 674       MESSAGE(STATUS
 675           "Found the ability to use plug-ins when building shared libaries, "
 676           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 677           "formats).")
 678     endif()
 679     if(NOT GMX_VMD_PLUGIN_PATH)
 680       find_package(VMD)
 681     endif()
 682     set(GMX_USE_PLUGINS ON)
 683     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 684     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 685   else()
 686     set(PKG_DL_LIBS)
 687   endif()
 688 endif()
 689 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 690
 691 # Link real-time library for POSIX timers. The check for clock_gettime
 692 # confirms the linkability of rt.
 693 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 694     list(APPEND GMX_EXTRA_LIBRARIES rt)
 695 endif()
 696
 697 # Math and thread libraries must often come after all others when linking...
 698 if(HAVE_LIBM)
 699     list(APPEND GMX_EXTRA_LIBRARIES m)
 700 endif()
 701
 702 option(GMX_NACL "Configure for Native Client builds" OFF)
 703 if (GMX_NACL)
 704   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 705   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 706   set(GMX_NO_NICE 1)
 707   set(GMX_NO_RENAME 1)
 708 endif()
 709 mark_as_advanced(GMX_NACL)
 710
 711 if(GMX_FAHCORE)
 712   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 713       "Path to swindirect.h")
 714   include_directories(${COREWRAP_INCLUDE_DIR})
 715 endif()
 716
 717 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 718 mark_as_advanced(GMX_BUILD_HELP)
 719 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 720     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 721
 722     message(FATAL_ERROR
 723         "Rebuilding HTML and man pages is not supported for in-source "
 724         "builds from a source distribution. "
 725         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 726 endif()
 727
 728 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 729 # these are set after everything else
 730 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 731     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 732     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 733     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 734     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 735 else()
 736     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 737     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 738     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 739     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 740     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 741     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 742     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 743     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 744     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 745 endif()
 746
 747 if(NOT GMX_OPENMP)
 748     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 749     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 750     unset(OpenMP_C_FLAGS CACHE)
 751     unset(OpenMP_CXX_FLAGS CACHE)
 752 else()
 753     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 754     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 755 endif()
 756 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 757
 758 ########################################################################
 759 # Specify install locations
 760 ########################################################################
 761 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 762     "Library installation directory (default: lib)")
 763 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 764     "Data installation directory under share/ (default: gromacs)")
 765 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 766
 767 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 768 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 769 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 770 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 771 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 772
 773 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 774 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 775
 776 # Binary and library suffix options
 777 include(gmxManageSuffixes)
 778
 779 ##################################################################
 780 # Shared library settings
 781 ##################################################################
 782 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 783     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 784         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 785     endif()
 786     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 787     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 788 else()
 789     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 790         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 791         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 792     else()
 793         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 794     endif()
 795 endif()
 796
 797 #COPYING file: Only necessary for binary distributions.
 798 #Simpler to always install.
 799 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 800
 801 if(GMX_EXTERNAL_BOOST)
 802     include_directories(${Boost_INCLUDE_DIRS})
 803     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 804 else()
 805     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 806     # typeid not supported for minimal internal version
 807     # (would add significant amount of code)
 808     add_definitions(-DBOOST_NO_TYPEID)
 809     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 810     # (from share/template/)
 811     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 812     if (NOT GMX_BUILD_MDRUN_ONLY)
 813         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 814                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 815                 COMPONENT development)
 816     endif()
 817 endif()
 818
 819 if(GMX_USE_TNG)
 820     find_package(ZLIB QUIET)
 821     include(gmxTestZLib)
 822     gmx_test_zlib(HAVE_ZLIB)
 823     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 824     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 825     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 826     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 827     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 828     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 829     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 830     set(GMX_TNG_LIBRARIES tng_io)
 831 endif()
 832 mark_as_advanced(TNG_BUILD_FORTRAN)
 833 mark_as_advanced(TNG_BUILD_EXAMPLES)
 834 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 835 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 836 mark_as_advanced(TNG_BUILD_TEST)
 837 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 838
 839 if (GMX_BUILD_FOR_COVERAGE)
 840     # Code heavy with asserts makes conditional coverage close to useless metric,
 841     # as by design most of the false branches are impossible to trigger in
 842     # correctly functioning code.  And the benefit of testing those that could
 843     # be triggered by using an API against its specification isn't usually
 844     # worth the effort.
 845     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 846 endif()
 847
 848 if (BUILD_TESTING)
 849     # "tests" target builds all the separate test binaries.
 850     add_custom_target(tests)
 851     # "run-ctest" is an internal target that actually runs the tests.
 852     # This is necessary to be able to add separate targets that execute as part
 853     # of 'make check', but are ensured to be executed after the actual tests.
 854     add_custom_target(run-ctest
 855                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 856                       COMMENT "Running all tests"
 857                       VERBATIM)
 858     add_dependencies(run-ctest tests)
 859     # "check" target builds and runs all tests.
 860     add_custom_target(check DEPENDS run-ctest)
 861 endif()
 862
 863 if (NOT GMX_BUILD_MDRUN_ONLY)
 864     add_subdirectory(doxygen)
 865     add_subdirectory(share)
 866     add_subdirectory(scripts)
 867 endif()
 868 add_subdirectory(src)
 869
 870 if (BUILD_TESTING)
 871     add_subdirectory(tests)
 872 endif()
 873
 874 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 875 # Don't bother the user after the first configure pass.
 876 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 877     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 878 endif()
 879 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 880
 881 #######################
 882 ## uninstall target
 883 #######################
 884     CONFIGURE_FILE(
 885                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 886                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 887                    IMMEDIATE @ONLY)
 888 ###########################
 889 ADD_CUSTOM_TARGET(uninstall
 890                   "${CMAKE_COMMAND}" -P
 891                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 892 ###########################
 893
 894 ########################################################################
 895 # Manual                                                               #
 896 ########################################################################
 897
 898 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 899 mark_as_advanced(GMX_BUILD_MANUAL)
 900 if(GMX_BUILD_MANUAL)
 901     # Make sure we only do detection of manual-building dependencies
 902     # when the user opted in for that.
 903     add_subdirectory(manual)
 904 endif()