CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6-beta3-dev")
  60 set(CUSTOM_VERSION_STRING ""
  61     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  62 mark_as_advanced(CUSTOM_VERSION_STRING)
  63 if (CUSTOM_VERSION_STRING)
  64     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  65 endif (CUSTOM_VERSION_STRING)
  66 set(SOVERSION 6)
  67 # It is a bit irritating, but this has to be set separately for now!
  68 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  69 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  70 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  71
  72 # The numerical gromacs version. It is 40600 for 4.6.0.
  73 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  74 math(EXPR NUM_VERSION
  75     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  76 if(CPACK_PACKAGE_VERSION_PATCH)
  77     math(EXPR NUM_VERSION
  78          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  79 endif()
  80
  81 # The API version tracks the numerical Gromacs version (for now).
  82 # It is potentially different from the Gromacs version in the future, if
  83 # the programs/libraries diverge from the presumably more stable API.
  84 # The #define GMX_API_VERSION in version.h is set to this value to
  85 # provide backward compatibility of software written against the Gromacs API.
  86 set(API_VERSION ${NUM_VERSION})
  87
  88 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  89 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  90 endif()
  91
  92 include(gmxBuildTypeReference)
  93
  94 if(NOT CMAKE_BUILD_TYPE)
  95     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  96 endif(NOT CMAKE_BUILD_TYPE)
  97
  98 enable_language(C)
  99
 100 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 101 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 102
 103 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 104 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 105 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 106 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 107     set(CPACK_SET_DESTDIR "ON")
 108 endif()
 109 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 110 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 111 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 112 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 113 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 114 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 115 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 116 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 117
 118 #must come after all cpack settings!
 119 include(CPack)
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsitencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # User input options - enable C++ - before any CXX flags are changed   #
 140 ########################################################################
 141
 142 # decide on GPU settings based on user-settings and GPU/CUDA detection
 143 include(gmxManageGPU)
 144
 145 # TODO: move OpenMM to contrib
 146 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (not fully supported)" OFF)
 147 mark_as_advanced(GMX_OPENMM)
 148
 149 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 150 mark_as_advanced(GMX_FORCE_CXX)
 151
 152 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 153 mark_as_advanced(GMX_COOL_QUOTES)
 154
 155 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 156     enable_language(CXX)
 157 endif()
 158 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 159
 160 ########################################################################
 161 # User input options                                                   #
 162 ########################################################################
 163 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 164 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 165 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 166 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 167 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 168 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 169 mark_as_advanced(GMX_FAHCORE)
 170
 171 include(gmxDetectAcceleration)
 172 if(NOT DEFINED GMX_CPU_ACCELERATION)
 173     if(CMAKE_CROSSCOMPILING)
 174         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 175             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 176         else()
 177             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 178         endif()
 179     else(CMAKE_CROSSCOMPILING)
 180         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 181     endif(CMAKE_CROSSCOMPILING)
 182 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 183
 184 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 185     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 186
 187 set(GMX_FFT_LIBRARY "fftw3"
 188     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 189 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 190 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 191 option(GMX_DISABLE_FFTW_MEASURE
 192        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 193 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 194 set(GMX_QMMM_PROGRAM "none"
 195     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 196 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 197 mark_as_advanced(GMX_BROKEN_CALLOC)
 198 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 199 mark_as_advanced(GMX_MPI_IN_PLACE)
 200 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 201 mark_as_advanced(GMX_LOAD_PLUGINS)
 202
 203 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 204
 205 option(USE_VERSION_H "Generate development version string/information" ON)
 206 mark_as_advanced(USE_VERSION_H)
 207
 208 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 209
 210 if(UNIX)
 211     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 212     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 213 endif()
 214
 215 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 216 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 217
 218 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 219 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 220
 221 ######################################################################
 222 # Compiler tests
 223 # These need to be done early (before further tests).
 224 #####################################################################
 225
 226 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 227 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 228 # invalid options with the Intel Compilers.
 229 # These files should be removed from the source tree when a CMake version that
 230 # includes the features in question becomes required for building GROMACS.
 231 include(CheckCCompilerFlag)
 232 if(CMAKE_CXX_COMPILER_LOADED)
 233     include(CheckCXXCompilerFlag)
 234 endif()
 235
 236 # OpenMP check must come before other CFLAGS!
 237 if(GMX_OPENMP)
 238     find_package(OpenMP)
 239     if(OPENMP_FOUND)
 240         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 241         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 242         if(NOT (WIN32 AND NOT CYGWIN))
 243             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 244                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 245                 set(OpenMP_SHARED_LINKER_FLAGS "")
 246             else()
 247                 # Only set a linker flag if the user didn't set them manually
 248                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 249                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 250                 endif()
 251                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 252                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 253                 endif()
 254             endif()
 255         endif()
 256     else(OPENMP_FOUND)
 257         message(WARNING
 258                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 259         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 260     endif(OPENMP_FOUND)
 261 endif()
 262
 263
 264 include(gmxCFlags)
 265 gmx_c_flags()
 266
 267 include(gmxGetCompilerInfo)
 268 get_compiler_version()
 269
 270 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 271 # Detect here whether applying a workaround is needed and will apply it later
 272 # on the affected files.
 273 include(gmxGCC44O3BugWorkaround)
 274 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 275
 276 # clang 3.0 is buggy for some unknown reason detected during adding
 277 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 278 # that is, we should replace these tests with a compiler feature test,
 279 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 280 #
 281 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 282 # the compiler version for us. So we need a manual check for clang 3.0.
 283 include(gmxDetectClang30)
 284 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 285 if(COMPILER_IS_CLANG_3_0)
 286     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 287 endif()
 288
 289 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 290     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 291 endif()
 292
 293 ########################################################################
 294 # Set up binary and library suffixing
 295 ########################################################################
 296 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 297 set(GMX_LIBS_SUFFIX ""
 298   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 299 if (GMX_DEFAULT_SUFFIX)
 300   set(GMX_BINARY_SUFFIX "")
 301   set(GMX_LIBS_SUFFIX "")
 302   if (GMX_MPI)
 303     set(GMX_BINARY_SUFFIX "_mpi")
 304     set(GMX_LIBS_SUFFIX "_mpi")
 305   endif(GMX_MPI)
 306   if (GMX_DOUBLE)
 307     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 308     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 309   endif(GMX_DOUBLE)
 310   if (GMX_OPENMM)
 311     set (GMX_BINARY_SUFFIX "-openmm")
 312     set (GMX_LIBS_SUFFIX "_openmm")
 313   endif(GMX_OPENMM)
 314   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 315   if (NOT SUFFIX_QUIETLY)
 316     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 317     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 318   endif (NOT SUFFIX_QUIETLY)
 319 else(GMX_DEFAULT_SUFFIX)
 320   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 321   if (NOT SUFFIX_QUIETLY)
 322     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 323     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 324   endif (NOT SUFFIX_QUIETLY)
 325 endif(GMX_DEFAULT_SUFFIX)
 326 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 327
 328 set(PKG_CFLAGS "")
 329 if(GMX_DOUBLE)
 330     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 331 endif(GMX_DOUBLE)
 332 if(GMX_SOFTWARE_INVSQRT)
 333   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 334 endif(GMX_SOFTWARE_INVSQRT)
 335
 336 #######################################################################
 337 # Check for options incompatible with OpenMM build                    #
 338 #######################################################################
 339 if(GMX_OPENMM)
 340     # we'll use the built-in fft to avoid unnecessary dependencies
 341     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 342     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 343         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 344         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 345                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 346     endif()
 347     if(GMX_MPI)
 348         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 349     endif(GMX_MPI)
 350     if(GMX_THREAD_MPI)
 351         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 352         set(GMX_THREAD_MPI OFF CACHE BOOL
 353                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 354     endif(GMX_THREAD_MPI)
 355     if(GMX_OPENMP)
 356         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 357         set(GMX_OPENMP OFF CACHE BOOL
 358             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 359     endif()
 360     if(GMX_SOFTWARE_INVSQRT)
 361         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 362                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 363     endif(GMX_SOFTWARE_INVSQRT)
 364     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 365     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
 366         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 367         set(GMX_CPU_ACCELERATION "None" CACHE STRING
 368             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 369     endif()
 370     if(GMX_FAHCORE)
 371         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 372     endif(GMX_FAHCORE)
 373     if(GMX_DOUBLE)
 374         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 375     endif()
 376     # mark as advanced the unused variables
 377     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 378         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 379 else(GMX_OPENMM)
 380      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 381         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 382 endif(GMX_OPENMM)
 383
 384
 385 ########################################################################
 386 # Basic system tests (standard libraries, headers, functions, types)   #
 387 ########################################################################
 388 include(CheckIncludeFiles)
 389 check_include_files(string.h     HAVE_STRING_H)
 390 check_include_files(math.h       HAVE_MATH_H)
 391 check_include_files(limits.h     HAVE_LIMITS_H)
 392 check_include_files(memory.h     HAVE_MEMORY_H)
 393 check_include_files(unistd.h     HAVE_UNISTD_H)
 394 check_include_files(direct.h     HAVE_DIRECT_H)
 395 check_include_files(pwd.h        HAVE_PWD_H)
 396 check_include_files(stdint.h     HAVE_STDINT_H)
 397 check_include_files(stdlib.h     HAVE_STDLIB_H)
 398 check_include_files(pthread.h    HAVE_PTHREAD_H)
 399 check_include_files(dirent.h     HAVE_DIRENT_H)
 400 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 401 check_include_files(regex.h      HAVE_REGEX_H)
 402 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 403 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 404 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 405 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 406 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 407 check_include_files(io.h                 HAVE_IO_H)
 408 check_include_files(sched.h      HAVE_SCHED_H)
 409
 410 include(CheckFunctionExists)
 411 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 412 check_function_exists(strdup            HAVE_STRDUP)
 413 check_function_exists(vprintf           HAVE_VPRINTF)
 414 check_function_exists(memcmp            HAVE_MEMCMP)
 415 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 416 check_function_exists(memalign          HAVE_MEMALIGN)
 417 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 418 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 419 check_function_exists(isnan             HAVE_ISNAN)
 420 check_function_exists(_isnan            HAVE__ISNAN)
 421 check_function_exists(fsync             HAVE_FSYNC)
 422 check_function_exists(_fileno           HAVE__FILENO)
 423 check_function_exists(fileno            HAVE_FILENO)
 424 check_function_exists(_commit           HAVE__COMMIT)
 425 check_function_exists(sigaction         HAVE_SIGACTION)
 426 check_function_exists(sysconf           HAVE_SYSCONF)
 427 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 428 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 429 check_function_exists(rsqrt             HAVE_RSQRT)
 430 check_function_exists(rsqrtf            HAVE_RSQRTF)
 431 check_function_exists(sqrtf             HAVE_SQRTF)
 432
 433 include(CheckLibraryExists)
 434 check_library_exists(m sqrt "" HAVE_LIBM)
 435 check_library_exists(m cbrt "" HAVE_CBRT)
 436
 437
 438 include(CheckTypeSize)
 439
 440 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 441 check_type_size("int"           SIZEOF_INT)
 442 check_type_size("long int"      SIZEOF_LONG_INT)
 443 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 444 check_type_size("off_t"         SIZEOF_OFF_T)
 445 check_type_size("void *"        SIZEOF_VOIDP)
 446
 447 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 448     set(GMX_64_BIT TRUE)
 449 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 450     set(GMX_64_BIT FALSE)
 451 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 452
 453 # Check for some basic types that we *need*, so set these to int if they are not present
 454 check_type_size(uid_t uid_t)
 455 if(NOT uid_t)
 456   set(uid_t int)
 457 else(NOT uid_t)
 458   set(uid_t 0)
 459 endif(NOT uid_t)
 460
 461 check_type_size(gid_t gid_t)
 462 if(NOT gid_t)
 463   set(gid_t 1)
 464 else(NOT gid_t)
 465   set(gid_t 0)
 466 endif(NOT gid_t)
 467
 468 check_type_size(size_t size_t)
 469 if(NOT size_t)
 470   set(size_t int)
 471 else(NOT size_t)
 472   set(size_t 0)
 473 endif(NOT size_t)
 474
 475 check_type_size(off_t off_t)
 476 if(NOT off_t)
 477   set(off_t int)
 478 else(NOT off_t)
 479   set(off_t 0)
 480 endif(NOT off_t)
 481
 482 include(TestBigEndian)
 483 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 484
 485
 486 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 487     # Maybe Solaris should be here? Patch this if you know!
 488     SET(SHARED_LIBS_DEFAULT ON)
 489 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 490     # Support for shared libs on native Windows is a bit new. Its
 491     # default might change later if/when we sort things out. Also,
 492     # Cray should go here. What variable value can detect it?
 493     SET(SHARED_LIBS_DEFAULT OFF)
 494 else()
 495     message(STATUS "Defaulting to building static libraries")
 496     SET(SHARED_LIBS_DEFAULT OFF)
 497 endif()
 498
 499 # Management of GROMACS options for specific toolchains should go
 500 # here. Because the initial settings for some of the main options have
 501 # already happened, but things like library detection and MPI compiler
 502 # feature detection have not, the docstrings for any over-rides of
 503 # GROMACS defaults or user settings will make sense. Also, any
 504 # toolchain-related reasons for choosing whether to detect various
 505 # things can be sorted out now, before the detection takes place.
 506 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 507     include(gmxManageBlueGene)
 508 endif()
 509
 510 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 511     if(BUILD_SHARED_LIBS)
 512         # Warn the user about the combination. But don't overwrite the request.
 513         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 514     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 515         # Change default to OFF. Don't warn if it's already off.
 516         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 517         set(SHARED_LIBS_DEFAULT OFF)
 518     endif()
 519 endif()
 520
 521 # By now, all tool chains should have spoken up if they care about
 522 # the setting of SHARED_LIBS_DEFAULT.
 523 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 524
 525 ########################################################################
 526 #Process MPI settings
 527 ########################################################################
 528 include(gmxManageMPI)
 529
 530 ########################################################################
 531 # Find external packages                                               #
 532 ########################################################################
 533 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 534     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 535     # be used, so we'll add both to the preference list.
 536     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 537 endif()
 538
 539 IF( WIN32 AND NOT CYGWIN)
 540   if (NOT BUILD_SHARED_LIBS)
 541       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 542       if(NOT GMX_PREFER_STATIC_LIBS)
 543           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 544       endif()
 545   else()
 546       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 547       if(GMX_PREFER_STATIC_LIBS)
 548           #this combination segfaults (illigal passing of file handles)
 549           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 550       endif()
 551       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 552       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 553   endif()
 554   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 555
 556   IF (GMX_PREFER_STATIC_LIBS)
 557       #Only setting Debug and Release flags. Others configurations are current not used.
 558       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 559       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 560       if(CMAKE_CXX_COMPILER_LOADED)
 561           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 562           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 563       endif()
 564   ENDIF()
 565   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 566     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 567         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 568     endif()
 569   ENDIF()
 570 ENDIF()
 571
 572 option(GMX_GSL "Add support for gsl" OFF)
 573 if (GMX_GSL)
 574   find_package(gsl)
 575   set(PKG_GSL "")
 576   if(GSL_FOUND)
 577     include_directories(${GSL_INCLUDE_DIR})
 578     set(PKG_GSL gsl)
 579     set(HAVE_LIBGSL 1)
 580   endif(GSL_FOUND)
 581 endif (GMX_GSL)
 582
 583 option(GMX_X11 "Use X window system" OFF)
 584 if (GMX_X11)
 585         find_package(X11)
 586         # X11 includes/libraries are only set in the ngmx subdirectory!
 587         if(X11_FOUND)
 588         set(HAVE_X11 1)
 589         endif(X11_FOUND)
 590 endif(GMX_X11)
 591
 592 include(ThreadMPI)
 593 set(THREAD_MPI_LIB thread_mpi)
 594 if(GMX_THREAD_MPI)
 595     tmpi_get_source_list(THREAD_MPI_SRC)
 596     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 597     set(GMX_MPI 1)
 598 else(GMX_THREAD_MPI)
 599     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 600 endif(GMX_THREAD_MPI)
 601
 602 if(GMX_OPENMM)
 603     set(CUDA_BUILD_EMULATION OFF)
 604     find_package(CUDA 3.1 REQUIRED)
 605     add_definitions(-DGMX_OPENMM)
 606     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 607         set(CUDA_VERBOSE_BUILD ON)
 608     endif()
 609     find_package(OpenMM)
 610 endif(GMX_OPENMM)
 611
 612 if(GMX_GPU)
 613     # now that we have detected the dependencies, do the second configure pass
 614     gmx_gpu_setup()
 615 endif(GMX_GPU)
 616
 617 if(APPLE)
 618    find_library(ACCELERATE_FRAMEWORK Accelerate)
 619    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 620 endif(APPLE)
 621
 622 if(CYGWIN)
 623     set(GMX_CYGWIN 1)
 624 endif(CYGWIN)
 625
 626 if(WIN32 AND NOT CYGWIN)
 627     set(GMX_NATIVE_WINDOWS 1)
 628 endif()
 629
 630 # only bother with finding git and using version.h if the source is a git repo
 631 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 632     if(USE_VERSION_H)
 633         # We need at least git v1.5.3 be able to parse git's date output. If not
 634         # found or the version is too small, we can't generate version information.
 635         find_package(Git)
 636
 637         # Find out the git version
 638         if(GIT_FOUND AND NOT GIT_VERSION)
 639           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 640             OUTPUT_VARIABLE _exec_out
 641             OUTPUT_STRIP_TRAILING_WHITESPACE)
 642           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 643           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 644           mark_as_advanced(GIT_VERSION)
 645         endif()
 646
 647         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 648           message("No compatible git version found, won't be able to generate proper development version information.")
 649           set(USE_VERSION_H OFF)
 650         endif()
 651     endif()
 652 else()
 653     set(USE_VERSION_H OFF)
 654 endif()
 655
 656 ########################################################################
 657 # Generate development version info for cache
 658 ########################################################################
 659 # set(GEN_VERSION_INFO_INTERNAL "ON")
 660 # include(gmxGenerateVersionString)
 661
 662 ########################################################################
 663 # Our own GROMACS tests
 664 ########################################################################
 665
 666 add_definitions( -DHAVE_CONFIG_H )
 667 include_directories(${CMAKE_BINARY_DIR}/src)
 668 include_directories(${CMAKE_BINARY_DIR}/include)
 669 include_directories(${CMAKE_SOURCE_DIR}/include)
 670
 671 include(gmxTestInlineASM)
 672 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 673
 674 include(gmxSetBuildInformation)
 675 gmx_set_build_information()
 676 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 677     # The timestep counter headers do not include config.h
 678     add_definitions(-DHAVE_RDTSCP)
 679 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 680
 681 include(gmxTestFloatFormat)
 682 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 683                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 684                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 685
 686 include(gmxTestLargeFiles)
 687 gmx_test_large_files(GMX_LARGEFILES)
 688
 689 include(gmxTestSignal)
 690 gmx_test_sigusr1(HAVE_SIGUSR1)
 691
 692 include(gmxTestInline)
 693 gmx_test_inline(INLINE_KEYWORD)
 694
 695 include(gmxTestRestrict)
 696 gmx_test_restrict(RESTRICT_KEYWORD)
 697
 698 include(gmxTestPipes)
 699 gmx_test_pipes(HAVE_PIPES)
 700
 701 include(gmxTestIsfinite)
 702 gmx_test_isfinite(HAVE_ISFINITE)
 703 gmx_test__isfinite(HAVE__ISFINITE)
 704 gmx_test__finite(HAVE__FINITE)
 705
 706 include(gmxTestXDR)
 707 gmx_test_xdr(GMX_SYSTEM_XDR)
 708 if(NOT GMX_SYSTEM_XDR)
 709     set(GMX_INTERNAL_XDR 1)
 710     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 711 endif(NOT GMX_SYSTEM_XDR)
 712
 713 # include avx test source, used if the AVX flags are set below
 714 include(gmxTestAVXMaskload)
 715
 716 # Process nonbonded accelerated kernels settings
 717 string(TOUPPER ${GMX_CPU_ACCELERATION} ${GMX_CPU_ACCELERATION})
 718 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 719     # nothing to do
 720 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 721
 722     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 723     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 724         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 725     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 726
 727     if (CMAKE_CXX_COMPILER_LOADED)
 728         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 729         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 730             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 731         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 732     endif()
 733
 734     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 735
 736     # Only test the include after we have tried to add the correct flag for SSE2 support
 737     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 738
 739     if(NOT HAVE_EMMINTRIN_H)
 740         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 741     endif(NOT HAVE_EMMINTRIN_H)
 742
 743     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 744     # The user should not be able to set this orthogonally to the acceleration
 745     set(GMX_X86_SSE2 1)
 746     if (NOT ACCELERATION_QUIETLY)
 747       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 748     endif()
 749
 750 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 751
 752     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 753     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 754         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 755     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 756     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 757         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 758         # intrinsics when SSE2 support is enabled, so we try that instead first.
 759         if (GMX_NATIVE_WINDOWS)
 760             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 761             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 762         else()
 763             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 764         endif()
 765     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 766
 767     if (CMAKE_CXX_COMPILER_LOADED)
 768         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 769         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 770             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 771         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 772         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 773             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 774             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 775             # intrinsics when SSE2 support is enabled, so we try that instead.
 776             if (GMX_NATIVE_WINDOWS)
 777                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 778             endif()
 779         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 780     endif()
 781
 782     # This must come after we have added the -msse4.1 flag on some platforms.
 783     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 784
 785     if(NOT HAVE_SMMINTRIN_H)
 786         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 787     endif(NOT HAVE_SMMINTRIN_H)
 788
 789     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 790     # The user should not be able to set this orthogonally to the acceleration
 791     set(GMX_X86_SSE4_1 1)
 792     set(GMX_X86_SSE2   1)
 793     if (NOT ACCELERATION_QUIETLY)
 794       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 795     endif()
 796
 797 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 798
 799     # Set the AVX compiler flag for both these choices!
 800
 801     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 802     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 803         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 804     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 805     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 806         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 807     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 808
 809     if (CMAKE_CXX_COMPILER_LOADED)
 810         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 811         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 812             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 813         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 814         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 815             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 816         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 817     endif()
 818
 819     # Set the FMA4 flags (MSVC doesn't require any)
 820     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 821         if (${CMAKE_COMPILER_ID} MATCHES "Clang")
 822             message(FATAL_ERROR "Clang up to at least version 3.2 produces incorrect code for AVX_128_FMA. Sorry, but you will have to select a different compiler or acceleration.")
 823         endif()
 824         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 825         if (NOT GNU_FMA_CFLAG)
 826             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 827         endif(NOT GNU_FMA_CFLAG)
 828         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 829         # No big deal if we do not have xop, so no point yelling warnings about it.
 830         if (CMAKE_CXX_COMPILER_LOADED)
 831             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 832             if (NOT GNU_FMA_CXXFLAG)
 833                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 834             endif (NOT GNU_FMA_CXXFLAG)
 835             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 836             # No big deal if we do not have xop, so no point yelling warnings about it.
 837         endif()
 838     endif()
 839
 840     # Only test the header after we have tried to add the flag for AVX support
 841     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 842
 843     if(NOT HAVE_IMMINTRIN_H)
 844         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 845     endif(NOT HAVE_IMMINTRIN_H)
 846
 847     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 848         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 849             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 850             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 851         if(NOT TEST_AVX)
 852             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 853         endif()
 854     endif()
 855
 856     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 857     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 858     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 859
 860     # The user should not be able to set this orthogonally to the acceleration
 861     set(GMX_X86_SSE4_1 1)
 862     set(GMX_X86_SSE2   1)
 863
 864     # But just enable one of the choices internally...
 865     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 866         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 867         set(GMX_X86_AVX_128_FMA 1)
 868         if (NOT ACCELERATION_QUIETLY)
 869           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 870         endif()
 871     else()
 872         # If we are not doing AVX_128, it must be AVX_256...
 873         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 874         set(GMX_X86_AVX_256 1)
 875         if (NOT ACCELERATION_QUIETLY)
 876           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 877         endif()
 878     endif()
 879
 880     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 881     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 882     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 883
 884 else(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 885     # Used on BlueGene/Q
 886     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 887         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 888         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 889             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 890             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 891         if(NOT TEST_QPX)
 892             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 893         endif()
 894     endif()
 895     if (CMAKE_CXX_COMPILER_ID MATCHES "XL" AND CMAKE_CXX_COMPILER_LOADED)
 896         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 897         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 898             "cmake/TestQPX.c"
 899             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS")
 900         if(NOT TEST_QPX)
 901             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 902         endif()
 903     endif()
 904
 905     if (TEST_QPX)
 906         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 907         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 908     else()
 909         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 910     endif()
 911
 912 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 913     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 914 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 915 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 916
 917 # Process QM/MM Settings
 918 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 919 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 920     set(GMX_QMMM_GAUSSIAN 1)
 921 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 922     set(GMX_QMMM_MOPAC 1)
 923 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 924     set(GMX_QMMM_GAMESS 1)
 925 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 926     set(GMX_QMMM_ORCA 1)
 927 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 928     # nothing to do
 929 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 930     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 931 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 932
 933 # Process FFT library settings - if not OpenMM build
 934 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 935 set(PKG_FFT "")
 936 set(PKG_FFT_LIBS "")
 937 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 938     if(GMX_DOUBLE)
 939         set(FFTW fftw)
 940     else()
 941         set(FFTW fftwf)
 942     endif()
 943
 944     if(GMX_BUILD_OWN_FFTW)
 945       add_subdirectory(src/contrib/fftw)
 946     else()
 947       find_package(FFTW COMPONENTS ${FFTW})
 948     endif()
 949
 950     string(TOUPPER "${FFTW}" FFTW)
 951     set(PKG_FFT "${${FFTW}_PKG}")
 952     include_directories(${${FFTW}_INCLUDE_DIRS})
 953     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 954     if(NOT ${FFTW}_FOUND)
 955       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 956     endif()
 957
 958     set(GMX_FFT_FFTW3 1)
 959
 960     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 961       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 962     endif()
 963
 964     if(NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND ${FFTW}_HAVE_AVX)
 965         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 966         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 967     endif()
 968
 969 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 970 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 971     find_package(MKL REQUIRED)
 972     include_directories(${MKL_INCLUDE_DIR})
 973     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 974     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 975
 976     set(GMX_FFT_MKL 1)
 977     set(HAVE_MKL 1)
 978
 979 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 980 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 981 #    set(GMX_FFT_ACML 1)
 982 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 983     MESSAGE(STATUS "Using internal FFT library - fftpack")
 984     set(GMX_FFT_FFTPACK 1)
 985 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 986     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 987 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 988
 989 # enable threaded fftw3 if we've found it
 990 if(FFTW3_THREADS OR FFTW3F_THREADS)
 991     add_definitions(-DFFT5D_FFTW_THREADS)
 992 endif()
 993
 994 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 995 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 996 # MKL has BLAS/LAPACK routines
 997 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 998   if(GMX_EXTERNAL_BLAS)
 999     if (GMX_BLAS_USER)
1000         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
1001     else(GMX_BLAS_USER)
1002         set(BLAS_FIND_QUIETLY ON)
1003         find_package(BLAS)
1004         if (BLAS_FOUND)
1005           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
1006         else()
1007           MESSAGE(STATUS "Using internal BLAS library")
1008           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
1009         endif()
1010     endif(GMX_BLAS_USER)
1011   endif(GMX_EXTERNAL_BLAS)
1012   if(GMX_EXTERNAL_LAPACK)
1013     if (GMX_LAPACK_USER)
1014         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
1015     else(GMX_LAPACK_USER)
1016         set(LAPACK_FIND_QUIETLY ON)
1017         find_package(LAPACK)
1018         if (LAPACK_FOUND)
1019           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
1020         else()
1021           MESSAGE(STATUS "Using internal LAPACK library")
1022           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
1023         endif()
1024     endif(GMX_LAPACK_USER)
1025   endif(GMX_EXTERNAL_LAPACK)
1026 endif()
1027 mark_as_advanced(GMX_EXTERNAL_LAPACK)
1028 mark_as_advanced(GMX_EXTERNAL_BLAS)
1029
1030 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1031
1032 if(GMX_LOAD_PLUGINS)
1033   if(CYGWIN OR NOT WIN32)
1034     # Native Windows does not have, nor need dlopen
1035     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1036     include(gmxTestdlopen)
1037     gmx_test_dlopen(HAVE_DLOPEN)
1038   endif()
1039
1040   # so, should we use plug-ins?
1041   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1042     if(NOT VMD_QUIETLY)
1043       MESSAGE(STATUS
1044           "Found the ability to use plug-ins when building shared libaries, "
1045           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1046           "formats).")
1047     endif()
1048     if(NOT GMX_VMD_PLUGIN_PATH)
1049       find_package(VMD)
1050     endif()
1051     set(GMX_USE_PLUGINS ON)
1052     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1053     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1054   else()
1055     set(PKG_DL_LIBS)
1056   endif()
1057 endif(GMX_LOAD_PLUGINS)
1058 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1059
1060 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1061     if(NOT CMAKE_CROSSCOMPILING)
1062         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1063     else()
1064         message(STATUS "Building the man pages is not available when "
1065             "cross-compiling the developer version from git")
1066     endif()
1067 else()
1068     #make sure source package contains all man pages
1069     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1070         message(FATAL_ERROR "Man pages are missing from source package.")
1071     endif()
1072 endif()
1073 mark_as_advanced(GMX_BUILD_MANPAGES)
1074
1075 # Math and thread libraries must often come after all others when linking...
1076 if(HAVE_LIBM)
1077     list(APPEND GMX_EXTRA_LIBRARIES m)
1078 endif(HAVE_LIBM)
1079
1080 if(GMX_FAHCORE)
1081   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1082       "Path to swindirect.h")
1083   include_directories(${COREWRAP_INCLUDE_DIR})
1084   set_property(CACHE GMX_COOL_QUOTES VALUE OFF)
1085 endif(GMX_FAHCORE)
1086
1087 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1088 # these are set after everything else
1089 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1090     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_C_FLAGS}")
1091     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_CXX_FLAGS}")
1092     set(CMAKE_EXE_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1093     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1094 else()
1095     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1096     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CFLAGS}")
1097     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1098     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1099     if(CMAKE_CXX_COMPILER_LOADED)
1100         message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CXXFLAGS}")
1101         message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1102         message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1103     endif()
1104     message("CMAKE_EXE_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1105     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1106 endif()
1107
1108 if(NOT GMX_OPENMP)
1109     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1110     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1111     unset(OpenMP_C_FLAGS CACHE)
1112     unset(OpenMP_CXX_FLAGS CACHE)
1113     unset(OpenMP_LINKER_FLAGS CACHE)
1114     unset(OpenMP_SHARED_LINKER_FLAGS)
1115 endif()
1116 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1117
1118 ######################################
1119 # Output compiler and CFLAGS used
1120 ######################################
1121 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1122 if (CMAKE_CXX_COMPILER_LOADED)
1123     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1124 endif ()
1125
1126 ########################################################################
1127 # Specify install locations and which subdirectories to process        #
1128 ########################################################################
1129 if (GMX_USE_RELATIVE_INSTALL_PATH)
1130     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1131     mark_as_advanced(GMX_INSTALL_PREFIX)
1132 else()
1133     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1134 endif()
1135
1136 if ( NOT DEFINED GMXLIB )
1137     set(GMXLIB lib)
1138 endif()
1139 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1140 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1141 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1142 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1143 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1144
1145 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1146
1147 ##################################################################
1148 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1149 ##################################################################
1150 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1151     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1152     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1153     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1154     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1155 endif()
1156
1157 #COPYING file: Only necessary for binary distributions.
1158 #Simpler to always install.
1159 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1160
1161 add_subdirectory(share)
1162 add_subdirectory(include)
1163 add_subdirectory(src)
1164 add_subdirectory(scripts)
1165
1166 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1167 # Don't bother the user after the first configure pass.
1168 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1169     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1170     unset(CUDA_NOTFOUND_AUTO)
1171     unset(CUDA_NOTFOUND_MESSAGE)
1172 endif()
1173 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1174
1175 #######################
1176 ## uninstall target
1177 #######################
1178     CONFIGURE_FILE(
1179                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1180                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1181                    IMMEDIATE @ONLY)
1182 ###########################
1183 ADD_CUSTOM_TARGET(uninstall
1184                   "${CMAKE_COMMAND}" -P
1185                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1186 ###########################
1187
1188 ########################################################################
1189 # Tests                                                                #
1190 ########################################################################
1191
1192 include(CTest)
1193 mark_as_advanced(BUILD_TESTING)
1194 IF(BUILD_TESTING)
1195         enable_testing()
1196         add_subdirectory(tests)
1197 ENDIF()
1198