CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101     # Set the possible values of build type for cmake-gui
 102     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 103         "MinSizeRel" "RelWithDebInfo")
 104 endif(NOT CMAKE_BUILD_TYPE)
 105
 106 enable_language(C)
 107 enable_language(CXX)
 108
 109 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 110 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 111 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 112 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 113 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 114 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 115 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 116 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 117 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 118 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html")
 119 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 120
 121 #must come after all cpack settings!
 122 include(CPack)
 123
 124 # Set a default valgrind suppression file.
 125 # This unfortunately needs to duplicate information from CTest to work as
 126 # expected...
 127 set(MEMORYCHECK_SUPPRESSIONS_FILE
 128     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 129     CACHE FILEPATH
 130     "File that contains suppressions for the memory checker")
 131 include(CTest)
 132
 133 set(SOURCE_IS_GIT_REPOSITORY OFF)
 134 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 135 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 136     set(SOURCE_IS_GIT_REPOSITORY ON)
 137 endif()
 138 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 139     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 140 endif()
 141
 142 ########################################################################
 143 # Check and warn if cache generated on a different host is being reused
 144 ########################################################################
 145 if(CMAKE_HOST_UNIX)
 146     execute_process(COMMAND hostname
 147                     OUTPUT_VARIABLE TMP_HOSTNAME
 148                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 150         message(WARNING "
 151             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 152             is being reused! This could lead to inconsitencies; therefore, it is
 153             recommended to regenerate the cache!")
 154     endif()
 155     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 156             "Hostname of the machine where the cache was generated.")
 157 endif()
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 167 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 168 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 169 gmx_dependent_option(
 170     GMX_MPI_IN_PLACE
 171     "Enable MPI_IN_PLACE for MPIs that have it defined"
 172     ON
 173     GMX_MPI)
 174 mark_as_advanced(GMX_MPI_IN_PLACE)
 175 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 176 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 177 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 178 mark_as_advanced(GMX_FAHCORE)
 179
 180 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 181 mark_as_advanced(GMX_COOL_QUOTES)
 182 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 183
 184 # decide on GPU settings based on user-settings and GPU/CUDA detection
 185 include(gmxManageGPU)
 186
 187 # Detect the architecture the compiler is targetting, detect
 188 # acceleration possibilities on that hardware, suggest an acceleration
 189 # to use if none is specified, and populate the cache option for CPU
 190 # accleration.
 191 include(gmxDetectTargetArchitecture)
 192 gmx_detect_target_architecture()
 193 include(gmxDetectAcceleration)
 194 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 195
 196 gmx_option_multichoice(
 197     GMX_CPU_ACCELERATION
 198     "Acceleration for CPU kernels and compiler optimization"
 199     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 200     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE)
 201
 202 gmx_option_multichoice(
 203     GMX_FFT_LIBRARY
 204     "FFT library"
 205     "fftw3"
 206     fftw3 mkl "fftpack[built-in]")
 207 gmx_dependent_option(
 208     GMX_BUILD_OWN_FFTW
 209     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 210     OFF
 211     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 212 gmx_dependent_option(
 213     GMX_DISABLE_FFTW_MEASURE
 214     "Do not optimize FFTW setups (not needed with SSE)"
 215     OFF
 216     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 217 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 218 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 219
 220 gmx_option_multichoice(
 221     GMX_QMMM_PROGRAM
 222     "QM package for QM/MM"
 223     None
 224     none gaussian mopac gamess orca)
 225
 226 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 227 mark_as_advanced(GMX_BROKEN_CALLOC)
 228 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 229 mark_as_advanced(GMX_LOAD_PLUGINS)
 230
 231 option(GMX_GPU  "Enable GPU acceleration" ON)
 232 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 233
 234 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 235 mark_as_advanced(GMX_GIT_VERSION_INFO)
 236
 237 if(UNIX)
 238     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 239 endif()
 240 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 241
 242 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 243 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 244
 245 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 246 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 247
 248 option(GMX_BUILD_FOR_COVERAGE
 249        "Tune build for better code coverage metrics (e.g., disable asserts)"
 250        OFF)
 251 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 252
 253
 254 ######################################################################
 255 # Detect OpenMP support
 256 ######################################################################
 257 # The OpenMP detection _must_ come before tests for other CFLAGS.
 258 include(gmxManageOpenMP)
 259
 260
 261
 262 ######################################################################
 263 # Compiler tests
 264 # These need to be done early (before further tests).
 265 #####################################################################
 266
 267 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 268 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 269 # invalid options with the Intel Compilers.
 270 # These files should be removed from the source tree when a CMake version that
 271 # includes the features in question becomes required for building GROMACS.
 272 include(CheckCCompilerFlag)
 273 include(CheckCXXCompilerFlag)
 274
 275
 276 include(gmxCFlags)
 277 gmx_c_flags()
 278
 279 # This variable should be used for additional compiler flags which are not
 280 # generated in gmxCFlags nor are acceleration or MPI related.
 281 set(EXTRA_C_FLAGS "")
 282 set(EXTRA_CXX_FLAGS "")
 283
 284 # Run through a number of tests for buggy compilers and other issues
 285 include(gmxTestCompilerProblems)
 286 gmx_test_compiler_problems()
 287
 288
 289 set(PKG_CFLAGS "")
 290 if(GMX_DOUBLE)
 291     add_definitions(-DGMX_DOUBLE)
 292     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 293 endif(GMX_DOUBLE)
 294 if(GMX_SOFTWARE_INVSQRT)
 295   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 296 endif(GMX_SOFTWARE_INVSQRT)
 297
 298
 299
 300 ########################################################################
 301 # Basic system tests (standard libraries, headers, functions, types)   #
 302 ########################################################################
 303 include(CheckIncludeFiles)
 304 include(CheckIncludeFileCXX)
 305 check_include_files(unistd.h     HAVE_UNISTD_H)
 306 check_include_files(pwd.h        HAVE_PWD_H)
 307 check_include_files(dirent.h     HAVE_DIRENT_H)
 308 check_include_files(time.h       HAVE_TIME_H)
 309 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 310 check_include_files(io.h         HAVE_IO_H)
 311 check_include_files(sched.h      HAVE_SCHED_H)
 312
 313 check_include_files(regex.h      HAVE_POSIX_REGEX)
 314 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 315 # TODO: It could be nice to inform the user if no regex support is found,
 316 # as selections won't be fully functional.
 317
 318 include(CheckFunctionExists)
 319 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 320 check_function_exists(memalign          HAVE_MEMALIGN)
 321 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 322 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 323 check_function_exists(fsync             HAVE_FSYNC)
 324 check_function_exists(_fileno           HAVE__FILENO)
 325 check_function_exists(fileno            HAVE_FILENO)
 326 check_function_exists(_commit           HAVE__COMMIT)
 327 check_function_exists(sigaction         HAVE_SIGACTION)
 328 check_function_exists(sysconf           HAVE_SYSCONF)
 329 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 330 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 331 check_function_exists(rsqrt             HAVE_RSQRT)
 332 check_function_exists(rsqrtf            HAVE_RSQRTF)
 333 check_function_exists(sqrtf             HAVE_SQRTF)
 334
 335 include(CheckLibraryExists)
 336 check_library_exists(m sqrt "" HAVE_LIBM)
 337 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 338
 339
 340 include(CheckTypeSize)
 341
 342 check_type_size("int"           SIZEOF_INT)
 343 check_type_size("long int"      SIZEOF_LONG_INT)
 344 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 345 check_type_size("off_t"         SIZEOF_OFF_T)
 346 check_type_size("void *"        SIZEOF_VOIDP)
 347
 348 include(TestBigEndian)
 349 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 350
 351 # Management of GROMACS options for specific toolchains should go
 352 # here. Because the initial settings for some of the main options have
 353 # already happened, but things like library detection and MPI compiler
 354 # feature detection have not, the docstrings for any over-rides of
 355 # GROMACS defaults or user settings will make sense. Also, any
 356 # toolchain-related reasons for choosing whether to detect various
 357 # things can be sorted out now, before the detection takes place.
 358 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 359     include(gmxManageBlueGene)
 360 endif()
 361
 362 ########################################################################
 363 #Process MPI settings
 364 ########################################################################
 365 include(gmxManageMPI)
 366
 367
 368 ########################################################################
 369 #Process shared/static library settings
 370 ########################################################################
 371 include(gmxManageSharedLibraries)
 372
 373
 374 ########################################################################
 375 # Find external packages                                               #
 376 ########################################################################
 377
 378 # Unconditionally find the package, as it is also required for unit tests
 379 find_package(LibXml2)
 380 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 381 set(PKG_XML "")
 382 mark_as_advanced(GMX_XML)
 383 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 384 #if(GMX_XML AND NOT LIBXML2_FOUND)
 385 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 386 #endif()
 387 #if(GMX_XML)
 388 #    include_directories(${LIBXML2_INCLUDE_DIR})
 389 #    set(PKG_XML libxml-2.0)
 390 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 391 #endif(GMX_XML)
 392
 393 option(GMX_GSL "Add support for gsl" OFF)
 394 if (GMX_GSL)
 395   find_package(GSL)
 396   set(PKG_GSL "")
 397   if(GSL_FOUND)
 398     include_directories(${GSL_INCLUDE_DIR})
 399     set(PKG_GSL gsl)
 400     set(HAVE_LIBGSL 1)
 401   endif(GSL_FOUND)
 402 endif (GMX_GSL)
 403
 404 option(GMX_X11 "Use X window system" OFF)
 405 if (GMX_X11)
 406     find_package(X11)
 407     # X11 includes/libraries are only set in the ngmx subdirectory!
 408     if(NOT X11_FOUND)
 409         message(FATAL_ERROR
 410                 "X11 include files and/or libraries were not found. "
 411                 "Set GMX_X11=OFF to compile without X11 support. "
 412                 "gmx view will not be available.")
 413     endif()
 414     include_directories(${X11_INCLUDE_DIR})
 415 endif(GMX_X11)
 416
 417 include(ThreadMPI)
 418 set(THREAD_MPI_LIB thread_mpi)
 419 # Enable core threading facilities
 420 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 421 # Enable tMPI C++ support
 422 tmpi_enable_cxx()
 423 if(GMX_THREAD_MPI)
 424     # enable MPI functions
 425     tmpi_enable()
 426     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 427     set(GMX_MPI 1)
 428     set(MPI_IN_PLACE_EXISTS 1)
 429 endif(GMX_THREAD_MPI)
 430 tmpi_get_source_list(THREAD_MPI_SRC)
 431
 432 if(GMX_GPU)
 433     # now that we have detected the dependencies, do the second configure pass
 434     gmx_gpu_setup()
 435 endif(GMX_GPU)
 436
 437 if(CYGWIN)
 438     set(GMX_CYGWIN 1)
 439 endif(CYGWIN)
 440
 441 if(WIN32 AND NOT CYGWIN)
 442     set(GMX_NATIVE_WINDOWS 1)
 443     # This makes windows.h not declare min/max as macros that would break
 444     # C++ code using std::min/std::max.
 445     add_definitions(-DNOMINMAX)
 446 endif()
 447
 448 # only bother with finding git and using version.h if the source is a git repo
 449 if(GMX_GIT_VERSION_INFO)
 450     if (NOT SOURCE_IS_GIT_REPOSITORY)
 451         message(FATAL_ERROR
 452             "Cannot generate git version information from source tree not under git. "
 453             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 454     endif ()
 455     # We need at least git v1.5.3 be able to parse git's date output. If not
 456     # found or the version is too small, we can't generate version information.
 457     find_package(Git)
 458
 459     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 460         message(FATAL_ERROR
 461             "No compatible git version found (>= 1.5.3 required). "
 462             "Won't be able to generate development version information. "
 463             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 464     endif()
 465 endif()
 466
 467 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 468 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 469 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 470     find_package(Boost 1.44.0)
 471     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 472         set(Boost_FOUND FALSE)
 473     endif()
 474     # Print the notification only on first run, when determining the default
 475     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 476         message("Boost >= 1.44 not found. Using minimal internal version. "
 477                 "This may cause trouble if you plan on compiling/linking other "
 478                 "software that uses Boost against Gromacs.")
 479     endif()
 480 endif()
 481 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 482        ${Boost_FOUND})
 483 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 484     message(FATAL_ERROR
 485         "Boost >= 1.44 not found. "
 486         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 487         "version of Boost included with Gromacs.")
 488 endif()
 489
 490 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 491 mark_as_advanced(GMX_BUILD_UNITTESTS)
 492 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 493 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 494     message(FATAL_ERROR
 495         "Cannot build unit tests without libxml2. "
 496         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 497 endif()
 498
 499 ########################################################################
 500 # Generate development version info for cache
 501 ########################################################################
 502 # set(GEN_VERSION_INFO_INTERNAL "ON")
 503 # include(gmxGenerateVersionString)
 504
 505 ########################################################################
 506 # Our own GROMACS tests
 507 ########################################################################
 508
 509 add_definitions( -DHAVE_CONFIG_H )
 510 include_directories(${CMAKE_SOURCE_DIR}/src)
 511 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 512 include_directories(${CMAKE_BINARY_DIR}/src)
 513 # Required for gmx_header_config_gen.h to be found before installation
 514 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 515 # Required for now to make old code compile
 516 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 517
 518 include(gmxTestInlineASM)
 519 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 520
 521 include(gmxSetBuildInformation)
 522 gmx_set_build_information()
 523 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 524     set(HAVE_RDTSCP 1)
 525 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 526
 527 include(gmxTestFloatFormat)
 528 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 529                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 530                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 531
 532 include(gmxTestLargeFiles)
 533 gmx_test_large_files(GMX_LARGEFILES)
 534
 535 include(gmxTestSignal)
 536 gmx_test_sigusr1(HAVE_SIGUSR1)
 537
 538 include(gmxTestInline)
 539 gmx_test_inline(INLINE_KEYWORD)
 540
 541 include(gmxTestRestrict)
 542 gmx_test_restrict(RESTRICT_KEYWORD)
 543
 544 include(gmxTestPipes)
 545 gmx_test_pipes(HAVE_PIPES)
 546
 547 include(gmxTestIsfinite)
 548 gmx_test_isfinite(HAVE_ISFINITE)
 549 gmx_test__isfinite(HAVE__ISFINITE)
 550 gmx_test__finite(HAVE__FINITE)
 551
 552 include(gmxTestCXX11)
 553 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 554 include(CMakeDependentOption)
 555 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 556 # entirely to keep the compilation environment uniform.
 557 cmake_dependent_option(GMX_CXX11
 558     "Use C++11 features"
 559     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 560 mark_as_advanced(GMX_CXX11)
 561 if(GMX_CXX11)
 562     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 563 endif()
 564
 565
 566 include(gmxTestXDR)
 567 gmx_test_xdr(GMX_SYSTEM_XDR)
 568 if(NOT GMX_SYSTEM_XDR)
 569     set(GMX_INTERNAL_XDR 1)
 570 endif(NOT GMX_SYSTEM_XDR)
 571
 572 # include avx test source, used if the AVX flags are set below
 573 include(gmxTestAVXMaskload)
 574
 575 # Process nonbonded accelerated kernels settings
 576 #
 577 # Note that for the backward-compatible x86 SIMD architectures, the
 578 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 579 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 580 # SSE2). Accordingly, there are a set of CMake variables
 581 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 582 # CPU features that should be used. This means that the logic for
 583 # requiring such backward compatibility is all located here.
 584 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 585     # nothing to do
 586     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 587
 588 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 589
 590     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 591     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 592         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 593     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 594
 595     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 596     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 597         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 598     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 599
 600     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 601
 602     # Only test the include after we have tried to add the correct flag for SSE2 support
 603     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 604
 605     if(NOT HAVE_EMMINTRIN_H)
 606         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 607     endif(NOT HAVE_EMMINTRIN_H)
 608
 609     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 610     # The user should not be able to set this orthogonally to the acceleration
 611     set(GMX_X86_SSE2 1)
 612     set(ACCELERATION_STATUS_MESSAGE
 613         "Enabling SSE2 Gromacs acceleration")
 614
 615 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 616
 617     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 618     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 619         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 620     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 621     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 622         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 623         # intrinsics when SSE2 support is enabled, so we try that instead first.
 624         if (GMX_NATIVE_WINDOWS)
 625             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 626             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 627         else()
 628             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 629         endif()
 630     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 631
 632     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 633     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 634         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 635     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 636     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 637         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 638         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 639         # intrinsics when SSE2 support is enabled, so we try that instead.
 640         if (GMX_NATIVE_WINDOWS)
 641             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 642         endif()
 643     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 644
 645     # This must come after we have added the -msse4.1 flag on some platforms.
 646     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 647
 648     if(NOT HAVE_SMMINTRIN_H)
 649         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 650     endif(NOT HAVE_SMMINTRIN_H)
 651
 652     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 653         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 654     endif()
 655
 656     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 657     # The user should not be able to set this orthogonally to the acceleration
 658     set(GMX_X86_SSE4_1 1)
 659     set(GMX_X86_SSE2   1)
 660     set(ACCELERATION_STATUS_MESSAGE
 661         "Enabling SSE4.1 Gromacs acceleration")
 662
 663 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 664
 665     # Set the AVX compiler flag for both these choices!
 666
 667     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 668     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 669         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 670     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 671     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 672         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 673     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 674
 675     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 676     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 677         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 678     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 679     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 680         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 681     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 682
 683     # Set the FMA4 flags (MSVC doesn't require any)
 684     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 685         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 686         if (NOT GNU_FMA_CFLAG)
 687             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 688         endif(NOT GNU_FMA_CFLAG)
 689         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 690         # No big deal if we do not have xop, so no point yelling warnings about it.
 691         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 692         if (NOT GNU_FMA_CXXFLAG)
 693             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 694         endif (NOT GNU_FMA_CXXFLAG)
 695         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 696         # No big deal if we do not have xop, so no point yelling warnings about it.
 697     endif()
 698
 699     # Only test the header after we have tried to add the flag for AVX support
 700     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 701
 702     if(NOT HAVE_IMMINTRIN_H)
 703         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 704     endif(NOT HAVE_IMMINTRIN_H)
 705
 706     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 707         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 708             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 709             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 710         if(NOT TEST_AVX)
 711             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 712         endif()
 713     endif()
 714
 715     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 716     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 717     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 718
 719     # The user should not be able to set this orthogonally to the acceleration
 720     set(GMX_X86_SSE4_1 1)
 721     set(GMX_X86_SSE2   1)
 722
 723     # But just enable one of the choices internally...
 724     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 725         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 726         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 727         # hackintoshes is not worth the effort.
 728         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 729                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 730             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 731         endif()
 732
 733         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 734             # we assume that we have an external assembler that supports AVX
 735             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 736             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 737         endif()
 738         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 739             # we assume that we have an external assembler that supports AVX
 740             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 741             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 742         endif()
 743
 744         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 745         set(GMX_X86_AVX_128_FMA 1)
 746         set(ACCELERATION_STATUS_MESSAGE
 747             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 748
 749     else()
 750         # If we are not doing AVX_128, it must be AVX_256...
 751         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 752         set(GMX_X86_AVX_256 1)
 753         set(ACCELERATION_STATUS_MESSAGE
 754             "Enabling 256-bit AVX Gromacs acceleration")
 755     endif()
 756
 757     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 758     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 759     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 760
 761 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 762     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 763         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 764
 765     if (TEST_QPX)
 766         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 767         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 768     else()
 769         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 770     endif()
 771 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 772     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 773 else()
 774     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 775 endif()
 776 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 777 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 778     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 779 endif()
 780
 781 # Process QM/MM Settings
 782 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 783     set(GMX_QMMM_GAUSSIAN 1)
 784 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 785     set(GMX_QMMM_MOPAC 1)
 786 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 787     set(GMX_QMMM_GAMESS 1)
 788 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 789     set(GMX_QMMM_ORCA 1)
 790 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 791     # nothing to do
 792 else()
 793     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 794 endif()
 795
 796
 797 ##################################################
 798 # Process FFT library settings
 799 ##################################################
 800 include(gmxManageFFTLibraries)
 801
 802
 803 include(gmxManageLinearAlgebraLibraries)
 804
 805 # Whether GROMACS will really try to compile support for VMD plugins
 806 set(GMX_USE_PLUGINS OFF)
 807
 808 if(GMX_LOAD_PLUGINS)
 809   if(CYGWIN OR NOT WIN32)
 810     # Native Windows does not have, nor need dlopen
 811     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 812     include(gmxTestdlopen)
 813     gmx_test_dlopen(HAVE_DLOPEN)
 814   endif()
 815
 816   # so, should we use plug-ins?
 817   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 818     if(NOT VMD_QUIETLY)
 819       MESSAGE(STATUS
 820           "Found the ability to use plug-ins when building shared libaries, "
 821           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 822           "formats).")
 823     endif()
 824     if(NOT GMX_VMD_PLUGIN_PATH)
 825       find_package(VMD)
 826     endif()
 827     set(GMX_USE_PLUGINS ON)
 828     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 829     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 830   else()
 831     set(PKG_DL_LIBS)
 832   endif()
 833 endif(GMX_LOAD_PLUGINS)
 834 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 835
 836 # Link real-time library for POSIX timers. The check for clock_gettime
 837 # confirms the linkability of rt.
 838 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 839     list(APPEND GMX_EXTRA_LIBRARIES rt)
 840 endif()
 841
 842 # Math and thread libraries must often come after all others when linking...
 843 if(HAVE_LIBM)
 844     list(APPEND GMX_EXTRA_LIBRARIES m)
 845 endif(HAVE_LIBM)
 846 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 847     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 848     if(HAVE_MASS_SIMD)
 849         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 850     else()
 851         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 852     endif()
 853 endif()
 854
 855 if(GMX_FAHCORE)
 856   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 857       "Path to swindirect.h")
 858   include_directories(${COREWRAP_INCLUDE_DIR})
 859 endif(GMX_FAHCORE)
 860
 861 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 862 # these are set after everything else
 863 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 864     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 865     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 866     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 867     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 868 else()
 869     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 870     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 871     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 872     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 873     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 874     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 875     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 876     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 877     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 878 endif()
 879
 880 if(NOT GMX_OPENMP)
 881     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 882     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 883     unset(OpenMP_C_FLAGS CACHE)
 884     unset(OpenMP_CXX_FLAGS CACHE)
 885 else()
 886     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 887     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 888 endif()
 889 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 890
 891 ########################################################################
 892 # Specify install locations
 893 ########################################################################
 894 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 895     "Library installation directory (default: lib)")
 896 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 897     "Data installation directory under share/ (default: gromacs)")
 898 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 899
 900 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 901 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 902 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 903 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 904 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 905
 906 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 907 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 908
 909 # Binary and library suffix options
 910 include(gmxManageSuffixes)
 911
 912 ##################################################################
 913 # Shared library settings
 914 ##################################################################
 915 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 916     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 917     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 918     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
 919     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 920 else()
 921     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 922         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 923         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
 924     else()
 925         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 926     endif()
 927 endif()
 928
 929 #COPYING file: Only necessary for binary distributions.
 930 #Simpler to always install.
 931 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 932
 933 if(GMX_EXTERNAL_BOOST)
 934     include_directories(${Boost_INCLUDE_DIRS})
 935 else()
 936     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 937     # typeid not supported for minimal internal version
 938     # (would add significant amount of code)
 939     add_definitions(-DBOOST_NO_TYPEID)
 940     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 941     # (from share/template/)
 942     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 943     if (NOT GMX_BUILD_MDRUN_ONLY)
 944         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 945                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 946                 COMPONENT development)
 947     endif ()
 948 endif()
 949
 950 if (GMX_BUILD_FOR_COVERAGE)
 951     # Code heavy with asserts makes conditional coverage close to useless metric,
 952     # as by design most of the false branches are impossible to trigger in
 953     # correctly functioning code.  And the benefit of testing those that could
 954     # be triggered by using an API against its specification isn't usually
 955     # worth the effort.
 956     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 957 endif ()
 958
 959 if (NOT GMX_BUILD_MDRUN_ONLY)
 960     add_subdirectory(doxygen)
 961     add_subdirectory(share)
 962     add_subdirectory(scripts)
 963 endif ()
 964 add_subdirectory(src)
 965
 966 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 967 # Don't bother the user after the first configure pass.
 968 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 969     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 970 endif()
 971 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 972
 973 #######################
 974 ## uninstall target
 975 #######################
 976     CONFIGURE_FILE(
 977                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 978                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 979                    IMMEDIATE @ONLY)
 980 ###########################
 981 ADD_CUSTOM_TARGET(uninstall
 982                   "${CMAKE_COMMAND}" -P
 983                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 984 ###########################
 985
 986 ########################################################################
 987 # Tests                                                                #
 988 ########################################################################
 989
 990 IF(BUILD_TESTING)
 991     enable_testing()
 992     #"check" target builds and runs all tests
 993     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
 994     add_dependencies(check tests)
 995     # TODO: This would be better within tests/CMakeLists.txt
 996     if (NOT GMX_BUILD_MDRUN_ONLY)
 997         #gmxtests target builds all binaries required for running gmxtest
 998         add_custom_target(gmxtests DEPENDS gmx links)
 999         add_dependencies(check gmxtests)
1000         add_subdirectory(tests)
1001     endif()
1002     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1003 ENDIF()
1004
1005 ########################################################################
1006 # Manual                                                               #
1007 ########################################################################
1008
1009 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1010 mark_as_advanced(GMX_BUILD_MANUAL)
1011 if(GMX_BUILD_MANUAL)
1012     # Make sure we only do detection of manual-building dependencies
1013     # when the user opted in for that.
1014     add_subdirectory(manual)
1015 endif()