CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101     # Set the possible values of build type for cmake-gui
 102     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 103         "MinSizeRel" "RelWithDebInfo")
 104 endif(NOT CMAKE_BUILD_TYPE)
 105
 106 enable_language(C)
 107 enable_language(CXX)
 108
 109 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 110 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 111 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 112 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 113 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 114 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 115 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 116 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 117 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 118 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 119 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 120
 121 #must come after all cpack settings!
 122 include(CPack)
 123
 124 # Set a default valgrind suppression file.
 125 # This unfortunately needs to duplicate information from CTest to work as
 126 # expected...
 127 set(MEMORYCHECK_SUPPRESSIONS_FILE
 128     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 129     CACHE FILEPATH
 130     "File that contains suppressions for the memory checker")
 131 include(CTest)
 132
 133 set(SOURCE_IS_GIT_REPOSITORY OFF)
 134 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 135 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 136     set(SOURCE_IS_GIT_REPOSITORY ON)
 137 endif()
 138 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 139     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 140 endif()
 141
 142 ########################################################################
 143 # Check and warn if cache generated on a different host is being reused
 144 ########################################################################
 145 if(CMAKE_HOST_UNIX)
 146     execute_process(COMMAND hostname
 147                     OUTPUT_VARIABLE TMP_HOSTNAME
 148                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 150         message(WARNING "
 151             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 152             is being reused! This could lead to inconsitencies; therefore, it is
 153             recommended to regenerate the cache!")
 154     endif()
 155     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 156             "Hostname of the machine where the cache was generated.")
 157 endif()
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 167 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 168 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 169 gmx_dependent_option(
 170     GMX_MPI_IN_PLACE
 171     "Enable MPI_IN_PLACE for MPIs that have it defined"
 172     ON
 173     GMX_MPI)
 174 mark_as_advanced(GMX_MPI_IN_PLACE)
 175 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 176 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 177 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 178 mark_as_advanced(GMX_FAHCORE)
 179
 180 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 181 mark_as_advanced(GMX_COOL_QUOTES)
 182 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 183
 184 # decide on GPU settings based on user-settings and GPU/CUDA detection
 185 include(gmxManageGPU)
 186
 187 # Detect the architecture the compiler is targetting, detect
 188 # acceleration possibilities on that hardware, suggest an acceleration
 189 # to use if none is specified, and populate the cache option for CPU
 190 # accleration.
 191 include(gmxDetectTargetArchitecture)
 192 gmx_detect_target_architecture()
 193 include(gmxDetectAcceleration)
 194 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 195
 196 gmx_option_multichoice(
 197     GMX_CPU_ACCELERATION
 198     "Acceleration for CPU kernels and compiler optimization"
 199     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 200     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE Reference)
 201
 202 gmx_option_multichoice(
 203     GMX_FFT_LIBRARY
 204     "FFT library"
 205     "fftw3"
 206     fftw3 mkl "fftpack[built-in]")
 207 gmx_dependent_option(
 208     GMX_BUILD_OWN_FFTW
 209     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 210     OFF
 211     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 212 gmx_dependent_option(
 213     GMX_DISABLE_FFTW_MEASURE
 214     "Do not optimize FFTW setups (not needed with SSE)"
 215     OFF
 216     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 217 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 218 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 219
 220 gmx_option_multichoice(
 221     GMX_QMMM_PROGRAM
 222     "QM package for QM/MM"
 223     None
 224     none gaussian mopac gamess orca)
 225
 226 gmx_dependent_cache_variable(GMX_NBNXN_REF_KERNEL_TYPE "Reference kernel type (4xn or 2xnn)" STRING "4xn" "GMX_CPU_ACCELERATION STREQUAL REFERENCE")
 227 gmx_dependent_cache_variable(GMX_NBNXN_REF_KERNEL_WIDTH "Reference kernel width" STRING "4" "GMX_CPU_ACCELERATION STREQUAL REFERENCE")
 228
 229 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 230 mark_as_advanced(GMX_BROKEN_CALLOC)
 231 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 232 mark_as_advanced(GMX_LOAD_PLUGINS)
 233
 234 option(GMX_GPU  "Enable GPU acceleration" ON)
 235 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 236
 237 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 238
 239 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 240 mark_as_advanced(GMX_GIT_VERSION_INFO)
 241
 242 if(UNIX)
 243     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 244 endif()
 245 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 246
 247 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 248 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 249
 250 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 251 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 252
 253 option(GMX_BUILD_FOR_COVERAGE
 254        "Tune build for better code coverage metrics (e.g., disable asserts)"
 255        OFF)
 256 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 257
 258
 259 ######################################################################
 260 # Detect OpenMP support
 261 ######################################################################
 262 # The OpenMP detection _must_ come before tests for other CFLAGS.
 263 include(gmxManageOpenMP)
 264
 265
 266
 267 ######################################################################
 268 # Compiler tests
 269 # These need to be done early (before further tests).
 270 #####################################################################
 271
 272 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 273 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 274 # invalid options with the Intel Compilers.
 275 # These files should be removed from the source tree when a CMake version that
 276 # includes the features in question becomes required for building GROMACS.
 277 include(CheckCCompilerFlag)
 278 include(CheckCXXCompilerFlag)
 279
 280
 281 include(gmxCFlags)
 282 gmx_c_flags()
 283
 284 # This variable should be used for additional compiler flags which are not
 285 # generated in gmxCFlags nor are acceleration or MPI related.
 286 set(EXTRA_C_FLAGS "")
 287 set(EXTRA_CXX_FLAGS "")
 288
 289 # Run through a number of tests for buggy compilers and other issues
 290 include(gmxTestCompilerProblems)
 291 gmx_test_compiler_problems()
 292
 293
 294 set(PKG_CFLAGS "")
 295 if(GMX_DOUBLE)
 296     add_definitions(-DGMX_DOUBLE)
 297     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 298 endif(GMX_DOUBLE)
 299 if(GMX_SOFTWARE_INVSQRT)
 300   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 301 endif(GMX_SOFTWARE_INVSQRT)
 302
 303
 304
 305 ########################################################################
 306 # Basic system tests (standard libraries, headers, functions, types)   #
 307 ########################################################################
 308 include(CheckIncludeFiles)
 309 include(CheckIncludeFileCXX)
 310 check_include_files(unistd.h     HAVE_UNISTD_H)
 311 check_include_files(pwd.h        HAVE_PWD_H)
 312 check_include_files(dirent.h     HAVE_DIRENT_H)
 313 check_include_files(time.h       HAVE_TIME_H)
 314 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 315 check_include_files(io.h         HAVE_IO_H)
 316 check_include_files(sched.h      HAVE_SCHED_H)
 317
 318 check_include_files(regex.h      HAVE_POSIX_REGEX)
 319 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 320 # TODO: It could be nice to inform the user if no regex support is found,
 321 # as selections won't be fully functional.
 322
 323 include(CheckFunctionExists)
 324 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 325 check_function_exists(memalign          HAVE_MEMALIGN)
 326 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 327 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 328 check_function_exists(fsync             HAVE_FSYNC)
 329 check_function_exists(_fileno           HAVE__FILENO)
 330 check_function_exists(fileno            HAVE_FILENO)
 331 check_function_exists(_commit           HAVE__COMMIT)
 332 check_function_exists(sigaction         HAVE_SIGACTION)
 333 check_function_exists(sysconf           HAVE_SYSCONF)
 334 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 335 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 336 check_function_exists(rsqrt             HAVE_RSQRT)
 337 check_function_exists(rsqrtf            HAVE_RSQRTF)
 338 check_function_exists(sqrtf             HAVE_SQRTF)
 339
 340 include(CheckLibraryExists)
 341 check_library_exists(m sqrt "" HAVE_LIBM)
 342 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 343
 344 include(TestBigEndian)
 345 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 346
 347 # Management of GROMACS options for specific toolchains should go
 348 # here. Because the initial settings for some of the main options have
 349 # already happened, but things like library detection and MPI compiler
 350 # feature detection have not, the docstrings for any over-rides of
 351 # GROMACS defaults or user settings will make sense. Also, any
 352 # toolchain-related reasons for choosing whether to detect various
 353 # things can be sorted out now, before the detection takes place.
 354 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 355     include(gmxManageBlueGene)
 356 endif()
 357
 358 ########################################################################
 359 #Process MPI settings
 360 ########################################################################
 361 include(gmxManageMPI)
 362
 363
 364 ########################################################################
 365 #Process shared/static library settings
 366 ########################################################################
 367 include(gmxManageSharedLibraries)
 368
 369
 370 ########################################################################
 371 # Find external packages                                               #
 372 ########################################################################
 373
 374 # Unconditionally find the package, as it is also required for unit
 375 # tests. This exports LIBXML2_FOUND, which we should not use because
 376 # it does not tell us that linking will succeed. Instead, we test that
 377 # next.
 378 find_package(LibXml2)
 379 include(gmxTestLibXml2)
 380 gmx_test_libxml2(HAVE_LIBXML2)
 381 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 382 set(PKG_XML "")
 383 mark_as_advanced(GMX_XML)
 384 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 385 #if(GMX_XML AND NOT HAVE_LIBXML2)
 386 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 387 #endif()
 388 #if(GMX_XML)
 389 #    include_directories(${LIBXML2_INCLUDE_DIR})
 390 #    set(PKG_XML libxml-2.0)
 391 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 392 #endif(GMX_XML)
 393
 394 option(GMX_GSL "Add support for gsl" OFF)
 395 if (GMX_GSL)
 396   find_package(GSL)
 397   set(PKG_GSL "")
 398   if(GSL_FOUND)
 399     include_directories(${GSL_INCLUDE_DIR})
 400     set(PKG_GSL gsl)
 401     set(HAVE_LIBGSL 1)
 402   endif(GSL_FOUND)
 403 endif (GMX_GSL)
 404
 405 option(GMX_X11 "Use X window system" OFF)
 406 if (GMX_X11)
 407     find_package(X11)
 408     # X11 includes/libraries are only set in the ngmx subdirectory!
 409     if(NOT X11_FOUND)
 410         message(FATAL_ERROR
 411                 "X11 include files and/or libraries were not found. "
 412                 "Set GMX_X11=OFF to compile without X11 support. "
 413                 "gmx view will not be available.")
 414     endif()
 415     include_directories(${X11_INCLUDE_DIR})
 416 endif(GMX_X11)
 417
 418 include(ThreadMPI)
 419 set(THREAD_MPI_LIB thread_mpi)
 420 # Enable core threading facilities
 421 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 422 # Enable tMPI C++ support
 423 tmpi_enable_cxx()
 424 if(GMX_THREAD_MPI)
 425     # enable MPI functions
 426     tmpi_enable()
 427     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 428     set(GMX_MPI 1)
 429     set(MPI_IN_PLACE_EXISTS 1)
 430 endif(GMX_THREAD_MPI)
 431 tmpi_get_source_list(THREAD_MPI_SRC)
 432
 433 if(GMX_GPU)
 434     # now that we have detected the dependencies, do the second configure pass
 435     gmx_gpu_setup()
 436 endif(GMX_GPU)
 437
 438 if(CYGWIN)
 439     set(GMX_CYGWIN 1)
 440 endif(CYGWIN)
 441
 442 if(WIN32 AND NOT CYGWIN)
 443     set(GMX_NATIVE_WINDOWS 1)
 444     # This makes windows.h not declare min/max as macros that would break
 445     # C++ code using std::min/std::max.
 446     add_definitions(-DNOMINMAX)
 447 endif()
 448
 449 # only bother with finding git and using version.h if the source is a git repo
 450 if(GMX_GIT_VERSION_INFO)
 451     if (NOT SOURCE_IS_GIT_REPOSITORY)
 452         message(FATAL_ERROR
 453             "Cannot generate git version information from source tree not under git. "
 454             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 455     endif ()
 456     # We need at least git v1.5.3 be able to parse git's date output. If not
 457     # found or the version is too small, we can't generate version information.
 458     find_package(Git)
 459
 460     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 461         message(FATAL_ERROR
 462             "No compatible git version found (>= 1.5.3 required). "
 463             "Won't be able to generate development version information. "
 464             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 465     endif()
 466 endif()
 467
 468 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 469 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 470 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 471     find_package(Boost 1.44.0)
 472     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 473         set(Boost_FOUND FALSE)
 474     endif()
 475     # Print the notification only on first run, when determining the default
 476     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 477         message("Boost >= 1.44 not found. Using minimal internal version. "
 478                 "This may cause trouble if you plan on compiling/linking other "
 479                 "software that uses Boost against Gromacs.")
 480     endif()
 481 endif()
 482 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 483        ${Boost_FOUND})
 484 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 485     message(FATAL_ERROR
 486         "Boost >= 1.44 not found. "
 487         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 488         "version of Boost included with Gromacs.")
 489 endif()
 490
 491 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 492 mark_as_advanced(GMX_BUILD_UNITTESTS)
 493 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 494 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 495     message(FATAL_ERROR
 496         "Cannot build unit tests without libxml2. "
 497         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 498 endif()
 499
 500 ########################################################################
 501 # Generate development version info for cache
 502 ########################################################################
 503 # set(GEN_VERSION_INFO_INTERNAL "ON")
 504 # include(gmxGenerateVersionString)
 505
 506 ########################################################################
 507 # Our own GROMACS tests
 508 ########################################################################
 509
 510 add_definitions( -DHAVE_CONFIG_H )
 511 include_directories(${CMAKE_SOURCE_DIR}/src)
 512 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 513 include_directories(${CMAKE_BINARY_DIR}/src)
 514 # Required for gmx_header_config_gen.h to be found before installation
 515 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 516 # Required for now to make old code compile
 517 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 518
 519 include(gmxTestInlineASM)
 520 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 521
 522 include(gmxSetBuildInformation)
 523 gmx_set_build_information()
 524 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 525     set(HAVE_RDTSCP 1)
 526 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 527
 528 include(gmxTestFloatFormat)
 529 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 530                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 531                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 532
 533 include(gmxTestLargeFiles)
 534 gmx_test_large_files(GMX_LARGEFILES)
 535
 536 include(gmxTestSignal)
 537 gmx_test_sigusr1(HAVE_SIGUSR1)
 538
 539 include(gmxTestInline)
 540 gmx_test_inline(INLINE_KEYWORD)
 541
 542 include(gmxTestRestrict)
 543 gmx_test_restrict(RESTRICT_KEYWORD)
 544
 545 include(gmxTestPipes)
 546 gmx_test_pipes(HAVE_PIPES)
 547
 548 include(gmxTestIsfinite)
 549 gmx_test_isfinite(HAVE_ISFINITE)
 550 gmx_test__isfinite(HAVE__ISFINITE)
 551 gmx_test__finite(HAVE__FINITE)
 552
 553 include(gmxTestCXX11)
 554 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 555 include(CMakeDependentOption)
 556 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 557 # entirely to keep the compilation environment uniform.
 558 cmake_dependent_option(GMX_CXX11
 559     "Use C++11 features"
 560     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 561 mark_as_advanced(GMX_CXX11)
 562 if(GMX_CXX11)
 563     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 564 endif()
 565
 566
 567 include(gmxTestXDR)
 568 gmx_test_xdr(GMX_SYSTEM_XDR)
 569 if(NOT GMX_SYSTEM_XDR)
 570     set(GMX_INTERNAL_XDR 1)
 571 endif(NOT GMX_SYSTEM_XDR)
 572
 573 # include avx test source, used if the AVX flags are set below
 574 include(gmxTestAVXMaskload)
 575
 576 # Process nonbonded accelerated kernels settings
 577 #
 578 # Note that for the backward-compatible x86 SIMD architectures, the
 579 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 580 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 581 # SSE2). Accordingly, there are a set of CMake variables
 582 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 583 # CPU features that should be used. This means that the logic for
 584 # requiring such backward compatibility is all located here.
 585 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 586     # nothing to do
 587     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 588
 589 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 590
 591     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 592     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 593         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 594     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 595
 596     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 597     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 598         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 599     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 600
 601     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 602
 603     # Only test the include after we have tried to add the correct flag for SSE2 support
 604     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 605
 606     if(NOT HAVE_EMMINTRIN_H)
 607         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 608     endif(NOT HAVE_EMMINTRIN_H)
 609
 610     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 611     # The user should not be able to set this orthogonally to the acceleration
 612     set(GMX_X86_SSE2 1)
 613     set(ACCELERATION_STATUS_MESSAGE
 614         "Enabling SSE2 Gromacs acceleration")
 615
 616 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 617
 618     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 619     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 620         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 621     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 622     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 623         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 624         # intrinsics when SSE2 support is enabled, so we try that instead first.
 625         if (GMX_NATIVE_WINDOWS)
 626             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 627             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 628         else()
 629             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 630         endif()
 631     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 632
 633     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 634     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 635         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 636     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 637     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 638         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 639         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 640         # intrinsics when SSE2 support is enabled, so we try that instead.
 641         if (GMX_NATIVE_WINDOWS)
 642             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 643         endif()
 644     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 645
 646     # This must come after we have added the -msse4.1 flag on some platforms.
 647     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 648
 649     if(NOT HAVE_SMMINTRIN_H)
 650         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 651     endif(NOT HAVE_SMMINTRIN_H)
 652
 653     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 654         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 655     endif()
 656
 657     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 658     # The user should not be able to set this orthogonally to the acceleration
 659     set(GMX_X86_SSE4_1 1)
 660     set(GMX_X86_SSE2   1)
 661     set(ACCELERATION_STATUS_MESSAGE
 662         "Enabling SSE4.1 Gromacs acceleration")
 663
 664 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 665
 666     # Set the AVX compiler flag for both these choices!
 667
 668     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 669     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 670         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 671     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 672     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 673         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 674     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 675
 676     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 677     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 678         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 679     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 680     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 681         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 682     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 683
 684     # Set the FMA4 flags (MSVC doesn't require any)
 685     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 686         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 687         if (NOT GNU_FMA_CFLAG)
 688             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 689         endif(NOT GNU_FMA_CFLAG)
 690         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 691         # No big deal if we do not have xop, so no point yelling warnings about it.
 692         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 693         if (NOT GNU_FMA_CXXFLAG)
 694             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 695         endif (NOT GNU_FMA_CXXFLAG)
 696         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 697         # No big deal if we do not have xop, so no point yelling warnings about it.
 698     endif()
 699
 700     # Only test the header after we have tried to add the flag for AVX support
 701     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 702
 703     if(NOT HAVE_IMMINTRIN_H)
 704         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 705     endif(NOT HAVE_IMMINTRIN_H)
 706
 707     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 708         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 709             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 710             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 711         if(NOT TEST_AVX)
 712             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 713         endif()
 714     endif()
 715
 716     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 717     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 718     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 719
 720     # The user should not be able to set this orthogonally to the acceleration
 721     set(GMX_X86_SSE4_1 1)
 722     set(GMX_X86_SSE2   1)
 723
 724     # But just enable one of the choices internally...
 725     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 726         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 727         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 728         # hackintoshes is not worth the effort.
 729         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 730                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 731             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 732         endif()
 733
 734         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 735             # we assume that we have an external assembler that supports AVX
 736             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 737             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 738         endif()
 739         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 740             # we assume that we have an external assembler that supports AVX
 741             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 742             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 743         endif()
 744
 745         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 746         set(GMX_X86_AVX_128_FMA 1)
 747         set(ACCELERATION_STATUS_MESSAGE
 748             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 749
 750     else()
 751         # If we are not doing AVX_128, it must be AVX_256...
 752         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 753         set(GMX_X86_AVX_256 1)
 754         set(ACCELERATION_STATUS_MESSAGE
 755             "Enabling 256-bit AVX Gromacs acceleration")
 756     endif()
 757
 758     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 759     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 760     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 761
 762 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 763     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 764         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 765
 766     if (TEST_QPX)
 767         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 768         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 769     else()
 770         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 771     endif()
 772 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 773     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 774 elseif(${GMX_CPU_ACCELERATION} STREQUAL "REFERENCE")
 775     add_definitions(-DGMX_SIMD_REFERENCE_PLAIN_C)
 776     if(${GMX_NBNXN_REF_KERNEL_TYPE} STREQUAL "4xn")
 777         if(${GMX_NBNXN_REF_KERNEL_WIDTH} STREQUAL "2" OR ${GMX_NBNXN_REF_KERNEL_WIDTH} STREQUAL "4" OR ${GMX_NBNXN_REF_KERNEL_WIDTH} STREQUAL "8")
 778             add_definitions(-DGMX_NBNXN_SIMD_4XN -DGMX_SIMD_REF_WIDTH=${GMX_NBNXN_REF_KERNEL_WIDTH})
 779         else()
 780             message(FATAL_ERROR "Unsupported width for 4xn reference kernels")
 781         endif()
 782     elseif(${GMX_NBNXN_REF_KERNEL_TYPE} STREQUAL "2xnn")
 783         if(${GMX_NBNXN_REF_KERNEL_WIDTH} STREQUAL "8" OR ${GMX_NBNXN_REF_KERNEL_WIDTH} STREQUAL "16")
 784             add_definitions(-DGMX_NBNXN_SIMD_2XNN -DGMX_SIMD_REF_WIDTH=${GMX_NBNXN_REF_KERNEL_WIDTH})
 785         else()
 786             message(FATAL_ERROR "Unsupported width for 2xn reference kernels")
 787         endif()
 788     else()
 789         message(FATAL_ERROR "Unsupported kernel type")
 790     endif()
 791 else()
 792     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 793 endif()
 794 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 795 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 796     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 797 endif()
 798
 799 # Process QM/MM Settings
 800 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 801     set(GMX_QMMM_GAUSSIAN 1)
 802 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 803     set(GMX_QMMM_MOPAC 1)
 804 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 805     set(GMX_QMMM_GAMESS 1)
 806 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 807     set(GMX_QMMM_ORCA 1)
 808 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 809     # nothing to do
 810 else()
 811     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 812 endif()
 813
 814
 815 ##################################################
 816 # Process FFT library settings
 817 ##################################################
 818 include(gmxManageFFTLibraries)
 819
 820
 821 include(gmxManageLinearAlgebraLibraries)
 822
 823 # Whether GROMACS will really try to compile support for VMD plugins
 824 set(GMX_USE_PLUGINS OFF)
 825
 826 if(GMX_LOAD_PLUGINS)
 827   if(CYGWIN OR NOT WIN32)
 828     # Native Windows does not have, nor need dlopen
 829     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 830     include(gmxTestdlopen)
 831     gmx_test_dlopen(HAVE_DLOPEN)
 832   endif()
 833
 834   # so, should we use plug-ins?
 835   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 836     if(NOT VMD_QUIETLY)
 837       MESSAGE(STATUS
 838           "Found the ability to use plug-ins when building shared libaries, "
 839           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 840           "formats).")
 841     endif()
 842     if(NOT GMX_VMD_PLUGIN_PATH)
 843       find_package(VMD)
 844     endif()
 845     set(GMX_USE_PLUGINS ON)
 846     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 847     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 848   else()
 849     set(PKG_DL_LIBS)
 850   endif()
 851 endif(GMX_LOAD_PLUGINS)
 852 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 853
 854 # Link real-time library for POSIX timers. The check for clock_gettime
 855 # confirms the linkability of rt.
 856 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 857     list(APPEND GMX_EXTRA_LIBRARIES rt)
 858 endif()
 859
 860 # Math and thread libraries must often come after all others when linking...
 861 if(HAVE_LIBM)
 862     list(APPEND GMX_EXTRA_LIBRARIES m)
 863 endif(HAVE_LIBM)
 864 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 865     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 866     if(HAVE_MASS_SIMD)
 867         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 868     else()
 869         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 870     endif()
 871 endif()
 872
 873
 874 option(GMX_NACL "Configure for Native Client builds" OFF)
 875 if (GMX_NACL)
 876   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 877   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 878   set(GMX_NO_NICE 1)
 879   set(GMX_NO_RENAME 1)
 880 endif()
 881 mark_as_advanced(GMX_NACL)
 882
 883 if(GMX_FAHCORE)
 884   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 885       "Path to swindirect.h")
 886   include_directories(${COREWRAP_INCLUDE_DIR})
 887 endif(GMX_FAHCORE)
 888
 889 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 890 mark_as_advanced(GMX_BUILD_HELP)
 891 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 892     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 893
 894     message(FATAL_ERROR
 895         "Rebuilding HTML and man pages is not supported for in-source "
 896         "builds from a source distribution. "
 897         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 898 endif()
 899
 900 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 901 # these are set after everything else
 902 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 903     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 904     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 905     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 906     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 907 else()
 908     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 909     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 910     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 911     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 912     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 913     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 914     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 915     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 916     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 917 endif()
 918
 919 if(NOT GMX_OPENMP)
 920     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 921     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 922     unset(OpenMP_C_FLAGS CACHE)
 923     unset(OpenMP_CXX_FLAGS CACHE)
 924 else()
 925     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 926     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 927 endif()
 928 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 929
 930 ########################################################################
 931 # Specify install locations
 932 ########################################################################
 933 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 934     "Library installation directory (default: lib)")
 935 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 936     "Data installation directory under share/ (default: gromacs)")
 937 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 938
 939 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 940 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 941 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 942 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 943 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 944
 945 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 946 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 947
 948 # Binary and library suffix options
 949 include(gmxManageSuffixes)
 950
 951 ##################################################################
 952 # Shared library settings
 953 ##################################################################
 954 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 955     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 956     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 957     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
 958     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 959 else()
 960     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 961         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 962         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
 963     else()
 964         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 965     endif()
 966 endif()
 967
 968 #COPYING file: Only necessary for binary distributions.
 969 #Simpler to always install.
 970 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 971
 972 if(GMX_EXTERNAL_BOOST)
 973     include_directories(${Boost_INCLUDE_DIRS})
 974 else()
 975     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 976     # typeid not supported for minimal internal version
 977     # (would add significant amount of code)
 978     add_definitions(-DBOOST_NO_TYPEID)
 979     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 980     # (from share/template/)
 981     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 982     if (NOT GMX_BUILD_MDRUN_ONLY)
 983         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 984                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 985                 COMPONENT development)
 986     endif ()
 987 endif()
 988
 989 # TODO The Windows builds are still broken (we are avoiding some
 990 # unknown bug, perhaps with checkpointing?), because defaulting to
 991 # .tng output leads to calling null-op implementation functions, so
 992 # regressiontests will fail on Windows at the post-mdrun stages. We
 993 # can fix this during the 5.0 beta phase.
 994 gmx_add_cache_dependency(GMX_USE_TNG BOOL "NOT GMX_NATIVE_WINDOWS" OFF)
 995
 996 if(GMX_USE_TNG)
 997     find_package(ZLIB)
 998     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 999     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
1000     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
1001     # TODO reconsider use of OpenMP in TNG if/when trajectory writing is not serial in mdrun
1002     set(TNG_USE_OPENMP ${GMX_OPENMP} CACHE BOOL "Try to use the OpenMP library (if available) with TNG")
1003     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
1004     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
1005     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
1006     set(GMX_TNG_LIBRARIES tng_io)
1007 endif()
1008 mark_as_advanced(TNG_BUILD_FORTRAN)
1009 mark_as_advanced(TNG_BUILD_EXAMPLES)
1010 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
1011 mark_as_advanced(TNG_USE_OPENMP)
1012 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
1013 mark_as_advanced(TNG_BUILD_TEST)
1014 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
1015
1016 if (GMX_BUILD_FOR_COVERAGE)
1017     # Code heavy with asserts makes conditional coverage close to useless metric,
1018     # as by design most of the false branches are impossible to trigger in
1019     # correctly functioning code.  And the benefit of testing those that could
1020     # be triggered by using an API against its specification isn't usually
1021     # worth the effort.
1022     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
1023 endif ()
1024
1025 if (BUILD_TESTING)
1026     # "tests" target builds all the separate test binaries.
1027     add_custom_target(tests)
1028     # "run-ctest" is an internal target that actually runs the tests.
1029     # This is necessary to be able to add separate targets that execute as part
1030     # of 'make check', but are ensured to be executed after the actual tests.
1031     add_custom_target(run-ctest
1032                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
1033                       COMMENT "Running all tests"
1034                       VERBATIM)
1035     add_dependencies(run-ctest tests)
1036     # "check" target builds and runs all tests.
1037     add_custom_target(check DEPENDS run-ctest)
1038 endif()
1039
1040 if (NOT GMX_BUILD_MDRUN_ONLY)
1041     add_subdirectory(doxygen)
1042     add_subdirectory(share)
1043     add_subdirectory(scripts)
1044 endif ()
1045 add_subdirectory(src)
1046
1047 if (BUILD_TESTING)
1048     add_subdirectory(tests)
1049 endif()
1050
1051 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1052 # Don't bother the user after the first configure pass.
1053 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1054     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1055 endif()
1056 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1057
1058 #######################
1059 ## uninstall target
1060 #######################
1061     CONFIGURE_FILE(
1062                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1063                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1064                    IMMEDIATE @ONLY)
1065 ###########################
1066 ADD_CUSTOM_TARGET(uninstall
1067                   "${CMAKE_COMMAND}" -P
1068                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1069 ###########################
1070
1071 ########################################################################
1072 # Manual                                                               #
1073 ########################################################################
1074
1075 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1076 mark_as_advanced(GMX_BUILD_MANUAL)
1077 if(GMX_BUILD_MANUAL)
1078     # Make sure we only do detection of manual-building dependencies
1079     # when the user opted in for that.
1080     add_subdirectory(manual)
1081 endif()