CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6.1-dev")
  60 set(CUSTOM_VERSION_STRING ""
  61     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  62 mark_as_advanced(CUSTOM_VERSION_STRING)
  63 if (CUSTOM_VERSION_STRING)
  64     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  65 endif (CUSTOM_VERSION_STRING)
  66 set(SOVERSION 6)
  67 # It is a bit irritating, but this has to be set separately for now!
  68 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  69 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  70 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  71
  72 # The numerical gromacs version. It is 40600 for 4.6.0.
  73 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  74 math(EXPR NUM_VERSION
  75     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  76 if(CPACK_PACKAGE_VERSION_PATCH)
  77     math(EXPR NUM_VERSION
  78          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  79 endif()
  80
  81 # The API version tracks the numerical Gromacs version (for now).
  82 # It is potentially different from the Gromacs version in the future, if
  83 # the programs/libraries diverge from the presumably more stable API.
  84 # The #define GMX_API_VERSION in version.h is set to this value to
  85 # provide backward compatibility of software written against the Gromacs API.
  86 set(API_VERSION ${NUM_VERSION})
  87
  88 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  89 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  90 endif()
  91
  92 include(gmxBuildTypeReference)
  93
  94 if(NOT CMAKE_BUILD_TYPE)
  95     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  96 endif(NOT CMAKE_BUILD_TYPE)
  97
  98 enable_language(C)
  99
 100 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 101 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 102
 103 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 104 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 105 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 106 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 107     set(CPACK_SET_DESTDIR "ON")
 108 endif()
 109 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 110 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 111 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 112 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 113 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 114 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 115 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 116 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 117
 118 #must come after all cpack settings!
 119 include(CPack)
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsitencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # User input options - enable C++ - before any CXX flags are changed   #
 140 ########################################################################
 141
 142 # decide on GPU settings based on user-settings and GPU/CUDA detection
 143 include(gmxManageGPU)
 144
 145 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 146 mark_as_advanced(GMX_FORCE_CXX)
 147
 148 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 149 mark_as_advanced(GMX_COOL_QUOTES)
 150
 151 if(GMX_GPU OR GMX_FORCE_CXX)
 152     enable_language(CXX)
 153 endif()
 154 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 155
 156 ########################################################################
 157 # User input options                                                   #
 158 ########################################################################
 159 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 160 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 161 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 162 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 163 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 164 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 165 mark_as_advanced(GMX_FAHCORE)
 166
 167 include(gmxDetectAcceleration)
 168 if(NOT DEFINED GMX_CPU_ACCELERATION)
 169     if(CMAKE_CROSSCOMPILING)
 170         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 171             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 172         else()
 173             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 174         endif()
 175     else(CMAKE_CROSSCOMPILING)
 176         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 177     endif(CMAKE_CROSSCOMPILING)
 178 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 179
 180 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 181     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 182
 183 set(GMX_FFT_LIBRARY "fftw3"
 184     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 185 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 186 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 187 option(GMX_DISABLE_FFTW_MEASURE
 188        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 189 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 190 set(GMX_QMMM_PROGRAM "none"
 191     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 192 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 193 mark_as_advanced(GMX_BROKEN_CALLOC)
 194 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 195 mark_as_advanced(GMX_MPI_IN_PLACE)
 196 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 197 mark_as_advanced(GMX_LOAD_PLUGINS)
 198
 199 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 200
 201 option(USE_VERSION_H "Generate development version string/information" ON)
 202 mark_as_advanced(USE_VERSION_H)
 203
 204 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 205
 206 if(UNIX)
 207     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 208     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 209 endif()
 210
 211 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 212 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 213
 214 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 215 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 216
 217 ######################################################################
 218 # Compiler tests
 219 # These need to be done early (before further tests).
 220 #####################################################################
 221
 222 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 223 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 224 # invalid options with the Intel Compilers.
 225 # These files should be removed from the source tree when a CMake version that
 226 # includes the features in question becomes required for building GROMACS.
 227 include(CheckCCompilerFlag)
 228 if(CMAKE_CXX_COMPILER_LOADED)
 229     include(CheckCXXCompilerFlag)
 230 endif()
 231
 232 # Get compiler version information, needs to be done early as check that depend
 233 # on compiler verison follow below.
 234 include(gmxGetCompilerInfo)
 235 get_compiler_version()
 236
 237 # First exclude compilers known to not work with OpenMP although claim to support it:
 238 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 239 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 240 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 241     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 242     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 243     set(GMX_OPENMP OFF CACHE BOOL
 244         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 245 endif()
 246
 247 # OpenMP check must come before other CFLAGS!
 248 if(GMX_OPENMP)
 249     find_package(OpenMP)
 250     if(OPENMP_FOUND)
 251         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 252         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 253         if(NOT (WIN32 AND NOT CYGWIN))
 254             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 255                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 256                 set(OpenMP_SHARED_LINKER_FLAGS "")
 257             else()
 258                 # Only set a linker flag if the user didn't set them manually
 259                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 260                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 261                 endif()
 262                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 263                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 264                 endif()
 265             endif()
 266         endif()
 267     else(OPENMP_FOUND)
 268         message(WARNING
 269                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 270         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 271     endif(OPENMP_FOUND)
 272 endif()
 273
 274
 275 include(gmxCFlags)
 276 gmx_c_flags()
 277
 278 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 279 # Detect here whether applying a workaround is needed and will apply it later
 280 # on the affected files.
 281 include(gmxGCC44O3BugWorkaround)
 282 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 283
 284 # clang 3.0 is buggy for some unknown reason detected during adding
 285 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 286 # that is, we should replace these tests with a compiler feature test,
 287 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 288 #
 289 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 290 # the compiler version for us. So we need a manual check for clang 3.0.
 291 include(gmxDetectClang30)
 292 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 293 if(COMPILER_IS_CLANG_3_0)
 294     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 295 endif()
 296
 297 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 298     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 299 endif()
 300
 301 ########################################################################
 302 # Set up binary and library suffixing
 303 ########################################################################
 304 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 305 set(GMX_LIBS_SUFFIX ""
 306   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 307 if (GMX_DEFAULT_SUFFIX)
 308   set(GMX_BINARY_SUFFIX "")
 309   set(GMX_LIBS_SUFFIX "")
 310   if (GMX_MPI)
 311     set(GMX_BINARY_SUFFIX "_mpi")
 312     set(GMX_LIBS_SUFFIX "_mpi")
 313   endif(GMX_MPI)
 314   if (GMX_DOUBLE)
 315     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 316     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 317   endif(GMX_DOUBLE)
 318   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 319   if (NOT SUFFIX_QUIETLY)
 320     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 321     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 322   endif (NOT SUFFIX_QUIETLY)
 323 else(GMX_DEFAULT_SUFFIX)
 324   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 325   if (NOT SUFFIX_QUIETLY)
 326     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 327     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 328   endif (NOT SUFFIX_QUIETLY)
 329 endif(GMX_DEFAULT_SUFFIX)
 330 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 331
 332 set(PKG_CFLAGS "")
 333 if(GMX_DOUBLE)
 334     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 335 endif(GMX_DOUBLE)
 336 if(GMX_SOFTWARE_INVSQRT)
 337   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 338 endif(GMX_SOFTWARE_INVSQRT)
 339
 340
 341
 342 ########################################################################
 343 # Basic system tests (standard libraries, headers, functions, types)   #
 344 ########################################################################
 345 include(CheckIncludeFiles)
 346 check_include_files(string.h     HAVE_STRING_H)
 347 check_include_files(math.h       HAVE_MATH_H)
 348 check_include_files(limits.h     HAVE_LIMITS_H)
 349 check_include_files(memory.h     HAVE_MEMORY_H)
 350 check_include_files(unistd.h     HAVE_UNISTD_H)
 351 check_include_files(direct.h     HAVE_DIRECT_H)
 352 check_include_files(pwd.h        HAVE_PWD_H)
 353 check_include_files(stdint.h     HAVE_STDINT_H)
 354 check_include_files(stdlib.h     HAVE_STDLIB_H)
 355 check_include_files(pthread.h    HAVE_PTHREAD_H)
 356 check_include_files(dirent.h     HAVE_DIRENT_H)
 357 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 358 check_include_files(regex.h      HAVE_REGEX_H)
 359 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 360 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 361 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 362 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 363 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 364 check_include_files(io.h                 HAVE_IO_H)
 365 check_include_files(sched.h      HAVE_SCHED_H)
 366
 367 include(CheckFunctionExists)
 368 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 369 check_function_exists(strdup            HAVE_STRDUP)
 370 check_function_exists(vprintf           HAVE_VPRINTF)
 371 check_function_exists(memcmp            HAVE_MEMCMP)
 372 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 373 check_function_exists(memalign          HAVE_MEMALIGN)
 374 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 375 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 376 check_function_exists(isnan             HAVE_ISNAN)
 377 check_function_exists(_isnan            HAVE__ISNAN)
 378 check_function_exists(fsync             HAVE_FSYNC)
 379 check_function_exists(_fileno           HAVE__FILENO)
 380 check_function_exists(fileno            HAVE_FILENO)
 381 check_function_exists(_commit           HAVE__COMMIT)
 382 check_function_exists(sigaction         HAVE_SIGACTION)
 383 check_function_exists(sysconf           HAVE_SYSCONF)
 384 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 385 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 386 check_function_exists(rsqrt             HAVE_RSQRT)
 387 check_function_exists(rsqrtf            HAVE_RSQRTF)
 388 check_function_exists(sqrtf             HAVE_SQRTF)
 389
 390 include(CheckLibraryExists)
 391 check_library_exists(m sqrt "" HAVE_LIBM)
 392 check_library_exists(m cbrt "" HAVE_CBRT)
 393
 394
 395 include(CheckTypeSize)
 396
 397 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 398 check_type_size("int"           SIZEOF_INT)
 399 check_type_size("long int"      SIZEOF_LONG_INT)
 400 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 401 check_type_size("off_t"         SIZEOF_OFF_T)
 402 check_type_size("void *"        SIZEOF_VOIDP)
 403
 404 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 405     set(GMX_64_BIT TRUE)
 406 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 407     set(GMX_64_BIT FALSE)
 408 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 409
 410 # Check for some basic types that we *need*, so set these to int if they are not present
 411 check_type_size(uid_t uid_t)
 412 if(NOT uid_t)
 413   set(uid_t int)
 414 else(NOT uid_t)
 415   set(uid_t 0)
 416 endif(NOT uid_t)
 417
 418 check_type_size(gid_t gid_t)
 419 if(NOT gid_t)
 420   set(gid_t 1)
 421 else(NOT gid_t)
 422   set(gid_t 0)
 423 endif(NOT gid_t)
 424
 425 check_type_size(size_t size_t)
 426 if(NOT size_t)
 427   set(size_t int)
 428 else(NOT size_t)
 429   set(size_t 0)
 430 endif(NOT size_t)
 431
 432 check_type_size(off_t off_t)
 433 if(NOT off_t)
 434   set(off_t int)
 435 else(NOT off_t)
 436   set(off_t 0)
 437 endif(NOT off_t)
 438
 439 include(TestBigEndian)
 440 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 441
 442
 443 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 444     # Maybe Solaris should be here? Patch this if you know!
 445     SET(SHARED_LIBS_DEFAULT ON)
 446 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 447     # Support for shared libs on native Windows is a bit new. Its
 448     # default might change later if/when we sort things out. Also,
 449     # Cray should go here. What variable value can detect it?
 450     SET(SHARED_LIBS_DEFAULT OFF)
 451 else()
 452     message(STATUS "Defaulting to building static libraries")
 453     SET(SHARED_LIBS_DEFAULT OFF)
 454 endif()
 455
 456 # Management of GROMACS options for specific toolchains should go
 457 # here. Because the initial settings for some of the main options have
 458 # already happened, but things like library detection and MPI compiler
 459 # feature detection have not, the docstrings for any over-rides of
 460 # GROMACS defaults or user settings will make sense. Also, any
 461 # toolchain-related reasons for choosing whether to detect various
 462 # things can be sorted out now, before the detection takes place.
 463 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 464     include(gmxManageBlueGene)
 465 endif()
 466
 467 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 468     if(BUILD_SHARED_LIBS)
 469         # Warn the user about the combination. But don't overwrite the request.
 470         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 471     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 472         # Change default to OFF. Don't warn if it's already off.
 473         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 474         set(SHARED_LIBS_DEFAULT OFF)
 475     endif()
 476 endif()
 477
 478 # By now, all tool chains should have spoken up if they care about
 479 # the setting of SHARED_LIBS_DEFAULT.
 480 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 481
 482 ########################################################################
 483 #Process MPI settings
 484 ########################################################################
 485 include(gmxManageMPI)
 486
 487 ########################################################################
 488 # Find external packages                                               #
 489 ########################################################################
 490 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 491     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 492     # be used, so we'll add both to the preference list.
 493     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 494 endif()
 495
 496 IF( WIN32 AND NOT CYGWIN)
 497   if (NOT BUILD_SHARED_LIBS)
 498       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 499       if(NOT GMX_PREFER_STATIC_LIBS)
 500           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 501       endif()
 502   else()
 503       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 504       if(GMX_PREFER_STATIC_LIBS)
 505           #this combination segfaults (illigal passing of file handles)
 506           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 507       endif()
 508       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 509       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 510   endif()
 511   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 512
 513   IF (GMX_PREFER_STATIC_LIBS)
 514       #Only setting Debug and Release flags. Others configurations are current not used.
 515       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 516       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 517       if(CMAKE_CXX_COMPILER_LOADED)
 518           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 519           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 520       endif()
 521   ENDIF()
 522   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 523     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 524         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 525     endif()
 526   ENDIF()
 527 ENDIF()
 528
 529 option(GMX_GSL "Add support for gsl" OFF)
 530 if (GMX_GSL)
 531   find_package(gsl)
 532   set(PKG_GSL "")
 533   if(GSL_FOUND)
 534     include_directories(${GSL_INCLUDE_DIR})
 535     set(PKG_GSL gsl)
 536     set(HAVE_LIBGSL 1)
 537   endif(GSL_FOUND)
 538 endif (GMX_GSL)
 539
 540 option(GMX_X11 "Use X window system" OFF)
 541 if (GMX_X11)
 542         find_package(X11)
 543         # X11 includes/libraries are only set in the ngmx subdirectory!
 544         if(X11_FOUND)
 545         set(HAVE_X11 1)
 546         endif(X11_FOUND)
 547 endif(GMX_X11)
 548
 549 include(ThreadMPI)
 550 set(THREAD_MPI_LIB thread_mpi)
 551 if(GMX_THREAD_MPI)
 552     tmpi_get_source_list(THREAD_MPI_SRC)
 553     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 554     set(GMX_MPI 1)
 555 else(GMX_THREAD_MPI)
 556     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 557 endif(GMX_THREAD_MPI)
 558
 559 if(GMX_GPU)
 560     # now that we have detected the dependencies, do the second configure pass
 561     gmx_gpu_setup()
 562 endif(GMX_GPU)
 563
 564 if(APPLE)
 565    find_library(ACCELERATE_FRAMEWORK Accelerate)
 566    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 567 endif(APPLE)
 568
 569 if(CYGWIN)
 570     set(GMX_CYGWIN 1)
 571 endif(CYGWIN)
 572
 573 if(WIN32 AND NOT CYGWIN)
 574     set(GMX_NATIVE_WINDOWS 1)
 575 endif()
 576
 577 # only bother with finding git and using version.h if the source is a git repo
 578 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 579     if(USE_VERSION_H)
 580         # We need at least git v1.5.3 be able to parse git's date output. If not
 581         # found or the version is too small, we can't generate version information.
 582         find_package(Git)
 583
 584         # Find out the git version
 585         if(GIT_FOUND AND NOT GIT_VERSION)
 586           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 587             OUTPUT_VARIABLE _exec_out
 588             OUTPUT_STRIP_TRAILING_WHITESPACE)
 589           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 590           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 591           mark_as_advanced(GIT_VERSION)
 592         endif()
 593
 594         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 595           message("No compatible git version found, won't be able to generate proper development version information.")
 596           set(USE_VERSION_H OFF)
 597         endif()
 598     endif()
 599 else()
 600     set(USE_VERSION_H OFF)
 601 endif()
 602
 603 ########################################################################
 604 # Generate development version info for cache
 605 ########################################################################
 606 # set(GEN_VERSION_INFO_INTERNAL "ON")
 607 # include(gmxGenerateVersionString)
 608
 609 ########################################################################
 610 # Our own GROMACS tests
 611 ########################################################################
 612
 613 add_definitions( -DHAVE_CONFIG_H )
 614 include_directories(${CMAKE_BINARY_DIR}/src)
 615 include_directories(${CMAKE_BINARY_DIR}/include)
 616 include_directories(${CMAKE_SOURCE_DIR}/include)
 617
 618 include(gmxTestInlineASM)
 619 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 620
 621 include(gmxSetBuildInformation)
 622 gmx_set_build_information()
 623 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 624     # The timestep counter headers do not include config.h
 625     add_definitions(-DHAVE_RDTSCP)
 626 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 627
 628 include(gmxTestFloatFormat)
 629 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 630                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 631                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 632
 633 include(gmxTestLargeFiles)
 634 gmx_test_large_files(GMX_LARGEFILES)
 635
 636 include(gmxTestSignal)
 637 gmx_test_sigusr1(HAVE_SIGUSR1)
 638
 639 include(gmxTestInline)
 640 gmx_test_inline(INLINE_KEYWORD)
 641
 642 include(gmxTestRestrict)
 643 gmx_test_restrict(RESTRICT_KEYWORD)
 644
 645 include(gmxTestPipes)
 646 gmx_test_pipes(HAVE_PIPES)
 647
 648 include(gmxTestIsfinite)
 649 gmx_test_isfinite(HAVE_ISFINITE)
 650 gmx_test__isfinite(HAVE__ISFINITE)
 651 gmx_test__finite(HAVE__FINITE)
 652
 653 include(gmxTestXDR)
 654 gmx_test_xdr(GMX_SYSTEM_XDR)
 655 if(NOT GMX_SYSTEM_XDR)
 656     set(GMX_INTERNAL_XDR 1)
 657     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 658 endif(NOT GMX_SYSTEM_XDR)
 659
 660 # include avx test source, used if the AVX flags are set below
 661 include(gmxTestAVXMaskload)
 662
 663 # Process nonbonded accelerated kernels settings
 664 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 665 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 666     # nothing to do
 667 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 668
 669     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 670     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 671         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 672     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 673
 674     if (CMAKE_CXX_COMPILER_LOADED)
 675         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 676         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 677             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 678         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 679     endif()
 680
 681     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 682
 683     # Only test the include after we have tried to add the correct flag for SSE2 support
 684     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 685
 686     if(NOT HAVE_EMMINTRIN_H)
 687         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 688     endif(NOT HAVE_EMMINTRIN_H)
 689
 690     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 691     # The user should not be able to set this orthogonally to the acceleration
 692     set(GMX_X86_SSE2 1)
 693     if (NOT ACCELERATION_QUIETLY)
 694       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 695     endif()
 696
 697 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 698
 699     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 700     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 701         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 702     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 703     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 704         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 705         # intrinsics when SSE2 support is enabled, so we try that instead first.
 706         if (GMX_NATIVE_WINDOWS)
 707             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 708             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 709         else()
 710             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 711         endif()
 712     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 713
 714     if (CMAKE_CXX_COMPILER_LOADED)
 715         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 716         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 717             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 718         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 719         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 720             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 721             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 722             # intrinsics when SSE2 support is enabled, so we try that instead.
 723             if (GMX_NATIVE_WINDOWS)
 724                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 725             endif()
 726         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 727     endif()
 728
 729     # This must come after we have added the -msse4.1 flag on some platforms.
 730     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 731
 732     if(NOT HAVE_SMMINTRIN_H)
 733         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 734     endif(NOT HAVE_SMMINTRIN_H)
 735
 736     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 737     # The user should not be able to set this orthogonally to the acceleration
 738     set(GMX_X86_SSE4_1 1)
 739     set(GMX_X86_SSE2   1)
 740     if (NOT ACCELERATION_QUIETLY)
 741       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 742     endif()
 743
 744 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 745
 746     # Set the AVX compiler flag for both these choices!
 747
 748     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 749     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 750         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 751     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 752     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 753         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 754     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 755
 756     if (CMAKE_CXX_COMPILER_LOADED)
 757         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 758         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 759             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 760         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 761         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 762             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 763         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 764     endif()
 765
 766     # Set the FMA4 flags (MSVC doesn't require any)
 767     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 768         if (${CMAKE_COMPILER_ID} MATCHES "Clang")
 769             message(FATAL_ERROR "Clang up to at least version 3.2 produces incorrect code for AVX_128_FMA. Sorry, but you will have to select a different compiler or acceleration.")
 770         endif()
 771         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 772         if (NOT GNU_FMA_CFLAG)
 773             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 774         endif(NOT GNU_FMA_CFLAG)
 775         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 776         # No big deal if we do not have xop, so no point yelling warnings about it.
 777         if (CMAKE_CXX_COMPILER_LOADED)
 778             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 779             if (NOT GNU_FMA_CXXFLAG)
 780                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 781             endif (NOT GNU_FMA_CXXFLAG)
 782             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 783             # No big deal if we do not have xop, so no point yelling warnings about it.
 784         endif()
 785     endif()
 786
 787     # Only test the header after we have tried to add the flag for AVX support
 788     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 789
 790     if(NOT HAVE_IMMINTRIN_H)
 791         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 792     endif(NOT HAVE_IMMINTRIN_H)
 793
 794     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 795         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 796             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 797             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 798         if(NOT TEST_AVX)
 799             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 800         endif()
 801     endif()
 802
 803     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 804     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 805     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 806
 807     # The user should not be able to set this orthogonally to the acceleration
 808     set(GMX_X86_SSE4_1 1)
 809     set(GMX_X86_SSE2   1)
 810
 811     # But just enable one of the choices internally...
 812     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 813         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 814         set(GMX_X86_AVX_128_FMA 1)
 815         if (NOT ACCELERATION_QUIETLY)
 816           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 817         endif()
 818     else()
 819         # If we are not doing AVX_128, it must be AVX_256...
 820         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 821         set(GMX_X86_AVX_256 1)
 822         if (NOT ACCELERATION_QUIETLY)
 823           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 824         endif()
 825     endif()
 826
 827     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 828     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 829     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 830
 831 else(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 832     # Used on BlueGene/Q
 833     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 834         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 835         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 836             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 837             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 838         if(NOT TEST_QPX)
 839             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 840         endif()
 841     endif()
 842     if (CMAKE_CXX_COMPILER_ID MATCHES "XL" AND CMAKE_CXX_COMPILER_LOADED)
 843         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 844         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 845             "cmake/TestQPX.c"
 846             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS")
 847         if(NOT TEST_QPX)
 848             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 849         endif()
 850     endif()
 851
 852     if (TEST_QPX)
 853         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 854         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 855     else()
 856         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 857     endif()
 858
 859 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 860     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 861 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 862 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 863
 864 # Process QM/MM Settings
 865 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 866 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 867     set(GMX_QMMM_GAUSSIAN 1)
 868 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 869     set(GMX_QMMM_MOPAC 1)
 870 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 871     set(GMX_QMMM_GAMESS 1)
 872 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 873     set(GMX_QMMM_ORCA 1)
 874 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 875     # nothing to do
 876 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 877     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 878 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 879
 880 # Process FFT library settings
 881 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 882 set(PKG_FFT "")
 883 set(PKG_FFT_LIBS "")
 884 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 885     if(GMX_DOUBLE)
 886         set(FFTW fftw)
 887     else()
 888         set(FFTW fftwf)
 889     endif()
 890
 891     if(GMX_BUILD_OWN_FFTW)
 892       add_subdirectory(src/contrib/fftw)
 893     else()
 894       find_package(FFTW COMPONENTS ${FFTW})
 895     endif()
 896
 897     string(TOUPPER "${FFTW}" FFTW)
 898     set(PKG_FFT "${${FFTW}_PKG}")
 899     include_directories(${${FFTW}_INCLUDE_DIRS})
 900     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 901     if(NOT ${FFTW}_FOUND)
 902       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 903     endif()
 904
 905     set(GMX_FFT_FFTW3 1)
 906
 907     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 908       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 909     endif()
 910
 911     if(NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND ${FFTW}_HAVE_AVX)
 912         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 913         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 914     endif()
 915
 916 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 917 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 918     find_package(MKL REQUIRED)
 919     include_directories(${MKL_INCLUDE_DIR})
 920     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 921     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 922
 923     set(GMX_FFT_MKL 1)
 924     set(HAVE_MKL 1)
 925
 926 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 927 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 928 #    set(GMX_FFT_ACML 1)
 929 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 930     MESSAGE(STATUS "Using internal FFT library - fftpack")
 931     set(GMX_FFT_FFTPACK 1)
 932 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 933     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 934 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 935
 936 # enable threaded fftw3 if we've found it
 937 if(FFTW3_THREADS OR FFTW3F_THREADS)
 938     add_definitions(-DFFT5D_FFTW_THREADS)
 939 endif()
 940
 941 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 942 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 943 # MKL has BLAS/LAPACK routines
 944 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 945   if(GMX_EXTERNAL_BLAS)
 946     if (GMX_BLAS_USER)
 947         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 948     else(GMX_BLAS_USER)
 949         set(BLAS_FIND_QUIETLY ON)
 950         find_package(BLAS)
 951         if (BLAS_FOUND)
 952           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 953         else()
 954           MESSAGE(STATUS "Using internal BLAS library")
 955           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 956         endif()
 957     endif(GMX_BLAS_USER)
 958   endif(GMX_EXTERNAL_BLAS)
 959   if(GMX_EXTERNAL_LAPACK)
 960     if (GMX_LAPACK_USER)
 961         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 962     else(GMX_LAPACK_USER)
 963         set(LAPACK_FIND_QUIETLY ON)
 964         find_package(LAPACK)
 965         if (LAPACK_FOUND)
 966           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 967         else()
 968           MESSAGE(STATUS "Using internal LAPACK library")
 969           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 970         endif()
 971     endif(GMX_LAPACK_USER)
 972   endif(GMX_EXTERNAL_LAPACK)
 973 endif()
 974 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 975 mark_as_advanced(GMX_EXTERNAL_BLAS)
 976
 977 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 978
 979 if(GMX_LOAD_PLUGINS)
 980   if(CYGWIN OR NOT WIN32)
 981     # Native Windows does not have, nor need dlopen
 982     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 983     include(gmxTestdlopen)
 984     gmx_test_dlopen(HAVE_DLOPEN)
 985   endif()
 986
 987   # so, should we use plug-ins?
 988   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 989     if(NOT VMD_QUIETLY)
 990       MESSAGE(STATUS
 991           "Found the ability to use plug-ins when building shared libaries, "
 992           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 993           "formats).")
 994     endif()
 995     if(NOT GMX_VMD_PLUGIN_PATH)
 996       find_package(VMD)
 997     endif()
 998     set(GMX_USE_PLUGINS ON)
 999     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1000     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1001   else()
1002     set(PKG_DL_LIBS)
1003   endif()
1004 endif(GMX_LOAD_PLUGINS)
1005 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1006
1007 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1008     if(NOT CMAKE_CROSSCOMPILING)
1009         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1010     else()
1011         message(STATUS "Building the man pages is not available when "
1012             "cross-compiling the developer version from git")
1013     endif()
1014 else()
1015     #make sure source package contains all man pages
1016     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1017         message(FATAL_ERROR "Man pages are missing from source package.")
1018     endif()
1019 endif()
1020 mark_as_advanced(GMX_BUILD_MANPAGES)
1021
1022 # Math and thread libraries must often come after all others when linking...
1023 if(HAVE_LIBM)
1024     list(APPEND GMX_EXTRA_LIBRARIES m)
1025 endif(HAVE_LIBM)
1026
1027 if(GMX_FAHCORE)
1028   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1029       "Path to swindirect.h")
1030   include_directories(${COREWRAP_INCLUDE_DIR})
1031   set_property(CACHE GMX_COOL_QUOTES VALUE OFF)
1032 endif(GMX_FAHCORE)
1033
1034 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1035 # these are set after everything else
1036 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1037     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_C_FLAGS}")
1038     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_CXX_FLAGS}")
1039     set(CMAKE_EXE_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1040     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1041 else()
1042     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1043     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CFLAGS}")
1044     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1045     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1046     if(CMAKE_CXX_COMPILER_LOADED)
1047         message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CXXFLAGS}")
1048         message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1049         message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1050     endif()
1051     message("CMAKE_EXE_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1052     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1053 endif()
1054
1055 if(NOT GMX_OPENMP)
1056     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1057     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1058     unset(OpenMP_C_FLAGS CACHE)
1059     unset(OpenMP_CXX_FLAGS CACHE)
1060     unset(OpenMP_LINKER_FLAGS CACHE)
1061     unset(OpenMP_SHARED_LINKER_FLAGS)
1062 endif()
1063 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1064
1065 ######################################
1066 # Output compiler and CFLAGS used
1067 ######################################
1068 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1069 if (CMAKE_CXX_COMPILER_LOADED)
1070     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1071 endif ()
1072
1073 ########################################################################
1074 # Specify install locations and which subdirectories to process        #
1075 ########################################################################
1076 if (GMX_USE_RELATIVE_INSTALL_PATH)
1077     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1078     mark_as_advanced(GMX_INSTALL_PREFIX)
1079 else()
1080     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1081 endif()
1082
1083 if ( NOT DEFINED GMXLIB )
1084     set(GMXLIB lib)
1085 endif()
1086 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1087 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1088 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1089 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1090 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1091
1092 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1093
1094 ##################################################################
1095 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1096 ##################################################################
1097 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1098     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1099     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1100     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1101     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1102 endif()
1103
1104 #COPYING file: Only necessary for binary distributions.
1105 #Simpler to always install.
1106 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1107
1108 add_subdirectory(share)
1109 add_subdirectory(include)
1110 add_subdirectory(src)
1111 add_subdirectory(scripts)
1112
1113 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1114 # Don't bother the user after the first configure pass.
1115 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1116     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1117     unset(CUDA_NOTFOUND_AUTO)
1118     unset(CUDA_NOTFOUND_MESSAGE)
1119 endif()
1120 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1121
1122 #######################
1123 ## uninstall target
1124 #######################
1125     CONFIGURE_FILE(
1126                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1127                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1128                    IMMEDIATE @ONLY)
1129 ###########################
1130 ADD_CUSTOM_TARGET(uninstall
1131                   "${CMAKE_COMMAND}" -P
1132                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1133 ###########################
1134
1135 ########################################################################
1136 # Tests                                                                #
1137 ########################################################################
1138
1139 include(CTest)
1140 mark_as_advanced(BUILD_TESTING)
1141 #gmxtests target builds all binaries required for running gmxtest
1142 add_custom_target(gmxtests DEPENDS grompp mdrun pdb2gmx gmxcheck editconf)
1143 IF(BUILD_TESTING)
1144     enable_testing()
1145     add_subdirectory(tests)
1146     if(REGRESSIONTEST_PATH)
1147         #check target builds all to run tests and the runs tests
1148         add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1149         add_dependencies(check gmxtests)
1150     else()
1151         add_custom_target(check COMMAND ${CMAKE_COMMAND} -E echo "WARNING: No tests are run. Running the tests requires either of the cmake variables REGRESSIONTEST_PATH or REGRESSIONTEST_DOWNLOAD to be set.")
1152     endif()
1153 ENDIF()
1154