CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  56 # defined.
  57 set(PROJECT_VERSION "5.1-dev")
  58 # If this is a released tarball, "-dev" will not be present in
  59 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  60 # number of the regressiontest tarball against which the code tarball
  61 # can be tested. This will be the version of the last patch release.
  62 set(REGRESSIONTEST_VERSION "5.0-rc1")
  63 # If this is not a released tarball, "-dev" will be present in
  64 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  65 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  66 # code contains all recent fixes from the corresponding code branch.
  67 set(REGRESSIONTEST_BRANCH "refs/heads/master")
  68
  69 set(CUSTOM_VERSION_STRING ""
  70     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  71 mark_as_advanced(CUSTOM_VERSION_STRING)
  72 if (CUSTOM_VERSION_STRING)
  73     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  74 endif()
  75 set(LIBRARY_SOVERSION 0)
  76 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  77 # It is a bit irritating, but this has to be set separately for now!
  78 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  79 SET(CPACK_PACKAGE_VERSION_MINOR "1")
  80 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  81
  82 # The numerical gromacs version. It is 40600 for 4.6.0.
  83 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  84 math(EXPR NUM_VERSION
  85     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  86 if(CPACK_PACKAGE_VERSION_PATCH)
  87     math(EXPR NUM_VERSION
  88          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  89 endif()
  90
  91 # The API version tracks the numerical Gromacs version (for now).
  92 # It is potentially different from the Gromacs version in the future, if
  93 # the programs/libraries diverge from the presumably more stable API.
  94 # The #define GMX_API_VERSION in version.h is set to this value to
  95 # provide backward compatibility of software written against the Gromacs API.
  96 set(API_VERSION ${NUM_VERSION})
  97
  98 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  99     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 100 endif()
 101
 102 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 103 mark_as_advanced(GMX_INSTALL_PREFIX)
 104
 105 include(gmxBuildTypeReference)
 106 include(gmxBuildTypeProfile)
 107 include(gmxBuildTypeTSAN)
 108 include(gmxBuildTypeASAN)
 109 include(gmxBuildTypeReleaseWithAssert)
 110
 111 if(NOT CMAKE_BUILD_TYPE)
 112     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
 113     # There's no need to offer a user the choice of ThreadSanitizer
 114     # Set the possible values of build type for cmake-gui
 115     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 116         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
 117 endif()
 118 if(CMAKE_CONFIGURATION_TYPES)
 119     # Add appropriate GROMACS-specific build types for the Visual
 120     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 121     # are already present by default).
 122     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 123     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 124     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 125         "List of configuration types"
 126         FORCE)
 127 endif()
 128 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL PROFILE)
 129
 130 enable_language(C)
 131 enable_language(CXX)
 132
 133 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 134 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 135 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 136 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 137 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 138 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 139 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 140 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 141 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 142 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 143 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 144
 145 #must come after all cpack settings!
 146 include(CPack)
 147
 148 # Set a default valgrind suppression file.
 149 # This unfortunately needs to duplicate information from CTest to work as
 150 # expected...
 151 set(MEMORYCHECK_SUPPRESSIONS_FILE
 152     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 153     CACHE FILEPATH
 154     "File that contains suppressions for the memory checker")
 155 include(CTest)
 156
 157 set(SOURCE_IS_GIT_REPOSITORY OFF)
 158 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 159 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 160     set(SOURCE_IS_GIT_REPOSITORY ON)
 161 endif()
 162 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 163     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 164 endif()
 165
 166 ########################################################################
 167 # Check and warn if cache generated on a different host is being reused
 168 ########################################################################
 169 if(CMAKE_HOST_UNIX)
 170     execute_process(COMMAND hostname
 171                     OUTPUT_VARIABLE TMP_HOSTNAME
 172                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 173     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 174         message(WARNING "
 175             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 176             is being reused! This could lead to inconsitencies; therefore, it is
 177             recommended to regenerate the cache!")
 178     endif()
 179     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 180             "Hostname of the machine where the cache was generated.")
 181 endif()
 182
 183 ########################################################################
 184 # User input options                                                   #
 185 ########################################################################
 186 include(gmxOptionUtilities)
 187
 188 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 189
 190 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 191 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 192 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 193 gmx_dependent_option(
 194     GMX_MPI_IN_PLACE
 195     "Enable MPI_IN_PLACE for MPIs that have it defined"
 196     ON
 197     GMX_MPI)
 198 mark_as_advanced(GMX_MPI_IN_PLACE)
 199 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 200 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 201 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 202 mark_as_advanced(GMX_FAHCORE)
 203
 204 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 205 mark_as_advanced(GMX_COOL_QUOTES)
 206 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 207
 208 # decide on GPU settings based on user-settings and GPU/CUDA detection
 209 include(gmxManageGPU)
 210
 211 # Detect the architecture the compiler is targetting, detect
 212 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 213 # to use if none is specified, and populate the cache option for CPU
 214 # SIMD.
 215 include(gmxDetectTargetArchitecture)
 216 gmx_detect_target_architecture()
 217
 218 if(GMX_CPU_ACCELERATION)
 219     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 220     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 221     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 222     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 223 endif()
 224
 225 if(NOT GMX_TARGET_MIC)
 226     include(gmxDetectSimd)
 227     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 228 else()
 229     set(GMX_SUGGESTED_SIMD "None")
 230 endif()
 231
 232 gmx_option_multichoice(
 233     GMX_SIMD
 234     "SIMD instruction set for CPU kernels and compiler optimization"
 235     "${GMX_SUGGESTED_SIMD}"
 236     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 237
 238 gmx_option_multichoice(
 239     GMX_FFT_LIBRARY
 240     "FFT library"
 241     "fftw3"
 242     fftw3 mkl "fftpack[built-in]")
 243 gmx_dependent_option(
 244     GMX_BUILD_OWN_FFTW
 245     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 246     OFF
 247     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 248 gmx_dependent_option(
 249     GMX_DISABLE_FFTW_MEASURE
 250     "Do not optimize FFTW setups (not needed with SSE)"
 251     OFF
 252     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 253 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 254 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 255
 256 gmx_option_multichoice(
 257     GMX_QMMM_PROGRAM
 258     "QM package for QM/MM"
 259     None
 260     none gaussian mopac gamess orca)
 261
 262 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 263 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 264
 265 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 266
 267 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 268 mark_as_advanced(GMX_BROKEN_CALLOC)
 269 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 270 mark_as_advanced(GMX_LOAD_PLUGINS)
 271
 272 option(GMX_GPU  "Enable GPU acceleration" ON)
 273 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 274
 275 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 276
 277 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 278 mark_as_advanced(GMX_GIT_VERSION_INFO)
 279
 280 if(UNIX)
 281     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 282 endif()
 283 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 284
 285 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 286 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 287
 288 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 289 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 290
 291 option(GMX_BUILD_FOR_COVERAGE
 292        "Tune build for better code coverage metrics (e.g., disable asserts)"
 293        OFF)
 294 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 295
 296
 297 ######################################################################
 298 # Detect OpenMP support
 299 ######################################################################
 300 # The OpenMP detection _must_ come before tests for other CFLAGS.
 301 include(gmxManageOpenMP)
 302
 303
 304
 305 ######################################################################
 306 # Compiler tests
 307 # These need to be done early (before further tests).
 308 #####################################################################
 309
 310 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 311 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 312 # invalid options with the Intel Compilers.
 313 # These files should be removed from the source tree when a CMake version that
 314 # includes the features in question becomes required for building GROMACS.
 315 include(CheckCCompilerFlag)
 316 include(CheckCXXCompilerFlag)
 317
 318
 319 include(gmxCFlags)
 320 gmx_c_flags()
 321
 322 # This variable should be used for additional compiler flags which are not
 323 # generated in gmxCFlags nor are SIMD or MPI related.
 324 set(EXTRA_C_FLAGS "")
 325 set(EXTRA_CXX_FLAGS "")
 326
 327 # Run through a number of tests for buggy compilers and other issues
 328 include(gmxTestCompilerProblems)
 329 gmx_test_compiler_problems()
 330 # GMX_SIMD will not be set automatically until the second
 331 # pass (which is not strictly guaranteed to occur), so putting this
 332 # check here among logically-related tests is inefficient, but the
 333 # potential loss is likely zero.
 334 if(GMX_SIMD STREQUAL "AVX_256"
 335         AND CMAKE_COMPILER_IS_GNUCC
 336         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 337             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 338     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 339     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 340 endif()
 341
 342
 343
 344 set(PKG_CFLAGS "")
 345 if(GMX_DOUBLE)
 346     add_definitions(-DGMX_DOUBLE)
 347     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 348 endif()
 349 if(GMX_SOFTWARE_INVSQRT)
 350   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 351 endif()
 352
 353 if(WIN32 AND NOT CYGWIN)
 354     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 355     mark_as_advanced(GMX_WSOCKLIB_PATH)
 356     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 357     if(WSOCK32_LIBRARY)
 358         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 359         add_definitions(-DGMX_HAVE_WINSOCK)
 360     else()
 361         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 362     endif(WSOCK32_LIBRARY)
 363 endif()
 364
 365
 366
 367 ########################################################################
 368 # Basic system tests (standard libraries, headers, functions, types)   #
 369 ########################################################################
 370 include(CheckIncludeFiles)
 371 include(CheckIncludeFileCXX)
 372 check_include_files(unistd.h     HAVE_UNISTD_H)
 373 check_include_files(pwd.h        HAVE_PWD_H)
 374 check_include_files(dirent.h     HAVE_DIRENT_H)
 375 check_include_files(time.h       HAVE_TIME_H)
 376 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 377 check_include_files(io.h         HAVE_IO_H)
 378 check_include_files(sched.h      HAVE_SCHED_H)
 379
 380 check_include_files(regex.h      HAVE_POSIX_REGEX)
 381 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 382 # TODO: It could be nice to inform the user if no regex support is found,
 383 # as selections won't be fully functional.
 384
 385 include(CheckFunctionExists)
 386 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 387 check_function_exists(memalign          HAVE_MEMALIGN)
 388 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 389 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 390 check_function_exists(fsync             HAVE_FSYNC)
 391 check_function_exists(_fileno           HAVE__FILENO)
 392 check_function_exists(fileno            HAVE_FILENO)
 393 check_function_exists(_commit           HAVE__COMMIT)
 394 check_function_exists(sigaction         HAVE_SIGACTION)
 395 check_function_exists(sysconf           HAVE_SYSCONF)
 396 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 397 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 398 check_function_exists(rsqrt             HAVE_RSQRT)
 399 check_function_exists(rsqrtf            HAVE_RSQRTF)
 400 check_function_exists(sqrtf             HAVE_SQRTF)
 401
 402 include(CheckLibraryExists)
 403 check_library_exists(m sqrt "" HAVE_LIBM)
 404 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 405
 406 include(TestBigEndian)
 407 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 408
 409 # Management of GROMACS options for specific toolchains should go
 410 # here. Because the initial settings for some of the main options have
 411 # already happened, but things like library detection and MPI compiler
 412 # feature detection have not, the docstrings for any over-rides of
 413 # GROMACS defaults or user settings will make sense. Also, any
 414 # toolchain-related reasons for choosing whether to detect various
 415 # things can be sorted out now, before the detection takes place.
 416 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 417     include(gmxManageBlueGene)
 418 endif()
 419
 420 ########################################################################
 421 #Process MPI settings
 422 ########################################################################
 423 include(gmxManageMPI)
 424
 425
 426 ########################################################################
 427 #Process shared/static library settings
 428 ########################################################################
 429 include(gmxManageSharedLibraries)
 430
 431
 432 ########################################################################
 433 # Find external packages                                               #
 434 ########################################################################
 435
 436 # Unconditionally find the package, as it is also required for unit
 437 # tests. This exports LIBXML2_FOUND, which we should not use because
 438 # it does not tell us that linking will succeed. Instead, we test that
 439 # next.
 440 find_package(LibXml2)
 441 include(gmxTestLibXml2)
 442 gmx_test_libxml2(HAVE_LIBXML2)
 443 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 444 set(PKG_XML "")
 445 mark_as_advanced(GMX_XML)
 446 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 447 #if(GMX_XML AND NOT HAVE_LIBXML2)
 448 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 449 #endif()
 450 #if(GMX_XML)
 451 #    include_directories(${LIBXML2_INCLUDE_DIR})
 452 #    set(PKG_XML libxml-2.0)
 453 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 454 #endif()
 455
 456 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 457 mark_as_advanced(GMX_EXTRAE)
 458
 459 if (GMX_EXTRAE)
 460   find_package(EXTRAE)
 461   if(EXTRAE_FOUND)
 462     include_directories(${EXTRAE_INCLUDE_DIR})
 463     set(HAVE_EXTRAE 1)
 464   else()
 465     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 466   endif()
 467 endif()
 468
 469 option(GMX_X11 "Use X window system" OFF)
 470 if (GMX_X11)
 471     find_package(X11)
 472     # X11 includes/libraries are only set in the ngmx subdirectory!
 473     if(NOT X11_FOUND)
 474         message(FATAL_ERROR
 475                 "X11 include files and/or libraries were not found. "
 476                 "Set GMX_X11=OFF to compile without X11 support. "
 477                 "gmx view will not be available.")
 478     endif()
 479     include_directories(${X11_INCLUDE_DIR})
 480 endif()
 481
 482 include(ThreadMPI)
 483 # Enable core threading facilities
 484 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 485 # Enable tMPI C++ support
 486 tmpi_enable_cxx()
 487 if(GMX_THREAD_MPI)
 488     # enable MPI functions
 489     tmpi_enable()
 490     set(GMX_MPI 1)
 491     set(MPI_IN_PLACE_EXISTS 1)
 492 endif()
 493 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 494 if (TMPI_ATOMICS_DISABLED)
 495    add_definitions(-DTMPI_ATOMICS_DISABLED)
 496 endif()
 497
 498 if(GMX_GPU)
 499     # now that we have detected the dependencies, do the second configure pass
 500     gmx_gpu_setup()
 501 endif()
 502
 503 if(CYGWIN)
 504     set(GMX_CYGWIN 1)
 505 endif()
 506
 507 if(WIN32 AND NOT CYGWIN)
 508     set(GMX_NATIVE_WINDOWS 1)
 509     # This makes windows.h not declare min/max as macros that would break
 510     # C++ code using std::min/std::max.
 511     add_definitions(-DNOMINMAX)
 512 endif()
 513
 514 # only bother with finding git and using version.h if the source is a git repo
 515 if(GMX_GIT_VERSION_INFO)
 516     if (NOT SOURCE_IS_GIT_REPOSITORY)
 517         message(FATAL_ERROR
 518             "Cannot generate git version information from source tree not under git. "
 519             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 520     endif()
 521     # We need at least git v1.5.3 be able to parse git's date output. If not
 522     # found or the version is too small, we can't generate version information.
 523     find_package(Git)
 524
 525     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 526         message(FATAL_ERROR
 527             "No compatible git version found (>= 1.5.3 required). "
 528             "Won't be able to generate development version information. "
 529             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 530     endif()
 531 endif()
 532
 533 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 534 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 535 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 536     find_package(Boost 1.44.0)
 537     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 538         set(Boost_FOUND FALSE)
 539     endif()
 540     # Print the notification only on first run, when determining the default
 541     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 542         message("Boost >= 1.44 not found. Using minimal internal version. "
 543                 "This may cause trouble if you plan on compiling/linking other "
 544                 "software that uses Boost against Gromacs.")
 545     endif()
 546 endif()
 547 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 548        ${Boost_FOUND})
 549 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 550     message(FATAL_ERROR
 551         "Boost >= 1.44 not found. "
 552         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 553         "version of Boost included with Gromacs.")
 554 endif()
 555
 556 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 557 mark_as_advanced(GMX_BUILD_UNITTESTS)
 558 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 559 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 560     message(FATAL_ERROR
 561         "Cannot build unit tests without libxml2. "
 562         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 563 endif()
 564
 565 ########################################################################
 566 # Generate development version info for cache
 567 ########################################################################
 568 # set(GEN_VERSION_INFO_INTERNAL "ON")
 569 # include(gmxGenerateVersionString)
 570
 571 ########################################################################
 572 # Our own GROMACS tests
 573 ########################################################################
 574
 575 add_definitions( -DHAVE_CONFIG_H )
 576 include_directories(${CMAKE_SOURCE_DIR}/src)
 577 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 578 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 579 include_directories(${CMAKE_BINARY_DIR}/src)
 580 # Required for gmx_header_config_gen.h to be found before installation
 581 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 582 # Required for now to make old code compile
 583 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 584
 585 include(gmxTestInlineASM)
 586 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 587
 588 include(gmxSetBuildInformation)
 589 gmx_set_build_information()
 590 # Turn on RDTSCP if:
 591 # - the build system's CPU supports it
 592 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 593 #   at this point means that the user set it).
 594 # Note: it's better to not use the later set value of GMX_SIMD because
 595 # it reflects the system's capability of both compiling and running AVX code.
 596 # TODO: After merge with 5.0 one could implement a cache variable dependency
 597 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 598 # after the first cmake pass.
 599 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 600     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 601 else()
 602     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 603 endif()
 604 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 605 mark_as_advanced(GMX_USE_RDTSCP)
 606 if(GMX_USE_RDTSCP)
 607     set(HAVE_RDTSCP 1)
 608 endif()
 609
 610 include(gmxTestFloatFormat)
 611 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 612                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 613                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 614
 615 include(gmxTestLargeFiles)
 616 gmx_test_large_files(GMX_LARGEFILES)
 617
 618 include(gmxTestSignal)
 619 gmx_test_sigusr1(HAVE_SIGUSR1)
 620
 621 include(gmxTestPipes)
 622 gmx_test_pipes(HAVE_PIPES)
 623
 624 include(gmxTestIsfinite)
 625 gmx_test_isfinite(HAVE_ISFINITE)
 626 gmx_test__isfinite(HAVE__ISFINITE)
 627 gmx_test__finite(HAVE__FINITE)
 628
 629 include(gmxTestCXX11)
 630 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 631 include(CMakeDependentOption)
 632 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 633 # entirely to keep the compilation environment uniform.
 634 cmake_dependent_option(GMX_CXX11
 635     "Use C++11 features"
 636     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 637 mark_as_advanced(GMX_CXX11)
 638 if(GMX_CXX11)
 639     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 640 endif()
 641
 642
 643 include(gmxTestXDR)
 644 gmx_test_xdr(GMX_SYSTEM_XDR)
 645 if(NOT GMX_SYSTEM_XDR)
 646     set(GMX_INTERNAL_XDR 1)
 647 endif()
 648
 649
 650 ##################################################
 651 # Process SIMD instruction settings
 652 ##################################################
 653 # This checks what flags to add in order to
 654 # support the SIMD instructions we need, and sets
 655 # correct defines for the SIMD instructions supported.
 656 include(gmxTestSimd)
 657 gmx_test_simd()
 658
 659
 660 # Process QM/MM Settings
 661 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 662     set(GMX_QMMM_GAUSSIAN 1)
 663 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 664     set(GMX_QMMM_MOPAC 1)
 665 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 666     set(GMX_QMMM_GAMESS 1)
 667 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 668     set(GMX_QMMM_ORCA 1)
 669 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 670     # nothing to do
 671 else()
 672     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 673 endif()
 674
 675
 676 ##################################################
 677 # Process FFT library settings
 678 ##################################################
 679 include(gmxManageFFTLibraries)
 680
 681
 682 include(gmxManageLinearAlgebraLibraries)
 683
 684 # Whether GROMACS will really try to compile support for VMD plugins
 685 set(GMX_USE_PLUGINS OFF)
 686
 687 if(GMX_LOAD_PLUGINS)
 688   if(CYGWIN OR NOT WIN32)
 689     # Native Windows does not have, nor need dlopen
 690     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 691     include(gmxTestdlopen)
 692     gmx_test_dlopen(HAVE_DLOPEN)
 693   endif()
 694
 695   # so, should we use plug-ins?
 696   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 697     if(NOT VMD_QUIETLY)
 698       MESSAGE(STATUS
 699           "Found the ability to use plug-ins when building shared libaries, "
 700           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 701           "formats).")
 702     endif()
 703     if(NOT GMX_VMD_PLUGIN_PATH)
 704       find_package(VMD)
 705     endif()
 706     set(GMX_USE_PLUGINS ON)
 707     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 708     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 709   else()
 710     set(PKG_DL_LIBS)
 711   endif()
 712 endif()
 713 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 714
 715 # Link real-time library for POSIX timers. The check for clock_gettime
 716 # confirms the linkability of rt.
 717 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 718     list(APPEND GMX_EXTRA_LIBRARIES rt)
 719 endif()
 720
 721 # Math and thread libraries must often come after all others when linking...
 722 if(HAVE_LIBM)
 723     list(APPEND GMX_EXTRA_LIBRARIES m)
 724 endif()
 725
 726 option(GMX_NACL "Configure for Native Client builds" OFF)
 727 if (GMX_NACL)
 728   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 729   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 730   set(GMX_NO_NICE 1)
 731   set(GMX_NO_RENAME 1)
 732 endif()
 733 mark_as_advanced(GMX_NACL)
 734
 735 if(GMX_FAHCORE)
 736   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 737       "Path to swindirect.h")
 738   include_directories(${COREWRAP_INCLUDE_DIR})
 739 endif()
 740
 741 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 742 mark_as_advanced(GMX_BUILD_HELP)
 743 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 744     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 745
 746     message(FATAL_ERROR
 747         "Rebuilding HTML and man pages is not supported for in-source "
 748         "builds from a source distribution. "
 749         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 750 endif()
 751
 752 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 753 # these are set after everything else
 754 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 755     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 756     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 757     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 758     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 759 else()
 760     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 761     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 762     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 763     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 764     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 765     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 766     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 767     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 768     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 769 endif()
 770
 771 if(NOT GMX_OPENMP)
 772     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 773     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 774     unset(OpenMP_C_FLAGS CACHE)
 775     unset(OpenMP_CXX_FLAGS CACHE)
 776 else()
 777     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 778     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 779 endif()
 780 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 781
 782 ########################################################################
 783 # Specify install locations
 784 ########################################################################
 785 # Use GNUInstallDirst to set paths on multiarch systems
 786 include(GNUInstallDirs)
 787
 788 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 789     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 790 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 791     "Data installation directory under share/ (default: gromacs)")
 792 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 793
 794 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 795 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 796 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 797 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 798 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 799
 800 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 801 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 802
 803 # Binary and library suffix options
 804 include(gmxManageSuffixes)
 805
 806 ##################################################################
 807 # Shared library settings
 808 ##################################################################
 809 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 810     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 811         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 812     endif()
 813     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 814     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 815 else()
 816     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 817         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 818         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 819     else()
 820         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 821     endif()
 822 endif()
 823
 824 #COPYING file: Only necessary for binary distributions.
 825 #Simpler to always install.
 826 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 827
 828 if(GMX_EXTERNAL_BOOST)
 829     include_directories(${Boost_INCLUDE_DIRS})
 830     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 831 else()
 832     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 833     # typeid not supported for minimal internal version
 834     # (would add significant amount of code)
 835     add_definitions(-DBOOST_NO_TYPEID)
 836     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 837     # (from share/template/)
 838     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 839     if (NOT GMX_BUILD_MDRUN_ONLY)
 840         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 841                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 842                 COMPONENT development)
 843     endif()
 844 endif()
 845
 846 if(GMX_USE_TNG)
 847     find_package(ZLIB QUIET)
 848     include(gmxTestZLib)
 849     gmx_test_zlib(HAVE_ZLIB)
 850     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 851     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 852     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 853     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 854     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 855     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 856     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 857     set(GMX_TNG_LIBRARIES tng_io)
 858 endif()
 859 mark_as_advanced(TNG_BUILD_FORTRAN)
 860 mark_as_advanced(TNG_BUILD_EXAMPLES)
 861 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 862 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 863 mark_as_advanced(TNG_BUILD_TEST)
 864 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 865
 866 if (GMX_BUILD_FOR_COVERAGE)
 867     # Code heavy with asserts makes conditional coverage close to useless metric,
 868     # as by design most of the false branches are impossible to trigger in
 869     # correctly functioning code.  And the benefit of testing those that could
 870     # be triggered by using an API against its specification isn't usually
 871     # worth the effort.
 872     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 873 endif()
 874
 875 if (BUILD_TESTING)
 876     # "tests" target builds all the separate test binaries.
 877     add_custom_target(tests)
 878     # "run-ctest" is an internal target that actually runs the tests.
 879     # This is necessary to be able to add separate targets that execute as part
 880     # of 'make check', but are ensured to be executed after the actual tests.
 881     add_custom_target(run-ctest
 882                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 883                       COMMENT "Running all tests"
 884                       VERBATIM)
 885     add_dependencies(run-ctest tests)
 886     # "check" target builds and runs all tests.
 887     add_custom_target(check DEPENDS run-ctest)
 888 endif()
 889
 890 if (NOT GMX_BUILD_MDRUN_ONLY)
 891     add_subdirectory(doxygen)
 892     add_subdirectory(share)
 893     add_subdirectory(scripts)
 894 endif()
 895 add_subdirectory(src)
 896
 897 if (BUILD_TESTING)
 898     add_subdirectory(tests)
 899 endif()
 900
 901 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 902 # Don't bother the user after the first configure pass.
 903 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 904     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 905 endif()
 906 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 907
 908 #######################
 909 ## uninstall target
 910 #######################
 911     CONFIGURE_FILE(
 912                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 913                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 914                    IMMEDIATE @ONLY)
 915 ###########################
 916 ADD_CUSTOM_TARGET(uninstall
 917                   "${CMAKE_COMMAND}" -P
 918                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 919 ###########################
 920
 921 ########################################################################
 922 # Manual                                                               #
 923 ########################################################################
 924
 925 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 926 mark_as_advanced(GMX_BUILD_MANUAL)
 927 if(GMX_BUILD_MANUAL)
 928     # Make sure we only do detection of manual-building dependencies
 929     # when the user opted in for that.
 930     add_subdirectory(manual)
 931 endif()