CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  56 # defined.
  57 set(PROJECT_VERSION "5.0-rc1-dev")
  58 # If this is a released tarball, "-dev" will not be present in
  59 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  60 # number of the regressiontest tarball against which the code tarball
  61 # can be tested. This will be the version of the last patch release.
  62 set(REGRESSIONTEST_VERSION "5.0-rc1")
  63 # If this is not a released tarball, "-dev" will be present in
  64 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  65 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  66 # code contains all recent fixes from the corresponding code branch.
  67 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  68
  69 set(CUSTOM_VERSION_STRING ""
  70     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  71 mark_as_advanced(CUSTOM_VERSION_STRING)
  72 if (CUSTOM_VERSION_STRING)
  73     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  74 endif()
  75 set(LIBRARY_SOVERSION 0)
  76 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  77 # It is a bit irritating, but this has to be set separately for now!
  78 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  79 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  80 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  81
  82 # The numerical gromacs version. It is 40600 for 4.6.0.
  83 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  84 math(EXPR NUM_VERSION
  85     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  86 if(CPACK_PACKAGE_VERSION_PATCH)
  87     math(EXPR NUM_VERSION
  88          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  89 endif()
  90
  91 # The API version tracks the numerical Gromacs version (for now).
  92 # It is potentially different from the Gromacs version in the future, if
  93 # the programs/libraries diverge from the presumably more stable API.
  94 # The #define GMX_API_VERSION in version.h is set to this value to
  95 # provide backward compatibility of software written against the Gromacs API.
  96 set(API_VERSION ${NUM_VERSION})
  97
  98 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  99     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 100 endif()
 101
 102 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 103 mark_as_advanced(GMX_INSTALL_PREFIX)
 104
 105 include(gmxBuildTypeReference)
 106 include(gmxBuildTypeTSAN)
 107 include(gmxBuildTypeASAN)
 108 include(gmxBuildTypeReleaseWithAssert)
 109
 110 if(NOT CMAKE_BUILD_TYPE)
 111     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 112     # There's no need to offer a user the choice of ThreadSanitizer
 113     # Set the possible values of build type for cmake-gui
 114     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 115         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 116 endif()
 117 if(CMAKE_CONFIGURATION_TYPES)
 118     # Add appropriate GROMACS-specific build types for the Visual
 119     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 120     # are already present by default).
 121     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 122     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 123     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 124         "List of configuration types"
 125         FORCE)
 126 endif()
 127 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 128
 129 enable_language(C)
 130 enable_language(CXX)
 131
 132 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 133 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 134 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 135 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 136 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 137 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 138 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 139 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 140 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 141 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 142 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 143
 144 #must come after all cpack settings!
 145 include(CPack)
 146
 147 # Set a default valgrind suppression file.
 148 # This unfortunately needs to duplicate information from CTest to work as
 149 # expected...
 150 set(MEMORYCHECK_SUPPRESSIONS_FILE
 151     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 152     CACHE FILEPATH
 153     "File that contains suppressions for the memory checker")
 154 include(CTest)
 155
 156 set(SOURCE_IS_GIT_REPOSITORY OFF)
 157 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 158 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 159     set(SOURCE_IS_GIT_REPOSITORY ON)
 160 endif()
 161 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 162     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 163 endif()
 164
 165 ########################################################################
 166 # Check and warn if cache generated on a different host is being reused
 167 ########################################################################
 168 if(CMAKE_HOST_UNIX)
 169     execute_process(COMMAND hostname
 170                     OUTPUT_VARIABLE TMP_HOSTNAME
 171                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 172     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 173         message(WARNING "
 174             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 175             is being reused! This could lead to inconsitencies; therefore, it is
 176             recommended to regenerate the cache!")
 177     endif()
 178     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 179             "Hostname of the machine where the cache was generated.")
 180 endif()
 181
 182 ########################################################################
 183 # User input options                                                   #
 184 ########################################################################
 185 include(gmxOptionUtilities)
 186
 187 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 188
 189 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 190 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 191 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 192 gmx_dependent_option(
 193     GMX_MPI_IN_PLACE
 194     "Enable MPI_IN_PLACE for MPIs that have it defined"
 195     ON
 196     GMX_MPI)
 197 mark_as_advanced(GMX_MPI_IN_PLACE)
 198 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 199 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 200 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 201 mark_as_advanced(GMX_FAHCORE)
 202
 203 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 204 mark_as_advanced(GMX_COOL_QUOTES)
 205 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 206
 207 # decide on GPU settings based on user-settings and GPU/CUDA detection
 208 include(gmxManageGPU)
 209
 210 # Detect the architecture the compiler is targetting, detect
 211 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 212 # to use if none is specified, and populate the cache option for CPU
 213 # SIMD.
 214 include(gmxDetectTargetArchitecture)
 215 gmx_detect_target_architecture()
 216
 217 if(GMX_CPU_ACCELERATION)
 218     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 219     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 220     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 221     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 222 endif()
 223
 224 if(NOT GMX_TARGET_MIC)
 225     include(gmxDetectSimd)
 226     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 227 else()
 228     set(GMX_SUGGESTED_SIMD "None")
 229 endif()
 230
 231 gmx_option_multichoice(
 232     GMX_SIMD
 233     "SIMD instruction set for CPU kernels and compiler optimization"
 234     "${GMX_SUGGESTED_SIMD}"
 235     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 236
 237 gmx_option_multichoice(
 238     GMX_FFT_LIBRARY
 239     "FFT library"
 240     "fftw3"
 241     fftw3 mkl "fftpack[built-in]")
 242 gmx_dependent_option(
 243     GMX_BUILD_OWN_FFTW
 244     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 245     OFF
 246     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 247 gmx_dependent_option(
 248     GMX_DISABLE_FFTW_MEASURE
 249     "Do not optimize FFTW setups (not needed with SSE)"
 250     OFF
 251     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 252 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 253 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 254
 255 gmx_option_multichoice(
 256     GMX_QMMM_PROGRAM
 257     "QM package for QM/MM"
 258     None
 259     none gaussian mopac gamess orca)
 260
 261 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 262 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 263
 264 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 265
 266 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 267 mark_as_advanced(GMX_BROKEN_CALLOC)
 268 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 269 mark_as_advanced(GMX_LOAD_PLUGINS)
 270
 271 option(GMX_GPU  "Enable GPU acceleration" ON)
 272 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 273
 274 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 275
 276 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 277 mark_as_advanced(GMX_GIT_VERSION_INFO)
 278
 279 if(UNIX)
 280     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 281 endif()
 282 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 283
 284 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 285 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 286
 287 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 288 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 289
 290 option(GMX_BUILD_FOR_COVERAGE
 291        "Tune build for better code coverage metrics (e.g., disable asserts)"
 292        OFF)
 293 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 294
 295
 296 ######################################################################
 297 # Detect OpenMP support
 298 ######################################################################
 299 # The OpenMP detection _must_ come before tests for other CFLAGS.
 300 include(gmxManageOpenMP)
 301
 302
 303
 304 ######################################################################
 305 # Compiler tests
 306 # These need to be done early (before further tests).
 307 #####################################################################
 308
 309 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 310 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 311 # invalid options with the Intel Compilers.
 312 # These files should be removed from the source tree when a CMake version that
 313 # includes the features in question becomes required for building GROMACS.
 314 include(CheckCCompilerFlag)
 315 include(CheckCXXCompilerFlag)
 316
 317
 318 include(gmxCFlags)
 319 gmx_c_flags()
 320
 321 # This variable should be used for additional compiler flags which are not
 322 # generated in gmxCFlags nor are SIMD or MPI related.
 323 set(EXTRA_C_FLAGS "")
 324 set(EXTRA_CXX_FLAGS "")
 325
 326 # Run through a number of tests for buggy compilers and other issues
 327 include(gmxTestCompilerProblems)
 328 gmx_test_compiler_problems()
 329 # GMX_SIMD will not be set automatically until the second
 330 # pass (which is not strictly guaranteed to occur), so putting this
 331 # check here among logically-related tests is inefficient, but the
 332 # potential loss is likely zero.
 333 if(GMX_SIMD STREQUAL "AVX_256"
 334         AND CMAKE_COMPILER_IS_GNUCC
 335         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 336             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 337     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 338     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 339 endif()
 340
 341
 342
 343 set(PKG_CFLAGS "")
 344 if(GMX_DOUBLE)
 345     add_definitions(-DGMX_DOUBLE)
 346     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 347 endif()
 348 if(GMX_SOFTWARE_INVSQRT)
 349   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 350 endif()
 351
 352 if(WIN32 AND NOT CYGWIN)
 353     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 354     mark_as_advanced(GMX_WSOCKLIB_PATH)
 355     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 356     if(WSOCK32_LIBRARY)
 357         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 358         add_definitions(-DGMX_HAVE_WINSOCK)
 359     else()
 360         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 361     endif(WSOCK32_LIBRARY)
 362 endif()
 363
 364
 365
 366 ########################################################################
 367 # Basic system tests (standard libraries, headers, functions, types)   #
 368 ########################################################################
 369 include(CheckIncludeFiles)
 370 include(CheckIncludeFileCXX)
 371 check_include_files(unistd.h     HAVE_UNISTD_H)
 372 check_include_files(pwd.h        HAVE_PWD_H)
 373 check_include_files(dirent.h     HAVE_DIRENT_H)
 374 check_include_files(time.h       HAVE_TIME_H)
 375 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 376 check_include_files(io.h         HAVE_IO_H)
 377 check_include_files(sched.h      HAVE_SCHED_H)
 378
 379 check_include_files(regex.h      HAVE_POSIX_REGEX)
 380 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 381 # TODO: It could be nice to inform the user if no regex support is found,
 382 # as selections won't be fully functional.
 383
 384 include(CheckFunctionExists)
 385 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 386 check_function_exists(memalign          HAVE_MEMALIGN)
 387 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 388 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 389 check_function_exists(fsync             HAVE_FSYNC)
 390 check_function_exists(_fileno           HAVE__FILENO)
 391 check_function_exists(fileno            HAVE_FILENO)
 392 check_function_exists(_commit           HAVE__COMMIT)
 393 check_function_exists(sigaction         HAVE_SIGACTION)
 394 check_function_exists(sysconf           HAVE_SYSCONF)
 395 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 396 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 397 check_function_exists(rsqrt             HAVE_RSQRT)
 398 check_function_exists(rsqrtf            HAVE_RSQRTF)
 399 check_function_exists(sqrtf             HAVE_SQRTF)
 400
 401 include(CheckLibraryExists)
 402 check_library_exists(m sqrt "" HAVE_LIBM)
 403 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 404
 405 include(TestBigEndian)
 406 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 407
 408 # Management of GROMACS options for specific toolchains should go
 409 # here. Because the initial settings for some of the main options have
 410 # already happened, but things like library detection and MPI compiler
 411 # feature detection have not, the docstrings for any over-rides of
 412 # GROMACS defaults or user settings will make sense. Also, any
 413 # toolchain-related reasons for choosing whether to detect various
 414 # things can be sorted out now, before the detection takes place.
 415 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 416     include(gmxManageBlueGene)
 417 endif()
 418
 419 ########################################################################
 420 #Process MPI settings
 421 ########################################################################
 422 include(gmxManageMPI)
 423
 424
 425 ########################################################################
 426 #Process shared/static library settings
 427 ########################################################################
 428 include(gmxManageSharedLibraries)
 429
 430
 431 ########################################################################
 432 # Find external packages                                               #
 433 ########################################################################
 434
 435 # Unconditionally find the package, as it is also required for unit
 436 # tests. This exports LIBXML2_FOUND, which we should not use because
 437 # it does not tell us that linking will succeed. Instead, we test that
 438 # next.
 439 find_package(LibXml2)
 440 include(gmxTestLibXml2)
 441 gmx_test_libxml2(HAVE_LIBXML2)
 442 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 443 set(PKG_XML "")
 444 mark_as_advanced(GMX_XML)
 445 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 446 #if(GMX_XML AND NOT HAVE_LIBXML2)
 447 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 448 #endif()
 449 #if(GMX_XML)
 450 #    include_directories(${LIBXML2_INCLUDE_DIR})
 451 #    set(PKG_XML libxml-2.0)
 452 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 453 #endif()
 454
 455 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 456 mark_as_advanced(GMX_EXTRAE)
 457
 458 if (GMX_EXTRAE)
 459   find_package(EXTRAE)
 460   if(EXTRAE_FOUND)
 461     include_directories(${EXTRAE_INCLUDE_DIR})
 462     set(HAVE_EXTRAE 1)
 463   else()
 464     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 465   endif()
 466 endif()
 467
 468 option(GMX_X11 "Use X window system" OFF)
 469 if (GMX_X11)
 470     find_package(X11)
 471     # X11 includes/libraries are only set in the ngmx subdirectory!
 472     if(NOT X11_FOUND)
 473         message(FATAL_ERROR
 474                 "X11 include files and/or libraries were not found. "
 475                 "Set GMX_X11=OFF to compile without X11 support. "
 476                 "gmx view will not be available.")
 477     endif()
 478     include_directories(${X11_INCLUDE_DIR})
 479 endif()
 480
 481 include(ThreadMPI)
 482 # Enable core threading facilities
 483 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 484 # Enable tMPI C++ support
 485 tmpi_enable_cxx()
 486 if(GMX_THREAD_MPI)
 487     # enable MPI functions
 488     tmpi_enable()
 489     set(GMX_MPI 1)
 490     set(MPI_IN_PLACE_EXISTS 1)
 491 endif()
 492 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 493 if (TMPI_ATOMICS_DISABLED)
 494    add_definitions(-DTMPI_ATOMICS_DISABLED)
 495 endif()
 496
 497 if(GMX_GPU)
 498     # now that we have detected the dependencies, do the second configure pass
 499     gmx_gpu_setup()
 500 endif()
 501
 502 if(CYGWIN)
 503     set(GMX_CYGWIN 1)
 504 endif()
 505
 506 if(WIN32 AND NOT CYGWIN)
 507     set(GMX_NATIVE_WINDOWS 1)
 508     # This makes windows.h not declare min/max as macros that would break
 509     # C++ code using std::min/std::max.
 510     add_definitions(-DNOMINMAX)
 511 endif()
 512
 513 # only bother with finding git and using version.h if the source is a git repo
 514 if(GMX_GIT_VERSION_INFO)
 515     if (NOT SOURCE_IS_GIT_REPOSITORY)
 516         message(FATAL_ERROR
 517             "Cannot generate git version information from source tree not under git. "
 518             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 519     endif()
 520     # We need at least git v1.5.3 be able to parse git's date output. If not
 521     # found or the version is too small, we can't generate version information.
 522     find_package(Git)
 523
 524     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 525         message(FATAL_ERROR
 526             "No compatible git version found (>= 1.5.3 required). "
 527             "Won't be able to generate development version information. "
 528             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 529     endif()
 530 endif()
 531
 532 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 533 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 534 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 535     find_package(Boost 1.44.0)
 536     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 537         set(Boost_FOUND FALSE)
 538     endif()
 539     # Print the notification only on first run, when determining the default
 540     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 541         message("Boost >= 1.44 not found. Using minimal internal version. "
 542                 "This may cause trouble if you plan on compiling/linking other "
 543                 "software that uses Boost against Gromacs.")
 544     endif()
 545 endif()
 546 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 547        ${Boost_FOUND})
 548 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 549     message(FATAL_ERROR
 550         "Boost >= 1.44 not found. "
 551         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 552         "version of Boost included with Gromacs.")
 553 endif()
 554
 555 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 556 mark_as_advanced(GMX_BUILD_UNITTESTS)
 557 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 558 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 559     message(FATAL_ERROR
 560         "Cannot build unit tests without libxml2. "
 561         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 562 endif()
 563
 564 ########################################################################
 565 # Generate development version info for cache
 566 ########################################################################
 567 # set(GEN_VERSION_INFO_INTERNAL "ON")
 568 # include(gmxGenerateVersionString)
 569
 570 ########################################################################
 571 # Our own GROMACS tests
 572 ########################################################################
 573
 574 add_definitions( -DHAVE_CONFIG_H )
 575 include_directories(${CMAKE_SOURCE_DIR}/src)
 576 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 577 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 578 include_directories(${CMAKE_BINARY_DIR}/src)
 579 # Required for gmx_header_config_gen.h to be found before installation
 580 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 581 # Required for now to make old code compile
 582 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 583
 584 include(gmxTestInlineASM)
 585 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 586
 587 include(gmxSetBuildInformation)
 588 gmx_set_build_information()
 589 # Turn on RDTSCP if:
 590 # - the build system's CPU supports it
 591 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 592 #   at this point means that the user set it).
 593 # Note: it's better to not use the later set value of GMX_SIMD because
 594 # it reflects the system's capability of both compiling and running AVX code.
 595 # TODO: After merge with 5.0 one could implement a cache variable dependency
 596 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 597 # after the first cmake pass.
 598 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 599     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 600 else()
 601     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 602 endif()
 603 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 604 mark_as_advanced(GMX_USE_RDTSCP)
 605 if(GMX_USE_RDTSCP)
 606     set(HAVE_RDTSCP 1)
 607 endif()
 608
 609 include(gmxTestFloatFormat)
 610 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 611                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 612                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 613
 614 include(gmxTestLargeFiles)
 615 gmx_test_large_files(GMX_LARGEFILES)
 616
 617 include(gmxTestSignal)
 618 gmx_test_sigusr1(HAVE_SIGUSR1)
 619
 620 include(gmxTestPipes)
 621 gmx_test_pipes(HAVE_PIPES)
 622
 623 include(gmxTestIsfinite)
 624 gmx_test_isfinite(HAVE_ISFINITE)
 625 gmx_test__isfinite(HAVE__ISFINITE)
 626 gmx_test__finite(HAVE__FINITE)
 627
 628 include(gmxTestCXX11)
 629 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 630 include(CMakeDependentOption)
 631 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 632 # entirely to keep the compilation environment uniform.
 633 cmake_dependent_option(GMX_CXX11
 634     "Use C++11 features"
 635     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 636 mark_as_advanced(GMX_CXX11)
 637 if(GMX_CXX11)
 638     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 639 endif()
 640
 641
 642 include(gmxTestXDR)
 643 gmx_test_xdr(GMX_SYSTEM_XDR)
 644 if(NOT GMX_SYSTEM_XDR)
 645     set(GMX_INTERNAL_XDR 1)
 646 endif()
 647
 648
 649 ##################################################
 650 # Process SIMD instruction settings
 651 ##################################################
 652 # This checks what flags to add in order to
 653 # support the SIMD instructions we need, and sets
 654 # correct defines for the SIMD instructions supported.
 655 include(gmxTestSimd)
 656 gmx_test_simd()
 657
 658
 659 # Process QM/MM Settings
 660 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 661     set(GMX_QMMM_GAUSSIAN 1)
 662 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 663     set(GMX_QMMM_MOPAC 1)
 664 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 665     set(GMX_QMMM_GAMESS 1)
 666 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 667     set(GMX_QMMM_ORCA 1)
 668 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 669     # nothing to do
 670 else()
 671     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 672 endif()
 673
 674
 675 ##################################################
 676 # Process FFT library settings
 677 ##################################################
 678 include(gmxManageFFTLibraries)
 679
 680
 681 include(gmxManageLinearAlgebraLibraries)
 682
 683 # Whether GROMACS will really try to compile support for VMD plugins
 684 set(GMX_USE_PLUGINS OFF)
 685
 686 if(GMX_LOAD_PLUGINS)
 687   if(CYGWIN OR NOT WIN32)
 688     # Native Windows does not have, nor need dlopen
 689     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 690     include(gmxTestdlopen)
 691     gmx_test_dlopen(HAVE_DLOPEN)
 692   endif()
 693
 694   # so, should we use plug-ins?
 695   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 696     if(NOT VMD_QUIETLY)
 697       MESSAGE(STATUS
 698           "Found the ability to use plug-ins when building shared libaries, "
 699           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 700           "formats).")
 701     endif()
 702     if(NOT GMX_VMD_PLUGIN_PATH)
 703       find_package(VMD)
 704     endif()
 705     set(GMX_USE_PLUGINS ON)
 706     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 707     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 708   else()
 709     set(PKG_DL_LIBS)
 710   endif()
 711 endif()
 712 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 713
 714 # Link real-time library for POSIX timers. The check for clock_gettime
 715 # confirms the linkability of rt.
 716 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 717     list(APPEND GMX_EXTRA_LIBRARIES rt)
 718 endif()
 719
 720 # Math and thread libraries must often come after all others when linking...
 721 if(HAVE_LIBM)
 722     list(APPEND GMX_EXTRA_LIBRARIES m)
 723 endif()
 724
 725 option(GMX_NACL "Configure for Native Client builds" OFF)
 726 if (GMX_NACL)
 727   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 728   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 729   set(GMX_NO_NICE 1)
 730   set(GMX_NO_RENAME 1)
 731 endif()
 732 mark_as_advanced(GMX_NACL)
 733
 734 if(GMX_FAHCORE)
 735   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 736       "Path to swindirect.h")
 737   include_directories(${COREWRAP_INCLUDE_DIR})
 738 endif()
 739
 740 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 741 mark_as_advanced(GMX_BUILD_HELP)
 742 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 743     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 744
 745     message(FATAL_ERROR
 746         "Rebuilding HTML and man pages is not supported for in-source "
 747         "builds from a source distribution. "
 748         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 749 endif()
 750
 751 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 752 # these are set after everything else
 753 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 754     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 755     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 756     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 757     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 758 else()
 759     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 760     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 761     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 762     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 763     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 764     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 765     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 766     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 767     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 768 endif()
 769
 770 if(NOT GMX_OPENMP)
 771     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 772     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 773     unset(OpenMP_C_FLAGS CACHE)
 774     unset(OpenMP_CXX_FLAGS CACHE)
 775 else()
 776     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 777     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 778 endif()
 779 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 780
 781 ########################################################################
 782 # Specify install locations
 783 ########################################################################
 784 # Use GNUInstallDirst to set paths on multiarch systems
 785 include(GNUInstallDirs)
 786
 787 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 788     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 789 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 790     "Data installation directory under share/ (default: gromacs)")
 791 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 792
 793 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 794 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 795 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 796 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 797 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 798
 799 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 800 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 801
 802 # Binary and library suffix options
 803 include(gmxManageSuffixes)
 804
 805 ################################################################
 806 # Shared library settings
 807 ################################################################
 808 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (CMAKE_VERSION VERSION_GREATER 2.8.11)))
 809     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 810         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 811     endif()
 812     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 813         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 814     else()
 815         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 816     endif()
 817     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 818     set(CMAKE_MACOSX_RPATH 1)
 819 else()
 820     # We are on Darwin/OSX, and cmake cannot handle proper RPATHs
 821     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 822         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 823         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 824     else()
 825         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 826     endif()
 827 endif()
 828
 829 #COPYING file: Only necessary for binary distributions.
 830 #Simpler to always install.
 831 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 832
 833 if(GMX_EXTERNAL_BOOST)
 834     include_directories(${Boost_INCLUDE_DIRS})
 835     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 836 else()
 837     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 838     # typeid not supported for minimal internal version
 839     # (would add significant amount of code)
 840     add_definitions(-DBOOST_NO_TYPEID)
 841     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 842     # (from share/template/)
 843     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 844     if (NOT GMX_BUILD_MDRUN_ONLY)
 845         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 846                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 847                 COMPONENT development)
 848     endif()
 849 endif()
 850
 851 if(GMX_USE_TNG)
 852     find_package(ZLIB QUIET)
 853     include(gmxTestZLib)
 854     gmx_test_zlib(HAVE_ZLIB)
 855     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 856     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 857     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 858     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 859     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 860     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 861     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 862     set(GMX_TNG_LIBRARIES tng_io)
 863 endif()
 864 mark_as_advanced(TNG_BUILD_FORTRAN)
 865 mark_as_advanced(TNG_BUILD_EXAMPLES)
 866 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 867 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 868 mark_as_advanced(TNG_BUILD_TEST)
 869 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 870
 871 if (GMX_BUILD_FOR_COVERAGE)
 872     # Code heavy with asserts makes conditional coverage close to useless metric,
 873     # as by design most of the false branches are impossible to trigger in
 874     # correctly functioning code.  And the benefit of testing those that could
 875     # be triggered by using an API against its specification isn't usually
 876     # worth the effort.
 877     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 878 endif()
 879
 880 if (BUILD_TESTING)
 881     # "tests" target builds all the separate test binaries.
 882     add_custom_target(tests)
 883     # "run-ctest" is an internal target that actually runs the tests.
 884     # This is necessary to be able to add separate targets that execute as part
 885     # of 'make check', but are ensured to be executed after the actual tests.
 886     add_custom_target(run-ctest
 887                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 888                       COMMENT "Running all tests"
 889                       VERBATIM)
 890     add_dependencies(run-ctest tests)
 891     # "check" target builds and runs all tests.
 892     add_custom_target(check DEPENDS run-ctest)
 893 endif()
 894
 895 if (NOT GMX_BUILD_MDRUN_ONLY)
 896     add_subdirectory(doxygen)
 897     add_subdirectory(share)
 898     add_subdirectory(scripts)
 899 endif()
 900 add_subdirectory(src)
 901
 902 if (BUILD_TESTING)
 903     add_subdirectory(tests)
 904 endif()
 905
 906 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 907 # Don't bother the user after the first configure pass.
 908 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 909     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 910 endif()
 911 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 912
 913 #######################
 914 ## uninstall target
 915 #######################
 916 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 917                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 918                   IMMEDIATE @ONLY)
 919 ###########################
 920 ADD_CUSTOM_TARGET(uninstall
 921                   "${CMAKE_COMMAND}" -P
 922                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 923 ###########################
 924 set_directory_properties(PROPERTIES
 925             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 926
 927 ########################################################################
 928 # Manual                                                               #
 929 ########################################################################
 930
 931 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 932 mark_as_advanced(GMX_BUILD_MANUAL)
 933 if(GMX_BUILD_MANUAL)
 934     # Make sure we only do detection of manual-building dependencies
 935     # when the user opted in for that.
 936     add_subdirectory(manual)
 937 endif()